qga/meson.build

   1 if not have_ga
   2   if get_option('guest_agent_msi').enabled()
   3     error('Guest agent MSI requested, but the guest agent is not being built')
   4   endif
   5   have_qga_vss = false
   6   subdir_done()
   7 endif
   8
   9 have_qga_vss = get_option('qga_vss') \
  10   .require(targetos == 'windows',
  11            error_message: 'VSS support requires Windows') \
  12   .require(link_language == 'cpp',
  13            error_message: 'VSS support requires a C++ compiler') \
  14   .require(have_vss, error_message: '''VSS support requires VSS headers.
  15     If your Visual Studio installation doesn't have the VSS headers,
  16     Please download and install Microsoft VSS SDK:
  17     http://www.microsoft.com/en-us/download/details.aspx?id=23490
  18     On POSIX-systems, MinGW should provide headers in >=10.0 releases.
  19     you can extract the SDK headers by:
  20     $ scripts/extract-vsssdk-headers setup.exe
  21     The headers are extracted in the directory 'inc/win2003'.
  22     Then run configure with: --extra-cxxflags="-isystem /path/to/vss/inc/win2003"''') \
  23   .require(midl.found() or widl.found(),
  24            error_message: 'VSS support requires midl or widl') \
  25   .require(not enable_static,
  26            error_message: 'VSS support requires dynamic linking with GLib') \
  27   .allowed()
  28
  29 all_qga = []
  30
  31 qga_qapi_outputs = [
  32   'qga-qapi-commands.c',
  33   'qga-qapi-commands.h',
  34   'qga-qapi-emit-events.c',
  35   'qga-qapi-emit-events.h',
  36   'qga-qapi-events.c',
  37   'qga-qapi-events.h',
  38   'qga-qapi-init-commands.c',
  39   'qga-qapi-init-commands.h',
  40   'qga-qapi-introspect.c',
  41   'qga-qapi-introspect.h',
  42   'qga-qapi-types.c',
  43   'qga-qapi-types.h',
  44   'qga-qapi-visit.c',
  45   'qga-qapi-visit.h',
  46 ]
  47
  48 # Problem: to generate trace events, we'd have to add the .trace-events
  49 # file to qapi_trace_events like we do in qapi/meson.build.  Since
  50 # qapi_trace_events is used by trace/meson.build, we'd have to move
  51 # subdir('qga') above subdir('trace') in the top-level meson.build.
  52 # Can't, because it would break the dependency of qga on qemuutil (which
  53 # depends on trace_ss).  Not worth solving now; simply suppress trace
  54 # event generation instead.
  55 qga_qapi_files = custom_target('QGA QAPI files',
  56                                output: qga_qapi_outputs,
  57                                input: 'qapi-schema.json',
  58                                command: [ qapi_gen, '-o', 'qga', '-p', 'qga-', '@INPUT0@',
  59                                           '--suppress-tracing' ],
  60                                depend_files: qapi_gen_depends)
  61
  62 qga_ss = ss.source_set()
  63 qga_ss.add(qga_qapi_files.to_list())
  64 qga_ss.add(files(
  65   'commands.c',
  66   'guest-agent-command-state.c',
  67   'main.c',
  68   'cutils.c',
  69 ))
  70 qga_ss.add(when: 'CONFIG_POSIX', if_true: files(
  71   'channel-posix.c',
  72   'commands-posix.c',
  73   'commands-posix-ssh.c',
  74 ))
  75 qga_ss.add(when: 'CONFIG_LINUX', if_true: files(
  76   'commands-linux.c',
  77 ))
  78 qga_ss.add(when: 'CONFIG_BSD', if_true: files(
  79   'commands-bsd.c',
  80 ))
  81 qga_ss.add(when: 'CONFIG_WIN32', if_true: files(
  82   'channel-win32.c',
  83   'commands-win32.c',
  84   'service-win32.c',
  85   'vss-win32.c'
  86 ))
  87
  88 qga_ss = qga_ss.apply(config_host, strict: false)
  89
  90 gen_tlb = []
  91 qga_libs = []
  92 if targetos == 'windows'
  93   qga_libs += ['-lws2_32', '-lwinmm', '-lpowrprof', '-lwtsapi32', '-lwininet', '-liphlpapi', '-lnetapi32',
  94                '-lsetupapi', '-lcfgmgr32']
  95   if have_qga_vss
  96     qga_libs += ['-lole32', '-loleaut32', '-lshlwapi', '-lstdc++', '-Wl,--enable-stdcall-fixup']
  97     subdir('vss-win32')
  98   endif
  99 endif
 100
 101 qga = executable('qemu-ga', qga_ss.sources(),
 102                  link_args: qga_libs,
 103                  dependencies: [qemuutil, libudev],
 104                  install: true)
 105 all_qga += qga
 106
 107 if targetos == 'windows'
 108   qemu_ga_msi_arch = {
 109     'x86': ['-D', 'Arch=32'],
 110     'x86_64': ['-a', 'x64', '-D', 'Arch=64']
 111   }
 112   wixl = not_found
 113   if cpu in qemu_ga_msi_arch
 114     wixl = find_program('wixl', required: get_option('guest_agent_msi'))
 115   elif get_option('guest_agent_msi').enabled()
 116     error('CPU not supported for building guest agent installation package')
 117   endif
 118
 119   if wixl.found()
 120     deps = [gen_tlb, qga]
 121     qemu_ga_msi_vss = []
 122     if have_qga_vss
 123       qemu_ga_msi_vss = ['-D', 'InstallVss']
 124       deps += qga_vss
 125     endif
 126     qga_msi = custom_target('QGA MSI',
 127                             input: files('installer/qemu-ga.wxs'),
 128                             output: 'qemu-ga-@0@.msi'.format(host_arch),
 129                             depends: deps,
 130                             command: [
 131                               wixl, '-o', '@OUTPUT0@', '@INPUT0@',
 132                               qemu_ga_msi_arch[cpu],
 133                               qemu_ga_msi_vss,
 134                               '-D', 'BUILD_DIR=' + meson.project_build_root(),
 135                               '-D', 'BIN_DIR=' + glib.get_variable('bindir'),
 136                               '-D', 'QEMU_GA_VERSION=' + config_host['QEMU_GA_VERSION'],
 137                               '-D', 'QEMU_GA_MANUFACTURER=' + config_host['QEMU_GA_MANUFACTURER'],
 138                               '-D', 'QEMU_GA_DISTRO=' + config_host['QEMU_GA_DISTRO'],
 139                             ])
 140     all_qga += [qga_msi]
 141     alias_target('msi', qga_msi)
 142   endif
 143 else
 144   if get_option('guest_agent_msi').enabled()
 145     error('MSI guest agent package is available only for MinGW Windows cross-compilation')
 146   endif
 147   install_emptydir(get_option('localstatedir') / 'run')
 148 endif
 149
 150 alias_target('qemu-ga', all_qga)
 151
 152 test_env = environment()
 153 test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
 154 test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
 155
 156 # disable qga-ssh-test for now. glib's G_TEST_OPTION_ISOLATE_DIRS triggers
 157 # the leak detector in build-oss-fuzz Gitlab CI test. we should re-enable
 158 # this when an alternative is implemented or when the underlying glib
 159 # issue is identified/fix
 160 #if 'CONFIG_POSIX' in config_host
 161 if false
 162   srcs = [files('commands-posix-ssh.c')]
 163   i = 0
 164   foreach output: qga_qapi_outputs
 165     if output.startswith('qga-qapi-types') or output.startswith('qga-qapi-visit')
 166       srcs += qga_qapi_files[i]
 167     endif
 168     i = i + 1
 169   endforeach
 170   qga_ssh_test = executable('qga-ssh-test', srcs,
 171                             dependencies: [qemuutil],
 172                             c_args: ['-DQGA_BUILD_UNIT_TEST'])
 173
 174   test('qga-ssh-test',
 175        qga_ssh_test,
 176        env: test_env,
 177        suite: ['unit', 'qga'])
 178 endif