meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Allow both shared and static libraries unless --enable-static
  22 static_kwargs = enable_static ? {'static': true} : {}
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 config_host_data = configuration_data()
  44 genh = []
  45
  46 target_dirs = config_host['TARGET_DIRS'].split()
  47 have_user = false
  48 have_system = false
  49 foreach target : target_dirs
  50   have_user = have_user or target.endswith('-user')
  51   have_system = have_system or target.endswith('-softmmu')
  52 endforeach
  53 have_tools = 'CONFIG_TOOLS' in config_host
  54 have_block = have_system or have_tools
  55
  56 python = import('python').find_installation()
  57
  58 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  59 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  60   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  61
  62 cpu = host_machine.cpu_family()
  63 targetos = host_machine.system()
  64
  65 if cpu in ['x86', 'x86_64']
  66   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  67 elif cpu == 'aarch64'
  68   kvm_targets = ['aarch64-softmmu']
  69 elif cpu == 's390x'
  70   kvm_targets = ['s390x-softmmu']
  71 elif cpu in ['ppc', 'ppc64']
  72   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  73 elif cpu in ['mips', 'mips64']
  74   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  75 else
  76   kvm_targets = []
  77 endif
  78
  79 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  80 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  81   # i368 emulator provides xenpv machine type for multiple architectures
  82   accelerator_targets += {
  83     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  84   }
  85 endif
  86 if cpu in ['x86', 'x86_64']
  87   accelerator_targets += {
  88     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  89     'CONFIG_HVF': ['x86_64-softmmu'],
  90     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
  91     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  92   }
  93 endif
  94
  95 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
  96 install_edk2_blobs = false
  97 if get_option('install_blobs')
  98   foreach target : target_dirs
  99     install_edk2_blobs = install_edk2_blobs or target in edk2_targets
 100   endforeach
 101 endif
 102
 103 bzip2 = find_program('bzip2', required: install_edk2_blobs)
 104
 105 ##################
 106 # Compiler flags #
 107 ##################
 108
 109 # Specify linker-script with add_project_link_arguments so that it is not placed
 110 # within a linker --start-group/--end-group pair
 111 if 'CONFIG_FUZZ' in config_host
 112    add_project_link_arguments(['-Wl,-T,',
 113                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 114                               native: false, language: ['c', 'cpp', 'objc'])
 115 endif
 116
 117 add_global_arguments(config_host['QEMU_CFLAGS'].split(),
 118                      native: false, language: ['c', 'objc'])
 119 add_global_arguments(config_host['QEMU_CXXFLAGS'].split(),
 120                      native: false, language: 'cpp')
 121 add_global_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 122                           native: false, language: ['c', 'cpp', 'objc'])
 123
 124 if targetos == 'linux'
 125   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 126                         '-isystem', 'linux-headers',
 127                         language: ['c', 'cpp'])
 128 endif
 129
 130 add_project_arguments('-iquote', '.',
 131                       '-iquote', meson.current_source_dir(),
 132                       '-iquote', meson.current_source_dir() / 'include',
 133                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 134                       language: ['c', 'cpp', 'objc'])
 135
 136 link_language = meson.get_external_property('link_language', 'cpp')
 137 if link_language == 'cpp'
 138   add_languages('cpp', required: true, native: false)
 139 endif
 140 if host_machine.system() == 'darwin'
 141   add_languages('objc', required: false, native: false)
 142 endif
 143
 144 sparse = find_program('cgcc', required: get_option('sparse'))
 145 if sparse.found()
 146   run_target('sparse',
 147              command: [find_program('scripts/check_sparse.py'),
 148                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 149                        '-Wno-transparent-union', '-Wno-old-initializer',
 150                        '-Wno-non-pointer-null'])
 151 endif
 152
 153 ###########################################
 154 # Target-specific checks and dependencies #
 155 ###########################################
 156
 157 if targetos != 'linux' and get_option('mpath').enabled()
 158   error('Multipath is supported only on Linux')
 159 endif
 160
 161 if targetos != 'linux' and get_option('multiprocess').enabled()
 162   error('Multiprocess QEMU is supported only on Linux')
 163 endif
 164 multiprocess_allowed = targetos == 'linux' and not get_option('multiprocess').disabled()
 165
 166 libm = cc.find_library('m', required: false)
 167 threads = dependency('threads')
 168 util = cc.find_library('util', required: false)
 169 winmm = []
 170 socket = []
 171 version_res = []
 172 coref = []
 173 iokit = []
 174 emulator_link_args = []
 175 nvmm =not_found
 176 hvf = not_found
 177 if targetos == 'windows'
 178   socket = cc.find_library('ws2_32')
 179   winmm = cc.find_library('winmm')
 180
 181   win = import('windows')
 182   version_res = win.compile_resources('version.rc',
 183                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 184                                       include_directories: include_directories('.'))
 185 elif targetos == 'darwin'
 186   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 187   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 188 elif targetos == 'sunos'
 189   socket = [cc.find_library('socket'),
 190             cc.find_library('nsl'),
 191             cc.find_library('resolv')]
 192 elif targetos == 'haiku'
 193   socket = [cc.find_library('posix_error_mapper'),
 194             cc.find_library('network'),
 195             cc.find_library('bsd')]
 196 elif targetos == 'openbsd'
 197   if not get_option('tcg').disabled() and target_dirs.length() > 0
 198     # Disable OpenBSD W^X if available
 199     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 200   endif
 201 endif
 202
 203 accelerators = []
 204 if not get_option('kvm').disabled() and targetos == 'linux'
 205   accelerators += 'CONFIG_KVM'
 206 endif
 207 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 208   accelerators += 'CONFIG_XEN'
 209   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 210 else
 211   have_xen_pci_passthrough = false
 212 endif
 213 if not get_option('whpx').disabled() and targetos == 'windows'
 214   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 215     error('WHPX requires 64-bit host')
 216   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 217        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 218     accelerators += 'CONFIG_WHPX'
 219   endif
 220 endif
 221 if not get_option('hvf').disabled()
 222   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 223                    required: get_option('hvf'))
 224   if hvf.found()
 225     accelerators += 'CONFIG_HVF'
 226   endif
 227 endif
 228 if not get_option('hax').disabled()
 229   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 230     accelerators += 'CONFIG_HAX'
 231   endif
 232 endif
 233 if targetos == 'netbsd'
 234   if cc.has_header_symbol('nvmm.h', 'nvmm_cpu_stop', required: get_option('nvmm'))
 235     nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 236   endif
 237   if nvmm.found()
 238     accelerators += 'CONFIG_NVMM'
 239   endif
 240 endif
 241
 242 tcg_arch = config_host['ARCH']
 243 if not get_option('tcg').disabled()
 244   if cpu not in supported_cpus
 245     if get_option('tcg_interpreter')
 246       warning('Unsupported CPU @0@, will use TCG with TCI (experimental and slow)'.format(cpu))
 247     else
 248       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 249     endif
 250   elif get_option('tcg_interpreter')
 251     warning('Use of the TCG interpretor is not recommended on this host')
 252     warning('architecture. There is a native TCG execution backend available')
 253     warning('which provides substantially better performance and reliability.')
 254     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 255     warning('configuration option on this architecture to use the native')
 256     warning('backend.')
 257   endif
 258   if get_option('tcg_interpreter')
 259     tcg_arch = 'tci'
 260   elif config_host['ARCH'] == 'sparc64'
 261     tcg_arch = 'sparc'
 262   elif config_host['ARCH'] == 's390x'
 263     tcg_arch = 's390'
 264   elif config_host['ARCH'] in ['x86_64', 'x32']
 265     tcg_arch = 'i386'
 266   elif config_host['ARCH'] == 'ppc64'
 267     tcg_arch = 'ppc'
 268   elif config_host['ARCH'] in ['riscv32', 'riscv64']
 269     tcg_arch = 'riscv'
 270   endif
 271   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 272                         language: ['c', 'cpp', 'objc'])
 273
 274   accelerators += 'CONFIG_TCG'
 275   config_host += { 'CONFIG_TCG': 'y' }
 276 endif
 277
 278 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 279   error('KVM not available on this platform')
 280 endif
 281 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 282   error('HVF not available on this platform')
 283 endif
 284 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 285   error('NVMM not available on this platform')
 286 endif
 287 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 288   error('WHPX not available on this platform')
 289 endif
 290 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 291   if 'CONFIG_XEN' in accelerators
 292     error('Xen PCI passthrough not available on this platform')
 293   else
 294     error('Xen PCI passthrough requested but Xen not enabled')
 295   endif
 296 endif
 297
 298 ################
 299 # Dependencies #
 300 ################
 301
 302 # The path to glib.h is added to all compilation commands.  This was
 303 # grandfathered in from the QEMU Makefiles.
 304 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 305                       native: false, language: ['c', 'cpp', 'objc'])
 306 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 307                           link_args: config_host['GLIB_LIBS'].split())
 308 # override glib dep with the configure results (for subprojects)
 309 meson.override_dependency('glib-2.0', glib)
 310
 311 gio = not_found
 312 if 'CONFIG_GIO' in config_host
 313   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 314                            link_args: config_host['GIO_LIBS'].split())
 315 endif
 316 lttng = not_found
 317 if 'CONFIG_TRACE_UST' in config_host
 318   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 319 endif
 320 urcubp = not_found
 321 if 'CONFIG_TRACE_UST' in config_host
 322   urcubp = declare_dependency(link_args: config_host['URCU_BP_LIBS'].split())
 323 endif
 324 pixman = not_found
 325 if have_system or have_tools
 326   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 327                       method: 'pkg-config', kwargs: static_kwargs)
 328 endif
 329 libaio = cc.find_library('aio', required: false)
 330 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 331
 332 linux_io_uring = not_found
 333 if not get_option('linux_io_uring').auto() or have_block
 334   linux_io_uring = dependency('liburing', required: get_option('linux_io_uring'),
 335                               method: 'pkg-config', kwargs: static_kwargs)
 336 endif
 337 libxml2 = not_found
 338 if not get_option('libxml2').auto() or have_block
 339   libxml2 = dependency('libxml-2.0', required: get_option('libxml2'),
 340                        method: 'pkg-config', kwargs: static_kwargs)
 341 endif
 342 libnfs = not_found
 343 if not get_option('libnfs').auto() or have_block
 344   libnfs = dependency('libnfs', version: '>=1.9.3',
 345                       required: get_option('libnfs'),
 346                       method: 'pkg-config', kwargs: static_kwargs)
 347 endif
 348
 349 libattr_test = '''
 350   #include <stddef.h>
 351   #include <sys/types.h>
 352   #ifdef CONFIG_LIBATTR
 353   #include <attr/xattr.h>
 354   #else
 355   #include <sys/xattr.h>
 356   #endif
 357   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 358
 359 libattr = not_found
 360 have_old_libattr = false
 361 if not get_option('attr').disabled()
 362   if cc.links(libattr_test)
 363     libattr = declare_dependency()
 364   else
 365     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 366                               required: get_option('attr'),
 367                               kwargs: static_kwargs)
 368     if libattr.found() and not \
 369       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 370       libattr = not_found
 371       if get_option('attr').enabled()
 372         error('could not link libattr')
 373       else
 374         warning('could not link libattr, disabling')
 375       endif
 376     else
 377       have_old_libattr = libattr.found()
 378     endif
 379   endif
 380 endif
 381
 382 cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 383 if cocoa.found() and get_option('sdl').enabled()
 384   error('Cocoa and SDL cannot be enabled at the same time')
 385 endif
 386 if cocoa.found() and get_option('gtk').enabled()
 387   error('Cocoa and GTK+ cannot be enabled at the same time')
 388 endif
 389
 390 seccomp = not_found
 391 if not get_option('seccomp').auto() or have_system or have_tools
 392   seccomp = dependency('libseccomp', version: '>=2.3.0',
 393                        required: get_option('seccomp'),
 394                        method: 'pkg-config', kwargs: static_kwargs)
 395 endif
 396
 397 libcap_ng = not_found
 398 if not get_option('cap_ng').auto() or have_system or have_tools
 399   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 400                               required: get_option('cap_ng'),
 401                               kwargs: static_kwargs)
 402 endif
 403 if libcap_ng.found() and not cc.links('''
 404    #include <cap-ng.h>
 405    int main(void)
 406    {
 407      capng_capability_to_name(CAPNG_EFFECTIVE);
 408      return 0;
 409    }''', dependencies: libcap_ng)
 410   libcap_ng = not_found
 411   if get_option('cap_ng').enabled()
 412     error('could not link libcap-ng')
 413   else
 414     warning('could not link libcap-ng, disabling')
 415   endif
 416 endif
 417
 418 if get_option('xkbcommon').auto() and not have_system and not have_tools
 419   xkbcommon = not_found
 420 else
 421   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 422                          method: 'pkg-config', kwargs: static_kwargs)
 423 endif
 424 vde = not_found
 425 if config_host.has_key('CONFIG_VDE')
 426   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 427 endif
 428 pulse = not_found
 429 if 'CONFIG_LIBPULSE' in config_host
 430   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 431                              link_args: config_host['PULSE_LIBS'].split())
 432 endif
 433 alsa = not_found
 434 if 'CONFIG_ALSA' in config_host
 435   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 436                             link_args: config_host['ALSA_LIBS'].split())
 437 endif
 438 jack = not_found
 439 if 'CONFIG_LIBJACK' in config_host
 440   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 441 endif
 442 spice = not_found
 443 spice_headers = not_found
 444 spice_protocol = not_found
 445 if 'CONFIG_SPICE' in config_host
 446   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 447                              link_args: config_host['SPICE_LIBS'].split())
 448   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 449 endif
 450 if 'CONFIG_SPICE_PROTOCOL' in config_host
 451   spice_protocol = declare_dependency(compile_args: config_host['SPICE_PROTOCOL_CFLAGS'].split())
 452 endif
 453 rt = cc.find_library('rt', required: false)
 454 libdl = not_found
 455 if 'CONFIG_PLUGIN' in config_host
 456   libdl = cc.find_library('dl', required: true)
 457 endif
 458 libiscsi = not_found
 459 if not get_option('libiscsi').auto() or have_block
 460   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 461                          required: get_option('libiscsi'),
 462                          method: 'pkg-config', kwargs: static_kwargs)
 463 endif
 464 zstd = not_found
 465 if not get_option('zstd').auto() or have_block
 466   zstd = dependency('libzstd', version: '>=1.4.0',
 467                     required: get_option('zstd'),
 468                     method: 'pkg-config', kwargs: static_kwargs)
 469 endif
 470 gbm = not_found
 471 if 'CONFIG_GBM' in config_host
 472   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 473                            link_args: config_host['GBM_LIBS'].split())
 474 endif
 475 virgl = not_found
 476 if not get_option('virglrenderer').auto() or have_system
 477   virgl = dependency('virglrenderer',
 478                      method: 'pkg-config',
 479                      required: get_option('virglrenderer'),
 480                      kwargs: static_kwargs)
 481 endif
 482 curl = not_found
 483 if not get_option('curl').auto() or have_block
 484   curl = dependency('libcurl', version: '>=7.29.0',
 485                     method: 'pkg-config',
 486                     required: get_option('curl'),
 487                     kwargs: static_kwargs)
 488 endif
 489 libudev = not_found
 490 if targetos == 'linux' and (have_system or have_tools)
 491   libudev = dependency('libudev',
 492                        method: 'pkg-config',
 493                        required: get_option('libudev'),
 494                        kwargs: static_kwargs)
 495 endif
 496
 497 mpathlibs = [libudev]
 498 mpathpersist = not_found
 499 mpathpersist_new_api = false
 500 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 501   mpath_test_source_new = '''
 502     #include <libudev.h>
 503     #include <mpath_persist.h>
 504     unsigned mpath_mx_alloc_len = 1024;
 505     int logsink;
 506     static struct config *multipath_conf;
 507     extern struct udev *udev;
 508     extern struct config *get_multipath_config(void);
 509     extern void put_multipath_config(struct config *conf);
 510     struct udev *udev;
 511     struct config *get_multipath_config(void) { return multipath_conf; }
 512     void put_multipath_config(struct config *conf) { }
 513     int main(void) {
 514         udev = udev_new();
 515         multipath_conf = mpath_lib_init();
 516         return 0;
 517     }'''
 518   mpath_test_source_old = '''
 519       #include <libudev.h>
 520       #include <mpath_persist.h>
 521       unsigned mpath_mx_alloc_len = 1024;
 522       int logsink;
 523       int main(void) {
 524           struct udev *udev = udev_new();
 525           mpath_lib_init(udev);
 526           return 0;
 527       }'''
 528   libmpathpersist = cc.find_library('mpathpersist',
 529                                     required: get_option('mpath'),
 530                                     kwargs: static_kwargs)
 531   if libmpathpersist.found()
 532     mpathlibs += libmpathpersist
 533     if enable_static
 534       mpathlibs += cc.find_library('devmapper',
 535                                      required: get_option('mpath'),
 536                                      kwargs: static_kwargs)
 537     endif
 538     mpathlibs += cc.find_library('multipath',
 539                                  required: get_option('mpath'),
 540                                  kwargs: static_kwargs)
 541     foreach lib: mpathlibs
 542       if not lib.found()
 543         mpathlibs = []
 544         break
 545       endif
 546     endforeach
 547     if mpathlibs.length() == 0
 548       msg = 'Dependencies missing for libmpathpersist'
 549     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 550       mpathpersist = declare_dependency(dependencies: mpathlibs)
 551       mpathpersist_new_api = true
 552     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 553       mpathpersist = declare_dependency(dependencies: mpathlibs)
 554     else
 555       msg = 'Cannot detect libmpathpersist API'
 556     endif
 557     if not mpathpersist.found()
 558       if get_option('mpath').enabled()
 559         error(msg)
 560       else
 561         warning(msg + ', disabling')
 562       endif
 563     endif
 564   endif
 565 endif
 566
 567 iconv = not_found
 568 curses = not_found
 569 if have_system and not get_option('curses').disabled()
 570   curses_test = '''
 571     #include <locale.h>
 572     #include <curses.h>
 573     #include <wchar.h>
 574     int main(void) {
 575       wchar_t wch = L'w';
 576       setlocale(LC_ALL, "");
 577       resize_term(0, 0);
 578       addwstr(L"wide chars\n");
 579       addnwstr(&wch, 1);
 580       add_wch(WACS_DEGREE);
 581       return 0;
 582     }'''
 583
 584   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 585   foreach curses_dep : curses_dep_list
 586     if not curses.found()
 587       curses = dependency(curses_dep,
 588                           required: false,
 589                           method: 'pkg-config',
 590                           kwargs: static_kwargs)
 591     endif
 592   endforeach
 593   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 594   curses_compile_args = ['-DNCURSES_WIDECHAR']
 595   if curses.found()
 596     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 597       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 598     else
 599       msg = 'curses package not usable'
 600       curses = not_found
 601     endif
 602   endif
 603   if not curses.found()
 604     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 605     if targetos != 'windows' and not has_curses_h
 606       message('Trying with /usr/include/ncursesw')
 607       curses_compile_args += ['-I/usr/include/ncursesw']
 608       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 609     endif
 610     if has_curses_h
 611       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 612       foreach curses_libname : curses_libname_list
 613         libcurses = cc.find_library(curses_libname,
 614                                     required: false,
 615                                     kwargs: static_kwargs)
 616         if libcurses.found()
 617           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 618             curses = declare_dependency(compile_args: curses_compile_args,
 619                                         dependencies: [libcurses])
 620             break
 621           else
 622             msg = 'curses library not usable'
 623           endif
 624         endif
 625       endforeach
 626     endif
 627   endif
 628   if not get_option('iconv').disabled()
 629     foreach link_args : [ ['-liconv'], [] ]
 630       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 631       # We need to use libiconv if available because mixing libiconv's headers with
 632       # the system libc does not work.
 633       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 634       # included in the command line and libiconv will not be found.
 635       if cc.links('''
 636         #include <iconv.h>
 637         int main(void) {
 638           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 639           return conv != (iconv_t) -1;
 640         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 641         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 642         break
 643       endif
 644     endforeach
 645   endif
 646   if curses.found() and not iconv.found()
 647     if get_option('iconv').enabled()
 648       error('iconv not available')
 649     endif
 650     msg = 'iconv required for curses UI but not available'
 651     curses = not_found
 652   endif
 653   if not curses.found() and msg != ''
 654     if get_option('curses').enabled()
 655       error(msg)
 656     else
 657       warning(msg + ', disabling')
 658     endif
 659   endif
 660 endif
 661
 662 brlapi = not_found
 663 if not get_option('brlapi').auto() or have_system
 664   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 665                          required: get_option('brlapi'),
 666                          kwargs: static_kwargs)
 667   if brlapi.found() and not cc.links('''
 668      #include <brlapi.h>
 669      #include <stddef.h>
 670      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 671     brlapi = not_found
 672     if get_option('brlapi').enabled()
 673       error('could not link brlapi')
 674     else
 675       warning('could not link brlapi, disabling')
 676     endif
 677   endif
 678 endif
 679
 680 sdl = not_found
 681 if not get_option('sdl').auto() or (have_system and not cocoa.found())
 682   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 683   sdl_image = not_found
 684 endif
 685 if sdl.found()
 686   # work around 2.0.8 bug
 687   sdl = declare_dependency(compile_args: '-Wno-undef',
 688                            dependencies: sdl)
 689   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 690                          method: 'pkg-config', kwargs: static_kwargs)
 691 else
 692   if get_option('sdl_image').enabled()
 693     error('sdl-image required, but SDL was @0@'.format(
 694           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 695   endif
 696   sdl_image = not_found
 697 endif
 698
 699 rbd = not_found
 700 if not get_option('rbd').auto() or have_block
 701   librados = cc.find_library('rados', required: get_option('rbd'),
 702                              kwargs: static_kwargs)
 703   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
 704                            required: get_option('rbd'),
 705                            kwargs: static_kwargs)
 706   if librados.found() and librbd.found()
 707     if cc.links('''
 708       #include <stdio.h>
 709       #include <rbd/librbd.h>
 710       int main(void) {
 711         rados_t cluster;
 712         rados_create(&cluster, NULL);
 713         return 0;
 714       }''', dependencies: [librbd, librados])
 715       rbd = declare_dependency(dependencies: [librbd, librados])
 716     elif get_option('rbd').enabled()
 717       error('could not link librados')
 718     else
 719       warning('could not link librados, disabling')
 720     endif
 721   endif
 722 endif
 723
 724 glusterfs = not_found
 725 glusterfs_ftruncate_has_stat = false
 726 glusterfs_iocb_has_stat = false
 727 if not get_option('glusterfs').auto() or have_block
 728   glusterfs = dependency('glusterfs-api', version: '>=3',
 729                          required: get_option('glusterfs'),
 730                          method: 'pkg-config', kwargs: static_kwargs)
 731   if glusterfs.found()
 732     glusterfs_ftruncate_has_stat = cc.links('''
 733       #include <glusterfs/api/glfs.h>
 734
 735       int
 736       main(void)
 737       {
 738           /* new glfs_ftruncate() passes two additional args */
 739           return glfs_ftruncate(NULL, 0, NULL, NULL);
 740       }
 741     ''', dependencies: glusterfs)
 742     glusterfs_iocb_has_stat = cc.links('''
 743       #include <glusterfs/api/glfs.h>
 744
 745       /* new glfs_io_cbk() passes two additional glfs_stat structs */
 746       static void
 747       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
 748       {}
 749
 750       int
 751       main(void)
 752       {
 753           glfs_io_cbk iocb = &glusterfs_iocb;
 754           iocb(NULL, 0 , NULL, NULL, NULL);
 755           return 0;
 756       }
 757     ''', dependencies: glusterfs)
 758   endif
 759 endif
 760 libssh = not_found
 761 if 'CONFIG_LIBSSH' in config_host
 762   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 763                               link_args: config_host['LIBSSH_LIBS'].split())
 764 endif
 765 libbzip2 = not_found
 766 if not get_option('bzip2').auto() or have_block
 767   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
 768                              required: get_option('bzip2'),
 769                              kwargs: static_kwargs)
 770   if libbzip2.found() and not cc.links('''
 771      #include <bzlib.h>
 772      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
 773     libbzip2 = not_found
 774     if get_option('bzip2').enabled()
 775       error('could not link libbzip2')
 776     else
 777       warning('could not link libbzip2, disabling')
 778     endif
 779   endif
 780 endif
 781
 782 liblzfse = not_found
 783 if not get_option('lzfse').auto() or have_block
 784   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
 785                              required: get_option('lzfse'),
 786                              kwargs: static_kwargs)
 787 endif
 788 if liblzfse.found() and not cc.links('''
 789    #include <lzfse.h>
 790    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
 791   liblzfse = not_found
 792   if get_option('lzfse').enabled()
 793     error('could not link liblzfse')
 794   else
 795     warning('could not link liblzfse, disabling')
 796   endif
 797 endif
 798
 799 oss = not_found
 800 if 'CONFIG_AUDIO_OSS' in config_host
 801   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 802 endif
 803 dsound = not_found
 804 if 'CONFIG_AUDIO_DSOUND' in config_host
 805   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 806 endif
 807 coreaudio = not_found
 808 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 809   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 810 endif
 811 opengl = not_found
 812 if 'CONFIG_OPENGL' in config_host
 813   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 814                               link_args: config_host['OPENGL_LIBS'].split())
 815 endif
 816
 817 gnutls = not_found
 818 if not get_option('gnutls').auto() or have_system
 819   gnutls = dependency('gnutls', version: '>=3.5.18',
 820                       method: 'pkg-config',
 821                       required: get_option('gnutls'),
 822                       kwargs: static_kwargs)
 823 endif
 824
 825 # Nettle has priority over gcrypt
 826 gcrypt = not_found
 827 nettle = not_found
 828 xts = 'private'
 829 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
 830   error('Only one of gcrypt & nettle can be enabled')
 831 elif (not get_option('nettle').auto() or have_system) and not get_option('gcrypt').enabled()
 832   nettle = dependency('nettle', version: '>=3.4',
 833                       method: 'pkg-config',
 834                       required: get_option('nettle'),
 835                       kwargs: static_kwargs)
 836   if nettle.found() and cc.has_header('nettle/xts.h', dependencies: nettle)
 837     xts = 'nettle'
 838   endif
 839 endif
 840 if (not get_option('gcrypt').auto() or have_system) and not nettle.found()
 841   gcrypt = dependency('libgcrypt', version: '>=1.5',
 842                          method: 'config-tool',
 843                          required: get_option('gcrypt'),
 844                          kwargs: static_kwargs)
 845   if gcrypt.found() and cc.compiles('''
 846     #include <gcrypt.h>
 847     int main(void) {
 848       gcry_cipher_hd_t handle;
 849       gcry_cipher_open(&handle, GCRY_CIPHER_AES, GCRY_CIPHER_MODE_XTS, 0);
 850       return 0;
 851     }
 852     ''', dependencies: gcrypt)
 853     xts = 'gcrypt'
 854   endif
 855   # Debian has removed -lgpg-error from libgcrypt-config
 856   # as it "spreads unnecessary dependencies" which in
 857   # turn breaks static builds...
 858   if gcrypt.found() and enable_static
 859     gcrypt = declare_dependency(dependencies: [
 860       gcrypt,
 861       cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
 862   endif
 863 endif
 864
 865 gtk = not_found
 866 gtkx11 = not_found
 867 vte = not_found
 868 if not get_option('gtk').auto() or (have_system and not cocoa.found())
 869   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
 870                    method: 'pkg-config',
 871                    required: get_option('gtk'),
 872                    kwargs: static_kwargs)
 873   if gtk.found()
 874     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
 875                         method: 'pkg-config',
 876                         required: false,
 877                         kwargs: static_kwargs)
 878     gtk = declare_dependency(dependencies: [gtk, gtkx11])
 879
 880     if not get_option('vte').auto() or have_system
 881       vte = dependency('vte-2.91',
 882                        method: 'pkg-config',
 883                        required: get_option('vte'),
 884                        kwargs: static_kwargs)
 885     endif
 886   endif
 887 endif
 888
 889 x11 = not_found
 890 if gtkx11.found()
 891   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
 892                    kwargs: static_kwargs)
 893 endif
 894 vnc = not_found
 895 png = not_found
 896 jpeg = not_found
 897 sasl = not_found
 898 if get_option('vnc').enabled()
 899   vnc = declare_dependency() # dummy dependency
 900   png = dependency('libpng', required: get_option('vnc_png'),
 901                    method: 'pkg-config', kwargs: static_kwargs)
 902   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 903                     method: 'pkg-config', kwargs: static_kwargs)
 904   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 905                          required: get_option('vnc_sasl'),
 906                          kwargs: static_kwargs)
 907   if sasl.found()
 908     sasl = declare_dependency(dependencies: sasl,
 909                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 910   endif
 911 endif
 912
 913 pam = not_found
 914 if not get_option('auth_pam').auto() or have_system
 915   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
 916                         required: get_option('auth_pam'),
 917                         kwargs: static_kwargs)
 918 endif
 919 if pam.found() and not cc.links('''
 920    #include <stddef.h>
 921    #include <security/pam_appl.h>
 922    int main(void) {
 923      const char *service_name = "qemu";
 924      const char *user = "frank";
 925      const struct pam_conv pam_conv = { 0 };
 926      pam_handle_t *pamh = NULL;
 927      pam_start(service_name, user, &pam_conv, &pamh);
 928      return 0;
 929    }''', dependencies: pam)
 930   pam = not_found
 931   if get_option('auth_pam').enabled()
 932     error('could not link libpam')
 933   else
 934     warning('could not link libpam, disabling')
 935   endif
 936 endif
 937
 938 snappy = not_found
 939 if not get_option('snappy').auto() or have_system
 940   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
 941                            required: get_option('snappy'),
 942                            kwargs: static_kwargs)
 943 endif
 944 if snappy.found() and not cc.links('''
 945    #include <snappy-c.h>
 946    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
 947   snappy = not_found
 948   if get_option('snappy').enabled()
 949     error('could not link libsnappy')
 950   else
 951     warning('could not link libsnappy, disabling')
 952   endif
 953 endif
 954
 955 lzo = not_found
 956 if not get_option('lzo').auto() or have_system
 957   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
 958                         required: get_option('lzo'),
 959                         kwargs: static_kwargs)
 960 endif
 961 if lzo.found() and not cc.links('''
 962    #include <lzo/lzo1x.h>
 963    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
 964   lzo = not_found
 965   if get_option('lzo').enabled()
 966     error('could not link liblzo2')
 967   else
 968     warning('could not link liblzo2, disabling')
 969   endif
 970 endif
 971
 972 rdma = not_found
 973 if 'CONFIG_RDMA' in config_host
 974   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 975 endif
 976 numa = not_found
 977 if 'CONFIG_NUMA' in config_host
 978   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 979 endif
 980 xen = not_found
 981 if 'CONFIG_XEN_BACKEND' in config_host
 982   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 983                            link_args: config_host['XEN_LIBS'].split())
 984 endif
 985 cacard = not_found
 986 if not get_option('smartcard').auto() or have_system
 987   cacard = dependency('libcacard', required: get_option('smartcard'),
 988                       version: '>=2.5.1', method: 'pkg-config',
 989                       kwargs: static_kwargs)
 990 endif
 991 u2f = not_found
 992 if have_system
 993   u2f = dependency('u2f-emu', required: get_option('u2f'),
 994                    method: 'pkg-config',
 995                    kwargs: static_kwargs)
 996 endif
 997 usbredir = not_found
 998 if not get_option('usb_redir').auto() or have_system
 999   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1000                         version: '>=0.6', method: 'pkg-config',
1001                         kwargs: static_kwargs)
1002 endif
1003 libusb = not_found
1004 if not get_option('libusb').auto() or have_system
1005   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1006                       version: '>=1.0.13', method: 'pkg-config',
1007                       kwargs: static_kwargs)
1008 endif
1009
1010 libpmem = not_found
1011 if not get_option('libpmem').auto() or have_system
1012   libpmem = dependency('libpmem', required: get_option('libpmem'),
1013                        method: 'pkg-config', kwargs: static_kwargs)
1014 endif
1015 libdaxctl = not_found
1016 if not get_option('libdaxctl').auto() or have_system
1017   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1018                          version: '>=57', method: 'pkg-config',
1019                          kwargs: static_kwargs)
1020 endif
1021 tasn1 = not_found
1022 if gnutls.found()
1023   tasn1 = dependency('libtasn1',
1024                      method: 'pkg-config',
1025                      kwargs: static_kwargs)
1026 endif
1027 keyutils = dependency('libkeyutils', required: false,
1028                       method: 'pkg-config', kwargs: static_kwargs)
1029
1030 has_gettid = cc.has_function('gettid')
1031
1032 # Malloc tests
1033
1034 malloc = []
1035 if get_option('malloc') == 'system'
1036   has_malloc_trim = \
1037     not get_option('malloc_trim').disabled() and \
1038     cc.links('''#include <malloc.h>
1039                 int main(void) { malloc_trim(0); return 0; }''')
1040 else
1041   has_malloc_trim = false
1042   malloc = cc.find_library(get_option('malloc'), required: true)
1043 endif
1044 if not has_malloc_trim and get_option('malloc_trim').enabled()
1045   if get_option('malloc') == 'system'
1046     error('malloc_trim not available on this platform.')
1047   else
1048     error('malloc_trim not available with non-libc memory allocator')
1049   endif
1050 endif
1051
1052 # Check whether the glibc provides statx()
1053
1054 gnu_source_prefix = '''
1055   #ifndef _GNU_SOURCE
1056   #define _GNU_SOURCE
1057   #endif
1058 '''
1059 statx_test = gnu_source_prefix + '''
1060   #include <sys/stat.h>
1061   int main(void) {
1062     struct statx statxbuf;
1063     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1064     return 0;
1065   }'''
1066
1067 has_statx = cc.links(statx_test)
1068
1069 have_vhost_user_blk_server = (targetos == 'linux' and
1070     'CONFIG_VHOST_USER' in config_host)
1071
1072 if get_option('vhost_user_blk_server').enabled()
1073     if targetos != 'linux'
1074         error('vhost_user_blk_server requires linux')
1075     elif 'CONFIG_VHOST_USER' not in config_host
1076         error('vhost_user_blk_server requires vhost-user support')
1077     endif
1078 elif get_option('vhost_user_blk_server').disabled() or not have_system
1079     have_vhost_user_blk_server = false
1080 endif
1081
1082
1083 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1084   error('Cannot enable fuse-lseek while fuse is disabled')
1085 endif
1086
1087 fuse = dependency('fuse3', required: get_option('fuse'),
1088                   version: '>=3.1', method: 'pkg-config',
1089                   kwargs: static_kwargs)
1090
1091 fuse_lseek = not_found
1092 if not get_option('fuse_lseek').disabled()
1093   if fuse.version().version_compare('>=3.8')
1094     # Dummy dependency
1095     fuse_lseek = declare_dependency()
1096   elif get_option('fuse_lseek').enabled()
1097     if fuse.found()
1098       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1099     else
1100       error('fuse-lseek requires libfuse, which was not found')
1101     endif
1102   endif
1103 endif
1104
1105 # libbpf
1106 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1107 if libbpf.found() and not cc.links('''
1108    #include <bpf/libbpf.h>
1109    int main(void)
1110    {
1111      bpf_object__destroy_skeleton(NULL);
1112      return 0;
1113    }''', dependencies: libbpf)
1114   libbpf = not_found
1115   if get_option('bpf').enabled()
1116     error('libbpf skeleton test failed')
1117   else
1118     warning('libbpf skeleton test failed, disabling')
1119   endif
1120 endif
1121
1122 if get_option('cfi')
1123   cfi_flags=[]
1124   # Check for dependency on LTO
1125   if not get_option('b_lto')
1126     error('Selected Control-Flow Integrity but LTO is disabled')
1127   endif
1128   if config_host.has_key('CONFIG_MODULES')
1129     error('Selected Control-Flow Integrity is not compatible with modules')
1130   endif
1131   # Check for cfi flags. CFI requires LTO so we can't use
1132   # get_supported_arguments, but need a more complex "compiles" which allows
1133   # custom arguments
1134   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1135                  args: ['-flto', '-fsanitize=cfi-icall'] )
1136     cfi_flags += '-fsanitize=cfi-icall'
1137   else
1138     error('-fsanitize=cfi-icall is not supported by the compiler')
1139   endif
1140   if cc.compiles('int main () { return 0; }',
1141                  name: '-fsanitize-cfi-icall-generalize-pointers',
1142                  args: ['-flto', '-fsanitize=cfi-icall',
1143                         '-fsanitize-cfi-icall-generalize-pointers'] )
1144     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1145   else
1146     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1147   endif
1148   if get_option('cfi_debug')
1149     if cc.compiles('int main () { return 0; }',
1150                    name: '-fno-sanitize-trap=cfi-icall',
1151                    args: ['-flto', '-fsanitize=cfi-icall',
1152                           '-fno-sanitize-trap=cfi-icall'] )
1153       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1154     else
1155       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1156     endif
1157   endif
1158   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1159   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1160 endif
1161
1162 have_host_block_device = (targetos != 'darwin' or
1163     cc.has_header('IOKit/storage/IOMedia.h'))
1164
1165 #################
1166 # config-host.h #
1167 #################
1168
1169 have_virtfs = (targetos == 'linux' and
1170     have_system and
1171     libattr.found() and
1172     libcap_ng.found())
1173
1174 have_virtfs_proxy_helper = have_virtfs and have_tools
1175
1176 if get_option('virtfs').enabled()
1177   if not have_virtfs
1178     if targetos != 'linux'
1179       error('virtio-9p (virtfs) requires Linux')
1180     elif not libcap_ng.found() or not libattr.found()
1181       error('virtio-9p (virtfs) requires libcap-ng-devel and libattr-devel')
1182     elif not have_system
1183       error('virtio-9p (virtfs) needs system emulation support')
1184     endif
1185   endif
1186 elif get_option('virtfs').disabled()
1187   have_virtfs = false
1188 endif
1189
1190 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1191 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1192 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1193 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1194 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1195 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
1196 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1197 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1198 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1199 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1200 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1201 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1202
1203 config_host_data.set('CONFIG_ATTR', libattr.found())
1204 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1205 config_host_data.set('CONFIG_COCOA', cocoa.found())
1206 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1207 config_host_data.set('CONFIG_LZO', lzo.found())
1208 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1209 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1210 config_host_data.set('CONFIG_CURL', curl.found())
1211 config_host_data.set('CONFIG_CURSES', curses.found())
1212 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1213 if glusterfs.found()
1214   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1215   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1216   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1217   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1218   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1219   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1220 endif
1221 config_host_data.set('CONFIG_GTK', gtk.found())
1222 config_host_data.set('CONFIG_VTE', vte.found())
1223 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1224 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1225 config_host_data.set('CONFIG_EBPF', libbpf.found())
1226 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1227 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1228 config_host_data.set('CONFIG_RBD', rbd.found())
1229 config_host_data.set('CONFIG_SDL', sdl.found())
1230 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1231 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1232 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1233 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1234 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1235 config_host_data.set('CONFIG_VNC', vnc.found())
1236 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1237 config_host_data.set('CONFIG_VNC_PNG', png.found())
1238 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1239 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1240 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1241 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1242 config_host_data.set('CONFIG_GETTID', has_gettid)
1243 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1244 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1245 config_host_data.set('CONFIG_NETTLE', nettle.found())
1246 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1247 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1248 config_host_data.set('CONFIG_STATX', has_statx)
1249 config_host_data.set('CONFIG_ZSTD', zstd.found())
1250 config_host_data.set('CONFIG_FUSE', fuse.found())
1251 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1252 config_host_data.set('CONFIG_X11', x11.found())
1253 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1254 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1255 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1256 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1257 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1258
1259 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1260
1261 # has_header
1262 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1263 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1264 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1265 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1266 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1267 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1268 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1269
1270 # has_function
1271 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1272 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1273 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1274 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1275 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1276 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1277 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1278 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1279 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1280 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1281 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1282 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1283 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1284
1285 # has_header_symbol
1286 config_host_data.set('CONFIG_BYTESWAP_H',
1287                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
1288 config_host_data.set('CONFIG_EPOLL_CREATE1',
1289                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
1290 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
1291                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
1292                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
1293 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
1294                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
1295 config_host_data.set('CONFIG_FIEMAP',
1296                      cc.has_header('linux/fiemap.h') and
1297                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
1298 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
1299                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
1300                                           prefix: '''#include <sys/endian.h>
1301                                                      #include <sys/types.h>'''))
1302 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
1303                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
1304
1305 # has_member
1306 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
1307                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
1308                                    prefix: '#include <signal.h>'))
1309
1310 # Some versions of Mac OS X incorrectly define SIZE_MAX
1311 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
1312     #include <stdint.h>
1313     #include <stdio.h>
1314     int main(int argc, char *argv[]) {
1315         return printf("%zu", SIZE_MAX);
1316     }''', args: ['-Werror']))
1317
1318
1319 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
1320 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
1321 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
1322 foreach k, v: config_host
1323   if ignored.contains(k)
1324     # do nothing
1325   elif arrays.contains(k)
1326     if v != ''
1327       v = '"' + '", "'.join(v.split()) + '", '
1328     endif
1329     config_host_data.set(k, v)
1330   elif k == 'ARCH'
1331     config_host_data.set('HOST_' + v.to_upper(), 1)
1332   elif strings.contains(k)
1333     if not k.startswith('CONFIG_')
1334       k = 'CONFIG_' + k.to_upper()
1335     endif
1336     config_host_data.set_quoted(k, v)
1337   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
1338     config_host_data.set(k, v == 'y' ? 1 : v)
1339   endif
1340 endforeach
1341
1342 ########################
1343 # Target configuration #
1344 ########################
1345
1346 minikconf = find_program('scripts/minikconf.py')
1347 config_all = {}
1348 config_all_devices = {}
1349 config_all_disas = {}
1350 config_devices_mak_list = []
1351 config_devices_h = {}
1352 config_target_h = {}
1353 config_target_mak = {}
1354
1355 disassemblers = {
1356   'alpha' : ['CONFIG_ALPHA_DIS'],
1357   'arm' : ['CONFIG_ARM_DIS'],
1358   'avr' : ['CONFIG_AVR_DIS'],
1359   'cris' : ['CONFIG_CRIS_DIS'],
1360   'hexagon' : ['CONFIG_HEXAGON_DIS'],
1361   'hppa' : ['CONFIG_HPPA_DIS'],
1362   'i386' : ['CONFIG_I386_DIS'],
1363   'x86_64' : ['CONFIG_I386_DIS'],
1364   'x32' : ['CONFIG_I386_DIS'],
1365   'm68k' : ['CONFIG_M68K_DIS'],
1366   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
1367   'mips' : ['CONFIG_MIPS_DIS'],
1368   'nios2' : ['CONFIG_NIOS2_DIS'],
1369   'or1k' : ['CONFIG_OPENRISC_DIS'],
1370   'ppc' : ['CONFIG_PPC_DIS'],
1371   'riscv' : ['CONFIG_RISCV_DIS'],
1372   'rx' : ['CONFIG_RX_DIS'],
1373   's390' : ['CONFIG_S390_DIS'],
1374   'sh4' : ['CONFIG_SH4_DIS'],
1375   'sparc' : ['CONFIG_SPARC_DIS'],
1376   'xtensa' : ['CONFIG_XTENSA_DIS'],
1377 }
1378 if link_language == 'cpp'
1379   disassemblers += {
1380     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
1381     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
1382     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
1383   }
1384 endif
1385
1386 have_ivshmem = config_host.has_key('CONFIG_EVENTFD')
1387 host_kconfig = \
1388   ('CONFIG_TPM' in config_host ? ['CONFIG_TPM=y'] : []) + \
1389   ('CONFIG_SPICE' in config_host ? ['CONFIG_SPICE=y'] : []) + \
1390   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
1391   ('CONFIG_OPENGL' in config_host ? ['CONFIG_OPENGL=y'] : []) + \
1392   (x11.found() ? ['CONFIG_X11=y'] : []) + \
1393   ('CONFIG_VHOST_USER' in config_host ? ['CONFIG_VHOST_USER=y'] : []) + \
1394   ('CONFIG_VHOST_VDPA' in config_host ? ['CONFIG_VHOST_VDPA=y'] : []) + \
1395   ('CONFIG_VHOST_KERNEL' in config_host ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
1396   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
1397   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
1398   ('CONFIG_PVRDMA' in config_host ? ['CONFIG_PVRDMA=y'] : []) + \
1399   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : [])
1400
1401 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
1402
1403 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
1404 actual_target_dirs = []
1405 fdt_required = []
1406 foreach target : target_dirs
1407   config_target = { 'TARGET_NAME': target.split('-')[0] }
1408   if target.endswith('linux-user')
1409     if targetos != 'linux'
1410       if default_targets
1411         continue
1412       endif
1413       error('Target @0@ is only available on a Linux host'.format(target))
1414     endif
1415     config_target += { 'CONFIG_LINUX_USER': 'y' }
1416   elif target.endswith('bsd-user')
1417     if 'CONFIG_BSD' not in config_host
1418       if default_targets
1419         continue
1420       endif
1421       error('Target @0@ is only available on a BSD host'.format(target))
1422     endif
1423     config_target += { 'CONFIG_BSD_USER': 'y' }
1424   elif target.endswith('softmmu')
1425     config_target += { 'CONFIG_SOFTMMU': 'y' }
1426   endif
1427   if target.endswith('-user')
1428     config_target += {
1429       'CONFIG_USER_ONLY': 'y',
1430       'CONFIG_QEMU_INTERP_PREFIX':
1431         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
1432     }
1433   endif
1434
1435   accel_kconfig = []
1436   foreach sym: accelerators
1437     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
1438       config_target += { sym: 'y' }
1439       config_all += { sym: 'y' }
1440       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
1441         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
1442       elif sym == 'CONFIG_XEN' and have_xen_pci_passthrough
1443         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
1444       endif
1445       accel_kconfig += [ sym + '=y' ]
1446     endif
1447   endforeach
1448   if accel_kconfig.length() == 0
1449     if default_targets
1450       continue
1451     endif
1452     error('No accelerator available for target @0@'.format(target))
1453   endif
1454
1455   actual_target_dirs += target
1456   config_target += keyval.load('default-configs/targets' / target + '.mak')
1457   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
1458
1459   if 'TARGET_NEED_FDT' in config_target
1460     fdt_required += target
1461   endif
1462
1463   # Add default keys
1464   if 'TARGET_BASE_ARCH' not in config_target
1465     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
1466   endif
1467   if 'TARGET_ABI_DIR' not in config_target
1468     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
1469   endif
1470
1471   foreach k, v: disassemblers
1472     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
1473       foreach sym: v
1474         config_target += { sym: 'y' }
1475         config_all_disas += { sym: 'y' }
1476       endforeach
1477     endif
1478   endforeach
1479
1480   config_target_data = configuration_data()
1481   foreach k, v: config_target
1482     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1483       # do nothing
1484     elif ignored.contains(k)
1485       # do nothing
1486     elif k == 'TARGET_BASE_ARCH'
1487       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1488       # not used to select files from sourcesets.
1489       config_target_data.set('TARGET_' + v.to_upper(), 1)
1490     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1491       config_target_data.set_quoted(k, v)
1492     elif v == 'y'
1493       config_target_data.set(k, 1)
1494     else
1495       config_target_data.set(k, v)
1496     endif
1497   endforeach
1498   config_target_h += {target: configure_file(output: target + '-config-target.h',
1499                                                configuration: config_target_data)}
1500
1501   if target.endswith('-softmmu')
1502     config_devices_mak = target + '-config-devices.mak'
1503     config_devices_mak = configure_file(
1504       input: ['default-configs/devices' / target + '.mak', 'Kconfig'],
1505       output: config_devices_mak,
1506       depfile: config_devices_mak + '.d',
1507       capture: true,
1508       command: [minikconf,
1509                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
1510                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1511                 host_kconfig, accel_kconfig])
1512
1513     config_devices_data = configuration_data()
1514     config_devices = keyval.load(config_devices_mak)
1515     foreach k, v: config_devices
1516       config_devices_data.set(k, 1)
1517     endforeach
1518     config_devices_mak_list += config_devices_mak
1519     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1520                                                 configuration: config_devices_data)}
1521     config_target += config_devices
1522     config_all_devices += config_devices
1523   endif
1524   config_target_mak += {target: config_target}
1525 endforeach
1526 target_dirs = actual_target_dirs
1527
1528 # This configuration is used to build files that are shared by
1529 # multiple binaries, and then extracted out of the "common"
1530 # static_library target.
1531 #
1532 # We do not use all_sources()/all_dependencies(), because it would
1533 # build literally all source files, including devices only used by
1534 # targets that are not built for this compilation.  The CONFIG_ALL
1535 # pseudo symbol replaces it.
1536
1537 config_all += config_all_devices
1538 config_all += config_host
1539 config_all += config_all_disas
1540 config_all += {
1541   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1542   'CONFIG_SOFTMMU': have_system,
1543   'CONFIG_USER_ONLY': have_user,
1544   'CONFIG_ALL': true,
1545 }
1546
1547 ##############
1548 # Submodules #
1549 ##############
1550
1551 capstone = not_found
1552 capstone_opt = get_option('capstone')
1553 if capstone_opt in ['enabled', 'auto', 'system']
1554   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1555   capstone = dependency('capstone', version: '>=4.0',
1556                         kwargs: static_kwargs, method: 'pkg-config',
1557                         required: capstone_opt == 'system' or
1558                                   capstone_opt == 'enabled' and not have_internal)
1559   if capstone.found()
1560     capstone_opt = 'system'
1561   elif have_internal
1562     capstone_opt = 'internal'
1563   else
1564     capstone_opt = 'disabled'
1565   endif
1566 endif
1567 if capstone_opt == 'internal'
1568   capstone_data = configuration_data()
1569   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1570
1571   capstone_files = files(
1572     'capstone/cs.c',
1573     'capstone/MCInst.c',
1574     'capstone/MCInstrDesc.c',
1575     'capstone/MCRegisterInfo.c',
1576     'capstone/SStream.c',
1577     'capstone/utils.c'
1578   )
1579
1580   if 'CONFIG_ARM_DIS' in config_all_disas
1581     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1582     capstone_files += files(
1583       'capstone/arch/ARM/ARMDisassembler.c',
1584       'capstone/arch/ARM/ARMInstPrinter.c',
1585       'capstone/arch/ARM/ARMMapping.c',
1586       'capstone/arch/ARM/ARMModule.c'
1587     )
1588   endif
1589
1590   # FIXME: This config entry currently depends on a c++ compiler.
1591   # Which is needed for building libvixl, but not for capstone.
1592   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1593     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1594     capstone_files += files(
1595       'capstone/arch/AArch64/AArch64BaseInfo.c',
1596       'capstone/arch/AArch64/AArch64Disassembler.c',
1597       'capstone/arch/AArch64/AArch64InstPrinter.c',
1598       'capstone/arch/AArch64/AArch64Mapping.c',
1599       'capstone/arch/AArch64/AArch64Module.c'
1600     )
1601   endif
1602
1603   if 'CONFIG_PPC_DIS' in config_all_disas
1604     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1605     capstone_files += files(
1606       'capstone/arch/PowerPC/PPCDisassembler.c',
1607       'capstone/arch/PowerPC/PPCInstPrinter.c',
1608       'capstone/arch/PowerPC/PPCMapping.c',
1609       'capstone/arch/PowerPC/PPCModule.c'
1610     )
1611   endif
1612
1613   if 'CONFIG_S390_DIS' in config_all_disas
1614     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1615     capstone_files += files(
1616       'capstone/arch/SystemZ/SystemZDisassembler.c',
1617       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1618       'capstone/arch/SystemZ/SystemZMapping.c',
1619       'capstone/arch/SystemZ/SystemZModule.c',
1620       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1621     )
1622   endif
1623
1624   if 'CONFIG_I386_DIS' in config_all_disas
1625     capstone_data.set('CAPSTONE_HAS_X86', 1)
1626     capstone_files += files(
1627       'capstone/arch/X86/X86Disassembler.c',
1628       'capstone/arch/X86/X86DisassemblerDecoder.c',
1629       'capstone/arch/X86/X86ATTInstPrinter.c',
1630       'capstone/arch/X86/X86IntelInstPrinter.c',
1631       'capstone/arch/X86/X86InstPrinterCommon.c',
1632       'capstone/arch/X86/X86Mapping.c',
1633       'capstone/arch/X86/X86Module.c'
1634     )
1635   endif
1636
1637   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1638
1639   capstone_cargs = [
1640     # FIXME: There does not seem to be a way to completely replace the c_args
1641     # that come from add_project_arguments() -- we can only add to them.
1642     # So: disable all warnings with a big hammer.
1643     '-Wno-error', '-w',
1644
1645     # Include all configuration defines via a header file, which will wind up
1646     # as a dependency on the object file, and thus changes here will result
1647     # in a rebuild.
1648     '-include', 'capstone-defs.h'
1649   ]
1650
1651   libcapstone = static_library('capstone',
1652                                build_by_default: false,
1653                                sources: capstone_files,
1654                                c_args: capstone_cargs,
1655                                include_directories: 'capstone/include')
1656   capstone = declare_dependency(link_with: libcapstone,
1657                                 include_directories: 'capstone/include/capstone')
1658 endif
1659
1660 slirp = not_found
1661 slirp_opt = 'disabled'
1662 if have_system
1663   slirp_opt = get_option('slirp')
1664   if slirp_opt in ['enabled', 'auto', 'system']
1665     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1666     slirp = dependency('slirp', kwargs: static_kwargs,
1667                        method: 'pkg-config',
1668                        required: slirp_opt == 'system' or
1669                                  slirp_opt == 'enabled' and not have_internal)
1670     if slirp.found()
1671       slirp_opt = 'system'
1672     elif have_internal
1673       slirp_opt = 'internal'
1674     else
1675       slirp_opt = 'disabled'
1676     endif
1677   endif
1678   if slirp_opt == 'internal'
1679     slirp_deps = []
1680     if targetos == 'windows'
1681       slirp_deps = cc.find_library('iphlpapi')
1682     endif
1683     slirp_conf = configuration_data()
1684     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1685     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1686     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1687     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1688     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1689     slirp_files = [
1690       'slirp/src/arp_table.c',
1691       'slirp/src/bootp.c',
1692       'slirp/src/cksum.c',
1693       'slirp/src/dhcpv6.c',
1694       'slirp/src/dnssearch.c',
1695       'slirp/src/if.c',
1696       'slirp/src/ip6_icmp.c',
1697       'slirp/src/ip6_input.c',
1698       'slirp/src/ip6_output.c',
1699       'slirp/src/ip_icmp.c',
1700       'slirp/src/ip_input.c',
1701       'slirp/src/ip_output.c',
1702       'slirp/src/mbuf.c',
1703       'slirp/src/misc.c',
1704       'slirp/src/ncsi.c',
1705       'slirp/src/ndp_table.c',
1706       'slirp/src/sbuf.c',
1707       'slirp/src/slirp.c',
1708       'slirp/src/socket.c',
1709       'slirp/src/state.c',
1710       'slirp/src/stream.c',
1711       'slirp/src/tcp_input.c',
1712       'slirp/src/tcp_output.c',
1713       'slirp/src/tcp_subr.c',
1714       'slirp/src/tcp_timer.c',
1715       'slirp/src/tftp.c',
1716       'slirp/src/udp.c',
1717       'slirp/src/udp6.c',
1718       'slirp/src/util.c',
1719       'slirp/src/version.c',
1720       'slirp/src/vmstate.c',
1721     ]
1722
1723     configure_file(
1724       input : 'slirp/src/libslirp-version.h.in',
1725       output : 'libslirp-version.h',
1726       configuration: slirp_conf)
1727
1728     slirp_inc = include_directories('slirp', 'slirp/src')
1729     libslirp = static_library('slirp',
1730                               build_by_default: false,
1731                               sources: slirp_files,
1732                               c_args: slirp_cargs,
1733                               include_directories: slirp_inc)
1734     slirp = declare_dependency(link_with: libslirp,
1735                                dependencies: slirp_deps,
1736                                include_directories: slirp_inc)
1737   endif
1738 endif
1739
1740 # For CFI, we need to compile slirp as a static library together with qemu.
1741 # This is because we register slirp functions as callbacks for QEMU Timers.
1742 # When using a system-wide shared libslirp, the type information for the
1743 # callback is missing and the timer call produces a false positive with CFI.
1744 #
1745 # Now that slirp_opt has been defined, check if the selected slirp is compatible
1746 # with control-flow integrity.
1747 if get_option('cfi') and slirp_opt == 'system'
1748   error('Control-Flow Integrity is not compatible with system-wide slirp.' \
1749          + ' Please configure with --enable-slirp=git')
1750 endif
1751
1752 fdt = not_found
1753 fdt_opt = get_option('fdt')
1754 if have_system
1755   if fdt_opt in ['enabled', 'auto', 'system']
1756     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1757     fdt = cc.find_library('fdt', kwargs: static_kwargs,
1758                           required: fdt_opt == 'system' or
1759                                     fdt_opt == 'enabled' and not have_internal)
1760     if fdt.found() and cc.links('''
1761        #include <libfdt.h>
1762        #include <libfdt_env.h>
1763        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1764          dependencies: fdt)
1765       fdt_opt = 'system'
1766     elif have_internal
1767       fdt_opt = 'internal'
1768     else
1769       fdt_opt = 'disabled'
1770     endif
1771   endif
1772   if fdt_opt == 'internal'
1773     fdt_files = files(
1774       'dtc/libfdt/fdt.c',
1775       'dtc/libfdt/fdt_ro.c',
1776       'dtc/libfdt/fdt_wip.c',
1777       'dtc/libfdt/fdt_sw.c',
1778       'dtc/libfdt/fdt_rw.c',
1779       'dtc/libfdt/fdt_strerror.c',
1780       'dtc/libfdt/fdt_empty_tree.c',
1781       'dtc/libfdt/fdt_addresses.c',
1782       'dtc/libfdt/fdt_overlay.c',
1783       'dtc/libfdt/fdt_check.c',
1784     )
1785
1786     fdt_inc = include_directories('dtc/libfdt')
1787     libfdt = static_library('fdt',
1788                             build_by_default: false,
1789                             sources: fdt_files,
1790                             include_directories: fdt_inc)
1791     fdt = declare_dependency(link_with: libfdt,
1792                              include_directories: fdt_inc)
1793   endif
1794 endif
1795 if not fdt.found() and fdt_required.length() > 0
1796   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1797 endif
1798
1799 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1800 config_host_data.set('CONFIG_FDT', fdt.found())
1801 config_host_data.set('CONFIG_SLIRP', slirp.found())
1802
1803 #####################
1804 # Generated sources #
1805 #####################
1806
1807 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1808
1809 hxtool = find_program('scripts/hxtool')
1810 shaderinclude = find_program('scripts/shaderinclude.pl')
1811 qapi_gen = find_program('scripts/qapi-gen.py')
1812 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1813                      meson.source_root() / 'scripts/qapi/commands.py',
1814                      meson.source_root() / 'scripts/qapi/common.py',
1815                      meson.source_root() / 'scripts/qapi/error.py',
1816                      meson.source_root() / 'scripts/qapi/events.py',
1817                      meson.source_root() / 'scripts/qapi/expr.py',
1818                      meson.source_root() / 'scripts/qapi/gen.py',
1819                      meson.source_root() / 'scripts/qapi/introspect.py',
1820                      meson.source_root() / 'scripts/qapi/parser.py',
1821                      meson.source_root() / 'scripts/qapi/schema.py',
1822                      meson.source_root() / 'scripts/qapi/source.py',
1823                      meson.source_root() / 'scripts/qapi/types.py',
1824                      meson.source_root() / 'scripts/qapi/visit.py',
1825                      meson.source_root() / 'scripts/qapi/common.py',
1826                      meson.source_root() / 'scripts/qapi-gen.py'
1827 ]
1828
1829 tracetool = [
1830   python, files('scripts/tracetool.py'),
1831    '--backend=' + config_host['TRACE_BACKENDS']
1832 ]
1833 tracetool_depends = files(
1834   'scripts/tracetool/backend/log.py',
1835   'scripts/tracetool/backend/__init__.py',
1836   'scripts/tracetool/backend/dtrace.py',
1837   'scripts/tracetool/backend/ftrace.py',
1838   'scripts/tracetool/backend/simple.py',
1839   'scripts/tracetool/backend/syslog.py',
1840   'scripts/tracetool/backend/ust.py',
1841   'scripts/tracetool/format/tcg_h.py',
1842   'scripts/tracetool/format/ust_events_c.py',
1843   'scripts/tracetool/format/ust_events_h.py',
1844   'scripts/tracetool/format/__init__.py',
1845   'scripts/tracetool/format/d.py',
1846   'scripts/tracetool/format/tcg_helper_c.py',
1847   'scripts/tracetool/format/simpletrace_stap.py',
1848   'scripts/tracetool/format/c.py',
1849   'scripts/tracetool/format/h.py',
1850   'scripts/tracetool/format/tcg_helper_h.py',
1851   'scripts/tracetool/format/log_stap.py',
1852   'scripts/tracetool/format/stap.py',
1853   'scripts/tracetool/format/tcg_helper_wrapper_h.py',
1854   'scripts/tracetool/__init__.py',
1855   'scripts/tracetool/transform.py',
1856   'scripts/tracetool/vcpu.py'
1857 )
1858
1859 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1860                     meson.current_source_dir(),
1861                     config_host['PKGVERSION'], meson.project_version()]
1862 qemu_version = custom_target('qemu-version.h',
1863                              output: 'qemu-version.h',
1864                              command: qemu_version_cmd,
1865                              capture: true,
1866                              build_by_default: true,
1867                              build_always_stale: true)
1868 genh += qemu_version
1869
1870 hxdep = []
1871 hx_headers = [
1872   ['qemu-options.hx', 'qemu-options.def'],
1873   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1874 ]
1875 if have_system
1876   hx_headers += [
1877     ['hmp-commands.hx', 'hmp-commands.h'],
1878     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1879   ]
1880 endif
1881 foreach d : hx_headers
1882   hxdep += custom_target(d[1],
1883                 input: files(d[0]),
1884                 output: d[1],
1885                 capture: true,
1886                 build_by_default: true, # to be removed when added to a target
1887                 command: [hxtool, '-h', '@INPUT0@'])
1888 endforeach
1889 genh += hxdep
1890
1891 ###################
1892 # Collect sources #
1893 ###################
1894
1895 authz_ss = ss.source_set()
1896 blockdev_ss = ss.source_set()
1897 block_ss = ss.source_set()
1898 bsd_user_ss = ss.source_set()
1899 chardev_ss = ss.source_set()
1900 common_ss = ss.source_set()
1901 crypto_ss = ss.source_set()
1902 io_ss = ss.source_set()
1903 linux_user_ss = ss.source_set()
1904 qmp_ss = ss.source_set()
1905 qom_ss = ss.source_set()
1906 softmmu_ss = ss.source_set()
1907 specific_fuzz_ss = ss.source_set()
1908 specific_ss = ss.source_set()
1909 stub_ss = ss.source_set()
1910 trace_ss = ss.source_set()
1911 user_ss = ss.source_set()
1912 util_ss = ss.source_set()
1913
1914 modules = {}
1915 hw_arch = {}
1916 target_arch = {}
1917 target_softmmu_arch = {}
1918 target_user_arch = {}
1919
1920 ###############
1921 # Trace files #
1922 ###############
1923
1924 # TODO: add each directory to the subdirs from its own meson.build, once
1925 # we have those
1926 trace_events_subdirs = [
1927   'crypto',
1928   'qapi',
1929   'qom',
1930   'monitor',
1931   'util',
1932 ]
1933 if have_user
1934   trace_events_subdirs += [ 'linux-user' ]
1935 endif
1936 if have_block
1937   trace_events_subdirs += [
1938     'authz',
1939     'block',
1940     'io',
1941     'nbd',
1942     'scsi',
1943   ]
1944 endif
1945 if have_system
1946   trace_events_subdirs += [
1947     'accel/kvm',
1948     'audio',
1949     'backends',
1950     'backends/tpm',
1951     'chardev',
1952     'ebpf',
1953     'hw/9pfs',
1954     'hw/acpi',
1955     'hw/adc',
1956     'hw/alpha',
1957     'hw/arm',
1958     'hw/audio',
1959     'hw/block',
1960     'hw/block/dataplane',
1961     'hw/char',
1962     'hw/display',
1963     'hw/dma',
1964     'hw/hppa',
1965     'hw/hyperv',
1966     'hw/i2c',
1967     'hw/i386',
1968     'hw/i386/xen',
1969     'hw/ide',
1970     'hw/input',
1971     'hw/intc',
1972     'hw/isa',
1973     'hw/mem',
1974     'hw/mips',
1975     'hw/misc',
1976     'hw/misc/macio',
1977     'hw/net',
1978     'hw/net/can',
1979     'hw/nvme',
1980     'hw/nvram',
1981     'hw/pci',
1982     'hw/pci-host',
1983     'hw/ppc',
1984     'hw/rdma',
1985     'hw/rdma/vmw',
1986     'hw/rtc',
1987     'hw/s390x',
1988     'hw/scsi',
1989     'hw/sd',
1990     'hw/sparc',
1991     'hw/sparc64',
1992     'hw/ssi',
1993     'hw/timer',
1994     'hw/tpm',
1995     'hw/usb',
1996     'hw/vfio',
1997     'hw/virtio',
1998     'hw/watchdog',
1999     'hw/xen',
2000     'hw/gpio',
2001     'migration',
2002     'net',
2003     'softmmu',
2004     'ui',
2005     'hw/remote',
2006   ]
2007 endif
2008 if have_system or have_user
2009   trace_events_subdirs += [
2010     'accel/tcg',
2011     'hw/core',
2012     'target/arm',
2013     'target/hppa',
2014     'target/i386',
2015     'target/i386/kvm',
2016     'target/mips/tcg',
2017     'target/ppc',
2018     'target/riscv',
2019     'target/s390x',
2020     'target/sparc',
2021   ]
2022 endif
2023
2024 vhost_user = not_found
2025 if 'CONFIG_VHOST_USER' in config_host
2026   libvhost_user = subproject('libvhost-user')
2027   vhost_user = libvhost_user.get_variable('vhost_user_dep')
2028 endif
2029
2030 subdir('qapi')
2031 subdir('qobject')
2032 subdir('stubs')
2033 subdir('trace')
2034 subdir('util')
2035 subdir('qom')
2036 subdir('authz')
2037 subdir('crypto')
2038 subdir('ui')
2039
2040
2041 if enable_modules
2042   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
2043   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
2044 endif
2045
2046 stub_ss = stub_ss.apply(config_all, strict: false)
2047
2048 util_ss.add_all(trace_ss)
2049 util_ss = util_ss.apply(config_all, strict: false)
2050 libqemuutil = static_library('qemuutil',
2051                              sources: util_ss.sources() + stub_ss.sources() + genh,
2052                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
2053 qemuutil = declare_dependency(link_with: libqemuutil,
2054                               sources: genh + version_res)
2055
2056 if have_system or have_user
2057   decodetree = generator(find_program('scripts/decodetree.py'),
2058                          output: 'decode-@BASENAME@.c.inc',
2059                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
2060   subdir('libdecnumber')
2061   subdir('target')
2062 endif
2063
2064 subdir('audio')
2065 subdir('io')
2066 subdir('chardev')
2067 subdir('fsdev')
2068 subdir('dump')
2069
2070 if have_block
2071   block_ss.add(files(
2072     'block.c',
2073     'blockjob.c',
2074     'job.c',
2075     'qemu-io-cmds.c',
2076   ))
2077   block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
2078
2079   subdir('nbd')
2080   subdir('scsi')
2081   subdir('block')
2082
2083   blockdev_ss.add(files(
2084     'blockdev.c',
2085     'blockdev-nbd.c',
2086     'iothread.c',
2087     'job-qmp.c',
2088   ), gnutls)
2089
2090   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
2091   # os-win32.c does not
2092   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
2093   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
2094 endif
2095
2096 common_ss.add(files('cpus-common.c'))
2097
2098 subdir('softmmu')
2099
2100 common_ss.add(capstone)
2101 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
2102
2103 # Work around a gcc bug/misfeature wherein constant propagation looks
2104 # through an alias:
2105 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
2106 # to guess that a const variable is always zero.  Without lto, this is
2107 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
2108 # without lto, not even the alias is required -- we simply use different
2109 # declarations in different compilation units.
2110 pagevary = files('page-vary-common.c')
2111 if get_option('b_lto')
2112   pagevary_flags = ['-fno-lto']
2113   if get_option('cfi')
2114     pagevary_flags += '-fno-sanitize=cfi-icall'
2115   endif
2116   pagevary = static_library('page-vary-common', sources: pagevary,
2117                             c_args: pagevary_flags)
2118   pagevary = declare_dependency(link_with: pagevary)
2119 endif
2120 common_ss.add(pagevary)
2121 specific_ss.add(files('page-vary.c'))
2122
2123 subdir('backends')
2124 subdir('disas')
2125 subdir('migration')
2126 subdir('monitor')
2127 subdir('net')
2128 subdir('replay')
2129 subdir('semihosting')
2130 subdir('hw')
2131 subdir('tcg')
2132 subdir('fpu')
2133 subdir('accel')
2134 subdir('plugins')
2135 subdir('bsd-user')
2136 subdir('linux-user')
2137 subdir('ebpf')
2138
2139 common_ss.add(libbpf)
2140
2141 bsd_user_ss.add(files('gdbstub.c'))
2142 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
2143
2144 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
2145 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
2146
2147 # needed for fuzzing binaries
2148 subdir('tests/qtest/libqos')
2149 subdir('tests/qtest/fuzz')
2150
2151 ########################
2152 # Library dependencies #
2153 ########################
2154
2155 block_mods = []
2156 softmmu_mods = []
2157 foreach d, list : modules
2158   foreach m, module_ss : list
2159     if enable_modules and targetos != 'windows'
2160       module_ss = module_ss.apply(config_all, strict: false)
2161       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
2162                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
2163       if d == 'block'
2164         block_mods += sl
2165       else
2166         softmmu_mods += sl
2167       endif
2168     else
2169       if d == 'block'
2170         block_ss.add_all(module_ss)
2171       else
2172         softmmu_ss.add_all(module_ss)
2173       endif
2174     endif
2175   endforeach
2176 endforeach
2177
2178 nm = find_program('nm')
2179 undefsym = find_program('scripts/undefsym.py')
2180 block_syms = custom_target('block.syms', output: 'block.syms',
2181                              input: [libqemuutil, block_mods],
2182                              capture: true,
2183                              command: [undefsym, nm, '@INPUT@'])
2184 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
2185                              input: [libqemuutil, softmmu_mods],
2186                              capture: true,
2187                              command: [undefsym, nm, '@INPUT@'])
2188
2189 qom_ss = qom_ss.apply(config_host, strict: false)
2190 libqom = static_library('qom', qom_ss.sources() + genh,
2191                         dependencies: [qom_ss.dependencies()],
2192                         name_suffix: 'fa')
2193
2194 qom = declare_dependency(link_whole: libqom)
2195
2196 authz_ss = authz_ss.apply(config_host, strict: false)
2197 libauthz = static_library('authz', authz_ss.sources() + genh,
2198                           dependencies: [authz_ss.dependencies()],
2199                           name_suffix: 'fa',
2200                           build_by_default: false)
2201
2202 authz = declare_dependency(link_whole: libauthz,
2203                            dependencies: qom)
2204
2205 crypto_ss = crypto_ss.apply(config_host, strict: false)
2206 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
2207                            dependencies: [crypto_ss.dependencies()],
2208                            name_suffix: 'fa',
2209                            build_by_default: false)
2210
2211 crypto = declare_dependency(link_whole: libcrypto,
2212                             dependencies: [authz, qom])
2213
2214 io_ss = io_ss.apply(config_host, strict: false)
2215 libio = static_library('io', io_ss.sources() + genh,
2216                        dependencies: [io_ss.dependencies()],
2217                        link_with: libqemuutil,
2218                        name_suffix: 'fa',
2219                        build_by_default: false)
2220
2221 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
2222
2223 libmigration = static_library('migration', sources: migration_files + genh,
2224                               name_suffix: 'fa',
2225                               build_by_default: false)
2226 migration = declare_dependency(link_with: libmigration,
2227                                dependencies: [zlib, qom, io])
2228 softmmu_ss.add(migration)
2229
2230 block_ss = block_ss.apply(config_host, strict: false)
2231 libblock = static_library('block', block_ss.sources() + genh,
2232                           dependencies: block_ss.dependencies(),
2233                           link_depends: block_syms,
2234                           name_suffix: 'fa',
2235                           build_by_default: false)
2236
2237 block = declare_dependency(link_whole: [libblock],
2238                            link_args: '@block.syms',
2239                            dependencies: [crypto, io])
2240
2241 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
2242 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
2243                              dependencies: blockdev_ss.dependencies(),
2244                              name_suffix: 'fa',
2245                              build_by_default: false)
2246
2247 blockdev = declare_dependency(link_whole: [libblockdev],
2248                               dependencies: [block])
2249
2250 qmp_ss = qmp_ss.apply(config_host, strict: false)
2251 libqmp = static_library('qmp', qmp_ss.sources() + genh,
2252                         dependencies: qmp_ss.dependencies(),
2253                         name_suffix: 'fa',
2254                         build_by_default: false)
2255
2256 qmp = declare_dependency(link_whole: [libqmp])
2257
2258 libchardev = static_library('chardev', chardev_ss.sources() + genh,
2259                             name_suffix: 'fa',
2260                             dependencies: [gnutls],
2261                             build_by_default: false)
2262
2263 chardev = declare_dependency(link_whole: libchardev)
2264
2265 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
2266                            name_suffix: 'fa',
2267                            build_by_default: false)
2268 hwcore = declare_dependency(link_whole: libhwcore)
2269 common_ss.add(hwcore)
2270
2271 ###########
2272 # Targets #
2273 ###########
2274
2275 foreach m : block_mods + softmmu_mods
2276   shared_module(m.name(),
2277                 name_prefix: '',
2278                 link_whole: m,
2279                 install: true,
2280                 install_dir: qemu_moddir)
2281 endforeach
2282
2283 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
2284 common_ss.add(qom, qemuutil)
2285
2286 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
2287 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
2288
2289 common_all = common_ss.apply(config_all, strict: false)
2290 common_all = static_library('common',
2291                             build_by_default: false,
2292                             sources: common_all.sources() + genh,
2293                             implicit_include_directories: false,
2294                             dependencies: common_all.dependencies(),
2295                             name_suffix: 'fa')
2296
2297 feature_to_c = find_program('scripts/feature_to_c.sh')
2298
2299 emulators = {}
2300 foreach target : target_dirs
2301   config_target = config_target_mak[target]
2302   target_name = config_target['TARGET_NAME']
2303   arch = config_target['TARGET_BASE_ARCH']
2304   arch_srcs = [config_target_h[target]]
2305   arch_deps = []
2306   c_args = ['-DNEED_CPU_H',
2307             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
2308             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
2309   link_args = emulator_link_args
2310
2311   config_target += config_host
2312   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
2313   if targetos == 'linux'
2314     target_inc += include_directories('linux-headers', is_system: true)
2315   endif
2316   if target.endswith('-softmmu')
2317     qemu_target_name = 'qemu-system-' + target_name
2318     target_type='system'
2319     t = target_softmmu_arch[arch].apply(config_target, strict: false)
2320     arch_srcs += t.sources()
2321     arch_deps += t.dependencies()
2322
2323     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
2324     hw = hw_arch[hw_dir].apply(config_target, strict: false)
2325     arch_srcs += hw.sources()
2326     arch_deps += hw.dependencies()
2327
2328     arch_srcs += config_devices_h[target]
2329     link_args += ['@block.syms', '@qemu.syms']
2330   else
2331     abi = config_target['TARGET_ABI_DIR']
2332     target_type='user'
2333     qemu_target_name = 'qemu-' + target_name
2334     if arch in target_user_arch
2335       t = target_user_arch[arch].apply(config_target, strict: false)
2336       arch_srcs += t.sources()
2337       arch_deps += t.dependencies()
2338     endif
2339     if 'CONFIG_LINUX_USER' in config_target
2340       base_dir = 'linux-user'
2341       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
2342     else
2343       base_dir = 'bsd-user'
2344       target_inc += include_directories('bsd-user/freebsd')
2345     endif
2346     target_inc += include_directories(
2347       base_dir,
2348       base_dir / abi,
2349     )
2350     if 'CONFIG_LINUX_USER' in config_target
2351       dir = base_dir / abi
2352       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
2353       if config_target.has_key('TARGET_SYSTBL_ABI')
2354         arch_srcs += \
2355           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
2356                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
2357       endif
2358     endif
2359   endif
2360
2361   if 'TARGET_XML_FILES' in config_target
2362     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
2363                                 output: target + '-gdbstub-xml.c',
2364                                 input: files(config_target['TARGET_XML_FILES'].split()),
2365                                 command: [feature_to_c, '@INPUT@'],
2366                                 capture: true)
2367     arch_srcs += gdbstub_xml
2368   endif
2369
2370   t = target_arch[arch].apply(config_target, strict: false)
2371   arch_srcs += t.sources()
2372   arch_deps += t.dependencies()
2373
2374   target_common = common_ss.apply(config_target, strict: false)
2375   objects = common_all.extract_objects(target_common.sources())
2376   deps = target_common.dependencies()
2377
2378   target_specific = specific_ss.apply(config_target, strict: false)
2379   arch_srcs += target_specific.sources()
2380   arch_deps += target_specific.dependencies()
2381
2382   lib = static_library('qemu-' + target,
2383                  sources: arch_srcs + genh,
2384                  dependencies: arch_deps,
2385                  objects: objects,
2386                  include_directories: target_inc,
2387                  c_args: c_args,
2388                  build_by_default: false,
2389                  name_suffix: 'fa')
2390
2391   if target.endswith('-softmmu')
2392     execs = [{
2393       'name': 'qemu-system-' + target_name,
2394       'gui': false,
2395       'sources': files('softmmu/main.c'),
2396       'dependencies': []
2397     }]
2398     if targetos == 'windows' and (sdl.found() or gtk.found())
2399       execs += [{
2400         'name': 'qemu-system-' + target_name + 'w',
2401         'gui': true,
2402         'sources': files('softmmu/main.c'),
2403         'dependencies': []
2404       }]
2405     endif
2406     if config_host.has_key('CONFIG_FUZZ')
2407       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
2408       execs += [{
2409         'name': 'qemu-fuzz-' + target_name,
2410         'gui': false,
2411         'sources': specific_fuzz.sources(),
2412         'dependencies': specific_fuzz.dependencies(),
2413       }]
2414     endif
2415   else
2416     execs = [{
2417       'name': 'qemu-' + target_name,
2418       'gui': false,
2419       'sources': [],
2420       'dependencies': []
2421     }]
2422   endif
2423   foreach exe: execs
2424     exe_name = exe['name']
2425     exe_sign = 'CONFIG_HVF' in config_target
2426     if exe_sign
2427       exe_name += '-unsigned'
2428     endif
2429
2430     emulator = executable(exe_name, exe['sources'],
2431                install: true,
2432                c_args: c_args,
2433                dependencies: arch_deps + deps + exe['dependencies'],
2434                objects: lib.extract_all_objects(recursive: true),
2435                link_language: link_language,
2436                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
2437                link_args: link_args,
2438                gui_app: exe['gui'])
2439
2440     if exe_sign
2441       emulators += {exe['name'] : custom_target(exe['name'],
2442                    depends: emulator,
2443                    output: exe['name'],
2444                    command: [
2445                      meson.current_source_dir() / 'scripts/entitlement.sh',
2446                      meson.current_build_dir() / exe_name,
2447                      meson.current_build_dir() / exe['name'],
2448                      meson.current_source_dir() / 'accel/hvf/entitlements.plist'
2449                    ])
2450       }
2451
2452       meson.add_install_script('scripts/entitlement.sh', '--install',
2453                                get_option('bindir') / exe_name,
2454                                get_option('bindir') / exe['name'],
2455                                meson.current_source_dir() / 'accel/hvf/entitlements.plist')
2456     else
2457       emulators += {exe['name']: emulator}
2458     endif
2459
2460     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
2461       foreach stp: [
2462         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
2463         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
2464         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
2465         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
2466       ]
2467         custom_target(exe['name'] + stp['ext'],
2468                       input: trace_events_all,
2469                       output: exe['name'] + stp['ext'],
2470                       install: stp['install'],
2471                       install_dir: get_option('datadir') / 'systemtap/tapset',
2472                       command: [
2473                         tracetool, '--group=all', '--format=' + stp['fmt'],
2474                         '--binary=' + stp['bin'],
2475                         '--target-name=' + target_name,
2476                         '--target-type=' + target_type,
2477                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
2478                         '@INPUT@', '@OUTPUT@'
2479                       ],
2480                       depend_files: tracetool_depends)
2481       endforeach
2482     endif
2483   endforeach
2484 endforeach
2485
2486 # Other build targets
2487
2488 if 'CONFIG_PLUGIN' in config_host
2489   install_headers('include/qemu/qemu-plugin.h')
2490 endif
2491
2492 if 'CONFIG_GUEST_AGENT' in config_host
2493   subdir('qga')
2494 elif get_option('guest_agent_msi').enabled()
2495   error('Guest agent MSI requested, but the guest agent is not being built')
2496 endif
2497
2498 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
2499 # when we don't build tools or system
2500 if xkbcommon.found()
2501   # used for the update-keymaps target, so include rules even if !have_tools
2502   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
2503                            dependencies: [qemuutil, xkbcommon], install: have_tools)
2504 endif
2505
2506 if have_tools
2507   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
2508              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
2509   qemu_io = executable('qemu-io', files('qemu-io.c'),
2510              dependencies: [block, qemuutil], install: true)
2511   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
2512                dependencies: [blockdev, qemuutil, gnutls], install: true)
2513
2514   subdir('storage-daemon')
2515   subdir('contrib/rdmacm-mux')
2516   subdir('contrib/elf2dmp')
2517
2518   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
2519              dependencies: qemuutil,
2520              install: true)
2521
2522   if 'CONFIG_VHOST_USER' in config_host
2523     subdir('contrib/vhost-user-blk')
2524     subdir('contrib/vhost-user-gpu')
2525     subdir('contrib/vhost-user-input')
2526     subdir('contrib/vhost-user-scsi')
2527   endif
2528
2529   if targetos == 'linux'
2530     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
2531                dependencies: [qemuutil, libcap_ng],
2532                install: true,
2533                install_dir: get_option('libexecdir'))
2534
2535     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
2536                dependencies: [authz, crypto, io, qom, qemuutil,
2537                               libcap_ng, mpathpersist],
2538                install: true)
2539   endif
2540
2541   if have_ivshmem
2542     subdir('contrib/ivshmem-client')
2543     subdir('contrib/ivshmem-server')
2544   endif
2545 endif
2546
2547 subdir('scripts')
2548 subdir('tools')
2549 subdir('pc-bios')
2550 subdir('docs')
2551 subdir('tests')
2552 if gtk.found()
2553   subdir('po')
2554 endif
2555
2556 if host_machine.system() == 'windows'
2557   nsis_cmd = [
2558     find_program('scripts/nsis.py'),
2559     '@OUTPUT@',
2560     get_option('prefix'),
2561     meson.current_source_dir(),
2562     host_machine.cpu(),
2563     '--',
2564     '-DDISPLAYVERSION=' + meson.project_version(),
2565   ]
2566   if build_docs
2567     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
2568   endif
2569   if gtk.found()
2570     nsis_cmd += '-DCONFIG_GTK=y'
2571   endif
2572
2573   nsis = custom_target('nsis',
2574                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2575                        input: files('qemu.nsi'),
2576                        build_always_stale: true,
2577                        command: nsis_cmd + ['@INPUT@'])
2578   alias_target('installer', nsis)
2579 endif
2580
2581 #########################
2582 # Configuration summary #
2583 #########################
2584
2585 # Directories
2586 summary_info = {}
2587 summary_info += {'Install prefix':    get_option('prefix')}
2588 summary_info += {'BIOS directory':    qemu_datadir}
2589 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2590 summary_info += {'binary directory':  get_option('bindir')}
2591 summary_info += {'library directory': get_option('libdir')}
2592 summary_info += {'module directory':  qemu_moddir}
2593 summary_info += {'libexec directory': get_option('libexecdir')}
2594 summary_info += {'include directory': get_option('includedir')}
2595 summary_info += {'config directory':  get_option('sysconfdir')}
2596 if targetos != 'windows'
2597   summary_info += {'local state directory': get_option('localstatedir')}
2598   summary_info += {'Manual directory':      get_option('mandir')}
2599 else
2600   summary_info += {'local state directory': 'queried at runtime'}
2601 endif
2602 summary_info += {'Doc directory':     get_option('docdir')}
2603 summary_info += {'Build directory':   meson.current_build_dir()}
2604 summary_info += {'Source path':       meson.current_source_dir()}
2605 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2606 summary(summary_info, bool_yn: true, section: 'Directories')
2607
2608 # Host binaries
2609 summary_info = {}
2610 summary_info += {'git':               config_host['GIT']}
2611 summary_info += {'make':              config_host['MAKE']}
2612 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2613 summary_info += {'sphinx-build':      sphinx_build.found()}
2614 if config_host.has_key('HAVE_GDB_BIN')
2615   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2616 endif
2617 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2618 if targetos == 'windows' and config_host.has_key('CONFIG_GUEST_AGENT')
2619   summary_info += {'wixl':            wixl.found() ? wixl.full_path() : false}
2620 endif
2621 if slirp_opt != 'disabled' and 'CONFIG_SLIRP_SMBD' in config_host
2622   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2623 endif
2624 summary(summary_info, bool_yn: true, section: 'Host binaries')
2625
2626 # Configurable features
2627 summary_info = {}
2628 summary_info += {'Documentation':     build_docs}
2629 summary_info += {'system-mode emulation': have_system}
2630 summary_info += {'user-mode emulation': have_user}
2631 summary_info += {'block layer':       have_block}
2632 summary_info += {'Install blobs':     get_option('install_blobs')}
2633 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2634 if config_host.has_key('CONFIG_MODULES')
2635   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2636 endif
2637 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2638 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2639 if have_system
2640   summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2641 endif
2642 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2643 if config_host['TRACE_BACKENDS'].split().contains('simple')
2644   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2645 endif
2646 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2647 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2648 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2649 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2650 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2651 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2652 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2653 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2654 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2655 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2656 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2657 summary(summary_info, bool_yn: true, section: 'Configurable features')
2658
2659 # Compilation information
2660 summary_info = {}
2661 summary_info += {'host CPU':          cpu}
2662 summary_info += {'host endianness':   build_machine.endian()}
2663 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
2664 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
2665 if link_language == 'cpp'
2666   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
2667 else
2668   summary_info += {'C++ compiler':      false}
2669 endif
2670 if targetos == 'darwin'
2671   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
2672 endif
2673 if targetos == 'windows'
2674   if 'WIN_SDK' in config_host
2675     summary_info += {'Windows SDK':   config_host['WIN_SDK']}
2676   endif
2677 endif
2678 summary_info += {'ARFLAGS':           config_host['ARFLAGS']}
2679 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2680                                                + ['-O' + get_option('optimization')]
2681                                                + (get_option('debug') ? ['-g'] : []))}
2682 if link_language == 'cpp'
2683   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2684                                                + ['-O' + get_option('optimization')]
2685                                                + (get_option('debug') ? ['-g'] : []))}
2686 endif
2687 link_args = get_option(link_language + '_link_args')
2688 if link_args.length() > 0
2689   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2690 endif
2691 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2692 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2693 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2694 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
2695 summary_info += {'PIE':               get_option('b_pie')}
2696 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2697 summary_info += {'malloc trim support': has_malloc_trim}
2698 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2699 summary_info += {'fdatasync':         config_host.has_key('CONFIG_FDATASYNC')}
2700 summary_info += {'madvise':           config_host.has_key('CONFIG_MADVISE')}
2701 summary_info += {'posix_madvise':     config_host.has_key('CONFIG_POSIX_MADVISE')}
2702 summary_info += {'posix_memalign':    config_host.has_key('CONFIG_POSIX_MEMALIGN')}
2703 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2704 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2705 summary_info += {'memory allocator':  get_option('malloc')}
2706 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2707 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2708 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2709 summary_info += {'gcov':              get_option('b_coverage')}
2710 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2711 summary_info += {'CFI support':       get_option('cfi')}
2712 if get_option('cfi')
2713   summary_info += {'CFI debug support': get_option('cfi_debug')}
2714 endif
2715 summary_info += {'strip binaries':    get_option('strip')}
2716 summary_info += {'sparse':            sparse.found() ? sparse.full_path() : false}
2717 summary_info += {'mingw32 support':   targetos == 'windows'}
2718
2719 # snarf the cross-compilation information for tests
2720 foreach target: target_dirs
2721   tcg_mak = meson.current_build_dir() / 'tests/tcg' / 'config-' + target + '.mak'
2722   if fs.exists(tcg_mak)
2723     config_cross_tcg = keyval.load(tcg_mak)
2724     target = config_cross_tcg['TARGET_NAME']
2725     compiler = ''
2726     if 'DOCKER_CROSS_CC_GUEST' in config_cross_tcg
2727       summary_info += {target + ' tests': config_cross_tcg['DOCKER_CROSS_CC_GUEST'] +
2728                                           ' via ' + config_cross_tcg['DOCKER_IMAGE']}
2729     elif 'CROSS_CC_GUEST' in config_cross_tcg
2730       summary_info += {target + ' tests'
2731                                 : config_cross_tcg['CROSS_CC_GUEST'] }
2732     endif
2733    endif
2734 endforeach
2735
2736 summary(summary_info, bool_yn: true, section: 'Compilation')
2737
2738 # Targets and accelerators
2739 summary_info = {}
2740 if have_system
2741   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2742   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2743   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2744   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2745   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
2746   summary_info += {'Xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2747   if config_host.has_key('CONFIG_XEN_BACKEND')
2748     summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2749   endif
2750 endif
2751 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2752 if config_all.has_key('CONFIG_TCG')
2753   if get_option('tcg_interpreter')
2754     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, experimental and slow)'}
2755   else
2756     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
2757   endif
2758   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2759 endif
2760 summary_info += {'target list':       ' '.join(target_dirs)}
2761 if have_system
2762   summary_info += {'default devices':   get_option('default_devices')}
2763   summary_info += {'out of process emulation': multiprocess_allowed}
2764 endif
2765 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
2766
2767 # Block layer
2768 summary_info = {}
2769 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2770 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2771 if have_block
2772   summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2773   summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2774   summary_info += {'VirtFS support':    have_virtfs}
2775   summary_info += {'build virtiofs daemon': have_virtiofsd}
2776   summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2777   summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2778   summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2779   summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2780   summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2781   summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2782   summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2783   summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2784   summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2785   summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2786   summary_info += {'FUSE exports':      fuse.found()}
2787 endif
2788 summary(summary_info, bool_yn: true, section: 'Block layer support')
2789
2790 # Crypto
2791 summary_info = {}
2792 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2793 summary_info += {'GNUTLS support':    gnutls.found()}
2794 # TODO: add back version
2795 summary_info += {'libgcrypt':         gcrypt.found()}
2796 if gcrypt.found()
2797    summary_info += {'  XTS':             xts != 'private'}
2798 endif
2799 # TODO: add back version
2800 summary_info += {'nettle':            nettle.found()}
2801 if nettle.found()
2802    summary_info += {'  XTS':             xts != 'private'}
2803 endif
2804 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2805 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
2806 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
2807 summary(summary_info, bool_yn: true, section: 'Crypto')
2808
2809 # Libraries
2810 summary_info = {}
2811 if targetos == 'darwin'
2812   summary_info += {'Cocoa support':   cocoa.found()}
2813 endif
2814 # TODO: add back version
2815 summary_info += {'SDL support':       sdl.found()}
2816 summary_info += {'SDL image support': sdl_image.found()}
2817 # TODO: add back version
2818 summary_info += {'GTK support':       gtk.found()}
2819 summary_info += {'pixman':            pixman.found()}
2820 # TODO: add back version
2821 summary_info += {'VTE support':       vte.found()}
2822 # TODO: add back version
2823 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
2824 summary_info += {'libtasn1':          tasn1.found()}
2825 summary_info += {'PAM':               pam.found()}
2826 summary_info += {'iconv support':     iconv.found()}
2827 summary_info += {'curses support':    curses.found()}
2828 # TODO: add back version
2829 summary_info += {'virgl support':     virgl.found()}
2830 summary_info += {'curl support':      curl.found()}
2831 summary_info += {'Multipath support': mpathpersist.found()}
2832 summary_info += {'VNC support':       vnc.found()}
2833 if vnc.found()
2834   summary_info += {'VNC SASL support':  sasl.found()}
2835   summary_info += {'VNC JPEG support':  jpeg.found()}
2836   summary_info += {'VNC PNG support':   png.found()}
2837 endif
2838 summary_info += {'brlapi support':    brlapi.found()}
2839 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
2840 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
2841 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
2842 summary_info += {'Linux io_uring support': linux_io_uring.found()}
2843 summary_info += {'ATTR/XATTR support': libattr.found()}
2844 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
2845 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
2846 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
2847 summary_info += {'libcap-ng support': libcap_ng.found()}
2848 summary_info += {'bpf support': libbpf.found()}
2849 # TODO: add back protocol and server version
2850 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
2851 summary_info += {'rbd support':       rbd.found()}
2852 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
2853 summary_info += {'smartcard support': cacard.found()}
2854 summary_info += {'U2F support':       u2f.found()}
2855 summary_info += {'libusb':            libusb.found()}
2856 summary_info += {'usb net redir':     usbredir.found()}
2857 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
2858 summary_info += {'GBM':               config_host.has_key('CONFIG_GBM')}
2859 summary_info += {'libiscsi support':  libiscsi.found()}
2860 summary_info += {'libnfs support':    libnfs.found()}
2861 if targetos == 'windows'
2862   if config_host.has_key('CONFIG_GUEST_AGENT')
2863     summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
2864     summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
2865   endif
2866 endif
2867 summary_info += {'seccomp support':   seccomp.found()}
2868 summary_info += {'GlusterFS support': glusterfs.found()}
2869 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
2870 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
2871 summary_info += {'lzo support':       lzo.found()}
2872 summary_info += {'snappy support':    snappy.found()}
2873 summary_info += {'bzip2 support':     libbzip2.found()}
2874 summary_info += {'lzfse support':     liblzfse.found()}
2875 summary_info += {'zstd support':      zstd.found()}
2876 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
2877 summary_info += {'libxml2':           libxml2.found()}
2878 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
2879 summary_info += {'libpmem support':   libpmem.found()}
2880 summary_info += {'libdaxctl support': libdaxctl.found()}
2881 summary_info += {'libudev':           libudev.found()}
2882 summary_info += {'FUSE lseek':        fuse_lseek.found()}
2883 summary(summary_info, bool_yn: true, section: 'Dependencies')
2884
2885 if not supported_cpus.contains(cpu)
2886   message()
2887   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
2888   message()
2889   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
2890   message('The QEMU project intends to remove support for this host CPU in')
2891   message('a future release if nobody volunteers to maintain it and to')
2892   message('provide a build host for our continuous integration setup.')
2893   message('configure has succeeded and you can continue to build, but')
2894   message('if you care about QEMU on this platform you should contact')
2895   message('us upstream at qemu-devel@nongnu.org.')
2896 endif
2897
2898 if not supported_oses.contains(targetos)
2899   message()
2900   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
2901   message()
2902   message('Host OS ' + targetos + 'support is not currently maintained.')
2903   message('The QEMU project intends to remove support for this host OS in')
2904   message('a future release if nobody volunteers to maintain it and to')
2905   message('provide a build host for our continuous integration setup.')
2906   message('configure has succeeded and you can continue to build, but')
2907   message('if you care about QEMU on this platform you should contact')
2908   message('us upstream at qemu-devel@nongnu.org.')
2909 endif