scripts/kconfig/streamline_config.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2005-2009 - Steven Rostedt
   4 # Licensed under the terms of the GNU GPL License version 2
   5 #
   6 #  It's simple enough to figure out how this works.
   7 #  If not, then you can ask me at stripconfig@goodmis.org
   8 #
   9 # What it does?
  10 #
  11 #   If you have installed a Linux kernel from a distribution
  12 #   that turns on way too many modules than you need, and
  13 #   you only want the modules you use, then this program
  14 #   is perfect for you.
  15 #
  16 #   It gives you the ability to turn off all the modules that are
  17 #   not loaded on your system.
  18 #
  19 # Howto:
  20 #
  21 #  1. Boot up the kernel that you want to stream line the config on.
  22 #  2. Change directory to the directory holding the source of the
  23 #       kernel that you just booted.
  24 #  3. Copy the configuraton file to this directory as .config
  25 #  4. Have all your devices that you need modules for connected and
  26 #      operational (make sure that their corresponding modules are loaded)
  27 #  5. Run this script redirecting the output to some other file
  28 #       like config_strip.
  29 #  6. Back up your old config (if you want too).
  30 #  7. copy the config_strip file to .config
  31 #  8. Run "make oldconfig"
  32 #
  33 #  Now your kernel is ready to be built with only the modules that
  34 #  are loaded.
  35 #
  36 # Here's what I did with my Debian distribution.
  37 #
  38 #    cd /usr/src/linux-2.6.10
  39 #    cp /boot/config-2.6.10-1-686-smp .config
  40 #    ~/bin/streamline_config > config_strip
  41 #    mv .config config_sav
  42 #    mv config_strip .config
  43 #    make oldconfig
  44 #
  45 use strict;
  46 use Getopt::Long;
  47
  48 # set the environment variable LOCALMODCONFIG_DEBUG to get
  49 # debug output.
  50 my $debugprint = 0;
  51 $debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
  52
  53 sub dprint {
  54     return if (!$debugprint);
  55     print STDERR @_;
  56 }
  57
  58 my $config = ".config";
  59
  60 my $uname = `uname -r`;
  61 chomp $uname;
  62
  63 my @searchconfigs = (
  64         {
  65             "file" => ".config",
  66             "exec" => "cat",
  67         },
  68         {
  69             "file" => "/proc/config.gz",
  70             "exec" => "zcat",
  71         },
  72         {
  73             "file" => "/boot/config-$uname",
  74             "exec" => "cat",
  75         },
  76         {
  77             "file" => "/boot/vmlinuz-$uname",
  78             "exec" => "scripts/extract-ikconfig",
  79             "test" => "scripts/extract-ikconfig",
  80         },
  81         {
  82             "file" => "vmlinux",
  83             "exec" => "scripts/extract-ikconfig",
  84             "test" => "scripts/extract-ikconfig",
  85         },
  86         {
  87             "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
  88             "exec" => "scripts/extract-ikconfig",
  89             "test" => "scripts/extract-ikconfig",
  90         },
  91         {
  92             "file" => "kernel/configs.ko",
  93             "exec" => "scripts/extract-ikconfig",
  94             "test" => "scripts/extract-ikconfig",
  95         },
  96         {
  97             "file" => "kernel/configs.o",
  98             "exec" => "scripts/extract-ikconfig",
  99             "test" => "scripts/extract-ikconfig",
 100         },
 101 );
 102
 103 sub read_config {
 104     foreach my $conf (@searchconfigs) {
 105         my $file = $conf->{"file"};
 106
 107         next if ( ! -f "$file");
 108
 109         if (defined($conf->{"test"})) {
 110             `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
 111             next if ($?);
 112         }
 113
 114         my $exec = $conf->{"exec"};
 115
 116         print STDERR "using config: '$file'\n";
 117
 118         open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
 119         my @x = <$infile>;
 120         close $infile;
 121         return @x;
 122     }
 123     die "No config file found";
 124 }
 125
 126 my @config_file = read_config;
 127
 128 # Parse options
 129 my $localmodconfig = 0;
 130 my $localyesconfig = 0;
 131
 132 GetOptions("localmodconfig" => \$localmodconfig,
 133            "localyesconfig" => \$localyesconfig);
 134
 135 # Get the build source and top level Kconfig file (passed in)
 136 my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
 137 my $kconfig = $ARGV[1];
 138 my $lsmod_file = $ENV{'LSMOD'};
 139
 140 my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
 141 chomp @makefiles;
 142
 143 my %depends;
 144 my %selects;
 145 my %prompts;
 146 my %objects;
 147 my $var;
 148 my $iflevel = 0;
 149 my @ifdeps;
 150
 151 # prevent recursion
 152 my %read_kconfigs;
 153
 154 sub read_kconfig {
 155     my ($kconfig) = @_;
 156
 157     my $state = "NONE";
 158     my $config;
 159     my @kconfigs;
 160
 161     my $cont = 0;
 162     my $line;
 163
 164     my $source = "$ksource/$kconfig";
 165     my $last_source = "";
 166
 167     # Check for any environment variables used
 168     while ($source =~ /\$(\w+)/ && $last_source ne $source) {
 169         my $env = $1;
 170         $last_source = $source;
 171         $source =~ s/\$$env/$ENV{$env}/;
 172     }
 173
 174     open(my $kinfile, '<', $source) || die "Can't open $kconfig";
 175     while (<$kinfile>) {
 176         chomp;
 177
 178         # Make sure that lines ending with \ continue
 179         if ($cont) {
 180             $_ = $line . " " . $_;
 181         }
 182
 183         if (s/\\$//) {
 184             $cont = 1;
 185             $line = $_;
 186             next;
 187         }
 188
 189         $cont = 0;
 190
 191         # collect any Kconfig sources
 192         if (/^source\s*"(.*)"/) {
 193             $kconfigs[$#kconfigs+1] = $1;
 194         }
 195
 196         # configs found
 197         if (/^\s*(menu)?config\s+(\S+)\s*$/) {
 198             $state = "NEW";
 199             $config = $2;
 200
 201             # Add depends for 'if' nesting
 202             for (my $i = 0; $i < $iflevel; $i++) {
 203                 if ($i) {
 204                     $depends{$config} .= " " . $ifdeps[$i];
 205                 } else {
 206                     $depends{$config} = $ifdeps[$i];
 207                 }
 208                 $state = "DEP";
 209             }
 210
 211         # collect the depends for the config
 212         } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
 213             $state = "DEP";
 214             $depends{$config} = $1;
 215         } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
 216             $depends{$config} .= " " . $1;
 217
 218         # Get the configs that select this config
 219         } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
 220             my $conf = $1;
 221             if (defined($selects{$conf})) {
 222                 $selects{$conf} .= " " . $config;
 223             } else {
 224                 $selects{$conf} = $config;
 225             }
 226
 227         # configs without prompts must be selected
 228         } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
 229             # note if the config has a prompt
 230             $prompts{$config} = 1;
 231
 232         # Check for if statements
 233         } elsif (/^if\s+(.*\S)\s*$/) {
 234             my $deps = $1;
 235             # remove beginning and ending non text
 236             $deps =~ s/^[^a-zA-Z0-9_]*//;
 237             $deps =~ s/[^a-zA-Z0-9_]*$//;
 238
 239             my @deps = split /[^a-zA-Z0-9_]+/, $deps;
 240
 241             $ifdeps[$iflevel++] = join ':', @deps;
 242
 243         } elsif (/^endif/) {
 244
 245             $iflevel-- if ($iflevel);
 246
 247         # stop on "help"
 248         } elsif (/^\s*help\s*$/) {
 249             $state = "NONE";
 250         }
 251     }
 252     close($kinfile);
 253
 254     # read in any configs that were found.
 255     foreach my $kconfig (@kconfigs) {
 256         if (!defined($read_kconfigs{$kconfig})) {
 257             $read_kconfigs{$kconfig} = 1;
 258             read_kconfig($kconfig);
 259         }
 260     }
 261 }
 262
 263 if ($kconfig) {
 264     read_kconfig($kconfig);
 265 }
 266
 267 # Makefiles can use variables to define their dependencies
 268 sub convert_vars {
 269     my ($line, %vars) = @_;
 270
 271     my $process = "";
 272
 273     while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
 274         my $start = $1;
 275         my $variable = $2;
 276         my $var = $3;
 277
 278         if (defined($vars{$var})) {
 279             $process .= $start . $vars{$var};
 280         } else {
 281             $process .= $start . $variable;
 282         }
 283     }
 284
 285     $process .= $line;
 286
 287     return $process;
 288 }
 289
 290 # Read all Makefiles to map the configs to the objects
 291 foreach my $makefile (@makefiles) {
 292
 293     my $line = "";
 294     my %make_vars;
 295
 296     open(my $infile, '<', $makefile) || die "Can't open $makefile";
 297     while (<$infile>) {
 298         # if this line ends with a backslash, continue
 299         chomp;
 300         if (/^(.*)\\$/) {
 301             $line .= $1;
 302             next;
 303         }
 304
 305         $line .= $_;
 306         $_ = $line;
 307         $line = "";
 308
 309         my $objs;
 310
 311         # Convert variables in a line (could define configs)
 312         $_ = convert_vars($_, %make_vars);
 313
 314         # collect objects after obj-$(CONFIG_FOO_BAR)
 315         if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
 316             $var = $1;
 317             $objs = $2;
 318
 319         # check if variables are set
 320         } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
 321             $make_vars{$1} = $2;
 322         }
 323         if (defined($objs)) {
 324             foreach my $obj (split /\s+/,$objs) {
 325                 $obj =~ s/-/_/g;
 326                 if ($obj =~ /(.*)\.o$/) {
 327                     # Objects may be enabled by more than one config.
 328                     # Store configs in an array.
 329                     my @arr;
 330
 331                     if (defined($objects{$1})) {
 332                         @arr = @{$objects{$1}};
 333                     }
 334
 335                     $arr[$#arr+1] = $var;
 336
 337                     # The objects have a hash mapping to a reference
 338                     # of an array of configs.
 339                     $objects{$1} = \@arr;
 340                 }
 341             }
 342         }
 343     }
 344     close($infile);
 345 }
 346
 347 my %modules;
 348 my $linfile;
 349
 350 if (defined($lsmod_file)) {
 351     if ( ! -f $lsmod_file) {
 352         if ( -f $ENV{'objtree'}."/".$lsmod_file) {
 353             $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
 354         } else {
 355                 die "$lsmod_file not found";
 356         }
 357     }
 358
 359     my $otype = ( -x $lsmod_file) ? '-|' : '<';
 360     open($linfile, $otype, $lsmod_file);
 361
 362 } else {
 363
 364     # see what modules are loaded on this system
 365     my $lsmod;
 366
 367     foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
 368         if ( -x "$dir/lsmod" ) {
 369             $lsmod = "$dir/lsmod";
 370             last;
 371         }
 372 }
 373     if (!defined($lsmod)) {
 374         # try just the path
 375         $lsmod = "lsmod";
 376     }
 377
 378     open($linfile, '-|', $lsmod) || die "Can not call lsmod with $lsmod";
 379 }
 380
 381 while (<$linfile>) {
 382         next if (/^Module/);  # Skip the first line.
 383         if (/^(\S+)/) {
 384                 $modules{$1} = 1;
 385         }
 386 }
 387 close ($linfile);
 388
 389 # add to the configs hash all configs that are needed to enable
 390 # a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
 391 # where we know we need bar.o so we add FOO to the list.
 392 my %configs;
 393 foreach my $module (keys(%modules)) {
 394     if (defined($objects{$module})) {
 395         my @arr = @{$objects{$module}};
 396         foreach my $conf (@arr) {
 397             $configs{$conf} = $module;
 398             dprint "$conf added by direct ($module)\n";
 399         }
 400     } else {
 401         # Most likely, someone has a custom (binary?) module loaded.
 402         print STDERR "$module config not found!!\n";
 403     }
 404 }
 405
 406 # Read the current config, and see what is enabled. We want to
 407 # ignore configs that we would not enable anyway.
 408
 409 my %orig_configs;
 410 my $valid = "A-Za-z_0-9";
 411
 412 foreach my $line (@config_file) {
 413     $_ = $line;
 414
 415     if (/(CONFIG_[$valid]*)=(m|y)/) {
 416         $orig_configs{$1} = $2;
 417     }
 418 }
 419
 420 my $repeat = 1;
 421
 422 my $depconfig;
 423
 424 #
 425 # Note, we do not care about operands (like: &&, ||, !) we want to add any
 426 # config that is in the depend list of another config. This script does
 427 # not enable configs that are not already enabled. If we come across a
 428 # config A that depends on !B, we can still add B to the list of depends
 429 # to keep on. If A was on in the original config, B would not have been
 430 # and B would not be turned on by this script.
 431 #
 432 sub parse_config_depends
 433 {
 434     my ($p) = @_;
 435
 436     while ($p =~ /[$valid]/) {
 437
 438         if ($p =~ /^[^$valid]*([$valid]+)/) {
 439             my $conf = "CONFIG_" . $1;
 440
 441             $p =~ s/^[^$valid]*[$valid]+//;
 442
 443             # We only need to process if the depend config is a module
 444             if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
 445                 next;
 446             }
 447
 448             if (!defined($configs{$conf})) {
 449                 # We must make sure that this config has its
 450                 # dependencies met.
 451                 $repeat = 1; # do again
 452                 dprint "$conf selected by depend $depconfig\n";
 453                 $configs{$conf} = 1;
 454             }
 455         } else {
 456             die "this should never happen";
 457         }
 458     }
 459 }
 460
 461 # Select is treated a bit differently than depends. We call this
 462 # when a config has no prompt and requires another config to be
 463 # selected. We use to just select all configs that selected this
 464 # config, but found that that can balloon into enabling hundreds
 465 # of configs that we do not care about.
 466 #
 467 # The idea is we look at all the configs that select it. If one
 468 # is already in our list of configs to enable, then there's nothing
 469 # else to do. If there isn't, we pick the first config that was
 470 # enabled in the orignal config and use that.
 471 sub parse_config_selects
 472 {
 473     my ($config, $p) = @_;
 474
 475     my $next_config;
 476
 477     while ($p =~ /[$valid]/) {
 478
 479         if ($p =~ /^[^$valid]*([$valid]+)/) {
 480             my $conf = "CONFIG_" . $1;
 481
 482             $p =~ s/^[^$valid]*[$valid]+//;
 483
 484             # Make sure that this config exists in the current .config file
 485             if (!defined($orig_configs{$conf})) {
 486                 dprint "$conf not set for $config select\n";
 487                 next;
 488             }
 489
 490             # Check if something other than a module selects this config
 491             if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
 492                 dprint "$conf (non module) selects config, we are good\n";
 493                 # we are good with this
 494                 return;
 495             }
 496             if (defined($configs{$conf})) {
 497                 dprint "$conf selects $config so we are good\n";
 498                 # A set config selects this config, we are good
 499                 return;
 500             }
 501             # Set this config to be selected
 502             if (!defined($next_config)) {
 503                 $next_config = $conf;
 504             }
 505         } else {
 506             die "this should never happen";
 507         }
 508     }
 509
 510     # If no possible config selected this, then something happened.
 511     if (!defined($next_config)) {
 512         print STDERR "WARNING: $config is required, but nothing in the\n";
 513         print STDERR "  current config selects it.\n";
 514         return;
 515     }
 516
 517     # If we are here, then we found no config that is set and
 518     # selects this config. Repeat.
 519     $repeat = 1;
 520     # Make this config need to be selected
 521     $configs{$next_config} = 1;
 522     dprint "$next_config selected by select $config\n";
 523 }
 524
 525 my %process_selects;
 526
 527 # loop through all configs, select their dependencies.
 528 sub loop_depend {
 529     $repeat = 1;
 530
 531     while ($repeat) {
 532         $repeat = 0;
 533
 534       forloop:
 535         foreach my $config (keys %configs) {
 536
 537             # If this config is not a module, we do not need to process it
 538             if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
 539                 next forloop;
 540             }
 541
 542             $config =~ s/^CONFIG_//;
 543             $depconfig = $config;
 544
 545             if (defined($depends{$config})) {
 546                 # This config has dependencies. Make sure they are also included
 547                 parse_config_depends $depends{$config};
 548             }
 549
 550             # If the config has no prompt, then we need to check if a config
 551             # that is enabled selected it. Or if we need to enable one.
 552             if (!defined($prompts{$config}) && defined($selects{$config})) {
 553                 $process_selects{$config} = 1;
 554             }
 555         }
 556     }
 557 }
 558
 559 sub loop_select {
 560
 561     foreach my $config (keys %process_selects) {
 562         $config =~ s/^CONFIG_//;
 563
 564         dprint "Process select $config\n";
 565
 566         # config has no prompt and must be selected.
 567         parse_config_selects $config, $selects{$config};
 568     }
 569 }
 570
 571 while ($repeat) {
 572     # Get the first set of configs and their dependencies.
 573     loop_depend;
 574
 575     $repeat = 0;
 576
 577     # Now we need to see if we have to check selects;
 578     loop_select;
 579 }
 580
 581 my %setconfigs;
 582
 583 # Finally, read the .config file and turn off any module enabled that
 584 # we could not find a reason to keep enabled.
 585 foreach my $line (@config_file) {
 586     $_ = $line;
 587
 588     if (/CONFIG_IKCONFIG/) {
 589         if (/# CONFIG_IKCONFIG is not set/) {
 590             # enable IKCONFIG at least as a module
 591             print "CONFIG_IKCONFIG=m\n";
 592             # don't ask about PROC
 593             print "# CONFIG_IKCONFIG_PROC is not set\n";
 594         } else {
 595             print;
 596         }
 597         next;
 598     }
 599
 600     if (/^(CONFIG.*)=(m|y)/) {
 601         if (defined($configs{$1})) {
 602             if ($localyesconfig) {
 603                 $setconfigs{$1} = 'y';
 604                 print "$1=y\n";
 605                 next;
 606             } else {
 607                 $setconfigs{$1} = $2;
 608             }
 609         } elsif ($2 eq "m") {
 610             print "# $1 is not set\n";
 611             next;
 612         }
 613     }
 614     print;
 615 }
 616
 617 # Integrity check, make sure all modules that we want enabled do
 618 # indeed have their configs set.
 619 loop:
 620 foreach my $module (keys(%modules)) {
 621     if (defined($objects{$module})) {
 622         my @arr = @{$objects{$module}};
 623         foreach my $conf (@arr) {
 624             if (defined($setconfigs{$conf})) {
 625                 next loop;
 626             }
 627         }
 628         print STDERR "module $module did not have configs";
 629         foreach my $conf (@arr) {
 630             print STDERR " " , $conf;
 631         }
 632         print STDERR "\n";
 633     }
 634 }