qga/meson.build

   1 if not have_ga
   2   if get_option('guest_agent_msi').enabled()
   3     error('Guest agent MSI requested, but the guest agent is not being built')
   4   endif
   5   have_qga_vss = false
   6   subdir_done()
   7 endif
   8
   9 have_qga_vss = get_option('qga_vss') \
  10   .require(targetos == 'windows',
  11            error_message: 'VSS support requires Windows') \
  12   .require('cpp' in all_languages,
  13            error_message: 'VSS support requires a C++ compiler') \
  14   .require(have_vss, error_message: '''VSS support requires VSS headers.
  15     If your Visual Studio installation doesn't have the VSS headers,
  16     Please download and install Microsoft VSS SDK:
  17     http://www.microsoft.com/en-us/download/details.aspx?id=23490
  18     On POSIX-systems, MinGW should provide headers in >=10.0 releases.
  19     you can extract the SDK headers by:
  20     $ scripts/extract-vsssdk-headers setup.exe
  21     The headers are extracted in the directory 'inc/win2003'.
  22     Then run configure with: --extra-cxxflags="-isystem /path/to/vss/inc/win2003"''') \
  23   .require(midl.found() or widl.found(),
  24            error_message: 'VSS support requires midl or widl') \
  25   .require(not get_option('prefer_static'),
  26            error_message: 'VSS support requires dynamic linking with GLib') \
  27   .allowed()
  28
  29 all_qga = []
  30
  31 qga_qapi_outputs = [
  32   'qga-qapi-commands.c',
  33   'qga-qapi-commands.h',
  34   'qga-qapi-emit-events.c',
  35   'qga-qapi-emit-events.h',
  36   'qga-qapi-events.c',
  37   'qga-qapi-events.h',
  38   'qga-qapi-init-commands.c',
  39   'qga-qapi-init-commands.h',
  40   'qga-qapi-introspect.c',
  41   'qga-qapi-introspect.h',
  42   'qga-qapi-types.c',
  43   'qga-qapi-types.h',
  44   'qga-qapi-visit.c',
  45   'qga-qapi-visit.h',
  46 ]
  47
  48 # Problem: to generate trace events, we'd have to add the .trace-events
  49 # file to qapi_trace_events like we do in qapi/meson.build.  Since
  50 # qapi_trace_events is used by trace/meson.build, we'd have to move
  51 # subdir('qga') above subdir('trace') in the top-level meson.build.
  52 # Can't, because it would break the dependency of qga on qemuutil (which
  53 # depends on trace_ss).  Not worth solving now; simply suppress trace
  54 # event generation instead.
  55 qga_qapi_files = custom_target('QGA QAPI files',
  56                                output: qga_qapi_outputs,
  57                                input: 'qapi-schema.json',
  58                                command: [ qapi_gen, '-o', 'qga', '-p', 'qga-', '@INPUT0@',
  59                                           '--suppress-tracing' ],
  60                                depend_files: qapi_gen_depends)
  61
  62 qga_ss = ss.source_set()
  63 qga_ss.add(qga_qapi_files.to_list())
  64 qga_ss.add(files(
  65   'commands.c',
  66   'guest-agent-command-state.c',
  67   'main.c',
  68   'cutils.c',
  69 ))
  70 qga_ss.add(when: 'CONFIG_POSIX', if_true: files(
  71   'channel-posix.c',
  72   'commands-posix.c',
  73   'commands-posix-ssh.c',
  74 ))
  75 if targetos == 'linux'
  76   qga_ss.add(files('commands-linux.c'))
  77 elif targetos in bsd_oses
  78   qga_ss.add(files('commands-bsd.c'))
  79 endif
  80 qga_ss.add(when: 'CONFIG_WIN32', if_true: files(
  81   'channel-win32.c',
  82   'commands-win32.c',
  83   'service-win32.c',
  84   'vss-win32.c'
  85 ))
  86
  87 qga_ss = qga_ss.apply(config_targetos, strict: false)
  88
  89 gen_tlb = []
  90 qga_libs = []
  91 if targetos == 'windows'
  92   qga_libs += ['-lws2_32', '-lwinmm', '-lpowrprof', '-lwtsapi32', '-lwininet', '-liphlpapi', '-lnetapi32',
  93                '-lsetupapi', '-lcfgmgr32']
  94   if have_qga_vss
  95     qga_libs += ['-lole32', '-loleaut32', '-lshlwapi', '-lstdc++', '-Wl,--enable-stdcall-fixup']
  96     subdir('vss-win32')
  97   endif
  98 endif
  99
 100 qga_objs = []
 101 if targetos == 'windows'
 102   windmc = find_program('windmc', required: true)
 103   windres = find_program('windres', required: true)
 104
 105   msgrc = custom_target('messages-win32.rc',
 106                         input: 'messages-win32.mc',
 107                         output: ['messages-win32.rc', 'MSG00409.bin', 'messages-win32.h'],
 108                         command: [windmc, '-h', '@OUTDIR@', '-r', '@OUTDIR@', '@INPUT@'])
 109   msgobj = custom_target('messages-win32.o',
 110                          input: msgrc[0],
 111                          output: 'messages-win32.o',
 112                          command: [windres, '-I', '@OUTDIR@', '-o', '@OUTPUT@', '@INPUT@'])
 113
 114   qga_objs = [msgobj]
 115 endif
 116
 117 qga = executable('qemu-ga', qga_ss.sources() + qga_objs,
 118                  link_args: qga_libs,
 119                  dependencies: [qemuutil, libudev],
 120                  install: true)
 121 all_qga += qga
 122
 123 if targetos == 'windows'
 124   qemu_ga_msi_arch = {
 125     'x86': ['-D', 'Arch=32'],
 126     'x86_64': ['-a', 'x64', '-D', 'Arch=64']
 127   }
 128   wixl = not_found
 129   if cpu in qemu_ga_msi_arch
 130     wixl = find_program('wixl', required: get_option('guest_agent_msi'))
 131   elif get_option('guest_agent_msi').enabled()
 132     error('CPU not supported for building guest agent installation package')
 133   endif
 134
 135   if wixl.found()
 136     deps = [gen_tlb, qga]
 137     qemu_ga_msi_vss = []
 138     if have_qga_vss
 139       qemu_ga_msi_vss = ['-D', 'InstallVss']
 140       deps += qga_vss
 141     endif
 142     if glib.version().version_compare('<2.73.2')
 143       libpcre = 'libpcre1'
 144     else
 145       libpcre = 'libpcre2'
 146     endif
 147     qga_msi_version = get_option('qemu_ga_version') == '' \
 148       ? meson.project_version() \
 149       : get_option('qemu_ga_version')
 150     qga_msi = custom_target('QGA MSI',
 151                             input: files('installer/qemu-ga.wxs'),
 152                             output: 'qemu-ga-@0@.msi'.format(host_arch),
 153                             depends: deps,
 154                             command: [
 155                               wixl, '-o', '@OUTPUT0@', '@INPUT0@',
 156                               qemu_ga_msi_arch[cpu],
 157                               qemu_ga_msi_vss,
 158                               '-D', 'BUILD_DIR=' + meson.project_build_root(),
 159                               '-D', 'BIN_DIR=' + glib_pc.get_variable('bindir'),
 160                               '-D', 'QEMU_GA_VERSION=' + qga_msi_version,
 161                               '-D', 'QEMU_GA_MANUFACTURER=' + get_option('qemu_ga_manufacturer'),
 162                               '-D', 'QEMU_GA_DISTRO=' + get_option('qemu_ga_distro'),
 163                               '-D', 'LIBPCRE=' + libpcre,
 164                             ])
 165     all_qga += [qga_msi]
 166     alias_target('msi', qga_msi)
 167   endif
 168 else
 169   if get_option('guest_agent_msi').enabled()
 170     error('MSI guest agent package is available only for MinGW Windows cross-compilation')
 171   endif
 172   install_emptydir(get_option('localstatedir') / 'run')
 173 endif
 174
 175 alias_target('qemu-ga', all_qga)
 176
 177 test_env = environment()
 178 test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
 179 test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
 180
 181 # disable qga-ssh-test for now. glib's G_TEST_OPTION_ISOLATE_DIRS triggers
 182 # the leak detector in build-oss-fuzz Gitlab CI test. we should re-enable
 183 # this when an alternative is implemented or when the underlying glib
 184 # issue is identified/fix
 185 #if targetos != 'windows'
 186 if false
 187   srcs = [files('commands-posix-ssh.c')]
 188   i = 0
 189   foreach output: qga_qapi_outputs
 190     if output.startswith('qga-qapi-types') or output.startswith('qga-qapi-visit')
 191       srcs += qga_qapi_files[i]
 192     endif
 193     i = i + 1
 194   endforeach
 195   qga_ssh_test = executable('qga-ssh-test', srcs,
 196                             dependencies: [qemuutil],
 197                             c_args: ['-DQGA_BUILD_UNIT_TEST'])
 198
 199   test('qga-ssh-test',
 200        qga_ssh_test,
 201        env: test_env,
 202        suite: ['unit', 'qga'])
 203 endif