qga/meson.build

   1 if not have_ga
   2   if get_option('guest_agent_msi').enabled()
   3     error('Guest agent MSI requested, but the guest agent is not being built')
   4   endif
   5   have_qga_vss = false
   6   subdir_done()
   7 endif
   8
   9 have_qga_vss = get_option('qga_vss') \
  10   .require(targetos == 'windows',
  11            error_message: 'VSS support requires Windows') \
  12   .require(link_language == 'cpp',
  13            error_message: 'VSS support requires a C++ compiler') \
  14   .require(have_vss, error_message: '''VSS support requires VSS headers.
  15     If your Visual Studio installation doesn't have the VSS headers,
  16     Please download and install Microsoft VSS SDK:
  17     http://www.microsoft.com/en-us/download/details.aspx?id=23490
  18     On POSIX-systems, MinGW should provide headers in >=10.0 releases.
  19     you can extract the SDK headers by:
  20     $ scripts/extract-vsssdk-headers setup.exe
  21     The headers are extracted in the directory 'inc/win2003'.
  22     Then run configure with: --extra-cxxflags="-isystem /path/to/vss/inc/win2003"''') \
  23   .require(midl.found() or widl.found(),
  24            error_message: 'VSS support requires midl or widl') \
  25   .require(not enable_static,
  26            error_message: 'VSS support requires dynamic linking with GLib') \
  27   .allowed()
  28
  29 all_qga = []
  30
  31 qga_qapi_outputs = [
  32   'qga-qapi-commands.c',
  33   'qga-qapi-commands.h',
  34   'qga-qapi-emit-events.c',
  35   'qga-qapi-emit-events.h',
  36   'qga-qapi-events.c',
  37   'qga-qapi-events.h',
  38   'qga-qapi-init-commands.c',
  39   'qga-qapi-init-commands.h',
  40   'qga-qapi-introspect.c',
  41   'qga-qapi-introspect.h',
  42   'qga-qapi-types.c',
  43   'qga-qapi-types.h',
  44   'qga-qapi-visit.c',
  45   'qga-qapi-visit.h',
  46 ]
  47
  48 # Problem: to generate trace events, we'd have to add the .trace-events
  49 # file to qapi_trace_events like we do in qapi/meson.build.  Since
  50 # qapi_trace_events is used by trace/meson.build, we'd have to move
  51 # subdir('qga') above subdir('trace') in the top-level meson.build.
  52 # Can't, because it would break the dependency of qga on qemuutil (which
  53 # depends on trace_ss).  Not worth solving now; simply suppress trace
  54 # event generation instead.
  55 qga_qapi_files = custom_target('QGA QAPI files',
  56                                output: qga_qapi_outputs,
  57                                input: 'qapi-schema.json',
  58                                command: [ qapi_gen, '-o', 'qga', '-p', 'qga-', '@INPUT0@',
  59                                           '--suppress-tracing' ],
  60                                depend_files: qapi_gen_depends)
  61
  62 qga_ss = ss.source_set()
  63 qga_ss.add(qga_qapi_files.to_list())
  64 qga_ss.add(files(
  65   'commands.c',
  66   'guest-agent-command-state.c',
  67   'main.c',
  68   'cutils.c',
  69 ))
  70 qga_ss.add(when: 'CONFIG_POSIX', if_true: files(
  71   'channel-posix.c',
  72   'commands-posix.c',
  73   'commands-posix-ssh.c',
  74 ))
  75 qga_ss.add(when: 'CONFIG_WIN32', if_true: files(
  76   'channel-win32.c',
  77   'commands-win32.c',
  78   'service-win32.c',
  79   'vss-win32.c'
  80 ))
  81
  82 qga_ss = qga_ss.apply(config_host, strict: false)
  83
  84 gen_tlb = []
  85 qga_libs = []
  86 if targetos == 'windows'
  87   qga_libs += ['-lws2_32', '-lwinmm', '-lpowrprof', '-lwtsapi32', '-lwininet', '-liphlpapi', '-lnetapi32',
  88                '-lsetupapi', '-lcfgmgr32']
  89   if have_qga_vss
  90     qga_libs += ['-lole32', '-loleaut32', '-lshlwapi', '-lstdc++', '-Wl,--enable-stdcall-fixup']
  91     subdir('vss-win32')
  92   endif
  93 endif
  94
  95 qga = executable('qemu-ga', qga_ss.sources(),
  96                  link_args: qga_libs,
  97                  dependencies: [qemuutil, libudev],
  98                  install: true)
  99 all_qga += qga
 100
 101 if targetos == 'windows'
 102   qemu_ga_msi_arch = {
 103     'x86': ['-D', 'Arch=32'],
 104     'x86_64': ['-a', 'x64', '-D', 'Arch=64']
 105   }
 106   wixl = not_found
 107   if cpu in qemu_ga_msi_arch
 108     wixl = find_program('wixl', required: get_option('guest_agent_msi'))
 109   elif get_option('guest_agent_msi').enabled()
 110     error('CPU not supported for building guest agent installation package')
 111   endif
 112
 113   if wixl.found()
 114     deps = [gen_tlb, qga]
 115     qemu_ga_msi_vss = []
 116     if have_qga_vss
 117       qemu_ga_msi_vss = ['-D', 'InstallVss']
 118       deps += qga_vss
 119     endif
 120     qga_msi = custom_target('QGA MSI',
 121                             input: files('installer/qemu-ga.wxs'),
 122                             output: 'qemu-ga-@0@.msi'.format(host_arch),
 123                             depends: deps,
 124                             command: [
 125                               wixl, '-o', '@OUTPUT0@', '@INPUT0@',
 126                               qemu_ga_msi_arch[cpu],
 127                               qemu_ga_msi_vss,
 128                               '-D', 'BUILD_DIR=' + meson.project_build_root(),
 129                               '-D', 'BIN_DIR=' + glib.get_variable('bindir'),
 130                               '-D', 'QEMU_GA_VERSION=' + config_host['QEMU_GA_VERSION'],
 131                               '-D', 'QEMU_GA_MANUFACTURER=' + config_host['QEMU_GA_MANUFACTURER'],
 132                               '-D', 'QEMU_GA_DISTRO=' + config_host['QEMU_GA_DISTRO'],
 133                             ])
 134     all_qga += [qga_msi]
 135     alias_target('msi', qga_msi)
 136   endif
 137 else
 138   if get_option('guest_agent_msi').enabled()
 139     error('MSI guest agent package is available only for MinGW Windows cross-compilation')
 140   endif
 141   install_subdir('run', install_dir: get_option('localstatedir'))
 142 endif
 143
 144 alias_target('qemu-ga', all_qga)
 145
 146 test_env = environment()
 147 test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
 148 test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
 149
 150 # disable qga-ssh-test for now. glib's G_TEST_OPTION_ISOLATE_DIRS triggers
 151 # the leak detector in build-oss-fuzz Gitlab CI test. we should re-enable
 152 # this when an alternative is implemented or when the underlying glib
 153 # issue is identified/fix
 154 #if 'CONFIG_POSIX' in config_host
 155 if false
 156   srcs = [files('commands-posix-ssh.c')]
 157   i = 0
 158   foreach output: qga_qapi_outputs
 159     if output.startswith('qga-qapi-types') or output.startswith('qga-qapi-visit')
 160       srcs += qga_qapi_files[i]
 161     endif
 162     i = i + 1
 163   endforeach
 164   qga_ssh_test = executable('qga-ssh-test', srcs,
 165                             dependencies: [qemuutil],
 166                             c_args: ['-DQGA_BUILD_UNIT_TEST'])
 167
 168   test('qga-ssh-test',
 169        qga_ssh_test,
 170        env: test_env,
 171        suite: ['unit', 'qga'])
 172 endif