qapi/meson.build

   1 util_ss.add(files(
   2   'opts-visitor.c',
   3   'qapi-clone-visitor.c',
   4   'qapi-dealloc-visitor.c',
   5   'qapi-util.c',
   6   'qapi-visit-core.c',
   7   'qmp-dispatch.c',
   8   'qmp-event.c',
   9   'qmp-registry.c',
  10   'qobject-input-visitor.c',
  11   'qobject-output-visitor.c',
  12   'string-input-visitor.c',
  13   'string-output-visitor.c',
  14 ))
  15
  16 qapi_all_modules = [
  17   'acpi',
  18   'audio',
  19   'authz',
  20   'block',
  21   'block-core',
  22   'block-export',
  23   'char',
  24   'common',
  25   'control',
  26   'crypto',
  27   'dump',
  28   'error',
  29   'introspect',
  30   'job',
  31   'machine',
  32   'machine-target',
  33   'migration',
  34   'misc',
  35   'misc-target',
  36   'net',
  37   'pragma',
  38   'pci',
  39   'qom',
  40   'rdma',
  41   'replay',
  42   'rocker',
  43   'run-state',
  44   'sockets',
  45   'tpm',
  46   'trace',
  47   'transaction',
  48   'ui',
  49   'yank',
  50 ]
  51 if have_system
  52   qapi_all_modules += [
  53     'qdev',
  54   ]
  55 endif
  56
  57 qapi_storage_daemon_modules = [
  58   'block-core',
  59   'block-export',
  60   'char',
  61   'common',
  62   'control',
  63   'crypto',
  64   'introspect',
  65   'job',
  66   'qom',
  67   'sockets',
  68   'pragma',
  69   'transaction',
  70 ]
  71
  72 qapi_nonmodule_outputs = [
  73   'qapi-introspect.c', 'qapi-introspect.h',
  74   'qapi-types.c', 'qapi-types.h',
  75   'qapi-visit.h', 'qapi-visit.c',
  76   'qapi-commands.h', 'qapi-commands.c',
  77   'qapi-init-commands.h', 'qapi-init-commands.c',
  78   'qapi-events.h', 'qapi-events.c',
  79   'qapi-emit-events.c', 'qapi-emit-events.h',
  80 ]
  81
  82 # First build all sources
  83 qapi_util_outputs = [
  84   'qapi-builtin-types.c', 'qapi-builtin-visit.c',
  85   'qapi-builtin-types.h', 'qapi-builtin-visit.h',
  86 ]
  87
  88 qapi_inputs = []
  89 qapi_specific_outputs = []
  90 foreach module : qapi_all_modules
  91   qapi_inputs += [ files(module + '.json') ]
  92   qapi_module_outputs = [
  93     'qapi-types-@0@.c'.format(module),
  94     'qapi-types-@0@.h'.format(module),
  95     'qapi-visit-@0@.c'.format(module),
  96     'qapi-visit-@0@.h'.format(module),
  97     'qapi-events-@0@.c'.format(module),
  98     'qapi-events-@0@.h'.format(module),
  99     'qapi-commands-@0@.c'.format(module),
 100     'qapi-commands-@0@.h'.format(module),
 101   ]
 102   if module.endswith('-target')
 103     qapi_specific_outputs += qapi_module_outputs
 104   else
 105     qapi_util_outputs += qapi_module_outputs
 106   endif
 107 endforeach
 108
 109 qapi_files = custom_target('shared QAPI source files',
 110   output: qapi_util_outputs + qapi_specific_outputs + qapi_nonmodule_outputs,
 111   input: [ files('qapi-schema.json') ],
 112   command: [ qapi_gen, '-o', 'qapi', '-b', '@INPUT0@' ],
 113   depend_files: [ qapi_inputs, qapi_gen_depends ])
 114
 115 # Now go through all the outputs and add them to the right sourceset.
 116 # These loops must be synchronized with the output of the above custom target.
 117
 118 i = 0
 119 foreach output : qapi_util_outputs
 120   if output.endswith('.h')
 121     genh += qapi_files[i]
 122   endif
 123   util_ss.add(qapi_files[i])
 124   i = i + 1
 125 endforeach
 126
 127 foreach output : qapi_specific_outputs + qapi_nonmodule_outputs
 128   if output.endswith('.h')
 129     genh += qapi_files[i]
 130   endif
 131   specific_ss.add(when: 'CONFIG_SOFTMMU', if_true: qapi_files[i])
 132   i = i + 1
 133 endforeach