meson.build

   1 project('qemu', ['c'], meson_version: '>=0.59.3',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto',
   3                           'b_staticpic=false', 'stdsplit=false', 'optimization=2', 'b_pie=true'],
   4         version: files('VERSION'))
   5
   6 add_test_setup('quick', exclude_suites: ['slow', 'thorough'], is_default: true)
   7 add_test_setup('slow', exclude_suites: ['thorough'], env: ['G_TEST_SLOW=1', 'SPEED=slow'])
   8 add_test_setup('thorough', env: ['G_TEST_SLOW=1', 'SPEED=thorough'])
   9
  10 not_found = dependency('', required: false)
  11 keyval = import('keyval')
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Allow both shared and static libraries unless --enable-static
  22 static_kwargs = enable_static ? {'static': true} : {}
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 config_host_data = configuration_data()
  44 genh = []
  45 qapi_trace_events = []
  46
  47 bsd_oses = ['gnu/kfreebsd', 'freebsd', 'netbsd', 'openbsd', 'dragonfly', 'darwin']
  48 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  49 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv', 'x86', 'x86_64',
  50   'arm', 'aarch64', 'loongarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  51
  52 cpu = host_machine.cpu_family()
  53
  54 # Unify riscv* to a single family.
  55 if cpu in ['riscv32', 'riscv64']
  56   cpu = 'riscv'
  57 endif
  58
  59 targetos = host_machine.system()
  60
  61 target_dirs = config_host['TARGET_DIRS'].split()
  62 have_linux_user = false
  63 have_bsd_user = false
  64 have_system = false
  65 foreach target : target_dirs
  66   have_linux_user = have_linux_user or target.endswith('linux-user')
  67   have_bsd_user = have_bsd_user or target.endswith('bsd-user')
  68   have_system = have_system or target.endswith('-softmmu')
  69 endforeach
  70 have_user = have_linux_user or have_bsd_user
  71 have_tools = get_option('tools') \
  72   .disable_auto_if(not have_system) \
  73   .allowed()
  74 have_ga = get_option('guest_agent') \
  75   .disable_auto_if(not have_system and not have_tools) \
  76   .require(targetos in ['sunos', 'linux', 'windows'],
  77            error_message: 'unsupported OS for QEMU guest agent') \
  78   .allowed()
  79 have_block = have_system or have_tools
  80
  81 python = import('python').find_installation()
  82
  83 if cpu not in supported_cpus
  84   host_arch = 'unknown'
  85 elif cpu == 'x86'
  86   host_arch = 'i386'
  87 elif cpu == 'mips64'
  88   host_arch = 'mips'
  89 else
  90   host_arch = cpu
  91 endif
  92
  93 if cpu in ['x86', 'x86_64']
  94   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  95 elif cpu == 'aarch64'
  96   kvm_targets = ['aarch64-softmmu']
  97 elif cpu == 's390x'
  98   kvm_targets = ['s390x-softmmu']
  99 elif cpu in ['ppc', 'ppc64']
 100   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
 101 elif cpu in ['mips', 'mips64']
 102   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
 103 elif cpu in ['riscv']
 104   kvm_targets = ['riscv32-softmmu', 'riscv64-softmmu']
 105 else
 106   kvm_targets = []
 107 endif
 108
 109 kvm_targets_c = '""'
 110 if get_option('kvm').allowed() and targetos == 'linux'
 111   kvm_targets_c = '"' + '" ,"'.join(kvm_targets) + '"'
 112 endif
 113 config_host_data.set('CONFIG_KVM_TARGETS', kvm_targets_c)
 114
 115 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
 116
 117 if cpu in ['aarch64']
 118   accelerator_targets += {
 119     'CONFIG_HVF': ['aarch64-softmmu']
 120   }
 121 endif
 122
 123 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
 124   # i386 emulator provides xenpv machine type for multiple architectures
 125   accelerator_targets += {
 126     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
 127   }
 128 endif
 129 if cpu in ['x86', 'x86_64']
 130   accelerator_targets += {
 131     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
 132     'CONFIG_HVF': ['x86_64-softmmu'],
 133     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
 134     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
 135   }
 136 endif
 137
 138 modular_tcg = []
 139 # Darwin does not support references to thread-local variables in modules
 140 if targetos != 'darwin'
 141   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
 142 endif
 143
 144 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
 145 unpack_edk2_blobs = false
 146 foreach target : edk2_targets
 147   if target in target_dirs
 148     bzip2 = find_program('bzip2', required: get_option('install_blobs'))
 149     unpack_edk2_blobs = bzip2.found()
 150     break
 151   endif
 152 endforeach
 153
 154 dtrace = not_found
 155 stap = not_found
 156 if 'dtrace' in get_option('trace_backends')
 157   dtrace = find_program('dtrace', required: true)
 158   stap = find_program('stap', required: false)
 159   if stap.found()
 160     # Workaround to avoid dtrace(1) producing a file with 'hidden' symbol
 161     # visibility. Define STAP_SDT_V2 to produce 'default' symbol visibility
 162     # instead. QEMU --enable-modules depends on this because the SystemTap
 163     # semaphores are linked into the main binary and not the module's shared
 164     # object.
 165     add_global_arguments('-DSTAP_SDT_V2',
 166                          native: false, language: ['c', 'cpp', 'objc'])
 167   endif
 168 endif
 169
 170 if get_option('iasl') == ''
 171   iasl = find_program('iasl', required: false)
 172 else
 173   iasl = find_program(get_option('iasl'), required: true)
 174 endif
 175
 176 ##################
 177 # Compiler flags #
 178 ##################
 179
 180 qemu_cflags = config_host['QEMU_CFLAGS'].split()
 181 qemu_cxxflags = config_host['QEMU_CXXFLAGS'].split()
 182 qemu_objcflags = config_host['QEMU_OBJCFLAGS'].split()
 183 qemu_ldflags = config_host['QEMU_LDFLAGS'].split()
 184
 185 if targetos == 'windows'
 186   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--no-seh', '-Wl,--nxcompat')
 187   # Disable ASLR for debug builds to allow debugging with gdb
 188   if get_option('optimization') == '0'
 189     qemu_ldflags += cc.get_supported_link_arguments('-Wl,--dynamicbase')
 190   endif
 191 endif
 192
 193 if get_option('gprof')
 194   qemu_cflags += ['-p']
 195   qemu_cxxflags += ['-p']
 196   qemu_objcflags += ['-p']
 197   qemu_ldflags += ['-p']
 198 endif
 199
 200 # Specify linker-script with add_project_link_arguments so that it is not placed
 201 # within a linker --start-group/--end-group pair
 202 if get_option('fuzzing')
 203   add_project_link_arguments(['-Wl,-T,',
 204                               (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 205                              native: false, language: ['c', 'cpp', 'objc'])
 206
 207   # Specify a filter to only instrument code that is directly related to
 208   # virtual-devices.
 209   configure_file(output: 'instrumentation-filter',
 210                  input: 'scripts/oss-fuzz/instrumentation-filter-template',
 211                  copy: true)
 212
 213   if cc.compiles('int main () { return 0; }',
 214                   name: '-fsanitize-coverage-allowlist=/dev/null',
 215                  args: ['-fsanitize-coverage-allowlist=/dev/null'] )
 216     add_global_arguments('-fsanitize-coverage-allowlist=instrumentation-filter',
 217                          native: false, language: ['c', 'cpp', 'objc'])
 218   endif
 219
 220   if get_option('fuzzing_engine') == ''
 221     # Add CFLAGS to tell clang to add fuzzer-related instrumentation to all the
 222     # compiled code.  To build non-fuzzer binaries with --enable-fuzzing, link
 223     # everything with fsanitize=fuzzer-no-link. Otherwise, the linker will be
 224     # unable to bind the fuzzer-related callbacks added by instrumentation.
 225     add_global_arguments('-fsanitize=fuzzer-no-link',
 226                          native: false, language: ['c', 'cpp', 'objc'])
 227     add_global_link_arguments('-fsanitize=fuzzer-no-link',
 228                               native: false, language: ['c', 'cpp', 'objc'])
 229     # For the actual fuzzer binaries, we need to link against the libfuzzer
 230     # library. They need to be configurable, to support OSS-Fuzz
 231     fuzz_exe_ldflags = ['-fsanitize=fuzzer']
 232   else
 233     # LIB_FUZZING_ENGINE was set; assume we are running on OSS-Fuzz, and
 234     # the needed CFLAGS have already been provided
 235     fuzz_exe_ldflags = get_option('fuzzing_engine').split()
 236   endif
 237 endif
 238
 239 add_global_arguments(qemu_cflags, native: false, language: ['c'])
 240 add_global_arguments(qemu_cxxflags, native: false, language: ['cpp'])
 241 add_global_arguments(qemu_objcflags, native: false, language: ['objc'])
 242 add_global_link_arguments(qemu_ldflags, native: false, language: ['c', 'cpp', 'objc'])
 243
 244 if targetos == 'linux'
 245   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 246                         '-isystem', 'linux-headers',
 247                         language: ['c', 'cpp'])
 248 endif
 249
 250 add_project_arguments('-iquote', '.',
 251                       '-iquote', meson.current_source_dir(),
 252                       '-iquote', meson.current_source_dir() / 'include',
 253                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 254                       language: ['c', 'cpp', 'objc'])
 255
 256 link_language = meson.get_external_property('link_language', 'cpp')
 257 if link_language == 'cpp'
 258   add_languages('cpp', required: true, native: false)
 259   cxx = meson.get_compiler('cpp')
 260   linker = cxx
 261 else
 262   linker = cc
 263 endif
 264 if host_machine.system() == 'darwin'
 265   add_languages('objc', required: false, native: false)
 266 endif
 267
 268 sparse = find_program('cgcc', required: get_option('sparse'))
 269 if sparse.found()
 270   run_target('sparse',
 271              command: [find_program('scripts/check_sparse.py'),
 272                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 273                        '-Wno-transparent-union', '-Wno-old-initializer',
 274                        '-Wno-non-pointer-null'])
 275 endif
 276
 277 ###########################################
 278 # Target-specific checks and dependencies #
 279 ###########################################
 280
 281 # Fuzzing
 282 if get_option('fuzzing') and get_option('fuzzing_engine') == '' and \
 283     not cc.links('''
 284           #include <stdint.h>
 285           #include <sys/types.h>
 286           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size);
 287           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size) { return 0; }
 288         ''',
 289         args: ['-Werror', '-fsanitize=fuzzer'])
 290   error('Your compiler does not support -fsanitize=fuzzer')
 291 endif
 292
 293 # Tracing backends
 294 if 'ftrace' in get_option('trace_backends') and targetos != 'linux'
 295   error('ftrace is supported only on Linux')
 296 endif
 297 if 'syslog' in get_option('trace_backends') and not cc.compiles('''
 298     #include <syslog.h>
 299     int main(void) {
 300         openlog("qemu", LOG_PID, LOG_DAEMON);
 301         syslog(LOG_INFO, "configure");
 302         return 0;
 303     }''')
 304   error('syslog is not supported on this system')
 305 endif
 306
 307 # Miscellaneous Linux-only features
 308 get_option('mpath') \
 309   .require(targetos == 'linux', error_message: 'Multipath is supported only on Linux')
 310
 311 multiprocess_allowed = get_option('multiprocess') \
 312   .require(targetos == 'linux', error_message: 'Multiprocess QEMU is supported only on Linux') \
 313   .allowed()
 314
 315 have_tpm = get_option('tpm') \
 316   .require(targetos != 'windows', error_message: 'TPM emulation only available on POSIX systems') \
 317   .allowed()
 318
 319 # vhost
 320 have_vhost_user = get_option('vhost_user') \
 321   .disable_auto_if(targetos != 'linux') \
 322   .require(targetos != 'windows',
 323            error_message: 'vhost-user is not available on Windows').allowed()
 324 have_vhost_vdpa = get_option('vhost_vdpa') \
 325   .require(targetos == 'linux',
 326            error_message: 'vhost-vdpa is only available on Linux').allowed()
 327 have_vhost_kernel = get_option('vhost_kernel') \
 328   .require(targetos == 'linux',
 329            error_message: 'vhost-kernel is only available on Linux').allowed()
 330 have_vhost_user_crypto = get_option('vhost_crypto') \
 331   .require(have_vhost_user,
 332            error_message: 'vhost-crypto requires vhost-user to be enabled').allowed()
 333
 334 have_vhost = have_vhost_user or have_vhost_vdpa or have_vhost_kernel
 335
 336 have_vhost_net_user = have_vhost_user and get_option('vhost_net').allowed()
 337 have_vhost_net_vdpa = have_vhost_vdpa and get_option('vhost_net').allowed()
 338 have_vhost_net_kernel = have_vhost_kernel and get_option('vhost_net').allowed()
 339 have_vhost_net = have_vhost_net_kernel or have_vhost_net_user or have_vhost_net_vdpa
 340
 341 # Target-specific libraries and flags
 342 libm = cc.find_library('m', required: false)
 343 threads = dependency('threads')
 344 util = cc.find_library('util', required: false)
 345 winmm = []
 346 socket = []
 347 version_res = []
 348 coref = []
 349 iokit = []
 350 emulator_link_args = []
 351 nvmm =not_found
 352 hvf = not_found
 353 midl = not_found
 354 widl = not_found
 355 host_dsosuf = '.so'
 356 if targetos == 'windows'
 357   midl = find_program('midl', required: false)
 358   widl = find_program('widl', required: false)
 359   socket = cc.find_library('ws2_32')
 360   winmm = cc.find_library('winmm')
 361
 362   win = import('windows')
 363   version_res = win.compile_resources('version.rc',
 364                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 365                                       include_directories: include_directories('.'))
 366   host_dsosuf = '.dll'
 367 elif targetos == 'darwin'
 368   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 369   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 370   host_dsosuf = '.dylib'
 371 elif targetos == 'sunos'
 372   socket = [cc.find_library('socket'),
 373             cc.find_library('nsl'),
 374             cc.find_library('resolv')]
 375 elif targetos == 'haiku'
 376   socket = [cc.find_library('posix_error_mapper'),
 377             cc.find_library('network'),
 378             cc.find_library('bsd')]
 379 elif targetos == 'openbsd'
 380   if get_option('tcg').allowed() and target_dirs.length() > 0
 381     # Disable OpenBSD W^X if available
 382     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 383   endif
 384 endif
 385
 386 # Target-specific configuration of accelerators
 387 accelerators = []
 388 if get_option('kvm').allowed() and targetos == 'linux'
 389   accelerators += 'CONFIG_KVM'
 390 endif
 391 if get_option('whpx').allowed() and targetos == 'windows'
 392   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 393     error('WHPX requires 64-bit host')
 394   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 395        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 396     accelerators += 'CONFIG_WHPX'
 397   endif
 398 endif
 399 if get_option('hvf').allowed()
 400   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 401                    required: get_option('hvf'))
 402   if hvf.found()
 403     accelerators += 'CONFIG_HVF'
 404   endif
 405 endif
 406 if get_option('hax').allowed()
 407   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 408     accelerators += 'CONFIG_HAX'
 409   endif
 410 endif
 411 if targetos == 'netbsd'
 412   nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 413   if nvmm.found()
 414     accelerators += 'CONFIG_NVMM'
 415   endif
 416 endif
 417
 418 tcg_arch = host_arch
 419 if get_option('tcg').allowed()
 420   if host_arch == 'unknown'
 421     if get_option('tcg_interpreter')
 422       warning('Unsupported CPU @0@, will use TCG with TCI (slow)'.format(cpu))
 423     else
 424       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 425     endif
 426   elif get_option('tcg_interpreter')
 427     warning('Use of the TCG interpreter is not recommended on this host')
 428     warning('architecture. There is a native TCG execution backend available')
 429     warning('which provides substantially better performance and reliability.')
 430     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 431     warning('configuration option on this architecture to use the native')
 432     warning('backend.')
 433   endif
 434   if get_option('tcg_interpreter')
 435     tcg_arch = 'tci'
 436   elif host_arch == 'sparc64'
 437     tcg_arch = 'sparc'
 438   elif host_arch == 'x86_64'
 439     tcg_arch = 'i386'
 440   elif host_arch == 'ppc64'
 441     tcg_arch = 'ppc'
 442   endif
 443   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 444                         language: ['c', 'cpp', 'objc'])
 445
 446   accelerators += 'CONFIG_TCG'
 447   config_host += { 'CONFIG_TCG': 'y' }
 448 endif
 449
 450 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 451   error('KVM not available on this platform')
 452 endif
 453 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 454   error('HVF not available on this platform')
 455 endif
 456 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 457   error('NVMM not available on this platform')
 458 endif
 459 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 460   error('WHPX not available on this platform')
 461 endif
 462
 463 ################
 464 # Dependencies #
 465 ################
 466
 467 # The path to glib.h is added to all compilation commands.  This was
 468 # grandfathered in from the QEMU Makefiles.
 469 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 470                       native: false, language: ['c', 'cpp', 'objc'])
 471 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 472                           link_args: config_host['GLIB_LIBS'].split(),
 473                           version: config_host['GLIB_VERSION'],
 474                           variables: {
 475                             'bindir': config_host['GLIB_BINDIR'],
 476                           })
 477 # override glib dep with the configure results (for subprojects)
 478 meson.override_dependency('glib-2.0', glib)
 479
 480 gio = not_found
 481 gdbus_codegen = not_found
 482 if not get_option('gio').auto() or have_system
 483   gio = dependency('gio-2.0', required: get_option('gio'),
 484                    method: 'pkg-config', kwargs: static_kwargs)
 485   if gio.found() and not cc.links('''
 486     #include <gio/gio.h>
 487     int main(void)
 488     {
 489       g_dbus_proxy_new_sync(0, 0, 0, 0, 0, 0, 0, 0);
 490       return 0;
 491     }''', dependencies: [glib, gio])
 492     if get_option('gio').enabled()
 493       error('The installed libgio is broken for static linking')
 494     endif
 495     gio = not_found
 496   endif
 497   if gio.found()
 498     gdbus_codegen = find_program(gio.get_variable('gdbus_codegen'),
 499                                  required: get_option('gio'))
 500     gio_unix = dependency('gio-unix-2.0', required: get_option('gio'),
 501                           method: 'pkg-config', kwargs: static_kwargs)
 502     gio = declare_dependency(dependencies: [gio, gio_unix],
 503                              version: gio.version())
 504   endif
 505 endif
 506
 507 lttng = not_found
 508 if 'ust' in get_option('trace_backends')
 509   lttng = dependency('lttng-ust', required: true, version: '>= 2.1',
 510                      method: 'pkg-config', kwargs: static_kwargs)
 511 endif
 512 pixman = not_found
 513 if have_system or have_tools
 514   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 515                       method: 'pkg-config', kwargs: static_kwargs)
 516 endif
 517 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 518
 519 libaio = not_found
 520 if not get_option('linux_aio').auto() or have_block
 521   libaio = cc.find_library('aio', has_headers: ['libaio.h'],
 522                            required: get_option('linux_aio'),
 523                            kwargs: static_kwargs)
 524 endif
 525
 526 linux_io_uring_test = '''
 527   #include <liburing.h>
 528   #include <linux/errqueue.h>
 529
 530   int main(void) { return 0; }'''
 531
 532 linux_io_uring = not_found
 533 if not get_option('linux_io_uring').auto() or have_block
 534   linux_io_uring = dependency('liburing', version: '>=0.3',
 535                               required: get_option('linux_io_uring'),
 536                               method: 'pkg-config', kwargs: static_kwargs)
 537   if not cc.links(linux_io_uring_test)
 538     linux_io_uring = not_found
 539   endif
 540 endif
 541
 542 libnfs = not_found
 543 if not get_option('libnfs').auto() or have_block
 544   libnfs = dependency('libnfs', version: '>=1.9.3',
 545                       required: get_option('libnfs'),
 546                       method: 'pkg-config', kwargs: static_kwargs)
 547 endif
 548
 549 libattr_test = '''
 550   #include <stddef.h>
 551   #include <sys/types.h>
 552   #ifdef CONFIG_LIBATTR
 553   #include <attr/xattr.h>
 554   #else
 555   #include <sys/xattr.h>
 556   #endif
 557   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 558
 559 libattr = not_found
 560 have_old_libattr = false
 561 if get_option('attr').allowed()
 562   if cc.links(libattr_test)
 563     libattr = declare_dependency()
 564   else
 565     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 566                               required: get_option('attr'),
 567                               kwargs: static_kwargs)
 568     if libattr.found() and not \
 569       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 570       libattr = not_found
 571       if get_option('attr').enabled()
 572         error('could not link libattr')
 573       else
 574         warning('could not link libattr, disabling')
 575       endif
 576     else
 577       have_old_libattr = libattr.found()
 578     endif
 579   endif
 580 endif
 581
 582 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 583 if cocoa.found() and get_option('sdl').enabled()
 584   error('Cocoa and SDL cannot be enabled at the same time')
 585 endif
 586 if cocoa.found() and get_option('gtk').enabled()
 587   error('Cocoa and GTK+ cannot be enabled at the same time')
 588 endif
 589
 590 vmnet = dependency('appleframeworks', modules: 'vmnet', required: get_option('vmnet'))
 591 if vmnet.found() and not cc.has_header_symbol('vmnet/vmnet.h',
 592                                               'VMNET_BRIDGED_MODE',
 593                                               dependencies: vmnet)
 594   vmnet = not_found
 595   if get_option('vmnet').enabled()
 596     error('vmnet.framework API is outdated')
 597   else
 598     warning('vmnet.framework API is outdated, disabling')
 599   endif
 600 endif
 601
 602 seccomp = not_found
 603 if not get_option('seccomp').auto() or have_system or have_tools
 604   seccomp = dependency('libseccomp', version: '>=2.3.0',
 605                        required: get_option('seccomp'),
 606                        method: 'pkg-config', kwargs: static_kwargs)
 607 endif
 608
 609 libcap_ng = not_found
 610 if not get_option('cap_ng').auto() or have_system or have_tools
 611   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 612                               required: get_option('cap_ng'),
 613                               kwargs: static_kwargs)
 614 endif
 615 if libcap_ng.found() and not cc.links('''
 616    #include <cap-ng.h>
 617    int main(void)
 618    {
 619      capng_capability_to_name(CAPNG_EFFECTIVE);
 620      return 0;
 621    }''', dependencies: libcap_ng)
 622   libcap_ng = not_found
 623   if get_option('cap_ng').enabled()
 624     error('could not link libcap-ng')
 625   else
 626     warning('could not link libcap-ng, disabling')
 627   endif
 628 endif
 629
 630 if get_option('xkbcommon').auto() and not have_system and not have_tools
 631   xkbcommon = not_found
 632 else
 633   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 634                          method: 'pkg-config', kwargs: static_kwargs)
 635 endif
 636
 637 vde = not_found
 638 if not get_option('vde').auto() or have_system or have_tools
 639   vde = cc.find_library('vdeplug', has_headers: ['libvdeplug.h'],
 640                            required: get_option('vde'),
 641                            kwargs: static_kwargs)
 642 endif
 643 if vde.found() and not cc.links('''
 644    #include <libvdeplug.h>
 645    int main(void)
 646    {
 647      struct vde_open_args a = {0, 0, 0};
 648      char s[] = "";
 649      vde_open(s, s, &a);
 650      return 0;
 651    }''', dependencies: vde)
 652   vde = not_found
 653   if get_option('cap_ng').enabled()
 654     error('could not link libvdeplug')
 655   else
 656     warning('could not link libvdeplug, disabling')
 657   endif
 658 endif
 659
 660 pulse = not_found
 661 if not get_option('pa').auto() or (targetos == 'linux' and have_system)
 662   pulse = dependency('libpulse', required: get_option('pa'),
 663                      method: 'pkg-config', kwargs: static_kwargs)
 664 endif
 665 alsa = not_found
 666 if not get_option('alsa').auto() or (targetos == 'linux' and have_system)
 667   alsa = dependency('alsa', required: get_option('alsa'),
 668                     method: 'pkg-config', kwargs: static_kwargs)
 669 endif
 670 jack = not_found
 671 if not get_option('jack').auto() or have_system
 672   jack = dependency('jack', required: get_option('jack'),
 673                     method: 'pkg-config', kwargs: static_kwargs)
 674 endif
 675
 676 spice_protocol = not_found
 677 if not get_option('spice_protocol').auto() or have_system
 678   spice_protocol = dependency('spice-protocol', version: '>=0.12.3',
 679                               required: get_option('spice_protocol'),
 680                               method: 'pkg-config', kwargs: static_kwargs)
 681 endif
 682 spice = not_found
 683 if not get_option('spice').auto() or have_system
 684   spice = dependency('spice-server', version: '>=0.12.5',
 685                      required: get_option('spice'),
 686                      method: 'pkg-config', kwargs: static_kwargs)
 687 endif
 688 spice_headers = spice.partial_dependency(compile_args: true, includes: true)
 689
 690 rt = cc.find_library('rt', required: false)
 691
 692 libiscsi = not_found
 693 if not get_option('libiscsi').auto() or have_block
 694   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 695                          required: get_option('libiscsi'),
 696                          method: 'pkg-config', kwargs: static_kwargs)
 697 endif
 698 zstd = not_found
 699 if not get_option('zstd').auto() or have_block
 700   zstd = dependency('libzstd', version: '>=1.4.0',
 701                     required: get_option('zstd'),
 702                     method: 'pkg-config', kwargs: static_kwargs)
 703 endif
 704 virgl = not_found
 705
 706 have_vhost_user_gpu = have_tools and targetos == 'linux' and pixman.found()
 707 if not get_option('virglrenderer').auto() or have_system or have_vhost_user_gpu
 708   virgl = dependency('virglrenderer',
 709                      method: 'pkg-config',
 710                      required: get_option('virglrenderer'),
 711                      kwargs: static_kwargs)
 712 endif
 713 curl = not_found
 714 if not get_option('curl').auto() or have_block
 715   curl = dependency('libcurl', version: '>=7.29.0',
 716                     method: 'pkg-config',
 717                     required: get_option('curl'),
 718                     kwargs: static_kwargs)
 719 endif
 720 libudev = not_found
 721 if targetos == 'linux' and (have_system or have_tools)
 722   libudev = dependency('libudev',
 723                        method: 'pkg-config',
 724                        required: get_option('libudev'),
 725                        kwargs: static_kwargs)
 726 endif
 727
 728 mpathlibs = [libudev]
 729 mpathpersist = not_found
 730 mpathpersist_new_api = false
 731 if targetos == 'linux' and have_tools and get_option('mpath').allowed()
 732   mpath_test_source_new = '''
 733     #include <libudev.h>
 734     #include <mpath_persist.h>
 735     unsigned mpath_mx_alloc_len = 1024;
 736     int logsink;
 737     static struct config *multipath_conf;
 738     extern struct udev *udev;
 739     extern struct config *get_multipath_config(void);
 740     extern void put_multipath_config(struct config *conf);
 741     struct udev *udev;
 742     struct config *get_multipath_config(void) { return multipath_conf; }
 743     void put_multipath_config(struct config *conf) { }
 744     int main(void) {
 745         udev = udev_new();
 746         multipath_conf = mpath_lib_init();
 747         return 0;
 748     }'''
 749   mpath_test_source_old = '''
 750       #include <libudev.h>
 751       #include <mpath_persist.h>
 752       unsigned mpath_mx_alloc_len = 1024;
 753       int logsink;
 754       int main(void) {
 755           struct udev *udev = udev_new();
 756           mpath_lib_init(udev);
 757           return 0;
 758       }'''
 759   libmpathpersist = cc.find_library('mpathpersist',
 760                                     required: get_option('mpath'),
 761                                     kwargs: static_kwargs)
 762   if libmpathpersist.found()
 763     mpathlibs += libmpathpersist
 764     if enable_static
 765       mpathlibs += cc.find_library('devmapper',
 766                                      required: get_option('mpath'),
 767                                      kwargs: static_kwargs)
 768     endif
 769     mpathlibs += cc.find_library('multipath',
 770                                  required: get_option('mpath'),
 771                                  kwargs: static_kwargs)
 772     foreach lib: mpathlibs
 773       if not lib.found()
 774         mpathlibs = []
 775         break
 776       endif
 777     endforeach
 778     if mpathlibs.length() == 0
 779       msg = 'Dependencies missing for libmpathpersist'
 780     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 781       mpathpersist = declare_dependency(dependencies: mpathlibs)
 782       mpathpersist_new_api = true
 783     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 784       mpathpersist = declare_dependency(dependencies: mpathlibs)
 785     else
 786       msg = 'Cannot detect libmpathpersist API'
 787     endif
 788     if not mpathpersist.found()
 789       if get_option('mpath').enabled()
 790         error(msg)
 791       else
 792         warning(msg + ', disabling')
 793       endif
 794     endif
 795   endif
 796 endif
 797
 798 iconv = not_found
 799 curses = not_found
 800 if have_system and get_option('curses').allowed()
 801   curses_test = '''
 802     #if defined(__APPLE__) || defined(__OpenBSD__)
 803     #define _XOPEN_SOURCE_EXTENDED 1
 804     #endif
 805     #include <locale.h>
 806     #include <curses.h>
 807     #include <wchar.h>
 808     int main(void) {
 809       wchar_t wch = L'w';
 810       setlocale(LC_ALL, "");
 811       resize_term(0, 0);
 812       addwstr(L"wide chars\n");
 813       addnwstr(&wch, 1);
 814       add_wch(WACS_DEGREE);
 815       return 0;
 816     }'''
 817
 818   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 819   foreach curses_dep : curses_dep_list
 820     if not curses.found()
 821       curses = dependency(curses_dep,
 822                           required: false,
 823                           method: 'pkg-config',
 824                           kwargs: static_kwargs)
 825     endif
 826   endforeach
 827   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 828   curses_compile_args = ['-DNCURSES_WIDECHAR=1']
 829   if curses.found()
 830     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 831       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 832     else
 833       msg = 'curses package not usable'
 834       curses = not_found
 835     endif
 836   endif
 837   if not curses.found()
 838     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 839     if targetos != 'windows' and not has_curses_h
 840       message('Trying with /usr/include/ncursesw')
 841       curses_compile_args += ['-I/usr/include/ncursesw']
 842       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 843     endif
 844     if has_curses_h
 845       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 846       foreach curses_libname : curses_libname_list
 847         libcurses = cc.find_library(curses_libname,
 848                                     required: false,
 849                                     kwargs: static_kwargs)
 850         if libcurses.found()
 851           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 852             curses = declare_dependency(compile_args: curses_compile_args,
 853                                         dependencies: [libcurses])
 854             break
 855           else
 856             msg = 'curses library not usable'
 857           endif
 858         endif
 859       endforeach
 860     endif
 861   endif
 862   if get_option('iconv').allowed()
 863     foreach link_args : [ ['-liconv'], [] ]
 864       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 865       # We need to use libiconv if available because mixing libiconv's headers with
 866       # the system libc does not work.
 867       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 868       # included in the command line and libiconv will not be found.
 869       if cc.links('''
 870         #include <iconv.h>
 871         int main(void) {
 872           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 873           return conv != (iconv_t) -1;
 874         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 875         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 876         break
 877       endif
 878     endforeach
 879   endif
 880   if curses.found() and not iconv.found()
 881     if get_option('iconv').enabled()
 882       error('iconv not available')
 883     endif
 884     msg = 'iconv required for curses UI but not available'
 885     curses = not_found
 886   endif
 887   if not curses.found() and msg != ''
 888     if get_option('curses').enabled()
 889       error(msg)
 890     else
 891       warning(msg + ', disabling')
 892     endif
 893   endif
 894 endif
 895
 896 brlapi = not_found
 897 if not get_option('brlapi').auto() or have_system
 898   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 899                          required: get_option('brlapi'),
 900                          kwargs: static_kwargs)
 901   if brlapi.found() and not cc.links('''
 902      #include <brlapi.h>
 903      #include <stddef.h>
 904      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 905     brlapi = not_found
 906     if get_option('brlapi').enabled()
 907       error('could not link brlapi')
 908     else
 909       warning('could not link brlapi, disabling')
 910     endif
 911   endif
 912 endif
 913
 914 sdl = not_found
 915 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 916   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 917   sdl_image = not_found
 918 endif
 919 if sdl.found()
 920   # work around 2.0.8 bug
 921   sdl = declare_dependency(compile_args: '-Wno-undef',
 922                            dependencies: sdl)
 923   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 924                          method: 'pkg-config', kwargs: static_kwargs)
 925 else
 926   if get_option('sdl_image').enabled()
 927     error('sdl-image required, but SDL was @0@'.format(
 928           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 929   endif
 930   sdl_image = not_found
 931 endif
 932
 933 rbd = not_found
 934 if not get_option('rbd').auto() or have_block
 935   librados = cc.find_library('rados', required: get_option('rbd'),
 936                              kwargs: static_kwargs)
 937   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 938                            required: get_option('rbd'),
 939                            kwargs: static_kwargs)
 940   if librados.found() and librbd.found()
 941     if cc.links('''
 942       #include <stdio.h>
 943       #include <rbd/librbd.h>
 944       int main(void) {
 945         rados_t cluster;
 946         rados_create(&cluster, NULL);
 947         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
 948         #error
 949         #endif
 950         return 0;
 951       }''', dependencies: [librbd, librados])
 952       rbd = declare_dependency(dependencies: [librbd, librados])
 953     elif get_option('rbd').enabled()
 954       error('librbd >= 1.12.0 required')
 955     else
 956       warning('librbd >= 1.12.0 not found, disabling')
 957     endif
 958   endif
 959 endif
 960
 961 glusterfs = not_found
 962 glusterfs_ftruncate_has_stat = false
 963 glusterfs_iocb_has_stat = false
 964 if not get_option('glusterfs').auto() or have_block
 965   glusterfs = dependency('glusterfs-api', version: '>=3',
 966                          required: get_option('glusterfs'),
 967                          method: 'pkg-config', kwargs: static_kwargs)
 968   if glusterfs.found()
 969     glusterfs_ftruncate_has_stat = cc.links('''
 970       #include <glusterfs/api/glfs.h>
 971
 972       int
 973       main(void)
 974       {
 975           /* new glfs_ftruncate() passes two additional args */
 976           return glfs_ftruncate(NULL, 0, NULL, NULL);
 977       }
 978     ''', dependencies: glusterfs)
 979     glusterfs_iocb_has_stat = cc.links('''
 980       #include <glusterfs/api/glfs.h>
 981
 982       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 983       static void
 984       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 985       {}
 986
 987       int
 988       main(void)
 989       {
 990           glfs_io_cbk iocb = &glusterfs_iocb;
 991           iocb(NULL, 0 , NULL, NULL, NULL);
 992           return 0;
 993       }
 994     ''', dependencies: glusterfs)
 995   endif
 996 endif
 997
 998 libssh = not_found
 999 if not get_option('libssh').auto() or have_block
1000   libssh = dependency('libssh', version: '>=0.8.7',
1001                     method: 'pkg-config',
1002                     required: get_option('libssh'),
1003                     kwargs: static_kwargs)
1004 endif
1005
1006 libbzip2 = not_found
1007 if not get_option('bzip2').auto() or have_block
1008   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
1009                              required: get_option('bzip2'),
1010                              kwargs: static_kwargs)
1011   if libbzip2.found() and not cc.links('''
1012      #include <bzlib.h>
1013      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
1014     libbzip2 = not_found
1015     if get_option('bzip2').enabled()
1016       error('could not link libbzip2')
1017     else
1018       warning('could not link libbzip2, disabling')
1019     endif
1020   endif
1021 endif
1022
1023 liblzfse = not_found
1024 if not get_option('lzfse').auto() or have_block
1025   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
1026                              required: get_option('lzfse'),
1027                              kwargs: static_kwargs)
1028 endif
1029 if liblzfse.found() and not cc.links('''
1030    #include <lzfse.h>
1031    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
1032   liblzfse = not_found
1033   if get_option('lzfse').enabled()
1034     error('could not link liblzfse')
1035   else
1036     warning('could not link liblzfse, disabling')
1037   endif
1038 endif
1039
1040 oss = not_found
1041 if get_option('oss').allowed() and have_system
1042   if not cc.has_header('sys/soundcard.h')
1043     # not found
1044   elif targetos == 'netbsd'
1045     oss = cc.find_library('ossaudio', required: get_option('oss'),
1046                           kwargs: static_kwargs)
1047   else
1048     oss = declare_dependency()
1049   endif
1050
1051   if not oss.found()
1052     if get_option('oss').enabled()
1053       error('OSS not found')
1054     endif
1055   endif
1056 endif
1057 dsound = not_found
1058 if not get_option('dsound').auto() or (targetos == 'windows' and have_system)
1059   if cc.has_header('dsound.h')
1060     dsound = declare_dependency(link_args: ['-lole32', '-ldxguid'])
1061   endif
1062
1063   if not dsound.found()
1064     if get_option('dsound').enabled()
1065       error('DirectSound not found')
1066     endif
1067   endif
1068 endif
1069
1070 coreaudio = not_found
1071 if not get_option('coreaudio').auto() or (targetos == 'darwin' and have_system)
1072   coreaudio = dependency('appleframeworks', modules: 'CoreAudio',
1073                          required: get_option('coreaudio'))
1074 endif
1075
1076 opengl = not_found
1077 if not get_option('opengl').auto() or have_system or have_vhost_user_gpu
1078   epoxy = dependency('epoxy', method: 'pkg-config',
1079                       required: get_option('opengl'), kwargs: static_kwargs)
1080   if cc.has_header('epoxy/egl.h', dependencies: epoxy)
1081     opengl = epoxy
1082   elif get_option('opengl').enabled()
1083     error('epoxy/egl.h not found')
1084   endif
1085 endif
1086 gbm = not_found
1087 if (have_system or have_tools) and (virgl.found() or opengl.found())
1088   gbm = dependency('gbm', method: 'pkg-config', required: false,
1089                    kwargs: static_kwargs)
1090 endif
1091 have_vhost_user_gpu = have_vhost_user_gpu and virgl.found() and gbm.found()
1092
1093 gnutls = not_found
1094 gnutls_crypto = not_found
1095 if get_option('gnutls').enabled() or (get_option('gnutls').auto() and have_system)
1096   # For general TLS support our min gnutls matches
1097   # that implied by our platform support matrix
1098   #
1099   # For the crypto backends, we look for a newer
1100   # gnutls:
1101   #
1102   #   Version 3.6.8  is needed to get XTS
1103   #   Version 3.6.13 is needed to get PBKDF
1104   #   Version 3.6.14 is needed to get HW accelerated XTS
1105   #
1106   # If newer enough gnutls isn't available, we can
1107   # still use a different crypto backend to satisfy
1108   # the platform support requirements
1109   gnutls_crypto = dependency('gnutls', version: '>=3.6.14',
1110                              method: 'pkg-config',
1111                              required: false,
1112                              kwargs: static_kwargs)
1113   if gnutls_crypto.found()
1114     gnutls = gnutls_crypto
1115   else
1116     # Our min version if all we need is TLS
1117     gnutls = dependency('gnutls', version: '>=3.5.18',
1118                         method: 'pkg-config',
1119                         required: get_option('gnutls'),
1120                         kwargs: static_kwargs)
1121   endif
1122 endif
1123
1124 # We prefer use of gnutls for crypto, unless the options
1125 # explicitly asked for nettle or gcrypt.
1126 #
1127 # If gnutls isn't available for crypto, then we'll prefer
1128 # gcrypt over nettle for performance reasons.
1129 gcrypt = not_found
1130 nettle = not_found
1131 hogweed = not_found
1132 xts = 'none'
1133
1134 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
1135   error('Only one of gcrypt & nettle can be enabled')
1136 endif
1137
1138 # Explicit nettle/gcrypt request, so ignore gnutls for crypto
1139 if get_option('nettle').enabled() or get_option('gcrypt').enabled()
1140   gnutls_crypto = not_found
1141 endif
1142
1143 if not gnutls_crypto.found()
1144   if (not get_option('gcrypt').auto() or have_system) and not get_option('nettle').enabled()
1145     gcrypt = dependency('libgcrypt', version: '>=1.8',
1146                         method: 'config-tool',
1147                         required: get_option('gcrypt'),
1148                         kwargs: static_kwargs)
1149     # Debian has removed -lgpg-error from libgcrypt-config
1150     # as it "spreads unnecessary dependencies" which in
1151     # turn breaks static builds...
1152     if gcrypt.found() and enable_static
1153       gcrypt = declare_dependency(dependencies: [
1154         gcrypt,
1155         cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
1156     endif
1157   endif
1158   if (not get_option('nettle').auto() or have_system) and not gcrypt.found()
1159     nettle = dependency('nettle', version: '>=3.4',
1160                         method: 'pkg-config',
1161                         required: get_option('nettle'),
1162                         kwargs: static_kwargs)
1163     if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
1164       xts = 'private'
1165     endif
1166   endif
1167 endif
1168
1169 gmp = dependency('gmp', required: false, method: 'pkg-config', kwargs: static_kwargs)
1170 if nettle.found() and gmp.found()
1171   hogweed = dependency('hogweed', version: '>=3.4',
1172                        method: 'pkg-config',
1173                        required: get_option('nettle'),
1174                        kwargs: static_kwargs)
1175 endif
1176
1177
1178 gtk = not_found
1179 gtkx11 = not_found
1180 vte = not_found
1181 if not get_option('gtk').auto() or (have_system and not cocoa.found())
1182   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
1183                    method: 'pkg-config',
1184                    required: get_option('gtk'),
1185                    kwargs: static_kwargs)
1186   if gtk.found()
1187     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
1188                         method: 'pkg-config',
1189                         required: false,
1190                         kwargs: static_kwargs)
1191     gtk = declare_dependency(dependencies: [gtk, gtkx11])
1192
1193     if not get_option('vte').auto() or have_system
1194       vte = dependency('vte-2.91',
1195                        method: 'pkg-config',
1196                        required: get_option('vte'),
1197                        kwargs: static_kwargs)
1198     endif
1199   endif
1200 endif
1201
1202 x11 = not_found
1203 if gtkx11.found()
1204   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
1205                    kwargs: static_kwargs)
1206 endif
1207 png = not_found
1208 if get_option('png').allowed() and have_system
1209    png = dependency('libpng', required: get_option('png'),
1210                     method: 'pkg-config', kwargs: static_kwargs)
1211 endif
1212 vnc = not_found
1213 jpeg = not_found
1214 sasl = not_found
1215 if get_option('vnc').allowed() and have_system
1216   vnc = declare_dependency() # dummy dependency
1217   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
1218                     method: 'pkg-config', kwargs: static_kwargs)
1219   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
1220                          required: get_option('vnc_sasl'),
1221                          kwargs: static_kwargs)
1222   if sasl.found()
1223     sasl = declare_dependency(dependencies: sasl,
1224                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
1225   endif
1226 endif
1227
1228 pam = not_found
1229 if not get_option('auth_pam').auto() or have_system
1230   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
1231                         required: get_option('auth_pam'),
1232                         kwargs: static_kwargs)
1233 endif
1234 if pam.found() and not cc.links('''
1235    #include <stddef.h>
1236    #include <security/pam_appl.h>
1237    int main(void) {
1238      const char *service_name = "qemu";
1239      const char *user = "frank";
1240      const struct pam_conv pam_conv = { 0 };
1241      pam_handle_t *pamh = NULL;
1242      pam_start(service_name, user, &pam_conv, &pamh);
1243      return 0;
1244    }''', dependencies: pam)
1245   pam = not_found
1246   if get_option('auth_pam').enabled()
1247     error('could not link libpam')
1248   else
1249     warning('could not link libpam, disabling')
1250   endif
1251 endif
1252
1253 snappy = not_found
1254 if not get_option('snappy').auto() or have_system
1255   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
1256                            required: get_option('snappy'),
1257                            kwargs: static_kwargs)
1258 endif
1259 if snappy.found() and not linker.links('''
1260    #include <snappy-c.h>
1261    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
1262   snappy = not_found
1263   if get_option('snappy').enabled()
1264     error('could not link libsnappy')
1265   else
1266     warning('could not link libsnappy, disabling')
1267   endif
1268 endif
1269
1270 lzo = not_found
1271 if not get_option('lzo').auto() or have_system
1272   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
1273                         required: get_option('lzo'),
1274                         kwargs: static_kwargs)
1275 endif
1276 if lzo.found() and not cc.links('''
1277    #include <lzo/lzo1x.h>
1278    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
1279   lzo = not_found
1280   if get_option('lzo').enabled()
1281     error('could not link liblzo2')
1282   else
1283     warning('could not link liblzo2, disabling')
1284   endif
1285 endif
1286
1287 numa = not_found
1288 if not get_option('numa').auto() or have_system or have_tools
1289   numa = cc.find_library('numa', has_headers: ['numa.h'],
1290                               required: get_option('numa'),
1291                               kwargs: static_kwargs)
1292 endif
1293 if numa.found() and not cc.links('''
1294    #include <numa.h>
1295    int main(void) { return numa_available(); }
1296    ''', dependencies: numa)
1297   numa = not_found
1298   if get_option('numa').enabled()
1299     error('could not link numa')
1300   else
1301     warning('could not link numa, disabling')
1302   endif
1303 endif
1304
1305 rdma = not_found
1306 if not get_option('rdma').auto() or have_system
1307   libumad = cc.find_library('ibumad', required: get_option('rdma'))
1308   rdma_libs = [cc.find_library('rdmacm', has_headers: ['rdma/rdma_cma.h'],
1309                                required: get_option('rdma'),
1310                                kwargs: static_kwargs),
1311                cc.find_library('ibverbs', required: get_option('rdma'),
1312                                kwargs: static_kwargs),
1313                libumad]
1314   rdma = declare_dependency(dependencies: rdma_libs)
1315   foreach lib: rdma_libs
1316     if not lib.found()
1317       rdma = not_found
1318     endif
1319   endforeach
1320 endif
1321
1322 xen = not_found
1323 if get_option('xen').enabled() or (get_option('xen').auto() and have_system)
1324   xencontrol = dependency('xencontrol', required: false,
1325                           method: 'pkg-config', kwargs: static_kwargs)
1326   if xencontrol.found()
1327     xen_pc = declare_dependency(version: xencontrol.version(),
1328       dependencies: [
1329         xencontrol,
1330         # disabler: true makes xen_pc.found() return false if any is not found
1331         dependency('xenstore', required: false,
1332                    method: 'pkg-config', kwargs: static_kwargs,
1333                    disabler: true),
1334         dependency('xenforeignmemory', required: false,
1335                    method: 'pkg-config', kwargs: static_kwargs,
1336                    disabler: true),
1337         dependency('xengnttab', required: false,
1338                    method: 'pkg-config', kwargs: static_kwargs,
1339                    disabler: true),
1340         dependency('xenevtchn', required: false,
1341                    method: 'pkg-config', kwargs: static_kwargs,
1342                    disabler: true),
1343         dependency('xendevicemodel', required: false,
1344                    method: 'pkg-config', kwargs: static_kwargs,
1345                    disabler: true),
1346         # optional, no "disabler: true"
1347         dependency('xentoolcore', required: false,
1348                    method: 'pkg-config', kwargs: static_kwargs)])
1349     if xen_pc.found()
1350       xen = xen_pc
1351     endif
1352   endif
1353   if not xen.found()
1354     xen_tests = [ '4.11.0', '4.10.0', '4.9.0', '4.8.0', '4.7.1', '4.6.0', '4.5.0', '4.2.0' ]
1355     xen_libs = {
1356       '4.11.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1357       '4.10.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1358       '4.9.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1359       '4.8.0': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1360       '4.7.1': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1361       '4.6.0': [ 'xenstore', 'xenctrl' ],
1362       '4.5.0': [ 'xenstore', 'xenctrl' ],
1363       '4.2.0': [ 'xenstore', 'xenctrl' ],
1364     }
1365     xen_deps = {}
1366     foreach ver: xen_tests
1367       # cache the various library tests to avoid polluting the logs
1368       xen_test_deps = []
1369       foreach l: xen_libs[ver]
1370         if l not in xen_deps
1371           xen_deps += { l: cc.find_library(l, required: false) }
1372         endif
1373         xen_test_deps += xen_deps[l]
1374       endforeach
1375
1376       # Use -D to pick just one of the test programs in scripts/xen-detect.c
1377       xen_version = ver.split('.')
1378       xen_ctrl_version = xen_version[0] + \
1379         ('0' + xen_version[1]).substring(-2) + \
1380         ('0' + xen_version[2]).substring(-2)
1381       if cc.links(files('scripts/xen-detect.c'),
1382                   args: '-DCONFIG_XEN_CTRL_INTERFACE_VERSION=' + xen_ctrl_version,
1383                   dependencies: xen_test_deps)
1384         xen = declare_dependency(version: ver, dependencies: xen_test_deps)
1385         break
1386       endif
1387     endforeach
1388   endif
1389   if xen.found()
1390     accelerators += 'CONFIG_XEN'
1391   elif get_option('xen').enabled()
1392     error('could not compile and link Xen test program')
1393   endif
1394 endif
1395 have_xen_pci_passthrough = get_option('xen_pci_passthrough') \
1396   .require(xen.found(),
1397            error_message: 'Xen PCI passthrough requested but Xen not enabled') \
1398   .require(targetos == 'linux',
1399            error_message: 'Xen PCI passthrough not available on this platform') \
1400   .allowed()
1401
1402
1403 cacard = not_found
1404 if not get_option('smartcard').auto() or have_system
1405   cacard = dependency('libcacard', required: get_option('smartcard'),
1406                       version: '>=2.5.1', method: 'pkg-config',
1407                       kwargs: static_kwargs)
1408 endif
1409 u2f = not_found
1410 if have_system
1411   u2f = dependency('u2f-emu', required: get_option('u2f'),
1412                    method: 'pkg-config',
1413                    kwargs: static_kwargs)
1414 endif
1415 usbredir = not_found
1416 if not get_option('usb_redir').auto() or have_system
1417   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1418                         version: '>=0.6', method: 'pkg-config',
1419                         kwargs: static_kwargs)
1420 endif
1421 libusb = not_found
1422 if not get_option('libusb').auto() or have_system
1423   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1424                       version: '>=1.0.13', method: 'pkg-config',
1425                       kwargs: static_kwargs)
1426 endif
1427
1428 libpmem = not_found
1429 if not get_option('libpmem').auto() or have_system
1430   libpmem = dependency('libpmem', required: get_option('libpmem'),
1431                        method: 'pkg-config', kwargs: static_kwargs)
1432 endif
1433 libdaxctl = not_found
1434 if not get_option('libdaxctl').auto() or have_system
1435   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1436                          version: '>=57', method: 'pkg-config',
1437                          kwargs: static_kwargs)
1438 endif
1439 tasn1 = not_found
1440 if gnutls.found()
1441   tasn1 = dependency('libtasn1',
1442                      method: 'pkg-config',
1443                      kwargs: static_kwargs)
1444 endif
1445 keyutils = dependency('libkeyutils', required: false,
1446                       method: 'pkg-config', kwargs: static_kwargs)
1447
1448 has_gettid = cc.has_function('gettid')
1449
1450 # libselinux
1451 selinux = dependency('libselinux',
1452                      required: get_option('selinux'),
1453                      method: 'pkg-config', kwargs: static_kwargs)
1454
1455 # Malloc tests
1456
1457 malloc = []
1458 if get_option('malloc') == 'system'
1459   has_malloc_trim = \
1460     get_option('malloc_trim').allowed() and \
1461     cc.links('''#include <malloc.h>
1462                 int main(void) { malloc_trim(0); return 0; }''')
1463 else
1464   has_malloc_trim = false
1465   malloc = cc.find_library(get_option('malloc'), required: true)
1466 endif
1467 if not has_malloc_trim and get_option('malloc_trim').enabled()
1468   if get_option('malloc') == 'system'
1469     error('malloc_trim not available on this platform.')
1470   else
1471     error('malloc_trim not available with non-libc memory allocator')
1472   endif
1473 endif
1474
1475 # Check whether the glibc provides statx()
1476
1477 gnu_source_prefix = '''
1478   #ifndef _GNU_SOURCE
1479   #define _GNU_SOURCE
1480   #endif
1481 '''
1482 statx_test = gnu_source_prefix + '''
1483   #include <sys/stat.h>
1484   int main(void) {
1485     struct statx statxbuf;
1486     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1487     return 0;
1488   }'''
1489
1490 has_statx = cc.links(statx_test)
1491
1492 # Check whether statx() provides mount ID information
1493
1494 statx_mnt_id_test = gnu_source_prefix + '''
1495   #include <sys/stat.h>
1496   int main(void) {
1497     struct statx statxbuf;
1498     statx(0, "", 0, STATX_BASIC_STATS | STATX_MNT_ID, &statxbuf);
1499     return statxbuf.stx_mnt_id;
1500   }'''
1501
1502 has_statx_mnt_id = cc.links(statx_mnt_id_test)
1503
1504 have_vhost_user_blk_server = get_option('vhost_user_blk_server') \
1505   .require(targetos == 'linux',
1506            error_message: 'vhost_user_blk_server requires linux') \
1507   .require(have_vhost_user,
1508            error_message: 'vhost_user_blk_server requires vhost-user support') \
1509   .disable_auto_if(not have_system) \
1510   .allowed()
1511
1512 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1513   error('Cannot enable fuse-lseek while fuse is disabled')
1514 endif
1515
1516 fuse = dependency('fuse3', required: get_option('fuse'),
1517                   version: '>=3.1', method: 'pkg-config',
1518                   kwargs: static_kwargs)
1519
1520 fuse_lseek = not_found
1521 if get_option('fuse_lseek').allowed()
1522   if fuse.version().version_compare('>=3.8')
1523     # Dummy dependency
1524     fuse_lseek = declare_dependency()
1525   elif get_option('fuse_lseek').enabled()
1526     if fuse.found()
1527       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1528     else
1529       error('fuse-lseek requires libfuse, which was not found')
1530     endif
1531   endif
1532 endif
1533
1534 # libbpf
1535 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1536 if libbpf.found() and not cc.links('''
1537    #include <bpf/libbpf.h>
1538    int main(void)
1539    {
1540      bpf_object__destroy_skeleton(NULL);
1541      return 0;
1542    }''', dependencies: libbpf)
1543   libbpf = not_found
1544   if get_option('bpf').enabled()
1545     error('libbpf skeleton test failed')
1546   else
1547     warning('libbpf skeleton test failed, disabling')
1548   endif
1549 endif
1550
1551 #################
1552 # config-host.h #
1553 #################
1554
1555 audio_drivers_selected = []
1556 if have_system
1557   audio_drivers_available = {
1558     'alsa': alsa.found(),
1559     'coreaudio': coreaudio.found(),
1560     'dsound': dsound.found(),
1561     'jack': jack.found(),
1562     'oss': oss.found(),
1563     'pa': pulse.found(),
1564     'sdl': sdl.found(),
1565   }
1566   foreach k, v: audio_drivers_available
1567     config_host_data.set('CONFIG_AUDIO_' + k.to_upper(), v)
1568   endforeach
1569
1570   # Default to native drivers first, OSS second, SDL third
1571   audio_drivers_priority = \
1572     [ 'pa', 'coreaudio', 'dsound', 'oss' ] + \
1573     (targetos == 'linux' ? [] : [ 'sdl' ])
1574   audio_drivers_default = []
1575   foreach k: audio_drivers_priority
1576     if audio_drivers_available[k]
1577       audio_drivers_default += k
1578     endif
1579   endforeach
1580
1581   foreach k: get_option('audio_drv_list')
1582     if k == 'default'
1583       audio_drivers_selected += audio_drivers_default
1584     elif not audio_drivers_available[k]
1585       error('Audio driver "@0@" not available.'.format(k))
1586     else
1587       audio_drivers_selected += k
1588     endif
1589   endforeach
1590 endif
1591 config_host_data.set('CONFIG_AUDIO_DRIVERS',
1592                      '"' + '", "'.join(audio_drivers_selected) + '", ')
1593
1594 if get_option('cfi')
1595   cfi_flags=[]
1596   # Check for dependency on LTO
1597   if not get_option('b_lto')
1598     error('Selected Control-Flow Integrity but LTO is disabled')
1599   endif
1600   if config_host.has_key('CONFIG_MODULES')
1601     error('Selected Control-Flow Integrity is not compatible with modules')
1602   endif
1603   # Check for cfi flags. CFI requires LTO so we can't use
1604   # get_supported_arguments, but need a more complex "compiles" which allows
1605   # custom arguments
1606   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1607                  args: ['-flto', '-fsanitize=cfi-icall'] )
1608     cfi_flags += '-fsanitize=cfi-icall'
1609   else
1610     error('-fsanitize=cfi-icall is not supported by the compiler')
1611   endif
1612   if cc.compiles('int main () { return 0; }',
1613                  name: '-fsanitize-cfi-icall-generalize-pointers',
1614                  args: ['-flto', '-fsanitize=cfi-icall',
1615                         '-fsanitize-cfi-icall-generalize-pointers'] )
1616     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1617   else
1618     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1619   endif
1620   if get_option('cfi_debug')
1621     if cc.compiles('int main () { return 0; }',
1622                    name: '-fno-sanitize-trap=cfi-icall',
1623                    args: ['-flto', '-fsanitize=cfi-icall',
1624                           '-fno-sanitize-trap=cfi-icall'] )
1625       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1626     else
1627       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1628     endif
1629   endif
1630   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1631   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1632 endif
1633
1634 have_host_block_device = (targetos != 'darwin' or
1635     cc.has_header('IOKit/storage/IOMedia.h'))
1636
1637 # FIXME enable_modules shouldn't be necessary, but: https://github.com/mesonbuild/meson/issues/8333
1638 dbus_display = get_option('dbus_display') \
1639   .require(gio.version().version_compare('>=2.64'),
1640            error_message: '-display dbus requires glib>=2.64') \
1641   .require(enable_modules,
1642            error_message: '-display dbus requires --enable-modules') \
1643   .require(gdbus_codegen.found(),
1644            error_message: '-display dbus requires gdbus-codegen') \
1645   .allowed()
1646
1647 have_virtfs = get_option('virtfs') \
1648     .require(targetos == 'linux' or targetos == 'darwin',
1649              error_message: 'virtio-9p (virtfs) requires Linux or macOS') \
1650     .require(targetos == 'linux' or cc.has_function('pthread_fchdir_np'),
1651              error_message: 'virtio-9p (virtfs) on macOS requires the presence of pthread_fchdir_np') \
1652     .require(targetos == 'darwin' or (libattr.found() and libcap_ng.found()),
1653              error_message: 'virtio-9p (virtfs) on Linux requires libcap-ng-devel and libattr-devel') \
1654     .disable_auto_if(not have_tools and not have_system) \
1655     .allowed()
1656
1657 have_virtfs_proxy_helper = targetos != 'darwin' and have_virtfs and have_tools
1658
1659 if get_option('block_drv_ro_whitelist') == ''
1660   config_host_data.set('CONFIG_BDRV_RO_WHITELIST', '')
1661 else
1662   config_host_data.set('CONFIG_BDRV_RO_WHITELIST',
1663         '"' + get_option('block_drv_ro_whitelist').replace(',', '", "') + '", ')
1664 endif
1665 if get_option('block_drv_rw_whitelist') == ''
1666   config_host_data.set('CONFIG_BDRV_RW_WHITELIST', '')
1667 else
1668   config_host_data.set('CONFIG_BDRV_RW_WHITELIST',
1669         '"' + get_option('block_drv_rw_whitelist').replace(',', '", "') + '", ')
1670 endif
1671
1672 foreach k : get_option('trace_backends')
1673   config_host_data.set('CONFIG_TRACE_' + k.to_upper(), true)
1674 endforeach
1675 config_host_data.set_quoted('CONFIG_TRACE_FILE', get_option('trace_file'))
1676 config_host_data.set_quoted('CONFIG_TLS_PRIORITY', get_option('tls_priority'))
1677 if iasl.found()
1678   config_host_data.set_quoted('CONFIG_IASL', iasl.full_path())
1679 endif
1680 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1681 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1682 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1683 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1684 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1685 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('prefix') / get_option('qemu_firmwarepath'))
1686 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1687 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1688 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1689 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1690 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1691 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1692
1693 if config_host.has_key('CONFIG_MODULES')
1694   config_host_data.set('CONFIG_STAMP', run_command(
1695       meson.current_source_dir() / 'scripts/qemu-stamp.py',
1696       meson.project_version(), get_option('pkgversion'), '--',
1697       meson.current_source_dir() / 'configure',
1698       capture: true, check: true).stdout().strip())
1699 endif
1700
1701 have_slirp_smbd = get_option('slirp_smbd') \
1702   .require(targetos != 'windows', error_message: 'Host smbd not supported on this platform.') \
1703   .allowed()
1704 if have_slirp_smbd
1705   smbd_path = get_option('smbd')
1706   if smbd_path == ''
1707     smbd_path = (targetos == 'solaris' ? '/usr/sfw/sbin/smbd' : '/usr/sbin/smbd')
1708   endif
1709   config_host_data.set_quoted('CONFIG_SMBD_COMMAND', smbd_path)
1710 endif
1711
1712 config_host_data.set('HOST_' + host_arch.to_upper(), 1)
1713
1714 if get_option('module_upgrades') and not enable_modules
1715   error('Cannot enable module-upgrades as modules are not enabled')
1716 endif
1717 config_host_data.set('CONFIG_MODULE_UPGRADES', get_option('module_upgrades'))
1718
1719 config_host_data.set('CONFIG_ATTR', libattr.found())
1720 config_host_data.set('CONFIG_BDRV_WHITELIST_TOOLS', get_option('block_drv_whitelist_in_tools'))
1721 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1722 config_host_data.set('CONFIG_COCOA', cocoa.found())
1723 config_host_data.set('CONFIG_FUZZ', get_option('fuzzing'))
1724 config_host_data.set('CONFIG_GCOV', get_option('b_coverage'))
1725 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1726 config_host_data.set('CONFIG_LZO', lzo.found())
1727 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1728 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1729 config_host_data.set('CONFIG_CURL', curl.found())
1730 config_host_data.set('CONFIG_CURSES', curses.found())
1731 config_host_data.set('CONFIG_GBM', gbm.found())
1732 config_host_data.set('CONFIG_GIO', gio.found())
1733 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1734 if glusterfs.found()
1735   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1736   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1737   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1738   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1739   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1740   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1741 endif
1742 config_host_data.set('CONFIG_GTK', gtk.found())
1743 config_host_data.set('CONFIG_VTE', vte.found())
1744 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1745 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1746 config_host_data.set('CONFIG_EBPF', libbpf.found())
1747 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1748 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1749 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1750 config_host_data.set('CONFIG_LIBSSH', libssh.found())
1751 config_host_data.set('CONFIG_LINUX_AIO', libaio.found())
1752 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1753 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1754 config_host_data.set('CONFIG_NUMA', numa.found())
1755 config_host_data.set('CONFIG_OPENGL', opengl.found())
1756 config_host_data.set('CONFIG_PROFILER', get_option('profiler'))
1757 config_host_data.set('CONFIG_RBD', rbd.found())
1758 config_host_data.set('CONFIG_RDMA', rdma.found())
1759 config_host_data.set('CONFIG_SDL', sdl.found())
1760 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1761 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1762 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1763 config_host_data.set('CONFIG_TPM', have_tpm)
1764 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1765 config_host_data.set('CONFIG_VDE', vde.found())
1766 config_host_data.set('CONFIG_VHOST_NET', have_vhost_net)
1767 config_host_data.set('CONFIG_VHOST_NET_USER', have_vhost_net_user)
1768 config_host_data.set('CONFIG_VHOST_NET_VDPA', have_vhost_net_vdpa)
1769 config_host_data.set('CONFIG_VHOST_KERNEL', have_vhost_kernel)
1770 config_host_data.set('CONFIG_VHOST_USER', have_vhost_user)
1771 config_host_data.set('CONFIG_VHOST_CRYPTO', have_vhost_user_crypto)
1772 config_host_data.set('CONFIG_VHOST_VDPA', have_vhost_vdpa)
1773 config_host_data.set('CONFIG_VMNET', vmnet.found())
1774 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1775 config_host_data.set('CONFIG_PNG', png.found())
1776 config_host_data.set('CONFIG_VNC', vnc.found())
1777 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1778 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1779 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1780 config_host_data.set('CONFIG_VTE', vte.found())
1781 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1782 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1783 config_host_data.set('CONFIG_GETTID', has_gettid)
1784 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1785 config_host_data.set('CONFIG_GNUTLS_CRYPTO', gnutls_crypto.found())
1786 config_host_data.set('CONFIG_TASN1', tasn1.found())
1787 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1788 config_host_data.set('CONFIG_NETTLE', nettle.found())
1789 config_host_data.set('CONFIG_HOGWEED', hogweed.found())
1790 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1791 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1792 config_host_data.set('CONFIG_STATX', has_statx)
1793 config_host_data.set('CONFIG_STATX_MNT_ID', has_statx_mnt_id)
1794 config_host_data.set('CONFIG_ZSTD', zstd.found())
1795 config_host_data.set('CONFIG_FUSE', fuse.found())
1796 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1797 config_host_data.set('CONFIG_SPICE_PROTOCOL', spice_protocol.found())
1798 if spice_protocol.found()
1799 config_host_data.set('CONFIG_SPICE_PROTOCOL_MAJOR', spice_protocol.version().split('.')[0])
1800 config_host_data.set('CONFIG_SPICE_PROTOCOL_MINOR', spice_protocol.version().split('.')[1])
1801 config_host_data.set('CONFIG_SPICE_PROTOCOL_MICRO', spice_protocol.version().split('.')[2])
1802 endif
1803 config_host_data.set('CONFIG_SPICE', spice.found())
1804 config_host_data.set('CONFIG_X11', x11.found())
1805 config_host_data.set('CONFIG_DBUS_DISPLAY', dbus_display)
1806 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1807 config_host_data.set('CONFIG_SELINUX', selinux.found())
1808 config_host_data.set('CONFIG_XEN_BACKEND', xen.found())
1809 if xen.found()
1810   # protect from xen.version() having less than three components
1811   xen_version = xen.version().split('.') + ['0', '0']
1812   xen_ctrl_version = xen_version[0] + \
1813     ('0' + xen_version[1]).substring(-2) + \
1814     ('0' + xen_version[2]).substring(-2)
1815   config_host_data.set('CONFIG_XEN_CTRL_INTERFACE_VERSION', xen_ctrl_version)
1816 endif
1817 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1818 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1819 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1820 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1821
1822 config_host_data.set_quoted('CONFIG_HOST_DSOSUF', host_dsosuf)
1823 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1824
1825 have_coroutine_pool = get_option('coroutine_pool')
1826 if get_option('debug_stack_usage') and have_coroutine_pool
1827   message('Disabling coroutine pool to measure stack usage')
1828   have_coroutine_pool = false
1829 endif
1830 config_host_data.set10('CONFIG_COROUTINE_POOL', have_coroutine_pool)
1831 config_host_data.set('CONFIG_DEBUG_MUTEX', get_option('debug_mutex'))
1832 config_host_data.set('CONFIG_DEBUG_STACK_USAGE', get_option('debug_stack_usage'))
1833 config_host_data.set('CONFIG_GPROF', get_option('gprof'))
1834 config_host_data.set('CONFIG_LIVE_BLOCK_MIGRATION', get_option('live_block_migration').allowed())
1835 config_host_data.set('CONFIG_QOM_CAST_DEBUG', get_option('qom_cast_debug'))
1836 config_host_data.set('CONFIG_REPLICATION', get_option('live_block_migration').allowed())
1837
1838 # has_header
1839 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1840 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1841 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1842 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1843 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1844 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1845 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1846 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1847 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1848
1849 # has_function
1850 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1851 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1852 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1853 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1854 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1855 # Note that we need to specify prefix: here to avoid incorrectly
1856 # thinking that Windows has posix_memalign()
1857 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign', prefix: '#include <stdlib.h>'))
1858 config_host_data.set('CONFIG_ALIGNED_MALLOC', cc.has_function('_aligned_malloc'))
1859 config_host_data.set('CONFIG_VALLOC', cc.has_function('valloc'))
1860 config_host_data.set('CONFIG_MEMALIGN', cc.has_function('memalign'))
1861 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1862 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1863 config_host_data.set('CONFIG_PTHREAD_FCHDIR_NP', cc.has_function('pthread_fchdir_np'))
1864 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1865 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1866 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1867 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1868 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1869 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1870 config_host_data.set('HAVE_GETIFADDRS', cc.has_function('getifaddrs'))
1871 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1872 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1873 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1874 if rdma.found()
1875   config_host_data.set('HAVE_IBV_ADVISE_MR',
1876                        cc.has_function('ibv_advise_mr',
1877                                        dependencies: rdma,
1878                                        prefix: '#include <infiniband/verbs.h>'))
1879 endif
1880
1881 # has_header_symbol
1882 config_host_data.set('CONFIG_BYTESWAP_H',
1883                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1884 config_host_data.set('CONFIG_EPOLL_CREATE1',
1885                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1886 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1887                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1888                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1889 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1890                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1891 config_host_data.set('CONFIG_FIEMAP',
1892                      cc.has_header('linux/fiemap.h') and
1893                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1894 config_host_data.set('CONFIG_GETRANDOM',
1895                      cc.has_function('getrandom') and
1896                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
1897 config_host_data.set('CONFIG_INOTIFY',
1898                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
1899 config_host_data.set('CONFIG_INOTIFY1',
1900                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
1901 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1902                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1903                                           prefix: '''#include <sys/endian.h>
1904                                                      #include <sys/types.h>'''))
1905 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1906                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1907 config_host_data.set('CONFIG_RTNETLINK',
1908                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
1909 config_host_data.set('CONFIG_SYSMACROS',
1910                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1911 config_host_data.set('HAVE_OPTRESET',
1912                      cc.has_header_symbol('getopt.h', 'optreset'))
1913 config_host_data.set('HAVE_IPPROTO_MPTCP',
1914                      cc.has_header_symbol('netinet/in.h', 'IPPROTO_MPTCP'))
1915
1916 # has_member
1917 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1918                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1919                                    prefix: '#include <signal.h>'))
1920 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
1921                      cc.has_member('struct stat', 'st_atim',
1922                                    prefix: '#include <sys/stat.h>'))
1923
1924 # has_type
1925 config_host_data.set('CONFIG_IOVEC',
1926                      cc.has_type('struct iovec',
1927                                  prefix: '#include <sys/uio.h>'))
1928 config_host_data.set('HAVE_UTMPX',
1929                      cc.has_type('struct utmpx',
1930                                  prefix: '#include <utmpx.h>'))
1931
1932 config_host_data.set('CONFIG_EVENTFD', cc.links('''
1933   #include <sys/eventfd.h>
1934   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
1935 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
1936   #include <unistd.h>
1937   int main(void) {
1938   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
1939   return fdatasync(0);
1940   #else
1941   #error Not supported
1942   #endif
1943   }'''))
1944
1945 has_madvise = cc.links(gnu_source_prefix + '''
1946   #include <sys/types.h>
1947   #include <sys/mman.h>
1948   #include <stddef.h>
1949   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }''')
1950 missing_madvise_proto = false
1951 if has_madvise
1952   # Some platforms (illumos and Solaris before Solaris 11) provide madvise()
1953   # but forget to prototype it. In this case, has_madvise will be true (the
1954   # test program links despite a compile warning). To detect the
1955   # missing-prototype case, we try again with a definitely-bogus prototype.
1956   # This will only compile if the system headers don't provide the prototype;
1957   # otherwise the conflicting prototypes will cause a compiler error.
1958   missing_madvise_proto = cc.links(gnu_source_prefix + '''
1959     #include <sys/types.h>
1960     #include <sys/mman.h>
1961     #include <stddef.h>
1962     extern int madvise(int);
1963     int main(void) { return madvise(0); }''')
1964 endif
1965 config_host_data.set('CONFIG_MADVISE', has_madvise)
1966 config_host_data.set('HAVE_MADVISE_WITHOUT_PROTOTYPE', missing_madvise_proto)
1967
1968 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
1969   #include <sys/mman.h>
1970   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
1971 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
1972   #include <fcntl.h>
1973   #if !defined(AT_EMPTY_PATH)
1974   # error missing definition
1975   #else
1976   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
1977   #endif'''))
1978 config_host_data.set('CONFIG_PIPE2', cc.links(gnu_source_prefix + '''
1979   #include <unistd.h>
1980   #include <fcntl.h>
1981
1982   int main(void)
1983   {
1984       int pipefd[2];
1985       return pipe2(pipefd, O_CLOEXEC);
1986   }'''))
1987 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
1988   #include <sys/mman.h>
1989   #include <stddef.h>
1990   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
1991
1992 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_W_TID', cc.links(gnu_source_prefix + '''
1993   #include <pthread.h>
1994
1995   static void *f(void *p) { return NULL; }
1996   int main(void)
1997   {
1998     pthread_t thread;
1999     pthread_create(&thread, 0, f, 0);
2000     pthread_setname_np(thread, "QEMU");
2001     return 0;
2002   }''', dependencies: threads))
2003 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_WO_TID', cc.links(gnu_source_prefix + '''
2004   #include <pthread.h>
2005
2006   static void *f(void *p) { pthread_setname_np("QEMU"); return NULL; }
2007   int main(void)
2008   {
2009     pthread_t thread;
2010     pthread_create(&thread, 0, f, 0);
2011     return 0;
2012   }''', dependencies: threads))
2013 config_host_data.set('CONFIG_PTHREAD_CONDATTR_SETCLOCK', cc.links(gnu_source_prefix + '''
2014   #include <pthread.h>
2015   #include <time.h>
2016
2017   int main(void)
2018   {
2019     pthread_condattr_t attr
2020     pthread_condattr_init(&attr);
2021     pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);
2022     return 0;
2023   }''', dependencies: threads))
2024
2025 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
2026   #include <sys/signalfd.h>
2027   #include <stddef.h>
2028   int main(void) { return signalfd(-1, NULL, SFD_CLOEXEC); }'''))
2029 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
2030   #include <unistd.h>
2031   #include <fcntl.h>
2032   #include <limits.h>
2033
2034   int main(void)
2035   {
2036     int len, fd = 0;
2037     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
2038     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
2039     return 0;
2040   }'''))
2041
2042 config_host_data.set('HAVE_MLOCKALL', cc.links(gnu_source_prefix + '''
2043   #include <sys/mman.h>
2044   int main(int argc, char *argv[]) {
2045     return mlockall(MCL_FUTURE);
2046   }'''))
2047
2048 have_l2tpv3 = false
2049 if get_option('l2tpv3').allowed() and have_system
2050   have_l2tpv3 = cc.has_type('struct mmsghdr',
2051     prefix: gnu_source_prefix + '''
2052       #include <sys/socket.h>
2053       #include <linux/ip.h>''')
2054 endif
2055 config_host_data.set('CONFIG_L2TPV3', have_l2tpv3)
2056
2057 have_netmap = false
2058 if get_option('netmap').allowed() and have_system
2059   have_netmap = cc.compiles('''
2060     #include <inttypes.h>
2061     #include <net/if.h>
2062     #include <net/netmap.h>
2063     #include <net/netmap_user.h>
2064     #if (NETMAP_API < 11) || (NETMAP_API > 15)
2065     #error
2066     #endif
2067     int main(void) { return 0; }''')
2068   if not have_netmap and get_option('netmap').enabled()
2069     error('Netmap headers not available')
2070   endif
2071 endif
2072 config_host_data.set('CONFIG_NETMAP', have_netmap)
2073
2074 # Work around a system header bug with some kernel/XFS header
2075 # versions where they both try to define 'struct fsxattr':
2076 # xfs headers will not try to redefine structs from linux headers
2077 # if this macro is set.
2078 config_host_data.set('HAVE_FSXATTR', cc.links('''
2079   #include <linux/fs.h>
2080   struct fsxattr foo;
2081   int main(void) {
2082     return 0;
2083   }'''))
2084
2085 # Some versions of Mac OS X incorrectly define SIZE_MAX
2086 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
2087     #include <stdint.h>
2088     #include <stdio.h>
2089     int main(int argc, char *argv[]) {
2090         return printf("%zu", SIZE_MAX);
2091     }''', args: ['-Werror']))
2092
2093 atomic_test = '''
2094   #include <stdint.h>
2095   int main(void)
2096   {
2097     @0@ x = 0, y = 0;
2098     y = __atomic_load_n(&x, __ATOMIC_RELAXED);
2099     __atomic_store_n(&x, y, __ATOMIC_RELAXED);
2100     __atomic_compare_exchange_n(&x, &y, x, 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2101     __atomic_exchange_n(&x, y, __ATOMIC_RELAXED);
2102     __atomic_fetch_add(&x, y, __ATOMIC_RELAXED);
2103     return 0;
2104   }'''
2105
2106 # See if 64-bit atomic operations are supported.
2107 # Note that without __atomic builtins, we can only
2108 # assume atomic loads/stores max at pointer size.
2109 config_host_data.set('CONFIG_ATOMIC64', cc.links(atomic_test.format('uint64_t')))
2110
2111 has_int128 = cc.links('''
2112   __int128_t a;
2113   __uint128_t b;
2114   int main (void) {
2115     a = a + b;
2116     b = a * b;
2117     a = a * a;
2118     return 0;
2119   }''')
2120
2121 config_host_data.set('CONFIG_INT128', has_int128)
2122
2123 if has_int128
2124   # "do we have 128-bit atomics which are handled inline and specifically not
2125   # via libatomic". The reason we can't use libatomic is documented in the
2126   # comment starting "GCC is a house divided" in include/qemu/atomic128.h.
2127   has_atomic128 = cc.links(atomic_test.format('unsigned __int128'))
2128
2129   config_host_data.set('CONFIG_ATOMIC128', has_atomic128)
2130
2131   if not has_atomic128
2132     has_cmpxchg128 = cc.links('''
2133       int main(void)
2134       {
2135         unsigned __int128 x = 0, y = 0;
2136         __sync_val_compare_and_swap_16(&x, y, x);
2137         return 0;
2138       }
2139     ''')
2140
2141     config_host_data.set('CONFIG_CMPXCHG128', has_cmpxchg128)
2142   endif
2143 endif
2144
2145 config_host_data.set('CONFIG_GETAUXVAL', cc.links(gnu_source_prefix + '''
2146   #include <sys/auxv.h>
2147   int main(void) {
2148     return getauxval(AT_HWCAP) == 0;
2149   }'''))
2150
2151 config_host_data.set('CONFIG_USBFS', have_linux_user and cc.compiles('''
2152   #include <linux/usbdevice_fs.h>
2153
2154   #ifndef USBDEVFS_GET_CAPABILITIES
2155   #error "USBDEVFS_GET_CAPABILITIES undefined"
2156   #endif
2157
2158   #ifndef USBDEVFS_DISCONNECT_CLAIM
2159   #error "USBDEVFS_DISCONNECT_CLAIM undefined"
2160   #endif
2161
2162   int main(void) { return 0; }'''))
2163
2164 have_keyring = get_option('keyring') \
2165   .require(targetos == 'linux', error_message: 'keyring is only available on Linux') \
2166   .require(cc.compiles('''
2167     #include <errno.h>
2168     #include <asm/unistd.h>
2169     #include <linux/keyctl.h>
2170     #include <sys/syscall.h>
2171     #include <unistd.h>
2172     int main(void) {
2173         return syscall(__NR_keyctl, KEYCTL_READ, 0, NULL, NULL, 0);
2174     }'''), error_message: 'keyctl syscall not available on this system').allowed()
2175 config_host_data.set('CONFIG_SECRET_KEYRING', have_keyring)
2176
2177 have_cpuid_h = cc.links('''
2178   #include <cpuid.h>
2179   int main(void) {
2180     unsigned a, b, c, d;
2181     unsigned max = __get_cpuid_max(0, 0);
2182
2183     if (max >= 1) {
2184         __cpuid(1, a, b, c, d);
2185     }
2186
2187     if (max >= 7) {
2188         __cpuid_count(7, 0, a, b, c, d);
2189     }
2190
2191     return 0;
2192   }''')
2193 config_host_data.set('CONFIG_CPUID_H', have_cpuid_h)
2194
2195 config_host_data.set('CONFIG_AVX2_OPT', get_option('avx2') \
2196   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX2') \
2197   .require(cc.links('''
2198     #pragma GCC push_options
2199     #pragma GCC target("avx2")
2200     #include <cpuid.h>
2201     #include <immintrin.h>
2202     static int bar(void *a) {
2203       __m256i x = *(__m256i *)a;
2204       return _mm256_testz_si256(x, x);
2205     }
2206     int main(int argc, char *argv[]) { return bar(argv[0]); }
2207   '''), error_message: 'AVX2 not available').allowed())
2208
2209 config_host_data.set('CONFIG_AVX512F_OPT', get_option('avx512f') \
2210   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512F') \
2211   .require(cc.links('''
2212     #pragma GCC push_options
2213     #pragma GCC target("avx512f")
2214     #include <cpuid.h>
2215     #include <immintrin.h>
2216     static int bar(void *a) {
2217       __m512i x = *(__m512i *)a;
2218       return _mm512_test_epi64_mask(x, x);
2219     }
2220     int main(int argc, char *argv[]) { return bar(argv[0]); }
2221   '''), error_message: 'AVX512F not available').allowed())
2222
2223 have_pvrdma = get_option('pvrdma') \
2224   .require(rdma.found(), error_message: 'PVRDMA requires OpenFabrics libraries') \
2225   .require(cc.compiles(gnu_source_prefix + '''
2226     #include <sys/mman.h>
2227     int main(void)
2228     {
2229       char buf = 0;
2230       void *addr = &buf;
2231       addr = mremap(addr, 0, 1, MREMAP_MAYMOVE | MREMAP_FIXED);
2232
2233       return 0;
2234     }'''), error_message: 'PVRDMA requires mremap').allowed()
2235
2236 if have_pvrdma
2237   config_host_data.set('LEGACY_RDMA_REG_MR', not cc.links('''
2238     #include <infiniband/verbs.h>
2239     int main(void)
2240     {
2241       struct ibv_mr *mr;
2242       struct ibv_pd *pd = NULL;
2243       size_t length = 10;
2244       uint64_t iova = 0;
2245       int access = 0;
2246       void *addr = NULL;
2247
2248       mr = ibv_reg_mr_iova(pd, addr, length, iova, access);
2249       ibv_dereg_mr(mr);
2250       return 0;
2251     }'''))
2252 endif
2253
2254 if get_option('membarrier').disabled()
2255   have_membarrier = false
2256 elif targetos == 'windows'
2257   have_membarrier = true
2258 elif targetos == 'linux'
2259   have_membarrier = cc.compiles('''
2260     #include <linux/membarrier.h>
2261     #include <sys/syscall.h>
2262     #include <unistd.h>
2263     #include <stdlib.h>
2264     int main(void) {
2265         syscall(__NR_membarrier, MEMBARRIER_CMD_QUERY, 0);
2266         syscall(__NR_membarrier, MEMBARRIER_CMD_SHARED, 0);
2267         exit(0);
2268     }''')
2269 endif
2270 config_host_data.set('CONFIG_MEMBARRIER', get_option('membarrier') \
2271   .require(have_membarrier, error_message: 'membarrier system call not available') \
2272   .allowed())
2273
2274 have_afalg = get_option('crypto_afalg') \
2275   .require(cc.compiles(gnu_source_prefix + '''
2276     #include <errno.h>
2277     #include <sys/types.h>
2278     #include <sys/socket.h>
2279     #include <linux/if_alg.h>
2280     int main(void) {
2281       int sock;
2282       sock = socket(AF_ALG, SOCK_SEQPACKET, 0);
2283       return sock;
2284     }
2285   '''), error_message: 'AF_ALG requested but could not be detected').allowed()
2286 config_host_data.set('CONFIG_AF_ALG', have_afalg)
2287
2288 config_host_data.set('CONFIG_AF_VSOCK', cc.has_header_symbol(
2289   'linux/vm_sockets.h', 'AF_VSOCK',
2290   prefix: '#include <sys/socket.h>',
2291 ))
2292
2293 have_vss = false
2294 have_vss_sdk = false # old xp/2003 SDK
2295 if targetos == 'windows' and link_language == 'cpp'
2296   have_vss = cxx.compiles('''
2297     #define __MIDL_user_allocate_free_DEFINED__
2298     #include <vss.h>
2299     int main(void) { return VSS_CTX_BACKUP; }''')
2300   have_vss_sdk = cxx.has_header('vscoordint.h')
2301 endif
2302 config_host_data.set('HAVE_VSS_SDK', have_vss_sdk)
2303
2304 foreach k, v: config_host
2305   if k.startswith('CONFIG_')
2306     config_host_data.set(k, v == 'y' ? 1 : v)
2307   endif
2308 endforeach
2309
2310 # Older versions of MinGW do not import _lock_file and _unlock_file properly.
2311 # This was fixed for v6.0.0 with commit b48e3ac8969d.
2312 if targetos == 'windows'
2313   config_host_data.set('HAVE__LOCK_FILE', cc.links('''
2314     #include <stdio.h>
2315     int main(void) {
2316       _lock_file(NULL);
2317       _unlock_file(NULL);
2318       return 0;
2319     }''', name: '_lock_file and _unlock_file'))
2320 endif
2321
2322 ########################
2323 # Target configuration #
2324 ########################
2325
2326 minikconf = find_program('scripts/minikconf.py')
2327 config_all = {}
2328 config_all_devices = {}
2329 config_all_disas = {}
2330 config_devices_mak_list = []
2331 config_devices_h = {}
2332 config_target_h = {}
2333 config_target_mak = {}
2334
2335 disassemblers = {
2336   'alpha' : ['CONFIG_ALPHA_DIS'],
2337   'arm' : ['CONFIG_ARM_DIS'],
2338   'avr' : ['CONFIG_AVR_DIS'],
2339   'cris' : ['CONFIG_CRIS_DIS'],
2340   'hexagon' : ['CONFIG_HEXAGON_DIS'],
2341   'hppa' : ['CONFIG_HPPA_DIS'],
2342   'i386' : ['CONFIG_I386_DIS'],
2343   'x86_64' : ['CONFIG_I386_DIS'],
2344   'm68k' : ['CONFIG_M68K_DIS'],
2345   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
2346   'mips' : ['CONFIG_MIPS_DIS'],
2347   'nios2' : ['CONFIG_NIOS2_DIS'],
2348   'or1k' : ['CONFIG_OPENRISC_DIS'],
2349   'ppc' : ['CONFIG_PPC_DIS'],
2350   'riscv' : ['CONFIG_RISCV_DIS'],
2351   'rx' : ['CONFIG_RX_DIS'],
2352   's390' : ['CONFIG_S390_DIS'],
2353   'sh4' : ['CONFIG_SH4_DIS'],
2354   'sparc' : ['CONFIG_SPARC_DIS'],
2355   'xtensa' : ['CONFIG_XTENSA_DIS'],
2356   'loongarch' : ['CONFIG_LOONGARCH_DIS'],
2357 }
2358 if link_language == 'cpp'
2359   disassemblers += {
2360     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
2361     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
2362     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
2363   }
2364 endif
2365
2366 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
2367 host_kconfig = \
2368   (get_option('fuzzing') ? ['CONFIG_FUZZ=y'] : []) + \
2369   (have_tpm ? ['CONFIG_TPM=y'] : []) + \
2370   (spice.found() ? ['CONFIG_SPICE=y'] : []) + \
2371   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
2372   (opengl.found() ? ['CONFIG_OPENGL=y'] : []) + \
2373   (x11.found() ? ['CONFIG_X11=y'] : []) + \
2374   (have_vhost_user ? ['CONFIG_VHOST_USER=y'] : []) + \
2375   (have_vhost_vdpa ? ['CONFIG_VHOST_VDPA=y'] : []) + \
2376   (have_vhost_kernel ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
2377   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
2378   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
2379   (have_pvrdma ? ['CONFIG_PVRDMA=y'] : []) + \
2380   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : [])
2381
2382 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
2383
2384 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
2385 actual_target_dirs = []
2386 fdt_required = []
2387 foreach target : target_dirs
2388   config_target = { 'TARGET_NAME': target.split('-')[0] }
2389   if target.endswith('linux-user')
2390     if targetos != 'linux'
2391       if default_targets
2392         continue
2393       endif
2394       error('Target @0@ is only available on a Linux host'.format(target))
2395     endif
2396     config_target += { 'CONFIG_LINUX_USER': 'y' }
2397   elif target.endswith('bsd-user')
2398     if 'CONFIG_BSD' not in config_host
2399       if default_targets
2400         continue
2401       endif
2402       error('Target @0@ is only available on a BSD host'.format(target))
2403     endif
2404     config_target += { 'CONFIG_BSD_USER': 'y' }
2405   elif target.endswith('softmmu')
2406     config_target += { 'CONFIG_SOFTMMU': 'y' }
2407   endif
2408   if target.endswith('-user')
2409     config_target += {
2410       'CONFIG_USER_ONLY': 'y',
2411       'CONFIG_QEMU_INTERP_PREFIX':
2412         get_option('interp_prefix').replace('%M', config_target['TARGET_NAME'])
2413     }
2414   endif
2415
2416   accel_kconfig = []
2417   foreach sym: accelerators
2418     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
2419       config_target += { sym: 'y' }
2420       config_all += { sym: 'y' }
2421       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
2422         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
2423       endif
2424       if target in modular_tcg
2425         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
2426       else
2427         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
2428       endif
2429       accel_kconfig += [ sym + '=y' ]
2430     endif
2431   endforeach
2432   if accel_kconfig.length() == 0
2433     if default_targets
2434       continue
2435     endif
2436     error('No accelerator available for target @0@'.format(target))
2437   endif
2438
2439   actual_target_dirs += target
2440   config_target += keyval.load('configs/targets' / target + '.mak')
2441   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
2442
2443   if 'TARGET_NEED_FDT' in config_target
2444     fdt_required += target
2445   endif
2446
2447   # Add default keys
2448   if 'TARGET_BASE_ARCH' not in config_target
2449     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
2450   endif
2451   if 'TARGET_ABI_DIR' not in config_target
2452     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
2453   endif
2454   if 'TARGET_BIG_ENDIAN' not in config_target
2455     config_target += {'TARGET_BIG_ENDIAN': 'n'}
2456   endif
2457
2458   foreach k, v: disassemblers
2459     if host_arch.startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
2460       foreach sym: v
2461         config_target += { sym: 'y' }
2462         config_all_disas += { sym: 'y' }
2463       endforeach
2464     endif
2465   endforeach
2466
2467   config_target_data = configuration_data()
2468   foreach k, v: config_target
2469     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
2470       # do nothing
2471     elif ignored.contains(k)
2472       # do nothing
2473     elif k == 'TARGET_BASE_ARCH'
2474       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
2475       # not used to select files from sourcesets.
2476       config_target_data.set('TARGET_' + v.to_upper(), 1)
2477     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
2478       config_target_data.set_quoted(k, v)
2479     elif v == 'y'
2480       config_target_data.set(k, 1)
2481     elif v == 'n'
2482       config_target_data.set(k, 0)
2483     else
2484       config_target_data.set(k, v)
2485     endif
2486   endforeach
2487   config_target_data.set('QEMU_ARCH',
2488                          'QEMU_ARCH_' + config_target['TARGET_BASE_ARCH'].to_upper())
2489   config_target_h += {target: configure_file(output: target + '-config-target.h',
2490                                                configuration: config_target_data)}
2491
2492   if target.endswith('-softmmu')
2493     config_input = meson.get_external_property(target, 'default')
2494     config_devices_mak = target + '-config-devices.mak'
2495     config_devices_mak = configure_file(
2496       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
2497       output: config_devices_mak,
2498       depfile: config_devices_mak + '.d',
2499       capture: true,
2500       command: [minikconf,
2501                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
2502                 config_devices_mak, '@DEPFILE@', '@INPUT@',
2503                 host_kconfig, accel_kconfig,
2504                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
2505
2506     config_devices_data = configuration_data()
2507     config_devices = keyval.load(config_devices_mak)
2508     foreach k, v: config_devices
2509       config_devices_data.set(k, 1)
2510     endforeach
2511     config_devices_mak_list += config_devices_mak
2512     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
2513                                                 configuration: config_devices_data)}
2514     config_target += config_devices
2515     config_all_devices += config_devices
2516   endif
2517   config_target_mak += {target: config_target}
2518 endforeach
2519 target_dirs = actual_target_dirs
2520
2521 # This configuration is used to build files that are shared by
2522 # multiple binaries, and then extracted out of the "common"
2523 # static_library target.
2524 #
2525 # We do not use all_sources()/all_dependencies(), because it would
2526 # build literally all source files, including devices only used by
2527 # targets that are not built for this compilation.  The CONFIG_ALL
2528 # pseudo symbol replaces it.
2529
2530 config_all += config_all_devices
2531 config_all += config_host
2532 config_all += config_all_disas
2533 config_all += {
2534   'CONFIG_XEN': xen.found(),
2535   'CONFIG_SOFTMMU': have_system,
2536   'CONFIG_USER_ONLY': have_user,
2537   'CONFIG_ALL': true,
2538 }
2539
2540 target_configs_h = []
2541 foreach target: target_dirs
2542   target_configs_h += config_target_h[target]
2543   target_configs_h += config_devices_h.get(target, [])
2544 endforeach
2545 genh += custom_target('config-poison.h',
2546                       input: [target_configs_h],
2547                       output: 'config-poison.h',
2548                       capture: true,
2549                       command: [find_program('scripts/make-config-poison.sh'),
2550                                 target_configs_h])
2551
2552 ##############
2553 # Submodules #
2554 ##############
2555
2556 capstone = not_found
2557 if not get_option('capstone').auto() or have_system or have_user
2558   capstone = dependency('capstone', version: '>=3.0.5',
2559                         kwargs: static_kwargs, method: 'pkg-config',
2560                         required: get_option('capstone'))
2561
2562   # Some versions of capstone have broken pkg-config file
2563   # that reports a wrong -I path, causing the #include to
2564   # fail later. If the system has such a broken version
2565   # do not use it.
2566   if capstone.found() and not cc.compiles('#include <capstone.h>',
2567                                           dependencies: [capstone])
2568     capstone = not_found
2569     if get_option('capstone').enabled()
2570       error('capstone requested, but it does not appear to work')
2571     endif
2572   endif
2573 endif
2574
2575 slirp = not_found
2576 slirp_opt = 'disabled'
2577 if have_system
2578   slirp_opt = get_option('slirp')
2579   if slirp_opt in ['enabled', 'auto', 'system']
2580     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
2581     slirp_dep_required = (slirp_opt == 'system' or
2582                           slirp_opt == 'enabled' and not have_internal)
2583     slirp = dependency('slirp', kwargs: static_kwargs,
2584                        method: 'pkg-config', version: '>=4.1.0',
2585                        required: slirp_dep_required)
2586     # slirp <4.7 is incompatible with CFI support in QEMU.  This is because
2587     # it passes function pointers within libslirp as callbacks for timers.
2588     # When using a system-wide shared libslirp, the type information for the
2589     # callback is missing and the timer call produces a false positive with CFI.
2590     # Do not use the "version" keyword argument to produce a better error.
2591     # with control-flow integrity.
2592     if get_option('cfi') and slirp.found() and slirp.version().version_compare('<4.7')
2593       if slirp_dep_required
2594         error('Control-Flow Integrity requires libslirp 4.7.')
2595       else
2596         warning('Control-Flow Integrity requires libslirp 4.7, not using system-wide libslirp.')
2597         slirp = not_found
2598       endif
2599     endif
2600     if slirp.found()
2601       slirp_opt = 'system'
2602     elif have_internal
2603       slirp_opt = 'internal'
2604     else
2605       slirp_opt = 'disabled'
2606     endif
2607   endif
2608   if slirp_opt == 'internal'
2609     slirp_deps = []
2610     if targetos == 'windows'
2611       slirp_deps = cc.find_library('iphlpapi')
2612     elif targetos == 'darwin'
2613       slirp_deps = cc.find_library('resolv')
2614     endif
2615     slirp_conf = configuration_data()
2616     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
2617     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
2618     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
2619     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
2620     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
2621     slirp_files = [
2622       'slirp/src/arp_table.c',
2623       'slirp/src/bootp.c',
2624       'slirp/src/cksum.c',
2625       'slirp/src/dhcpv6.c',
2626       'slirp/src/dnssearch.c',
2627       'slirp/src/if.c',
2628       'slirp/src/ip6_icmp.c',
2629       'slirp/src/ip6_input.c',
2630       'slirp/src/ip6_output.c',
2631       'slirp/src/ip_icmp.c',
2632       'slirp/src/ip_input.c',
2633       'slirp/src/ip_output.c',
2634       'slirp/src/mbuf.c',
2635       'slirp/src/misc.c',
2636       'slirp/src/ncsi.c',
2637       'slirp/src/ndp_table.c',
2638       'slirp/src/sbuf.c',
2639       'slirp/src/slirp.c',
2640       'slirp/src/socket.c',
2641       'slirp/src/state.c',
2642       'slirp/src/stream.c',
2643       'slirp/src/tcp_input.c',
2644       'slirp/src/tcp_output.c',
2645       'slirp/src/tcp_subr.c',
2646       'slirp/src/tcp_timer.c',
2647       'slirp/src/tftp.c',
2648       'slirp/src/udp.c',
2649       'slirp/src/udp6.c',
2650       'slirp/src/util.c',
2651       'slirp/src/version.c',
2652       'slirp/src/vmstate.c',
2653     ]
2654
2655     configure_file(
2656       input : 'slirp/src/libslirp-version.h.in',
2657       output : 'libslirp-version.h',
2658       configuration: slirp_conf)
2659
2660     slirp_inc = include_directories('slirp', 'slirp/src')
2661     libslirp = static_library('slirp',
2662                               build_by_default: false,
2663                               sources: slirp_files,
2664                               c_args: slirp_cargs,
2665                               include_directories: slirp_inc)
2666     slirp = declare_dependency(link_with: libslirp,
2667                                dependencies: slirp_deps,
2668                                include_directories: slirp_inc)
2669   endif
2670 endif
2671
2672 fdt = not_found
2673 if have_system
2674   fdt_opt = get_option('fdt')
2675   if fdt_opt in ['enabled', 'auto', 'system']
2676     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
2677     fdt = cc.find_library('fdt', kwargs: static_kwargs,
2678                           required: fdt_opt == 'system' or
2679                                     fdt_opt == 'enabled' and not have_internal)
2680     if fdt.found() and cc.links('''
2681        #include <libfdt.h>
2682        #include <libfdt_env.h>
2683        int main(void) { fdt_find_max_phandle(NULL, NULL); return 0; }''',
2684          dependencies: fdt)
2685       fdt_opt = 'system'
2686     elif fdt_opt == 'system'
2687        error('system libfdt requested, but it is too old (1.5.1 or newer required)')
2688     elif have_internal
2689       fdt_opt = 'internal'
2690     else
2691       fdt_opt = 'disabled'
2692       fdt = not_found
2693     endif
2694   endif
2695   if fdt_opt == 'internal'
2696     fdt_files = files(
2697       'dtc/libfdt/fdt.c',
2698       'dtc/libfdt/fdt_ro.c',
2699       'dtc/libfdt/fdt_wip.c',
2700       'dtc/libfdt/fdt_sw.c',
2701       'dtc/libfdt/fdt_rw.c',
2702       'dtc/libfdt/fdt_strerror.c',
2703       'dtc/libfdt/fdt_empty_tree.c',
2704       'dtc/libfdt/fdt_addresses.c',
2705       'dtc/libfdt/fdt_overlay.c',
2706       'dtc/libfdt/fdt_check.c',
2707     )
2708
2709     fdt_inc = include_directories('dtc/libfdt')
2710     libfdt = static_library('fdt',
2711                             build_by_default: false,
2712                             sources: fdt_files,
2713                             include_directories: fdt_inc)
2714     fdt = declare_dependency(link_with: libfdt,
2715                              include_directories: fdt_inc)
2716   endif
2717 else
2718   fdt_opt = 'disabled'
2719 endif
2720 if not fdt.found() and fdt_required.length() > 0
2721   error('fdt not available but required by targets ' + ', '.join(fdt_required))
2722 endif
2723
2724 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
2725 config_host_data.set('CONFIG_FDT', fdt.found())
2726 config_host_data.set('CONFIG_SLIRP', slirp.found())
2727
2728 #####################
2729 # Generated sources #
2730 #####################
2731
2732 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
2733
2734 hxtool = find_program('scripts/hxtool')
2735 shaderinclude = find_program('scripts/shaderinclude.pl')
2736 qapi_gen = find_program('scripts/qapi-gen.py')
2737 qapi_gen_depends = [ meson.current_source_dir() / 'scripts/qapi/__init__.py',
2738                      meson.current_source_dir() / 'scripts/qapi/commands.py',
2739                      meson.current_source_dir() / 'scripts/qapi/common.py',
2740                      meson.current_source_dir() / 'scripts/qapi/error.py',
2741                      meson.current_source_dir() / 'scripts/qapi/events.py',
2742                      meson.current_source_dir() / 'scripts/qapi/expr.py',
2743                      meson.current_source_dir() / 'scripts/qapi/gen.py',
2744                      meson.current_source_dir() / 'scripts/qapi/introspect.py',
2745                      meson.current_source_dir() / 'scripts/qapi/parser.py',
2746                      meson.current_source_dir() / 'scripts/qapi/schema.py',
2747                      meson.current_source_dir() / 'scripts/qapi/source.py',
2748                      meson.current_source_dir() / 'scripts/qapi/types.py',
2749                      meson.current_source_dir() / 'scripts/qapi/visit.py',
2750                      meson.current_source_dir() / 'scripts/qapi/common.py',
2751                      meson.current_source_dir() / 'scripts/qapi-gen.py'
2752 ]
2753
2754 tracetool = [
2755   python, files('scripts/tracetool.py'),
2756    '--backend=' + ','.join(get_option('trace_backends'))
2757 ]
2758 tracetool_depends = files(
2759   'scripts/tracetool/backend/log.py',
2760   'scripts/tracetool/backend/__init__.py',
2761   'scripts/tracetool/backend/dtrace.py',
2762   'scripts/tracetool/backend/ftrace.py',
2763   'scripts/tracetool/backend/simple.py',
2764   'scripts/tracetool/backend/syslog.py',
2765   'scripts/tracetool/backend/ust.py',
2766   'scripts/tracetool/format/ust_events_c.py',
2767   'scripts/tracetool/format/ust_events_h.py',
2768   'scripts/tracetool/format/__init__.py',
2769   'scripts/tracetool/format/d.py',
2770   'scripts/tracetool/format/simpletrace_stap.py',
2771   'scripts/tracetool/format/c.py',
2772   'scripts/tracetool/format/h.py',
2773   'scripts/tracetool/format/log_stap.py',
2774   'scripts/tracetool/format/stap.py',
2775   'scripts/tracetool/__init__.py',
2776   'scripts/tracetool/transform.py',
2777   'scripts/tracetool/vcpu.py'
2778 )
2779
2780 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
2781                     meson.current_source_dir(),
2782                     get_option('pkgversion'), meson.project_version()]
2783 qemu_version = custom_target('qemu-version.h',
2784                              output: 'qemu-version.h',
2785                              command: qemu_version_cmd,
2786                              capture: true,
2787                              build_by_default: true,
2788                              build_always_stale: true)
2789 genh += qemu_version
2790
2791 hxdep = []
2792 hx_headers = [
2793   ['qemu-options.hx', 'qemu-options.def'],
2794   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
2795 ]
2796 if have_system
2797   hx_headers += [
2798     ['hmp-commands.hx', 'hmp-commands.h'],
2799     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
2800   ]
2801 endif
2802 foreach d : hx_headers
2803   hxdep += custom_target(d[1],
2804                 input: files(d[0]),
2805                 output: d[1],
2806                 capture: true,
2807                 build_by_default: true, # to be removed when added to a target
2808                 command: [hxtool, '-h', '@INPUT0@'])
2809 endforeach
2810 genh += hxdep
2811
2812 ###################
2813 # Collect sources #
2814 ###################
2815
2816 authz_ss = ss.source_set()
2817 blockdev_ss = ss.source_set()
2818 block_ss = ss.source_set()
2819 chardev_ss = ss.source_set()
2820 common_ss = ss.source_set()
2821 crypto_ss = ss.source_set()
2822 hwcore_ss = ss.source_set()
2823 io_ss = ss.source_set()
2824 qmp_ss = ss.source_set()
2825 qom_ss = ss.source_set()
2826 softmmu_ss = ss.source_set()
2827 specific_fuzz_ss = ss.source_set()
2828 specific_ss = ss.source_set()
2829 stub_ss = ss.source_set()
2830 trace_ss = ss.source_set()
2831 user_ss = ss.source_set()
2832 util_ss = ss.source_set()
2833
2834 # accel modules
2835 qtest_module_ss = ss.source_set()
2836 tcg_module_ss = ss.source_set()
2837
2838 modules = {}
2839 target_modules = {}
2840 hw_arch = {}
2841 target_arch = {}
2842 target_softmmu_arch = {}
2843 target_user_arch = {}
2844
2845 ###############
2846 # Trace files #
2847 ###############
2848
2849 # TODO: add each directory to the subdirs from its own meson.build, once
2850 # we have those
2851 trace_events_subdirs = [
2852   'crypto',
2853   'qapi',
2854   'qom',
2855   'monitor',
2856   'util',
2857 ]
2858 if have_linux_user
2859   trace_events_subdirs += [ 'linux-user' ]
2860 endif
2861 if have_bsd_user
2862   trace_events_subdirs += [ 'bsd-user' ]
2863 endif
2864 if have_block
2865   trace_events_subdirs += [
2866     'authz',
2867     'block',
2868     'io',
2869     'nbd',
2870     'scsi',
2871   ]
2872 endif
2873 if have_system
2874   trace_events_subdirs += [
2875     'accel/kvm',
2876     'audio',
2877     'backends',
2878     'backends/tpm',
2879     'chardev',
2880     'ebpf',
2881     'hw/9pfs',
2882     'hw/acpi',
2883     'hw/adc',
2884     'hw/alpha',
2885     'hw/arm',
2886     'hw/audio',
2887     'hw/block',
2888     'hw/block/dataplane',
2889     'hw/char',
2890     'hw/display',
2891     'hw/dma',
2892     'hw/hyperv',
2893     'hw/i2c',
2894     'hw/i386',
2895     'hw/i386/xen',
2896     'hw/ide',
2897     'hw/input',
2898     'hw/intc',
2899     'hw/isa',
2900     'hw/mem',
2901     'hw/mips',
2902     'hw/misc',
2903     'hw/misc/macio',
2904     'hw/net',
2905     'hw/net/can',
2906     'hw/nubus',
2907     'hw/nvme',
2908     'hw/nvram',
2909     'hw/pci',
2910     'hw/pci-host',
2911     'hw/ppc',
2912     'hw/rdma',
2913     'hw/rdma/vmw',
2914     'hw/rtc',
2915     'hw/s390x',
2916     'hw/scsi',
2917     'hw/sd',
2918     'hw/sh4',
2919     'hw/sparc',
2920     'hw/sparc64',
2921     'hw/ssi',
2922     'hw/timer',
2923     'hw/tpm',
2924     'hw/usb',
2925     'hw/vfio',
2926     'hw/virtio',
2927     'hw/watchdog',
2928     'hw/xen',
2929     'hw/gpio',
2930     'migration',
2931     'net',
2932     'softmmu',
2933     'ui',
2934     'hw/remote',
2935   ]
2936 endif
2937 if have_system or have_user
2938   trace_events_subdirs += [
2939     'accel/tcg',
2940     'hw/core',
2941     'target/arm',
2942     'target/arm/hvf',
2943     'target/hppa',
2944     'target/i386',
2945     'target/i386/kvm',
2946     'target/mips/tcg',
2947     'target/nios2',
2948     'target/ppc',
2949     'target/riscv',
2950     'target/s390x',
2951     'target/s390x/kvm',
2952     'target/sparc',
2953   ]
2954 endif
2955
2956 vhost_user = not_found
2957 if targetos == 'linux' and have_vhost_user
2958   libvhost_user = subproject('libvhost-user')
2959   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2960 endif
2961
2962 # NOTE: the trace/ subdirectory needs the qapi_trace_events variable
2963 # that is filled in by qapi/.
2964 subdir('qapi')
2965 subdir('qobject')
2966 subdir('stubs')
2967 subdir('trace')
2968 subdir('util')
2969 subdir('qom')
2970 subdir('authz')
2971 subdir('crypto')
2972 subdir('ui')
2973 subdir('hw')
2974
2975
2976 if enable_modules
2977   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
2978   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
2979 endif
2980
2981 qom_ss = qom_ss.apply(config_host, strict: false)
2982 libqom = static_library('qom', qom_ss.sources() + genh,
2983                         dependencies: [qom_ss.dependencies()],
2984                         name_suffix: 'fa')
2985 qom = declare_dependency(link_whole: libqom)
2986
2987 event_loop_base = files('event-loop-base.c')
2988 event_loop_base = static_library('event-loop-base', sources: event_loop_base + genh,
2989                                  build_by_default: true)
2990 event_loop_base = declare_dependency(link_whole: event_loop_base,
2991                                      dependencies: [qom])
2992
2993 stub_ss = stub_ss.apply(config_all, strict: false)
2994
2995 util_ss.add_all(trace_ss)
2996 util_ss = util_ss.apply(config_all, strict: false)
2997 libqemuutil = static_library('qemuutil',
2998                              sources: util_ss.sources() + stub_ss.sources() + genh,
2999                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
3000 qemuutil = declare_dependency(link_with: libqemuutil,
3001                               sources: genh + version_res,
3002                               dependencies: [event_loop_base])
3003
3004 if have_system or have_user
3005   decodetree = generator(find_program('scripts/decodetree.py'),
3006                          output: 'decode-@BASENAME@.c.inc',
3007                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
3008   subdir('libdecnumber')
3009   subdir('target')
3010 endif
3011
3012 subdir('audio')
3013 subdir('io')
3014 subdir('chardev')
3015 subdir('fsdev')
3016 subdir('dump')
3017
3018 if have_block
3019   block_ss.add(files(
3020     'block.c',
3021     'blockjob.c',
3022     'job.c',
3023     'qemu-io-cmds.c',
3024   ))
3025   if config_host_data.get('CONFIG_REPLICATION')
3026     block_ss.add(files('replication.c'))
3027   endif
3028
3029   subdir('nbd')
3030   subdir('scsi')
3031   subdir('block')
3032
3033   blockdev_ss.add(files(
3034     'blockdev.c',
3035     'blockdev-nbd.c',
3036     'iothread.c',
3037     'job-qmp.c',
3038   ), gnutls)
3039
3040   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
3041   # os-win32.c does not
3042   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
3043   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
3044 endif
3045
3046 common_ss.add(files('cpus-common.c'))
3047
3048 subdir('softmmu')
3049
3050 common_ss.add(capstone)
3051 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
3052
3053 # Work around a gcc bug/misfeature wherein constant propagation looks
3054 # through an alias:
3055 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
3056 # to guess that a const variable is always zero.  Without lto, this is
3057 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
3058 # without lto, not even the alias is required -- we simply use different
3059 # declarations in different compilation units.
3060 pagevary = files('page-vary-common.c')
3061 if get_option('b_lto')
3062   pagevary_flags = ['-fno-lto']
3063   if get_option('cfi')
3064     pagevary_flags += '-fno-sanitize=cfi-icall'
3065   endif
3066   pagevary = static_library('page-vary-common', sources: pagevary + genh,
3067                             c_args: pagevary_flags)
3068   pagevary = declare_dependency(link_with: pagevary)
3069 endif
3070 common_ss.add(pagevary)
3071 specific_ss.add(files('page-vary.c'))
3072
3073 subdir('backends')
3074 subdir('disas')
3075 subdir('migration')
3076 subdir('monitor')
3077 subdir('net')
3078 subdir('replay')
3079 subdir('semihosting')
3080 subdir('tcg')
3081 subdir('fpu')
3082 subdir('accel')
3083 subdir('plugins')
3084 subdir('ebpf')
3085
3086 common_user_inc = []
3087
3088 subdir('common-user')
3089 subdir('bsd-user')
3090 subdir('linux-user')
3091
3092 # needed for fuzzing binaries
3093 subdir('tests/qtest/libqos')
3094 subdir('tests/qtest/fuzz')
3095
3096 # accel modules
3097 tcg_real_module_ss = ss.source_set()
3098 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
3099 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
3100 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
3101                                 'tcg': tcg_real_module_ss }}
3102
3103 ########################
3104 # Library dependencies #
3105 ########################
3106
3107 modinfo_collect = find_program('scripts/modinfo-collect.py')
3108 modinfo_generate = find_program('scripts/modinfo-generate.py')
3109 modinfo_files = []
3110
3111 block_mods = []
3112 softmmu_mods = []
3113 foreach d, list : modules
3114   foreach m, module_ss : list
3115     if enable_modules and targetos != 'windows'
3116       module_ss = module_ss.apply(config_all, strict: false)
3117       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
3118                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
3119       if d == 'block'
3120         block_mods += sl
3121       else
3122         softmmu_mods += sl
3123       endif
3124       if module_ss.sources() != []
3125         # FIXME: Should use sl.extract_all_objects(recursive: true) as
3126         # input. Sources can be used multiple times but objects are
3127         # unique when it comes to lookup in compile_commands.json.
3128         # Depnds on a mesion version with
3129         # https://github.com/mesonbuild/meson/pull/8900
3130         modinfo_files += custom_target(d + '-' + m + '.modinfo',
3131                                        output: d + '-' + m + '.modinfo',
3132                                        input: module_ss.sources() + genh,
3133                                        capture: true,
3134                                        command: [modinfo_collect, module_ss.sources()])
3135       endif
3136     else
3137       if d == 'block'
3138         block_ss.add_all(module_ss)
3139       else
3140         softmmu_ss.add_all(module_ss)
3141       endif
3142     endif
3143   endforeach
3144 endforeach
3145
3146 foreach d, list : target_modules
3147   foreach m, module_ss : list
3148     if enable_modules and targetos != 'windows'
3149       foreach target : target_dirs
3150         if target.endswith('-softmmu')
3151           config_target = config_target_mak[target]
3152           config_target += config_host
3153           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3154           c_args = ['-DNEED_CPU_H',
3155                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3156                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3157           target_module_ss = module_ss.apply(config_target, strict: false)
3158           if target_module_ss.sources() != []
3159             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
3160             sl = static_library(module_name,
3161                                 [genh, target_module_ss.sources()],
3162                                 dependencies: [modulecommon, target_module_ss.dependencies()],
3163                                 include_directories: target_inc,
3164                                 c_args: c_args,
3165                                 pic: true)
3166             softmmu_mods += sl
3167             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
3168             modinfo_files += custom_target(module_name + '.modinfo',
3169                                            output: module_name + '.modinfo',
3170                                            input: target_module_ss.sources() + genh,
3171                                            capture: true,
3172                                            command: [modinfo_collect, '--target', target, target_module_ss.sources()])
3173           endif
3174         endif
3175       endforeach
3176     else
3177       specific_ss.add_all(module_ss)
3178     endif
3179   endforeach
3180 endforeach
3181
3182 if enable_modules
3183   foreach target : target_dirs
3184     if target.endswith('-softmmu')
3185       config_target = config_target_mak[target]
3186       config_devices_mak = target + '-config-devices.mak'
3187       modinfo_src = custom_target('modinfo-' + target + '.c',
3188                                   output: 'modinfo-' + target + '.c',
3189                                   input: modinfo_files,
3190                                   command: [modinfo_generate, '--devices', config_devices_mak, '@INPUT@'],
3191                                   capture: true)
3192
3193       modinfo_lib = static_library('modinfo-' + target + '.c', modinfo_src)
3194       modinfo_dep = declare_dependency(link_with: modinfo_lib)
3195
3196       arch = config_target['TARGET_NAME'] == 'sparc64' ? 'sparc64' : config_target['TARGET_BASE_ARCH']
3197       hw_arch[arch].add(modinfo_dep)
3198     endif
3199   endforeach
3200 endif
3201
3202 nm = find_program('nm')
3203 undefsym = find_program('scripts/undefsym.py')
3204 block_syms = custom_target('block.syms', output: 'block.syms',
3205                              input: [libqemuutil, block_mods],
3206                              capture: true,
3207                              command: [undefsym, nm, '@INPUT@'])
3208 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
3209                              input: [libqemuutil, softmmu_mods],
3210                              capture: true,
3211                              command: [undefsym, nm, '@INPUT@'])
3212
3213 authz_ss = authz_ss.apply(config_host, strict: false)
3214 libauthz = static_library('authz', authz_ss.sources() + genh,
3215                           dependencies: [authz_ss.dependencies()],
3216                           name_suffix: 'fa',
3217                           build_by_default: false)
3218
3219 authz = declare_dependency(link_whole: libauthz,
3220                            dependencies: qom)
3221
3222 crypto_ss = crypto_ss.apply(config_host, strict: false)
3223 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
3224                            dependencies: [crypto_ss.dependencies()],
3225                            name_suffix: 'fa',
3226                            build_by_default: false)
3227
3228 crypto = declare_dependency(link_whole: libcrypto,
3229                             dependencies: [authz, qom])
3230
3231 io_ss = io_ss.apply(config_host, strict: false)
3232 libio = static_library('io', io_ss.sources() + genh,
3233                        dependencies: [io_ss.dependencies()],
3234                        link_with: libqemuutil,
3235                        name_suffix: 'fa',
3236                        build_by_default: false)
3237
3238 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
3239
3240 libmigration = static_library('migration', sources: migration_files + genh,
3241                               name_suffix: 'fa',
3242                               build_by_default: false)
3243 migration = declare_dependency(link_with: libmigration,
3244                                dependencies: [zlib, qom, io])
3245 softmmu_ss.add(migration)
3246
3247 block_ss = block_ss.apply(config_host, strict: false)
3248 libblock = static_library('block', block_ss.sources() + genh,
3249                           dependencies: block_ss.dependencies(),
3250                           link_depends: block_syms,
3251                           name_suffix: 'fa',
3252                           build_by_default: false)
3253
3254 block = declare_dependency(link_whole: [libblock],
3255                            link_args: '@block.syms',
3256                            dependencies: [crypto, io])
3257
3258 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
3259 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
3260                              dependencies: blockdev_ss.dependencies(),
3261                              name_suffix: 'fa',
3262                              build_by_default: false)
3263
3264 blockdev = declare_dependency(link_whole: [libblockdev],
3265                               dependencies: [block, event_loop_base])
3266
3267 qmp_ss = qmp_ss.apply(config_host, strict: false)
3268 libqmp = static_library('qmp', qmp_ss.sources() + genh,
3269                         dependencies: qmp_ss.dependencies(),
3270                         name_suffix: 'fa',
3271                         build_by_default: false)
3272
3273 qmp = declare_dependency(link_whole: [libqmp])
3274
3275 libchardev = static_library('chardev', chardev_ss.sources() + genh,
3276                             name_suffix: 'fa',
3277                             dependencies: chardev_ss.dependencies(),
3278                             build_by_default: false)
3279
3280 chardev = declare_dependency(link_whole: libchardev)
3281
3282 hwcore_ss = hwcore_ss.apply(config_host, strict: false)
3283 libhwcore = static_library('hwcore', sources: hwcore_ss.sources() + genh,
3284                            name_suffix: 'fa',
3285                            build_by_default: false)
3286 hwcore = declare_dependency(link_whole: libhwcore)
3287 common_ss.add(hwcore)
3288
3289 ###########
3290 # Targets #
3291 ###########
3292
3293 emulator_modules = []
3294 foreach m : block_mods + softmmu_mods
3295   emulator_modules += shared_module(m.name(),
3296                 build_by_default: true,
3297                 name_prefix: '',
3298                 link_whole: m,
3299                 install: true,
3300                 install_dir: qemu_moddir)
3301 endforeach
3302 if emulator_modules.length() > 0
3303   alias_target('modules', emulator_modules)
3304 endif
3305
3306 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
3307 common_ss.add(qom, qemuutil)
3308
3309 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
3310 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
3311
3312 common_all = common_ss.apply(config_all, strict: false)
3313 common_all = static_library('common',
3314                             build_by_default: false,
3315                             sources: common_all.sources() + genh,
3316                             include_directories: common_user_inc,
3317                             implicit_include_directories: false,
3318                             dependencies: common_all.dependencies(),
3319                             name_suffix: 'fa')
3320
3321 feature_to_c = find_program('scripts/feature_to_c.sh')
3322
3323 if targetos == 'darwin'
3324   entitlement = find_program('scripts/entitlement.sh')
3325 endif
3326
3327 emulators = {}
3328 foreach target : target_dirs
3329   config_target = config_target_mak[target]
3330   target_name = config_target['TARGET_NAME']
3331   target_base_arch = config_target['TARGET_BASE_ARCH']
3332   arch_srcs = [config_target_h[target]]
3333   arch_deps = []
3334   c_args = ['-DNEED_CPU_H',
3335             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3336             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3337   link_args = emulator_link_args
3338
3339   config_target += config_host
3340   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3341   if targetos == 'linux'
3342     target_inc += include_directories('linux-headers', is_system: true)
3343   endif
3344   if target.endswith('-softmmu')
3345     qemu_target_name = 'qemu-system-' + target_name
3346     target_type='system'
3347     t = target_softmmu_arch[target_base_arch].apply(config_target, strict: false)
3348     arch_srcs += t.sources()
3349     arch_deps += t.dependencies()
3350
3351     hw_dir = target_name == 'sparc64' ? 'sparc64' : target_base_arch
3352     hw = hw_arch[hw_dir].apply(config_target, strict: false)
3353     arch_srcs += hw.sources()
3354     arch_deps += hw.dependencies()
3355
3356     arch_srcs += config_devices_h[target]
3357     link_args += ['@block.syms', '@qemu.syms']
3358   else
3359     abi = config_target['TARGET_ABI_DIR']
3360     target_type='user'
3361     target_inc += common_user_inc
3362     qemu_target_name = 'qemu-' + target_name
3363     if target_base_arch in target_user_arch
3364       t = target_user_arch[target_base_arch].apply(config_target, strict: false)
3365       arch_srcs += t.sources()
3366       arch_deps += t.dependencies()
3367     endif
3368     if 'CONFIG_LINUX_USER' in config_target
3369       base_dir = 'linux-user'
3370     endif
3371     if 'CONFIG_BSD_USER' in config_target
3372       base_dir = 'bsd-user'
3373       target_inc += include_directories('bsd-user/' / targetos)
3374       target_inc += include_directories('bsd-user/host/' / host_arch)
3375       dir = base_dir / abi
3376       arch_srcs += files(dir / 'signal.c', dir / 'target_arch_cpu.c')
3377     endif
3378     target_inc += include_directories(
3379       base_dir,
3380       base_dir / abi,
3381     )
3382     if 'CONFIG_LINUX_USER' in config_target
3383       dir = base_dir / abi
3384       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
3385       if config_target.has_key('TARGET_SYSTBL_ABI')
3386         arch_srcs += \
3387           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
3388                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
3389       endif
3390     endif
3391   endif
3392
3393   if 'TARGET_XML_FILES' in config_target
3394     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
3395                                 output: target + '-gdbstub-xml.c',
3396                                 input: files(config_target['TARGET_XML_FILES'].split()),
3397                                 command: [feature_to_c, '@INPUT@'],
3398                                 capture: true)
3399     arch_srcs += gdbstub_xml
3400   endif
3401
3402   t = target_arch[target_base_arch].apply(config_target, strict: false)
3403   arch_srcs += t.sources()
3404   arch_deps += t.dependencies()
3405
3406   target_common = common_ss.apply(config_target, strict: false)
3407   objects = common_all.extract_objects(target_common.sources())
3408   deps = target_common.dependencies()
3409
3410   target_specific = specific_ss.apply(config_target, strict: false)
3411   arch_srcs += target_specific.sources()
3412   arch_deps += target_specific.dependencies()
3413
3414   lib = static_library('qemu-' + target,
3415                  sources: arch_srcs + genh,
3416                  dependencies: arch_deps,
3417                  objects: objects,
3418                  include_directories: target_inc,
3419                  c_args: c_args,
3420                  build_by_default: false,
3421                  name_suffix: 'fa')
3422
3423   if target.endswith('-softmmu')
3424     execs = [{
3425       'name': 'qemu-system-' + target_name,
3426       'win_subsystem': 'console',
3427       'sources': files('softmmu/main.c'),
3428       'dependencies': []
3429     }]
3430     if targetos == 'windows' and (sdl.found() or gtk.found())
3431       execs += [{
3432         'name': 'qemu-system-' + target_name + 'w',
3433         'win_subsystem': 'windows',
3434         'sources': files('softmmu/main.c'),
3435         'dependencies': []
3436       }]
3437     endif
3438     if get_option('fuzzing')
3439       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
3440       execs += [{
3441         'name': 'qemu-fuzz-' + target_name,
3442         'win_subsystem': 'console',
3443         'sources': specific_fuzz.sources(),
3444         'dependencies': specific_fuzz.dependencies(),
3445       }]
3446     endif
3447   else
3448     execs = [{
3449       'name': 'qemu-' + target_name,
3450       'win_subsystem': 'console',
3451       'sources': [],
3452       'dependencies': []
3453     }]
3454   endif
3455   foreach exe: execs
3456     exe_name = exe['name']
3457     if targetos == 'darwin'
3458       exe_name += '-unsigned'
3459     endif
3460
3461     emulator = executable(exe_name, exe['sources'],
3462                install: true,
3463                c_args: c_args,
3464                dependencies: arch_deps + deps + exe['dependencies'],
3465                objects: lib.extract_all_objects(recursive: true),
3466                link_language: link_language,
3467                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
3468                link_args: link_args,
3469                win_subsystem: exe['win_subsystem'])
3470
3471     if targetos == 'darwin'
3472       icon = 'pc-bios/qemu.rsrc'
3473       build_input = [emulator, files(icon)]
3474       install_input = [
3475         get_option('bindir') / exe_name,
3476         meson.current_source_dir() / icon
3477       ]
3478       if 'CONFIG_HVF' in config_target
3479         entitlements = 'accel/hvf/entitlements.plist'
3480         build_input += files(entitlements)
3481         install_input += meson.current_source_dir() / entitlements
3482       endif
3483
3484       emulators += {exe['name'] : custom_target(exe['name'],
3485                    input: build_input,
3486                    output: exe['name'],
3487                    command: [entitlement, '@OUTPUT@', '@INPUT@'])
3488       }
3489
3490       meson.add_install_script(entitlement, '--install',
3491                                get_option('bindir') / exe['name'],
3492                                install_input)
3493     else
3494       emulators += {exe['name']: emulator}
3495     endif
3496
3497     if stap.found()
3498       foreach stp: [
3499         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
3500         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
3501         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
3502         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
3503       ]
3504         custom_target(exe['name'] + stp['ext'],
3505                       input: trace_events_all,
3506                       output: exe['name'] + stp['ext'],
3507                       install: stp['install'],
3508                       install_dir: get_option('datadir') / 'systemtap/tapset',
3509                       command: [
3510                         tracetool, '--group=all', '--format=' + stp['fmt'],
3511                         '--binary=' + stp['bin'],
3512                         '--target-name=' + target_name,
3513                         '--target-type=' + target_type,
3514                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
3515                         '@INPUT@', '@OUTPUT@'
3516                       ],
3517                       depend_files: tracetool_depends)
3518       endforeach
3519     endif
3520   endforeach
3521 endforeach
3522
3523 # Other build targets
3524
3525 if 'CONFIG_PLUGIN' in config_host
3526   install_headers('include/qemu/qemu-plugin.h')
3527 endif
3528
3529 subdir('qga')
3530
3531 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
3532 # when we don't build tools or system
3533 if xkbcommon.found()
3534   # used for the update-keymaps target, so include rules even if !have_tools
3535   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
3536                            dependencies: [qemuutil, xkbcommon], install: have_tools)
3537 endif
3538
3539 if have_tools
3540   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
3541              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
3542   qemu_io = executable('qemu-io', files('qemu-io.c'),
3543              dependencies: [block, qemuutil], install: true)
3544   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
3545                dependencies: [blockdev, qemuutil, gnutls, selinux],
3546                install: true)
3547
3548   subdir('storage-daemon')
3549   subdir('contrib/rdmacm-mux')
3550   subdir('contrib/elf2dmp')
3551
3552   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
3553              dependencies: qemuutil,
3554              install: true)
3555
3556   if have_vhost_user
3557     subdir('contrib/vhost-user-blk')
3558     subdir('contrib/vhost-user-gpu')
3559     subdir('contrib/vhost-user-input')
3560     subdir('contrib/vhost-user-scsi')
3561   endif
3562
3563   if targetos == 'linux'
3564     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
3565                dependencies: [qemuutil, libcap_ng],
3566                install: true,
3567                install_dir: get_option('libexecdir'))
3568
3569     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
3570                dependencies: [authz, crypto, io, qom, qemuutil,
3571                               libcap_ng, mpathpersist],
3572                install: true)
3573   endif
3574
3575   if have_ivshmem
3576     subdir('contrib/ivshmem-client')
3577     subdir('contrib/ivshmem-server')
3578   endif
3579 endif
3580
3581 subdir('scripts')
3582 subdir('tools')
3583 subdir('pc-bios')
3584 subdir('docs')
3585 subdir('tests')
3586 if gtk.found()
3587   subdir('po')
3588 endif
3589
3590 if host_machine.system() == 'windows'
3591   nsis_cmd = [
3592     find_program('scripts/nsis.py'),
3593     '@OUTPUT@',
3594     get_option('prefix'),
3595     meson.current_source_dir(),
3596     host_machine.cpu(),
3597     '--',
3598     '-DDISPLAYVERSION=' + meson.project_version(),
3599   ]
3600   if build_docs
3601     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
3602   endif
3603   if gtk.found()
3604     nsis_cmd += '-DCONFIG_GTK=y'
3605   endif
3606
3607   nsis = custom_target('nsis',
3608                        output: 'qemu-setup-' + meson.project_version() + '.exe',
3609                        input: files('qemu.nsi'),
3610                        build_always_stale: true,
3611                        command: nsis_cmd + ['@INPUT@'])
3612   alias_target('installer', nsis)
3613 endif
3614
3615 #########################
3616 # Configuration summary #
3617 #########################
3618
3619 # Directories
3620 summary_info = {}
3621 summary_info += {'Install prefix':    get_option('prefix')}
3622 summary_info += {'BIOS directory':    qemu_datadir}
3623 summary_info += {'firmware path':     get_option('prefix') / get_option('qemu_firmwarepath')}
3624 summary_info += {'binary directory':  get_option('prefix') / get_option('bindir')}
3625 summary_info += {'library directory': get_option('prefix') / get_option('libdir')}
3626 summary_info += {'module directory':  qemu_moddir}
3627 summary_info += {'libexec directory': get_option('prefix') / get_option('libexecdir')}
3628 summary_info += {'include directory': get_option('prefix') / get_option('includedir')}
3629 summary_info += {'config directory':  get_option('prefix') / get_option('sysconfdir')}
3630 if targetos != 'windows'
3631   summary_info += {'local state directory': get_option('prefix') / get_option('localstatedir')}
3632   summary_info += {'Manual directory':      get_option('prefix') / get_option('mandir')}
3633 else
3634   summary_info += {'local state directory': 'queried at runtime'}
3635 endif
3636 summary_info += {'Doc directory':     get_option('prefix') / get_option('docdir')}
3637 summary_info += {'Build directory':   meson.current_build_dir()}
3638 summary_info += {'Source path':       meson.current_source_dir()}
3639 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
3640 summary(summary_info, bool_yn: true, section: 'Directories')
3641
3642 # Host binaries
3643 summary_info = {}
3644 summary_info += {'git':               config_host['GIT']}
3645 summary_info += {'make':              config_host['MAKE']}
3646 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
3647 summary_info += {'sphinx-build':      sphinx_build}
3648 if config_host.has_key('HAVE_GDB_BIN')
3649   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
3650 endif
3651 summary_info += {'iasl':              iasl}
3652 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
3653 if targetos == 'windows' and have_ga
3654   summary_info += {'wixl':            wixl}
3655 endif
3656 if slirp_opt != 'disabled' and have_system
3657   summary_info += {'smbd':            have_slirp_smbd ? smbd_path : false}
3658 endif
3659 summary(summary_info, bool_yn: true, section: 'Host binaries')
3660
3661 # Configurable features
3662 summary_info = {}
3663 summary_info += {'Documentation':     build_docs}
3664 summary_info += {'system-mode emulation': have_system}
3665 summary_info += {'user-mode emulation': have_user}
3666 summary_info += {'block layer':       have_block}
3667 summary_info += {'Install blobs':     get_option('install_blobs')}
3668 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
3669 if config_host.has_key('CONFIG_MODULES')
3670   summary_info += {'alternative module path': get_option('module_upgrades')}
3671 endif
3672 summary_info += {'fuzzing support':   get_option('fuzzing')}
3673 if have_system
3674   summary_info += {'Audio drivers':     ' '.join(audio_drivers_selected)}
3675 endif
3676 summary_info += {'Trace backends':    ','.join(get_option('trace_backends'))}
3677 if 'simple' in get_option('trace_backends')
3678   summary_info += {'Trace output file': get_option('trace_file') + '-<pid>'}
3679 endif
3680 summary_info += {'D-Bus display':     dbus_display}
3681 summary_info += {'QOM debugging':     get_option('qom_cast_debug')}
3682 summary_info += {'vhost-kernel support': have_vhost_kernel}
3683 summary_info += {'vhost-net support': have_vhost_net}
3684 summary_info += {'vhost-user support': have_vhost_user}
3685 summary_info += {'vhost-user-crypto support': have_vhost_user_crypto}
3686 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
3687 summary_info += {'vhost-vdpa support': have_vhost_vdpa}
3688 summary_info += {'build guest agent': have_ga}
3689 summary(summary_info, bool_yn: true, section: 'Configurable features')
3690
3691 # Compilation information
3692 summary_info = {}
3693 summary_info += {'host CPU':          cpu}
3694 summary_info += {'host endianness':   build_machine.endian()}
3695 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
3696 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
3697 if link_language == 'cpp'
3698   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
3699 else
3700   summary_info += {'C++ compiler':      false}
3701 endif
3702 if targetos == 'darwin'
3703   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
3704 endif
3705 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
3706                                                + ['-O' + get_option('optimization')]
3707                                                + (get_option('debug') ? ['-g'] : []))}
3708 if link_language == 'cpp'
3709   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
3710                                                + ['-O' + get_option('optimization')]
3711                                                + (get_option('debug') ? ['-g'] : []))}
3712 endif
3713 if targetos == 'darwin'
3714   summary_info += {'OBJCFLAGS':       ' '.join(get_option('objc_args')
3715                                                + ['-O' + get_option('optimization')]
3716                                                + (get_option('debug') ? ['-g'] : []))}
3717 endif
3718 link_args = get_option(link_language + '_link_args')
3719 if link_args.length() > 0
3720   summary_info += {'LDFLAGS':         ' '.join(link_args)}
3721 endif
3722 summary_info += {'QEMU_CFLAGS':       ' '.join(qemu_cflags)}
3723 summary_info += {'QEMU_CXXFLAGS':     ' '.join(qemu_cxxflags)}
3724 summary_info += {'QEMU_OBJCFLAGS':    ' '.join(qemu_objcflags)}
3725 summary_info += {'QEMU_LDFLAGS':      ' '.join(qemu_ldflags)}
3726 summary_info += {'profiler':          get_option('profiler')}
3727 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
3728 summary_info += {'PIE':               get_option('b_pie')}
3729 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
3730 summary_info += {'malloc trim support': has_malloc_trim}
3731 summary_info += {'membarrier':        have_membarrier}
3732 summary_info += {'debug stack usage': get_option('debug_stack_usage')}
3733 summary_info += {'mutex debugging':   get_option('debug_mutex')}
3734 summary_info += {'memory allocator':  get_option('malloc')}
3735 summary_info += {'avx2 optimization': config_host_data.get('CONFIG_AVX2_OPT')}
3736 summary_info += {'avx512f optimization': config_host_data.get('CONFIG_AVX512F_OPT')}
3737 summary_info += {'gprof enabled':     get_option('gprof')}
3738 summary_info += {'gcov':              get_option('b_coverage')}
3739 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
3740 summary_info += {'CFI support':       get_option('cfi')}
3741 if get_option('cfi')
3742   summary_info += {'CFI debug support': get_option('cfi_debug')}
3743 endif
3744 summary_info += {'strip binaries':    get_option('strip')}
3745 summary_info += {'sparse':            sparse}
3746 summary_info += {'mingw32 support':   targetos == 'windows'}
3747
3748 # snarf the cross-compilation information for tests
3749 foreach target: target_dirs
3750   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
3751   if fs.exists(tcg_mak)
3752     config_cross_tcg = keyval.load(tcg_mak)
3753     target = config_cross_tcg['TARGET_NAME']
3754     compiler = ''
3755     if 'CC' in config_cross_tcg
3756       summary_info += {target + ' tests': config_cross_tcg['CC']}
3757     endif
3758    endif
3759 endforeach
3760
3761 summary(summary_info, bool_yn: true, section: 'Compilation')
3762
3763 # Targets and accelerators
3764 summary_info = {}
3765 if have_system
3766   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
3767   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
3768   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
3769   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
3770   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
3771   summary_info += {'Xen support':       xen.found()}
3772   if xen.found()
3773     summary_info += {'xen ctrl version':  xen.version()}
3774   endif
3775 endif
3776 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
3777 if config_all.has_key('CONFIG_TCG')
3778   if get_option('tcg_interpreter')
3779     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, slow)'}
3780   else
3781     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
3782   endif
3783   summary_info += {'TCG plugins': config_host.has_key('CONFIG_PLUGIN')}
3784   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
3785 endif
3786 summary_info += {'target list':       ' '.join(target_dirs)}
3787 if have_system
3788   summary_info += {'default devices':   get_option('default_devices')}
3789   summary_info += {'out of process emulation': multiprocess_allowed}
3790 endif
3791 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
3792
3793 # Block layer
3794 summary_info = {}
3795 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
3796 summary_info += {'coroutine pool':    have_coroutine_pool}
3797 if have_block
3798   summary_info += {'Block whitelist (rw)': get_option('block_drv_rw_whitelist')}
3799   summary_info += {'Block whitelist (ro)': get_option('block_drv_ro_whitelist')}
3800   summary_info += {'Use block whitelist in tools': get_option('block_drv_whitelist_in_tools')}
3801   summary_info += {'VirtFS support':    have_virtfs}
3802   summary_info += {'build virtiofs daemon': have_virtiofsd}
3803   summary_info += {'Live block migration': config_host_data.get('CONFIG_LIVE_BLOCK_MIGRATION')}
3804   summary_info += {'replication support': config_host_data.get('CONFIG_REPLICATION')}
3805   summary_info += {'bochs support':     get_option('bochs').allowed()}
3806   summary_info += {'cloop support':     get_option('cloop').allowed()}
3807   summary_info += {'dmg support':       get_option('dmg').allowed()}
3808   summary_info += {'qcow v1 support':   get_option('qcow1').allowed()}
3809   summary_info += {'vdi support':       get_option('vdi').allowed()}
3810   summary_info += {'vvfat support':     get_option('vvfat').allowed()}
3811   summary_info += {'qed support':       get_option('qed').allowed()}
3812   summary_info += {'parallels support': get_option('parallels').allowed()}
3813   summary_info += {'FUSE exports':      fuse}
3814 endif
3815 summary(summary_info, bool_yn: true, section: 'Block layer support')
3816
3817 # Crypto
3818 summary_info = {}
3819 summary_info += {'TLS priority':      get_option('tls_priority')}
3820 summary_info += {'GNUTLS support':    gnutls}
3821 if gnutls.found()
3822   summary_info += {'  GNUTLS crypto':   gnutls_crypto.found()}
3823 endif
3824 summary_info += {'libgcrypt':         gcrypt}
3825 summary_info += {'nettle':            nettle}
3826 if nettle.found()
3827    summary_info += {'  XTS':             xts != 'private'}
3828 endif
3829 summary_info += {'AF_ALG support':    have_afalg}
3830 summary_info += {'rng-none':          get_option('rng_none')}
3831 summary_info += {'Linux keyring':     have_keyring}
3832 summary(summary_info, bool_yn: true, section: 'Crypto')
3833
3834 # Libraries
3835 summary_info = {}
3836 if targetos == 'darwin'
3837   summary_info += {'Cocoa support':           cocoa}
3838   summary_info += {'vmnet.framework support': vmnet}
3839 endif
3840 summary_info += {'SDL support':       sdl}
3841 summary_info += {'SDL image support': sdl_image}
3842 summary_info += {'GTK support':       gtk}
3843 summary_info += {'pixman':            pixman}
3844 summary_info += {'VTE support':       vte}
3845 summary_info += {'slirp support':     slirp_opt == 'internal' ? slirp_opt : slirp}
3846 summary_info += {'libtasn1':          tasn1}
3847 summary_info += {'PAM':               pam}
3848 summary_info += {'iconv support':     iconv}
3849 summary_info += {'curses support':    curses}
3850 summary_info += {'virgl support':     virgl}
3851 summary_info += {'curl support':      curl}
3852 summary_info += {'Multipath support': mpathpersist}
3853 summary_info += {'PNG support':       png}
3854 summary_info += {'VNC support':       vnc}
3855 if vnc.found()
3856   summary_info += {'VNC SASL support':  sasl}
3857   summary_info += {'VNC JPEG support':  jpeg}
3858 endif
3859 if targetos not in ['darwin', 'haiku', 'windows']
3860   summary_info += {'OSS support':     oss}
3861 elif targetos == 'darwin'
3862   summary_info += {'CoreAudio support': coreaudio}
3863 elif targetos == 'windows'
3864   summary_info += {'DirectSound support': dsound}
3865 endif
3866 if targetos == 'linux'
3867   summary_info += {'ALSA support':    alsa}
3868   summary_info += {'PulseAudio support': pulse}
3869 endif
3870 summary_info += {'JACK support':      jack}
3871 summary_info += {'brlapi support':    brlapi}
3872 summary_info += {'vde support':       vde}
3873 summary_info += {'netmap support':    have_netmap}
3874 summary_info += {'l2tpv3 support':    have_l2tpv3}
3875 summary_info += {'Linux AIO support': libaio}
3876 summary_info += {'Linux io_uring support': linux_io_uring}
3877 summary_info += {'ATTR/XATTR support': libattr}
3878 summary_info += {'RDMA support':      rdma}
3879 summary_info += {'PVRDMA support':    have_pvrdma}
3880 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3881 summary_info += {'libcap-ng support': libcap_ng}
3882 summary_info += {'bpf support':       libbpf}
3883 summary_info += {'spice protocol support': spice_protocol}
3884 if spice_protocol.found()
3885   summary_info += {'  spice server support': spice}
3886 endif
3887 summary_info += {'rbd support':       rbd}
3888 summary_info += {'smartcard support': cacard}
3889 summary_info += {'U2F support':       u2f}
3890 summary_info += {'libusb':            libusb}
3891 summary_info += {'usb net redir':     usbredir}
3892 summary_info += {'OpenGL support (epoxy)': opengl}
3893 summary_info += {'GBM':               gbm}
3894 summary_info += {'libiscsi support':  libiscsi}
3895 summary_info += {'libnfs support':    libnfs}
3896 if targetos == 'windows'
3897   if have_ga
3898     summary_info += {'QGA VSS support':   have_qga_vss}
3899   endif
3900 endif
3901 summary_info += {'seccomp support':   seccomp}
3902 summary_info += {'GlusterFS support': glusterfs}
3903 summary_info += {'TPM support':       have_tpm}
3904 summary_info += {'libssh support':    libssh}
3905 summary_info += {'lzo support':       lzo}
3906 summary_info += {'snappy support':    snappy}
3907 summary_info += {'bzip2 support':     libbzip2}
3908 summary_info += {'lzfse support':     liblzfse}
3909 summary_info += {'zstd support':      zstd}
3910 summary_info += {'NUMA host support': numa}
3911 summary_info += {'capstone':          capstone}
3912 summary_info += {'libpmem support':   libpmem}
3913 summary_info += {'libdaxctl support': libdaxctl}
3914 summary_info += {'libudev':           libudev}
3915 # Dummy dependency, keep .found()
3916 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3917 summary_info += {'selinux':           selinux}
3918 summary(summary_info, bool_yn: true, section: 'Dependencies')
3919
3920 if not supported_cpus.contains(cpu)
3921   message()
3922   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3923   message()
3924   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3925   message('The QEMU project intends to remove support for this host CPU in')
3926   message('a future release if nobody volunteers to maintain it and to')
3927   message('provide a build host for our continuous integration setup.')
3928   message('configure has succeeded and you can continue to build, but')
3929   message('if you care about QEMU on this platform you should contact')
3930   message('us upstream at qemu-devel@nongnu.org.')
3931 endif
3932
3933 if not supported_oses.contains(targetos)
3934   message()
3935   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3936   message()
3937   message('Host OS ' + targetos + 'support is not currently maintained.')
3938   message('The QEMU project intends to remove support for this host OS in')
3939   message('a future release if nobody volunteers to maintain it and to')
3940   message('provide a build host for our continuous integration setup.')
3941   message('configure has succeeded and you can continue to build, but')
3942   message('if you care about QEMU on this platform you should contact')
3943   message('us upstream at qemu-devel@nongnu.org.')
3944 endif