scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 ##                                                               ##
  16 ## This software falls under the GNU General Public License.     ##
  17 ## Please read the COPYING file for more information             ##
  18
  19 # 18/01/2001 -  Cleanups
  20 #               Functions prototyped as foo(void) same as foo()
  21 #               Stop eval'ing where we don't need to.
  22 # -- huggie@earth.li
  23
  24 # 27/06/2001 -  Allowed whitespace after initial "/**" and
  25 #               allowed comments before function declarations.
  26 # -- Christian Kreibich <ck@whoop.org>
  27
  28 # Still to do:
  29 #       - add perldoc documentation
  30 #       - Look more closely at some of the scarier bits :)
  31
  32 # 26/05/2001 -  Support for separate source and object trees.
  33 #               Return error code.
  34 #               Keith Owens <kaos@ocs.com.au>
  35
  36 # 23/09/2001 - Added support for typedefs, structs, enums and unions
  37 #              Support for Context section; can be terminated using empty line
  38 #              Small fixes (like spaces vs. \s in regex)
  39 # -- Tim Jansen <tim@tjansen.de>
  40
  41 # 25/07/2012 - Added support for HTML5
  42 # -- Dan Luedtke <mail@danrl.de>
  43
  44 sub usage {
  45     my $message = <<"EOF";
  46 Usage: $0 [OPTION ...] FILE ...
  47
  48 Read C language source or header FILEs, extract embedded documentation comments,
  49 and print formatted documentation to standard output.
  50
  51 The documentation comments are identified by "/**" opening comment mark. See
  52 Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  53
  54 Output format selection (mutually exclusive):
  55   -man                  Output troff manual page format. This is the default.
  56   -rst                  Output reStructuredText format.
  57   -none                 Do not output documentation, only warnings.
  58
  59 Output selection (mutually exclusive):
  60   -export               Only output documentation for symbols that have been
  61                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  62                         in any input FILE or -export-file FILE.
  63   -internal             Only output documentation for symbols that have NOT been
  64                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  65                         in any input FILE or -export-file FILE.
  66   -function NAME        Only output documentation for the given function(s)
  67                         or DOC: section title(s). All other functions and DOC:
  68                         sections are ignored. May be specified multiple times.
  69   -nofunction NAME      Do NOT output documentation for the given function(s);
  70                         only output documentation for the other functions and
  71                         DOC: sections. May be specified multiple times.
  72
  73 Output selection modifiers:
  74   -no-doc-sections      Do not output DOC: sections.
  75   -enable-lineno        Enable output of #define LINENO lines. Only works with
  76                         reStructuredText format.
  77   -export-file FILE     Specify an additional FILE in which to look for
  78                         EXPORT_SYMBOL() and EXPORT_SYMBOL_GPL(). To be used with
  79                         -export or -internal. May be specified multiple times.
  80
  81 Other parameters:
  82   -v                    Verbose output, more warnings and other information.
  83   -h                    Print this help.
  84
  85 EOF
  86     print $message;
  87     exit 1;
  88 }
  89
  90 #
  91 # format of comments.
  92 # In the following table, (...)? signifies optional structure.
  93 #                         (...)* signifies 0 or more structure elements
  94 # /**
  95 #  * function_name(:)? (- short description)?
  96 # (* @parameterx: (description of parameter x)?)*
  97 # (* a blank line)?
  98 #  * (Description:)? (Description of function)?
  99 #  * (section header: (section description)? )*
 100 #  (*)?*/
 101 #
 102 # So .. the trivial example would be:
 103 #
 104 # /**
 105 #  * my_function
 106 #  */
 107 #
 108 # If the Description: header tag is omitted, then there must be a blank line
 109 # after the last parameter specification.
 110 # e.g.
 111 # /**
 112 #  * my_function - does my stuff
 113 #  * @my_arg: its mine damnit
 114 #  *
 115 #  * Does my stuff explained.
 116 #  */
 117 #
 118 #  or, could also use:
 119 # /**
 120 #  * my_function - does my stuff
 121 #  * @my_arg: its mine damnit
 122 #  * Description: Does my stuff explained.
 123 #  */
 124 # etc.
 125 #
 126 # Besides functions you can also write documentation for structs, unions,
 127 # enums and typedefs. Instead of the function name you must write the name
 128 # of the declaration;  the struct/union/enum/typedef must always precede
 129 # the name. Nesting of declarations is not supported.
 130 # Use the argument mechanism to document members or constants.
 131 # e.g.
 132 # /**
 133 #  * struct my_struct - short description
 134 #  * @a: first member
 135 #  * @b: second member
 136 #  *
 137 #  * Longer description
 138 #  */
 139 # struct my_struct {
 140 #     int a;
 141 #     int b;
 142 # /* private: */
 143 #     int c;
 144 # };
 145 #
 146 # All descriptions can be multiline, except the short function description.
 147 #
 148 # For really longs structs, you can also describe arguments inside the
 149 # body of the struct.
 150 # eg.
 151 # /**
 152 #  * struct my_struct - short description
 153 #  * @a: first member
 154 #  * @b: second member
 155 #  *
 156 #  * Longer description
 157 #  */
 158 # struct my_struct {
 159 #     int a;
 160 #     int b;
 161 #     /**
 162 #      * @c: This is longer description of C
 163 #      *
 164 #      * You can use paragraphs to describe arguments
 165 #      * using this method.
 166 #      */
 167 #     int c;
 168 # };
 169 #
 170 # This should be use only for struct/enum members.
 171 #
 172 # You can also add additional sections. When documenting kernel functions you
 173 # should document the "Context:" of the function, e.g. whether the functions
 174 # can be called form interrupts. Unlike other sections you can end it with an
 175 # empty line.
 176 # A non-void function should have a "Return:" section describing the return
 177 # value(s).
 178 # Example-sections should contain the string EXAMPLE so that they are marked
 179 # appropriately in DocBook.
 180 #
 181 # Example:
 182 # /**
 183 #  * user_function - function that can only be called in user context
 184 #  * @a: some argument
 185 #  * Context: !in_interrupt()
 186 #  *
 187 #  * Some description
 188 #  * Example:
 189 #  *    user_function(22);
 190 #  */
 191 # ...
 192 #
 193 #
 194 # All descriptive text is further processed, scanning for the following special
 195 # patterns, which are highlighted appropriately.
 196 #
 197 # 'funcname()' - function
 198 # '$ENVVAR' - environmental variable
 199 # '&struct_name' - name of a structure (up to two words including 'struct')
 200 # '&struct_name.member' - name of a structure member
 201 # '@parameter' - name of a parameter
 202 # '%CONST' - name of a constant.
 203 # '``LITERAL``' - literal string without any spaces on it.
 204
 205 ## init lots of data
 206
 207 my $errors = 0;
 208 my $warnings = 0;
 209 my $anon_struct_union = 0;
 210
 211 # match expressions used to find embedded type information
 212 my $type_constant = '\b``([^\`]+)``\b';
 213 my $type_constant2 = '\%([-_\w]+)';
 214 my $type_func = '(\w+)\(\)';
 215 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
 216 my $type_param_ref = '([\!]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
 217 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
 218 my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
 219 my $type_env = '(\$\w+)';
 220 my $type_enum = '\&(enum\s*([_\w]+))';
 221 my $type_struct = '\&(struct\s*([_\w]+))';
 222 my $type_typedef = '\&(typedef\s*([_\w]+))';
 223 my $type_union = '\&(union\s*([_\w]+))';
 224 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
 225 my $type_fallback = '\&([_\w]+)';
 226 my $type_member_func = $type_member . '\(\)';
 227
 228 # Output conversion substitutions.
 229 #  One for each output format
 230
 231 # these are pretty rough
 232 my @highlights_man = (
 233                       [$type_constant, "\$1"],
 234                       [$type_constant2, "\$1"],
 235                       [$type_func, "\\\\fB\$1\\\\fP"],
 236                       [$type_enum, "\\\\fI\$1\\\\fP"],
 237                       [$type_struct, "\\\\fI\$1\\\\fP"],
 238                       [$type_typedef, "\\\\fI\$1\\\\fP"],
 239                       [$type_union, "\\\\fI\$1\\\\fP"],
 240                       [$type_param, "\\\\fI\$1\\\\fP"],
 241                       [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
 242                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
 243                       [$type_fallback, "\\\\fI\$1\\\\fP"]
 244                      );
 245 my $blankline_man = "";
 246
 247 # rst-mode
 248 my @highlights_rst = (
 249                        [$type_constant, "``\$1``"],
 250                        [$type_constant2, "``\$1``"],
 251                        # Note: need to escape () to avoid func matching later
 252                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 253                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 254                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 255                        [$type_fp_param2, "**\$1\\\\(\\\\)**"],
 256                        [$type_func, "\$1()"],
 257                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 258                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 259                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 260                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 261                        # in rst this can refer to any type
 262                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 263                        [$type_param_ref, "**\$1\$2**"]
 264                       );
 265 my $blankline_rst = "\n";
 266
 267 # read arguments
 268 if ($#ARGV == -1) {
 269     usage();
 270 }
 271
 272 my $kernelversion;
 273 my $dohighlight = "";
 274
 275 my $verbose = 0;
 276 my $output_mode = "rst";
 277 my $output_preformatted = 0;
 278 my $no_doc_sections = 0;
 279 my $enable_lineno = 0;
 280 my @highlights = @highlights_rst;
 281 my $blankline = $blankline_rst;
 282 my $modulename = "Kernel API";
 283
 284 use constant {
 285     OUTPUT_ALL          => 0, # output all symbols and doc sections
 286     OUTPUT_INCLUDE      => 1, # output only specified symbols
 287     OUTPUT_EXCLUDE      => 2, # output everything except specified symbols
 288     OUTPUT_EXPORTED     => 3, # output exported symbols
 289     OUTPUT_INTERNAL     => 4, # output non-exported symbols
 290 };
 291 my $output_selection = OUTPUT_ALL;
 292 my $show_not_found = 0; # No longer used
 293
 294 my @export_file_list;
 295
 296 my @build_time;
 297 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 298     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 299     @build_time = gmtime($seconds);
 300 } else {
 301     @build_time = localtime;
 302 }
 303
 304 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 305                 'July', 'August', 'September', 'October',
 306                 'November', 'December')[$build_time[4]] .
 307   " " . ($build_time[5]+1900);
 308
 309 # Essentially these are globals.
 310 # They probably want to be tidied up, made more localised or something.
 311 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 312 # could cause "use of undefined value" or other bugs.
 313 my ($function, %function_table, %parametertypes, $declaration_purpose);
 314 my $declaration_start_line;
 315 my ($type, $declaration_name, $return_type);
 316 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 317
 318 if (defined($ENV{'KBUILD_VERBOSE'})) {
 319         $verbose = "$ENV{'KBUILD_VERBOSE'}";
 320 }
 321
 322 # Generated docbook code is inserted in a template at a point where
 323 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 324 # https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 325 # We keep track of number of generated entries and generate a dummy
 326 # if needs be to ensure the expanded template can be postprocessed
 327 # into html.
 328 my $section_counter = 0;
 329
 330 my $lineprefix="";
 331
 332 # Parser states
 333 use constant {
 334     STATE_NORMAL        => 0,        # normal code
 335     STATE_NAME          => 1,        # looking for function name
 336     STATE_BODY_MAYBE    => 2,        # body - or maybe more description
 337     STATE_BODY          => 3,        # the body of the comment
 338     STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
 339     STATE_PROTO         => 5,        # scanning prototype
 340     STATE_DOCBLOCK      => 6,        # documentation block
 341     STATE_INLINE        => 7,        # gathering doc outside main block
 342 };
 343 my $state;
 344 my $in_doc_sect;
 345 my $leading_space;
 346
 347 # Inline documentation state
 348 use constant {
 349     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 350     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 351     STATE_INLINE_TEXT   => 2, # looking for member documentation
 352     STATE_INLINE_END    => 3, # done
 353     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 354                               # Spit a warning as it's not
 355                               # proper kernel-doc and ignore the rest.
 356 };
 357 my $inline_doc_state;
 358
 359 #declaration types: can be
 360 # 'function', 'struct', 'union', 'enum', 'typedef'
 361 my $decl_type;
 362
 363 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 364 my $doc_end = '\*/';
 365 my $doc_com = '\s*\*\s*';
 366 my $doc_com_body = '\s*\* ?';
 367 my $doc_decl = $doc_com . '(\w+)';
 368 # @params and a strictly limited set of supported section names
 369 my $doc_sect = $doc_com .
 370     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:(.*)';
 371 my $doc_content = $doc_com_body . '(.*)';
 372 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 373 my $doc_inline_start = '^\s*/\*\*\s*$';
 374 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 375 my $doc_inline_end = '^\s*\*/\s*$';
 376 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 377 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 378
 379 my %parameterdescs;
 380 my %parameterdesc_start_lines;
 381 my @parameterlist;
 382 my %sections;
 383 my @sectionlist;
 384 my %section_start_lines;
 385 my $sectcheck;
 386 my $struct_actual;
 387
 388 my $contents = "";
 389 my $new_start_line = 0;
 390
 391 # the canonical section names. see also $doc_sect above.
 392 my $section_default = "Description";    # default section
 393 my $section_intro = "Introduction";
 394 my $section = $section_default;
 395 my $section_context = "Context";
 396 my $section_return = "Return";
 397
 398 my $undescribed = "-- undescribed --";
 399
 400 reset_state();
 401
 402 while ($ARGV[0] =~ m/^--?(.*)/) {
 403     my $cmd = $1;
 404     shift @ARGV;
 405     if ($cmd eq "man") {
 406         $output_mode = "man";
 407         @highlights = @highlights_man;
 408         $blankline = $blankline_man;
 409     } elsif ($cmd eq "rst") {
 410         $output_mode = "rst";
 411         @highlights = @highlights_rst;
 412         $blankline = $blankline_rst;
 413     } elsif ($cmd eq "none") {
 414         $output_mode = "none";
 415     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 416         $modulename = shift @ARGV;
 417     } elsif ($cmd eq "function") { # to only output specific functions
 418         $output_selection = OUTPUT_INCLUDE;
 419         $function = shift @ARGV;
 420         $function_table{$function} = 1;
 421     } elsif ($cmd eq "nofunction") { # output all except specific functions
 422         $output_selection = OUTPUT_EXCLUDE;
 423         $function = shift @ARGV;
 424         $function_table{$function} = 1;
 425     } elsif ($cmd eq "export") { # only exported symbols
 426         $output_selection = OUTPUT_EXPORTED;
 427         %function_table = ();
 428     } elsif ($cmd eq "internal") { # only non-exported symbols
 429         $output_selection = OUTPUT_INTERNAL;
 430         %function_table = ();
 431     } elsif ($cmd eq "export-file") {
 432         my $file = shift @ARGV;
 433         push(@export_file_list, $file);
 434     } elsif ($cmd eq "v") {
 435         $verbose = 1;
 436     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 437         usage();
 438     } elsif ($cmd eq 'no-doc-sections') {
 439             $no_doc_sections = 1;
 440     } elsif ($cmd eq 'enable-lineno') {
 441             $enable_lineno = 1;
 442     } elsif ($cmd eq 'show-not-found') {
 443         $show_not_found = 1;  # A no-op but don't fail
 444     } else {
 445         # Unknown argument
 446         usage();
 447     }
 448 }
 449
 450 # continue execution near EOF;
 451
 452 # get kernel version from env
 453 sub get_kernel_version() {
 454     my $version = 'unknown kernel version';
 455
 456     if (defined($ENV{'KERNELVERSION'})) {
 457         $version = $ENV{'KERNELVERSION'};
 458     }
 459     return $version;
 460 }
 461
 462 #
 463 sub print_lineno {
 464     my $lineno = shift;
 465     if ($enable_lineno && defined($lineno)) {
 466         print "#define LINENO " . $lineno . "\n";
 467     }
 468 }
 469 ##
 470 # dumps section contents to arrays/hashes intended for that purpose.
 471 #
 472 sub dump_section {
 473     my $file = shift;
 474     my $name = shift;
 475     my $contents = join "\n", @_;
 476
 477     if ($name =~ m/$type_param/) {
 478         $name = $1;
 479         $parameterdescs{$name} = $contents;
 480         $sectcheck = $sectcheck . $name . " ";
 481         $parameterdesc_start_lines{$name} = $new_start_line;
 482         $new_start_line = 0;
 483     } elsif ($name eq "@\.\.\.") {
 484         $name = "...";
 485         $parameterdescs{$name} = $contents;
 486         $sectcheck = $sectcheck . $name . " ";
 487         $parameterdesc_start_lines{$name} = $new_start_line;
 488         $new_start_line = 0;
 489     } else {
 490         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 491             # Only warn on user specified duplicate section names.
 492             if ($name ne $section_default) {
 493                 print STDERR "${file}:$.: warning: duplicate section name '$name'\n";
 494                 ++$warnings;
 495             }
 496             $sections{$name} .= $contents;
 497         } else {
 498             $sections{$name} = $contents;
 499             push @sectionlist, $name;
 500             $section_start_lines{$name} = $new_start_line;
 501             $new_start_line = 0;
 502         }
 503     }
 504 }
 505
 506 ##
 507 # dump DOC: section after checking that it should go out
 508 #
 509 sub dump_doc_section {
 510     my $file = shift;
 511     my $name = shift;
 512     my $contents = join "\n", @_;
 513
 514     if ($no_doc_sections) {
 515         return;
 516     }
 517
 518     if (($output_selection == OUTPUT_ALL) ||
 519         ($output_selection == OUTPUT_INCLUDE &&
 520          defined($function_table{$name})) ||
 521         ($output_selection == OUTPUT_EXCLUDE &&
 522          !defined($function_table{$name})))
 523     {
 524         dump_section($file, $name, $contents);
 525         output_blockhead({'sectionlist' => \@sectionlist,
 526                           'sections' => \%sections,
 527                           'module' => $modulename,
 528                           'content-only' => ($output_selection != OUTPUT_ALL), });
 529     }
 530 }
 531
 532 ##
 533 # output function
 534 #
 535 # parameterdescs, a hash.
 536 #  function => "function name"
 537 #  parameterlist => @list of parameters
 538 #  parameterdescs => %parameter descriptions
 539 #  sectionlist => @list of sections
 540 #  sections => %section descriptions
 541 #
 542
 543 sub output_highlight {
 544     my $contents = join "\n",@_;
 545     my $line;
 546
 547 #   DEBUG
 548 #   if (!defined $contents) {
 549 #       use Carp;
 550 #       confess "output_highlight got called with no args?\n";
 551 #   }
 552
 553 #   print STDERR "contents b4:$contents\n";
 554     eval $dohighlight;
 555     die $@ if $@;
 556 #   print STDERR "contents af:$contents\n";
 557
 558     foreach $line (split "\n", $contents) {
 559         if (! $output_preformatted) {
 560             $line =~ s/^\s*//;
 561         }
 562         if ($line eq ""){
 563             if (! $output_preformatted) {
 564                 print $lineprefix, $blankline;
 565             }
 566         } else {
 567             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 568                 print "\\&$line";
 569             } else {
 570                 print $lineprefix, $line;
 571             }
 572         }
 573         print "\n";
 574     }
 575 }
 576
 577 ##
 578 # output function in man
 579 sub output_function_man(%) {
 580     my %args = %{$_[0]};
 581     my ($parameter, $section);
 582     my $count;
 583
 584     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 585
 586     print ".SH NAME\n";
 587     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 588
 589     print ".SH SYNOPSIS\n";
 590     if ($args{'functiontype'} ne "") {
 591         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 592     } else {
 593         print ".B \"" . $args{'function'} . "\n";
 594     }
 595     $count = 0;
 596     my $parenth = "(";
 597     my $post = ",";
 598     foreach my $parameter (@{$args{'parameterlist'}}) {
 599         if ($count == $#{$args{'parameterlist'}}) {
 600             $post = ");";
 601         }
 602         $type = $args{'parametertypes'}{$parameter};
 603         if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
 604             # pointer-to-function
 605             print ".BI \"" . $parenth . $1 . "\" " . $parameter . " \") (" . $2 . ")" . $post . "\"\n";
 606         } else {
 607             $type =~ s/([^\*])$/$1 /;
 608             print ".BI \"" . $parenth . $type . "\" " . $parameter . " \"" . $post . "\"\n";
 609         }
 610         $count++;
 611         $parenth = "";
 612     }
 613
 614     print ".SH ARGUMENTS\n";
 615     foreach $parameter (@{$args{'parameterlist'}}) {
 616         my $parameter_name = $parameter;
 617         $parameter_name =~ s/\[.*//;
 618
 619         print ".IP \"" . $parameter . "\" 12\n";
 620         output_highlight($args{'parameterdescs'}{$parameter_name});
 621     }
 622     foreach $section (@{$args{'sectionlist'}}) {
 623         print ".SH \"", uc $section, "\"\n";
 624         output_highlight($args{'sections'}{$section});
 625     }
 626 }
 627
 628 ##
 629 # output enum in man
 630 sub output_enum_man(%) {
 631     my %args = %{$_[0]};
 632     my ($parameter, $section);
 633     my $count;
 634
 635     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 636
 637     print ".SH NAME\n";
 638     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 639
 640     print ".SH SYNOPSIS\n";
 641     print "enum " . $args{'enum'} . " {\n";
 642     $count = 0;
 643     foreach my $parameter (@{$args{'parameterlist'}}) {
 644         print ".br\n.BI \"    $parameter\"\n";
 645         if ($count == $#{$args{'parameterlist'}}) {
 646             print "\n};\n";
 647             last;
 648         }
 649         else {
 650             print ", \n.br\n";
 651         }
 652         $count++;
 653     }
 654
 655     print ".SH Constants\n";
 656     foreach $parameter (@{$args{'parameterlist'}}) {
 657         my $parameter_name = $parameter;
 658         $parameter_name =~ s/\[.*//;
 659
 660         print ".IP \"" . $parameter . "\" 12\n";
 661         output_highlight($args{'parameterdescs'}{$parameter_name});
 662     }
 663     foreach $section (@{$args{'sectionlist'}}) {
 664         print ".SH \"$section\"\n";
 665         output_highlight($args{'sections'}{$section});
 666     }
 667 }
 668
 669 ##
 670 # output struct in man
 671 sub output_struct_man(%) {
 672     my %args = %{$_[0]};
 673     my ($parameter, $section);
 674
 675     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 676
 677     print ".SH NAME\n";
 678     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 679
 680     my $declaration = $args{'definition'};
 681     $declaration =~ s/\t/  /g;
 682     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 683     print ".SH SYNOPSIS\n";
 684     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 685     print ".BI \"$declaration\n};\n.br\n\n";
 686
 687     print ".SH Members\n";
 688     foreach $parameter (@{$args{'parameterlist'}}) {
 689         ($parameter =~ /^#/) && next;
 690
 691         my $parameter_name = $parameter;
 692         $parameter_name =~ s/\[.*//;
 693
 694         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 695         print ".IP \"" . $parameter . "\" 12\n";
 696         output_highlight($args{'parameterdescs'}{$parameter_name});
 697     }
 698     foreach $section (@{$args{'sectionlist'}}) {
 699         print ".SH \"$section\"\n";
 700         output_highlight($args{'sections'}{$section});
 701     }
 702 }
 703
 704 ##
 705 # output typedef in man
 706 sub output_typedef_man(%) {
 707     my %args = %{$_[0]};
 708     my ($parameter, $section);
 709
 710     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 711
 712     print ".SH NAME\n";
 713     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 714
 715     foreach $section (@{$args{'sectionlist'}}) {
 716         print ".SH \"$section\"\n";
 717         output_highlight($args{'sections'}{$section});
 718     }
 719 }
 720
 721 sub output_blockhead_man(%) {
 722     my %args = %{$_[0]};
 723     my ($parameter, $section);
 724     my $count;
 725
 726     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 727
 728     foreach $section (@{$args{'sectionlist'}}) {
 729         print ".SH \"$section\"\n";
 730         output_highlight($args{'sections'}{$section});
 731     }
 732 }
 733
 734 ##
 735 # output in restructured text
 736 #
 737
 738 #
 739 # This could use some work; it's used to output the DOC: sections, and
 740 # starts by putting out the name of the doc section itself, but that tends
 741 # to duplicate a header already in the template file.
 742 #
 743 sub output_blockhead_rst(%) {
 744     my %args = %{$_[0]};
 745     my ($parameter, $section);
 746
 747     foreach $section (@{$args{'sectionlist'}}) {
 748         if ($output_selection != OUTPUT_INCLUDE) {
 749             print "**$section**\n\n";
 750         }
 751         print_lineno($section_start_lines{$section});
 752         output_highlight_rst($args{'sections'}{$section});
 753         print "\n";
 754     }
 755 }
 756
 757 #
 758 # Apply the RST highlights to a sub-block of text.
 759 #
 760 sub highlight_block($) {
 761     # The dohighlight kludge requires the text be called $contents
 762     my $contents = shift;
 763     eval $dohighlight;
 764     die $@ if $@;
 765     return $contents;
 766 }
 767
 768 #
 769 # Regexes used only here.
 770 #
 771 my $sphinx_literal = '^[^.].*::$';
 772 my $sphinx_cblock = '^\.\.\ +code-block::';
 773
 774 sub output_highlight_rst {
 775     my $input = join "\n",@_;
 776     my $output = "";
 777     my $line;
 778     my $in_literal = 0;
 779     my $litprefix;
 780     my $block = "";
 781
 782     foreach $line (split "\n",$input) {
 783         #
 784         # If we're in a literal block, see if we should drop out
 785         # of it.  Otherwise pass the line straight through unmunged.
 786         #
 787         if ($in_literal) {
 788             if (! ($line =~ /^\s*$/)) {
 789                 #
 790                 # If this is the first non-blank line in a literal
 791                 # block we need to figure out what the proper indent is.
 792                 #
 793                 if ($litprefix eq "") {
 794                     $line =~ /^(\s*)/;
 795                     $litprefix = '^' . $1;
 796                     $output .= $line . "\n";
 797                 } elsif (! ($line =~ /$litprefix/)) {
 798                     $in_literal = 0;
 799                 } else {
 800                     $output .= $line . "\n";
 801                 }
 802             } else {
 803                 $output .= $line . "\n";
 804             }
 805         }
 806         #
 807         # Not in a literal block (or just dropped out)
 808         #
 809         if (! $in_literal) {
 810             $block .= $line . "\n";
 811             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 812                 $in_literal = 1;
 813                 $litprefix = "";
 814                 $output .= highlight_block($block);
 815                 $block = ""
 816             }
 817         }
 818     }
 819
 820     if ($block) {
 821         $output .= highlight_block($block);
 822     }
 823     foreach $line (split "\n", $output) {
 824         print $lineprefix . $line . "\n";
 825     }
 826 }
 827
 828 sub output_function_rst(%) {
 829     my %args = %{$_[0]};
 830     my ($parameter, $section);
 831     my $oldprefix = $lineprefix;
 832     my $start = "";
 833
 834     if ($args{'typedef'}) {
 835         print ".. c:type:: ". $args{'function'} . "\n\n";
 836         print_lineno($declaration_start_line);
 837         print "   **Typedef**: ";
 838         $lineprefix = "";
 839         output_highlight_rst($args{'purpose'});
 840         $start = "\n\n**Syntax**\n\n  ``";
 841     } else {
 842         print ".. c:function:: ";
 843     }
 844     if ($args{'functiontype'} ne "") {
 845         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 846     } else {
 847         $start .= $args{'function'} . " (";
 848     }
 849     print $start;
 850
 851     my $count = 0;
 852     foreach my $parameter (@{$args{'parameterlist'}}) {
 853         if ($count ne 0) {
 854             print ", ";
 855         }
 856         $count++;
 857         $type = $args{'parametertypes'}{$parameter};
 858
 859         if ($type =~ m/([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)/) {
 860             # pointer-to-function
 861             print $1 . $parameter . ") (" . $2 . ")";
 862         } else {
 863             print $type . " " . $parameter;
 864         }
 865     }
 866     if ($args{'typedef'}) {
 867         print ");``\n\n";
 868     } else {
 869         print ")\n\n";
 870         print_lineno($declaration_start_line);
 871         $lineprefix = "   ";
 872         output_highlight_rst($args{'purpose'});
 873         print "\n";
 874     }
 875
 876     print "**Parameters**\n\n";
 877     $lineprefix = "  ";
 878     foreach $parameter (@{$args{'parameterlist'}}) {
 879         my $parameter_name = $parameter;
 880         $parameter_name =~ s/\[.*//;
 881         $type = $args{'parametertypes'}{$parameter};
 882
 883         if ($type ne "") {
 884             print "``$type $parameter``\n";
 885         } else {
 886             print "``$parameter``\n";
 887         }
 888
 889         print_lineno($parameterdesc_start_lines{$parameter_name});
 890
 891         if (defined($args{'parameterdescs'}{$parameter_name}) &&
 892             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
 893             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 894         } else {
 895             print "  *undescribed*\n";
 896         }
 897         print "\n";
 898     }
 899
 900     $lineprefix = $oldprefix;
 901     output_section_rst(@_);
 902 }
 903
 904 sub output_section_rst(%) {
 905     my %args = %{$_[0]};
 906     my $section;
 907     my $oldprefix = $lineprefix;
 908     $lineprefix = "";
 909
 910     foreach $section (@{$args{'sectionlist'}}) {
 911         print "**$section**\n\n";
 912         print_lineno($section_start_lines{$section});
 913         output_highlight_rst($args{'sections'}{$section});
 914         print "\n";
 915     }
 916     print "\n";
 917     $lineprefix = $oldprefix;
 918 }
 919
 920 sub output_enum_rst(%) {
 921     my %args = %{$_[0]};
 922     my ($parameter);
 923     my $oldprefix = $lineprefix;
 924     my $count;
 925     my $name = "enum " . $args{'enum'};
 926
 927     print "\n\n.. c:type:: " . $name . "\n\n";
 928     print_lineno($declaration_start_line);
 929     $lineprefix = "   ";
 930     output_highlight_rst($args{'purpose'});
 931     print "\n";
 932
 933     print "**Constants**\n\n";
 934     $lineprefix = "  ";
 935     foreach $parameter (@{$args{'parameterlist'}}) {
 936         print "``$parameter``\n";
 937         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
 938             output_highlight_rst($args{'parameterdescs'}{$parameter});
 939         } else {
 940             print "  *undescribed*\n";
 941         }
 942         print "\n";
 943     }
 944
 945     $lineprefix = $oldprefix;
 946     output_section_rst(@_);
 947 }
 948
 949 sub output_typedef_rst(%) {
 950     my %args = %{$_[0]};
 951     my ($parameter);
 952     my $oldprefix = $lineprefix;
 953     my $name = "typedef " . $args{'typedef'};
 954
 955     print "\n\n.. c:type:: " . $name . "\n\n";
 956     print_lineno($declaration_start_line);
 957     $lineprefix = "   ";
 958     output_highlight_rst($args{'purpose'});
 959     print "\n";
 960
 961     $lineprefix = $oldprefix;
 962     output_section_rst(@_);
 963 }
 964
 965 sub output_struct_rst(%) {
 966     my %args = %{$_[0]};
 967     my ($parameter);
 968     my $oldprefix = $lineprefix;
 969     my $name = $args{'type'} . " " . $args{'struct'};
 970
 971     print "\n\n.. c:type:: " . $name . "\n\n";
 972     print_lineno($declaration_start_line);
 973     $lineprefix = "   ";
 974     output_highlight_rst($args{'purpose'});
 975     print "\n";
 976
 977     print "**Definition**\n\n";
 978     print "::\n\n";
 979     my $declaration = $args{'definition'};
 980     $declaration =~ s/\t/  /g;
 981     print "  " . $args{'type'} . " " . $args{'struct'} . " {\n$declaration  };\n\n";
 982
 983     print "**Members**\n\n";
 984     $lineprefix = "  ";
 985     foreach $parameter (@{$args{'parameterlist'}}) {
 986         ($parameter =~ /^#/) && next;
 987
 988         my $parameter_name = $parameter;
 989         $parameter_name =~ s/\[.*//;
 990
 991         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 992         $type = $args{'parametertypes'}{$parameter};
 993         print_lineno($parameterdesc_start_lines{$parameter_name});
 994         print "``" . $parameter . "``\n";
 995         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 996         print "\n";
 997     }
 998     print "\n";
 999
1000     $lineprefix = $oldprefix;
1001     output_section_rst(@_);
1002 }
1003
1004 ## none mode output functions
1005
1006 sub output_function_none(%) {
1007 }
1008
1009 sub output_enum_none(%) {
1010 }
1011
1012 sub output_typedef_none(%) {
1013 }
1014
1015 sub output_struct_none(%) {
1016 }
1017
1018 sub output_blockhead_none(%) {
1019 }
1020
1021 ##
1022 # generic output function for all types (function, struct/union, typedef, enum);
1023 # calls the generated, variable output_ function name based on
1024 # functype and output_mode
1025 sub output_declaration {
1026     no strict 'refs';
1027     my $name = shift;
1028     my $functype = shift;
1029     my $func = "output_${functype}_$output_mode";
1030     if (($output_selection == OUTPUT_ALL) ||
1031         (($output_selection == OUTPUT_INCLUDE ||
1032           $output_selection == OUTPUT_EXPORTED) &&
1033          defined($function_table{$name})) ||
1034         (($output_selection == OUTPUT_EXCLUDE ||
1035           $output_selection == OUTPUT_INTERNAL) &&
1036          !($functype eq "function" && defined($function_table{$name}))))
1037     {
1038         &$func(@_);
1039         $section_counter++;
1040     }
1041 }
1042
1043 ##
1044 # generic output function - calls the right one based on current output mode.
1045 sub output_blockhead {
1046     no strict 'refs';
1047     my $func = "output_blockhead_" . $output_mode;
1048     &$func(@_);
1049     $section_counter++;
1050 }
1051
1052 ##
1053 # takes a declaration (struct, union, enum, typedef) and
1054 # invokes the right handler. NOT called for functions.
1055 sub dump_declaration($$) {
1056     no strict 'refs';
1057     my ($prototype, $file) = @_;
1058     my $func = "dump_" . $decl_type;
1059     &$func(@_);
1060 }
1061
1062 sub dump_union($$) {
1063     dump_struct(@_);
1064 }
1065
1066 sub dump_struct($$) {
1067     my $x = shift;
1068     my $file = shift;
1069
1070     if ($x =~ /(struct|union)\s+(\w+)\s*\{(.*)\}(\s*(__packed|__aligned|____cacheline_aligned_in_smp|__attribute__\s*\(\([a-z0-9,_\s\(\)]*\)\)))*/) {
1071         my $decl_type = $1;
1072         $declaration_name = $2;
1073         my $members = $3;
1074
1075         # ignore members marked private:
1076         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1077         $members =~ s/\/\*\s*private:.*//gosi;
1078         # strip comments:
1079         $members =~ s/\/\*.*?\*\///gos;
1080         # strip attributes
1081         $members =~ s/\s*__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)/ /gi;
1082         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1083         $members =~ s/\s*__packed\s*/ /gos;
1084         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1085         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1086         # replace DECLARE_BITMAP
1087         $members =~ s/DECLARE_BITMAP\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1088         # replace DECLARE_HASHTABLE
1089         $members =~ s/DECLARE_HASHTABLE\s*\(([^,)]+),\s*([^,)]+)\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1090         # replace DECLARE_KFIFO
1091         $members =~ s/DECLARE_KFIFO\s*\(([^,)]+),\s*([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1092         # replace DECLARE_KFIFO_PTR
1093         $members =~ s/DECLARE_KFIFO_PTR\s*\(([^,)]+),\s*([^,)]+)\)/$2 \*$1/gos;
1094
1095         my $declaration = $members;
1096
1097         # Split nested struct/union elements as newer ones
1098         while ($members =~ m/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/) {
1099                 my $newmember;
1100                 my $maintype = $1;
1101                 my $ids = $4;
1102                 my $content = $3;
1103                 foreach my $id(split /,/, $ids) {
1104                         $newmember .= "$maintype $id; ";
1105
1106                         $id =~ s/[:\[].*//;
1107                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1108                         foreach my $arg (split /;/, $content) {
1109                                 next if ($arg =~ m/^\s*$/);
1110                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1111                                         # pointer-to-function
1112                                         my $type = $1;
1113                                         my $name = $2;
1114                                         my $extra = $3;
1115                                         next if (!$name);
1116                                         if ($id =~ m/^\s*$/) {
1117                                                 # anonymous struct/union
1118                                                 $newmember .= "$type$name$extra; ";
1119                                         } else {
1120                                                 $newmember .= "$type$id.$name$extra; ";
1121                                         }
1122                                 } else {
1123                                         my $type;
1124                                         my $names;
1125                                         $arg =~ s/^\s+//;
1126                                         $arg =~ s/\s+$//;
1127                                         # Handle bitmaps
1128                                         $arg =~ s/:\s*\d+\s*//g;
1129                                         # Handle arrays
1130                                         $arg =~ s/\[.*\]//g;
1131                                         # The type may have multiple words,
1132                                         # and multiple IDs can be defined, like:
1133                                         #       const struct foo, *bar, foobar
1134                                         # So, we remove spaces when parsing the
1135                                         # names, in order to match just names
1136                                         # and commas for the names
1137                                         $arg =~ s/\s*,\s*/,/g;
1138                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1139                                                 $type = $1;
1140                                                 $names = $2;
1141                                         } else {
1142                                                 $newmember .= "$arg; ";
1143                                                 next;
1144                                         }
1145                                         foreach my $name (split /,/, $names) {
1146                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1147                                                 next if (($name =~ m/^\s*$/));
1148                                                 if ($id =~ m/^\s*$/) {
1149                                                         # anonymous struct/union
1150                                                         $newmember .= "$type $name; ";
1151                                                 } else {
1152                                                         $newmember .= "$type $id.$name; ";
1153                                                 }
1154                                         }
1155                                 }
1156                         }
1157                 }
1158                 $members =~ s/(struct|union)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;/$newmember/;
1159         }
1160
1161         # Ignore other nested elements, like enums
1162         $members =~ s/(\{[^\{\}]*\})//g;
1163
1164         create_parameterlist($members, ';', $file, $declaration_name);
1165         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1166
1167         # Adjust declaration for better display
1168         $declaration =~ s/([\{;])/$1\n/g;
1169         $declaration =~ s/\}\s+;/};/g;
1170         # Better handle inlined enums
1171         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1172
1173         my @def_args = split /\n/, $declaration;
1174         my $level = 1;
1175         $declaration = "";
1176         foreach my $clause (@def_args) {
1177                 $clause =~ s/^\s+//;
1178                 $clause =~ s/\s+$//;
1179                 $clause =~ s/\s+/ /;
1180                 next if (!$clause);
1181                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1182                 if (!($clause =~ m/^\s*#/)) {
1183                         $declaration .= "\t" x $level;
1184                 }
1185                 $declaration .= "\t" . $clause . "\n";
1186                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1187         }
1188         output_declaration($declaration_name,
1189                            'struct',
1190                            {'struct' => $declaration_name,
1191                             'module' => $modulename,
1192                             'definition' => $declaration,
1193                             'parameterlist' => \@parameterlist,
1194                             'parameterdescs' => \%parameterdescs,
1195                             'parametertypes' => \%parametertypes,
1196                             'sectionlist' => \@sectionlist,
1197                             'sections' => \%sections,
1198                             'purpose' => $declaration_purpose,
1199                             'type' => $decl_type
1200                            });
1201     }
1202     else {
1203         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1204         ++$errors;
1205     }
1206 }
1207
1208
1209 sub show_warnings($$) {
1210         my $functype = shift;
1211         my $name = shift;
1212
1213         return 1 if ($output_selection == OUTPUT_ALL);
1214
1215         if ($output_selection == OUTPUT_EXPORTED) {
1216                 if (defined($function_table{$name})) {
1217                         return 1;
1218                 } else {
1219                         return 0;
1220                 }
1221         }
1222         if ($output_selection == OUTPUT_INTERNAL) {
1223                 if (!($functype eq "function" && defined($function_table{$name}))) {
1224                         return 1;
1225                 } else {
1226                         return 0;
1227                 }
1228         }
1229         if ($output_selection == OUTPUT_INCLUDE) {
1230                 if (defined($function_table{$name})) {
1231                         return 1;
1232                 } else {
1233                         return 0;
1234                 }
1235         }
1236         if ($output_selection == OUTPUT_EXCLUDE) {
1237                 if (!defined($function_table{$name})) {
1238                         return 1;
1239                 } else {
1240                         return 0;
1241                 }
1242         }
1243         die("Please add the new output type at show_warnings()");
1244 }
1245
1246 sub dump_enum($$) {
1247     my $x = shift;
1248     my $file = shift;
1249
1250     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1251     # strip #define macros inside enums
1252     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1253
1254     if ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1255         $declaration_name = $1;
1256         my $members = $2;
1257         my %_members;
1258
1259         $members =~ s/\s+$//;
1260
1261         foreach my $arg (split ',', $members) {
1262             $arg =~ s/^\s*(\w+).*/$1/;
1263             push @parameterlist, $arg;
1264             if (!$parameterdescs{$arg}) {
1265                 $parameterdescs{$arg} = $undescribed;
1266                 if (show_warnings("enum", $declaration_name)) {
1267                         print STDERR "${file}:$.: warning: Enum value '$arg' not described in enum '$declaration_name'\n";
1268                 }
1269             }
1270             $_members{$arg} = 1;
1271         }
1272
1273         while (my ($k, $v) = each %parameterdescs) {
1274             if (!exists($_members{$k})) {
1275                 if (show_warnings("enum", $declaration_name)) {
1276                      print STDERR "${file}:$.: warning: Excess enum value '$k' description in '$declaration_name'\n";
1277                 }
1278             }
1279         }
1280
1281         output_declaration($declaration_name,
1282                            'enum',
1283                            {'enum' => $declaration_name,
1284                             'module' => $modulename,
1285                             'parameterlist' => \@parameterlist,
1286                             'parameterdescs' => \%parameterdescs,
1287                             'sectionlist' => \@sectionlist,
1288                             'sections' => \%sections,
1289                             'purpose' => $declaration_purpose
1290                            });
1291     }
1292     else {
1293         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1294         ++$errors;
1295     }
1296 }
1297
1298 sub dump_typedef($$) {
1299     my $x = shift;
1300     my $file = shift;
1301
1302     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1303
1304     # Parse function prototypes
1305     if ($x =~ /typedef\s+(\w+)\s*\(\*\s*(\w\S+)\s*\)\s*\((.*)\);/ ||
1306         $x =~ /typedef\s+(\w+)\s*(\w\S+)\s*\s*\((.*)\);/) {
1307
1308         # Function typedefs
1309         $return_type = $1;
1310         $declaration_name = $2;
1311         my $args = $3;
1312
1313         create_parameterlist($args, ',', $file, $declaration_name);
1314
1315         output_declaration($declaration_name,
1316                            'function',
1317                            {'function' => $declaration_name,
1318                             'typedef' => 1,
1319                             'module' => $modulename,
1320                             'functiontype' => $return_type,
1321                             'parameterlist' => \@parameterlist,
1322                             'parameterdescs' => \%parameterdescs,
1323                             'parametertypes' => \%parametertypes,
1324                             'sectionlist' => \@sectionlist,
1325                             'sections' => \%sections,
1326                             'purpose' => $declaration_purpose
1327                            });
1328         return;
1329     }
1330
1331     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1332         $x =~ s/\(*.\)\s*;$/;/;
1333         $x =~ s/\[*.\]\s*;$/;/;
1334     }
1335
1336     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1337         $declaration_name = $1;
1338
1339         output_declaration($declaration_name,
1340                            'typedef',
1341                            {'typedef' => $declaration_name,
1342                             'module' => $modulename,
1343                             'sectionlist' => \@sectionlist,
1344                             'sections' => \%sections,
1345                             'purpose' => $declaration_purpose
1346                            });
1347     }
1348     else {
1349         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1350         ++$errors;
1351     }
1352 }
1353
1354 sub save_struct_actual($) {
1355     my $actual = shift;
1356
1357     # strip all spaces from the actual param so that it looks like one string item
1358     $actual =~ s/\s*//g;
1359     $struct_actual = $struct_actual . $actual . " ";
1360 }
1361
1362 sub create_parameterlist($$$$) {
1363     my $args = shift;
1364     my $splitter = shift;
1365     my $file = shift;
1366     my $declaration_name = shift;
1367     my $type;
1368     my $param;
1369
1370     # temporarily replace commas inside function pointer definition
1371     while ($args =~ /(\([^\),]+),/) {
1372         $args =~ s/(\([^\),]+),/$1#/g;
1373     }
1374
1375     foreach my $arg (split($splitter, $args)) {
1376         # strip comments
1377         $arg =~ s/\/\*.*\*\///;
1378         # strip leading/trailing spaces
1379         $arg =~ s/^\s*//;
1380         $arg =~ s/\s*$//;
1381         $arg =~ s/\s+/ /;
1382
1383         if ($arg =~ /^#/) {
1384             # Treat preprocessor directive as a typeless variable just to fill
1385             # corresponding data structures "correctly". Catch it later in
1386             # output_* subs.
1387             push_parameter($arg, "", $file);
1388         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1389             # pointer-to-function
1390             $arg =~ tr/#/,/;
1391             $arg =~ m/[^\(]+\(\*?\s*([\w\.]*)\s*\)/;
1392             $param = $1;
1393             $type = $arg;
1394             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1395             save_struct_actual($param);
1396             push_parameter($param, $type, $file, $declaration_name);
1397         } elsif ($arg) {
1398             $arg =~ s/\s*:\s*/:/g;
1399             $arg =~ s/\s*\[/\[/g;
1400
1401             my @args = split('\s*,\s*', $arg);
1402             if ($args[0] =~ m/\*/) {
1403                 $args[0] =~ s/(\*+)\s*/ $1/;
1404             }
1405
1406             my @first_arg;
1407             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1408                     shift @args;
1409                     push(@first_arg, split('\s+', $1));
1410                     push(@first_arg, $2);
1411             } else {
1412                     @first_arg = split('\s+', shift @args);
1413             }
1414
1415             unshift(@args, pop @first_arg);
1416             $type = join " ", @first_arg;
1417
1418             foreach $param (@args) {
1419                 if ($param =~ m/^(\*+)\s*(.*)/) {
1420                     save_struct_actual($2);
1421                     push_parameter($2, "$type $1", $file, $declaration_name);
1422                 }
1423                 elsif ($param =~ m/(.*?):(\d+)/) {
1424                     if ($type ne "") { # skip unnamed bit-fields
1425                         save_struct_actual($1);
1426                         push_parameter($1, "$type:$2", $file, $declaration_name)
1427                     }
1428                 }
1429                 else {
1430                     save_struct_actual($param);
1431                     push_parameter($param, $type, $file, $declaration_name);
1432                 }
1433             }
1434         }
1435     }
1436 }
1437
1438 sub push_parameter($$$$) {
1439         my $param = shift;
1440         my $type = shift;
1441         my $file = shift;
1442         my $declaration_name = shift;
1443
1444         if (($anon_struct_union == 1) && ($type eq "") &&
1445             ($param eq "}")) {
1446                 return;         # ignore the ending }; from anon. struct/union
1447         }
1448
1449         $anon_struct_union = 0;
1450         $param =~ s/[\[\)].*//;
1451
1452         if ($type eq "" && $param =~ /\.\.\.$/)
1453         {
1454             if (!$param =~ /\w\.\.\.$/) {
1455               # handles unnamed variable parameters
1456               $param = "...";
1457             }
1458             elsif ($param =~ /\w\.\.\.$/) {
1459               # for named variable parameters of the form `x...`, remove the dots
1460               $param =~ s/\.\.\.$//;
1461             }
1462             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1463                 $parameterdescs{$param} = "variable arguments";
1464             }
1465         }
1466         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1467         {
1468             $param="void";
1469             $parameterdescs{void} = "no arguments";
1470         }
1471         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1472         # handle unnamed (anonymous) union or struct:
1473         {
1474                 $type = $param;
1475                 $param = "{unnamed_" . $param . "}";
1476                 $parameterdescs{$param} = "anonymous\n";
1477                 $anon_struct_union = 1;
1478         }
1479
1480         # warn if parameter has no description
1481         # (but ignore ones starting with # as these are not parameters
1482         # but inline preprocessor statements);
1483         # Note: It will also ignore void params and unnamed structs/unions
1484         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1485                 $parameterdescs{$param} = $undescribed;
1486
1487                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1488                         print STDERR
1489                               "${file}:$.: warning: Function parameter or member '$param' not described in '$declaration_name'\n";
1490                         ++$warnings;
1491                 }
1492         }
1493
1494         # strip spaces from $param so that it is one continuous string
1495         # on @parameterlist;
1496         # this fixes a problem where check_sections() cannot find
1497         # a parameter like "addr[6 + 2]" because it actually appears
1498         # as "addr[6", "+", "2]" on the parameter list;
1499         # but it's better to maintain the param string unchanged for output,
1500         # so just weaken the string compare in check_sections() to ignore
1501         # "[blah" in a parameter string;
1502         ###$param =~ s/\s*//g;
1503         push @parameterlist, $param;
1504         $type =~ s/\s\s+/ /g;
1505         $parametertypes{$param} = $type;
1506 }
1507
1508 sub check_sections($$$$$) {
1509         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1510         my @sects = split ' ', $sectcheck;
1511         my @prms = split ' ', $prmscheck;
1512         my $err;
1513         my ($px, $sx);
1514         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1515
1516         foreach $sx (0 .. $#sects) {
1517                 $err = 1;
1518                 foreach $px (0 .. $#prms) {
1519                         $prm_clean = $prms[$px];
1520                         $prm_clean =~ s/\[.*\]//;
1521                         $prm_clean =~ s/__attribute__\s*\(\([a-z,_\*\s\(\)]*\)\)//i;
1522                         # ignore array size in a parameter string;
1523                         # however, the original param string may contain
1524                         # spaces, e.g.:  addr[6 + 2]
1525                         # and this appears in @prms as "addr[6" since the
1526                         # parameter list is split at spaces;
1527                         # hence just ignore "[..." for the sections check;
1528                         $prm_clean =~ s/\[.*//;
1529
1530                         ##$prm_clean =~ s/^\**//;
1531                         if ($prm_clean eq $sects[$sx]) {
1532                                 $err = 0;
1533                                 last;
1534                         }
1535                 }
1536                 if ($err) {
1537                         if ($decl_type eq "function") {
1538                                 print STDERR "${file}:$.: warning: " .
1539                                         "Excess function parameter " .
1540                                         "'$sects[$sx]' " .
1541                                         "description in '$decl_name'\n";
1542                                 ++$warnings;
1543                         }
1544                 }
1545         }
1546 }
1547
1548 ##
1549 # Checks the section describing the return value of a function.
1550 sub check_return_section {
1551         my $file = shift;
1552         my $declaration_name = shift;
1553         my $return_type = shift;
1554
1555         # Ignore an empty return type (It's a macro)
1556         # Ignore functions with a "void" return type. (But don't ignore "void *")
1557         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1558                 return;
1559         }
1560
1561         if (!defined($sections{$section_return}) ||
1562             $sections{$section_return} eq "") {
1563                 print STDERR "${file}:$.: warning: " .
1564                         "No description found for return value of " .
1565                         "'$declaration_name'\n";
1566                 ++$warnings;
1567         }
1568 }
1569
1570 ##
1571 # takes a function prototype and the name of the current file being
1572 # processed and spits out all the details stored in the global
1573 # arrays/hashes.
1574 sub dump_function($$) {
1575     my $prototype = shift;
1576     my $file = shift;
1577     my $noret = 0;
1578
1579     $prototype =~ s/^static +//;
1580     $prototype =~ s/^extern +//;
1581     $prototype =~ s/^asmlinkage +//;
1582     $prototype =~ s/^inline +//;
1583     $prototype =~ s/^__inline__ +//;
1584     $prototype =~ s/^__inline +//;
1585     $prototype =~ s/^__always_inline +//;
1586     $prototype =~ s/^noinline +//;
1587     $prototype =~ s/__init +//;
1588     $prototype =~ s/__init_or_module +//;
1589     $prototype =~ s/__meminit +//;
1590     $prototype =~ s/__must_check +//;
1591     $prototype =~ s/__weak +//;
1592     $prototype =~ s/__sched +//;
1593     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1594     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1595     $prototype =~ s/__attribute__\s*\(\(
1596             (?:
1597                  [\w\s]++          # attribute name
1598                  (?:\([^)]*+\))?   # attribute arguments
1599                  \s*+,?            # optional comma at the end
1600             )+
1601           \)\)\s+//x;
1602
1603     # Yes, this truly is vile.  We are looking for:
1604     # 1. Return type (may be nothing if we're looking at a macro)
1605     # 2. Function name
1606     # 3. Function parameters.
1607     #
1608     # All the while we have to watch out for function pointer parameters
1609     # (which IIRC is what the two sections are for), C types (these
1610     # regexps don't even start to express all the possibilities), and
1611     # so on.
1612     #
1613     # If you mess with these regexps, it's a good idea to check that
1614     # the following functions' documentation still comes out right:
1615     # - parport_register_device (function pointer parameters)
1616     # - atomic_set (macro)
1617     # - pci_match_device, __copy_to_user (long return type)
1618
1619     if ($define && $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s+/) {
1620         # This is an object-like macro, it has no return type and no parameter
1621         # list.
1622         # Function-like macros are not allowed to have spaces between
1623         # declaration_name and opening parenthesis (notice the \s+).
1624         $return_type = $1;
1625         $declaration_name = $2;
1626         $noret = 1;
1627     } elsif ($prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1628         $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1629         $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1630         $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1631         $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1632         $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1633         $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\(]*)\)/ ||
1634         $prototype =~ m/^()([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1635         $prototype =~ m/^(\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1636         $prototype =~ m/^(\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1637         $prototype =~ m/^(\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1638         $prototype =~ m/^(\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1639         $prototype =~ m/^(\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1640         $prototype =~ m/^(\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1641         $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+)\s+([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1642         $prototype =~ m/^(\w+\s+\w+\s+\w+\s+\w+\s*\*+)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/ ||
1643         $prototype =~ m/^(\w+\s+\w+\s*\*+\s*\w+\s*\*+\s*)\s*([a-zA-Z0-9_~:]+)\s*\(([^\{]*)\)/)  {
1644         $return_type = $1;
1645         $declaration_name = $2;
1646         my $args = $3;
1647
1648         create_parameterlist($args, ',', $file, $declaration_name);
1649     } else {
1650         print STDERR "${file}:$.: warning: cannot understand function prototype: '$prototype'\n";
1651         return;
1652     }
1653
1654         my $prms = join " ", @parameterlist;
1655         check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1656
1657         # This check emits a lot of warnings at the moment, because many
1658         # functions don't have a 'Return' doc section. So until the number
1659         # of warnings goes sufficiently down, the check is only performed in
1660         # verbose mode.
1661         # TODO: always perform the check.
1662         if ($verbose && !$noret) {
1663                 check_return_section($file, $declaration_name, $return_type);
1664         }
1665
1666     output_declaration($declaration_name,
1667                        'function',
1668                        {'function' => $declaration_name,
1669                         'module' => $modulename,
1670                         'functiontype' => $return_type,
1671                         'parameterlist' => \@parameterlist,
1672                         'parameterdescs' => \%parameterdescs,
1673                         'parametertypes' => \%parametertypes,
1674                         'sectionlist' => \@sectionlist,
1675                         'sections' => \%sections,
1676                         'purpose' => $declaration_purpose
1677                        });
1678 }
1679
1680 sub reset_state {
1681     $function = "";
1682     %parameterdescs = ();
1683     %parametertypes = ();
1684     @parameterlist = ();
1685     %sections = ();
1686     @sectionlist = ();
1687     $sectcheck = "";
1688     $struct_actual = "";
1689     $prototype = "";
1690
1691     $state = STATE_NORMAL;
1692     $inline_doc_state = STATE_INLINE_NA;
1693 }
1694
1695 sub tracepoint_munge($) {
1696         my $file = shift;
1697         my $tracepointname = 0;
1698         my $tracepointargs = 0;
1699
1700         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1701                 $tracepointname = $1;
1702         }
1703         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1704                 $tracepointname = $1;
1705         }
1706         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1707                 $tracepointname = $2;
1708         }
1709         $tracepointname =~ s/^\s+//; #strip leading whitespace
1710         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1711                 $tracepointargs = $1;
1712         }
1713         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1714                 print STDERR "${file}:$.: warning: Unrecognized tracepoint format: \n".
1715                              "$prototype\n";
1716         } else {
1717                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1718         }
1719 }
1720
1721 sub syscall_munge() {
1722         my $void = 0;
1723
1724         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1725 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1726         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1727                 $void = 1;
1728 ##              $prototype = "long sys_$1(void)";
1729         }
1730
1731         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1732         if ($prototype =~ m/long (sys_.*?),/) {
1733                 $prototype =~ s/,/\(/;
1734         } elsif ($void) {
1735                 $prototype =~ s/\)/\(void\)/;
1736         }
1737
1738         # now delete all of the odd-number commas in $prototype
1739         # so that arg types & arg names don't have a comma between them
1740         my $count = 0;
1741         my $len = length($prototype);
1742         if ($void) {
1743                 $len = 0;       # skip the for-loop
1744         }
1745         for (my $ix = 0; $ix < $len; $ix++) {
1746                 if (substr($prototype, $ix, 1) eq ',') {
1747                         $count++;
1748                         if ($count % 2 == 1) {
1749                                 substr($prototype, $ix, 1) = ' ';
1750                         }
1751                 }
1752         }
1753 }
1754
1755 sub process_proto_function($$) {
1756     my $x = shift;
1757     my $file = shift;
1758
1759     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1760
1761     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1762         # do nothing
1763     }
1764     elsif ($x =~ /([^\{]*)/) {
1765         $prototype .= $1;
1766     }
1767
1768     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1769         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1770         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1771         $prototype =~ s@^\s+@@gos; # strip leading spaces
1772         if ($prototype =~ /SYSCALL_DEFINE/) {
1773                 syscall_munge();
1774         }
1775         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1776             $prototype =~ /DEFINE_SINGLE_EVENT/)
1777         {
1778                 tracepoint_munge($file);
1779         }
1780         dump_function($prototype, $file);
1781         reset_state();
1782     }
1783 }
1784
1785 sub process_proto_type($$) {
1786     my $x = shift;
1787     my $file = shift;
1788
1789     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1790     $x =~ s@^\s+@@gos; # strip leading spaces
1791     $x =~ s@\s+$@@gos; # strip trailing spaces
1792     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1793
1794     if ($x =~ /^#/) {
1795         # To distinguish preprocessor directive from regular declaration later.
1796         $x .= ";";
1797     }
1798
1799     while (1) {
1800         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1801             if( length $prototype ) {
1802                 $prototype .= " "
1803             }
1804             $prototype .= $1 . $2;
1805             ($2 eq '{') && $brcount++;
1806             ($2 eq '}') && $brcount--;
1807             if (($2 eq ';') && ($brcount == 0)) {
1808                 dump_declaration($prototype, $file);
1809                 reset_state();
1810                 last;
1811             }
1812             $x = $3;
1813         } else {
1814             $prototype .= $x;
1815             last;
1816         }
1817     }
1818 }
1819
1820
1821 sub map_filename($) {
1822     my $file;
1823     my ($orig_file) = @_;
1824
1825     if (defined($ENV{'SRCTREE'})) {
1826         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1827     } else {
1828         $file = $orig_file;
1829     }
1830
1831     if (defined($source_map{$file})) {
1832         $file = $source_map{$file};
1833     }
1834
1835     return $file;
1836 }
1837
1838 sub process_export_file($) {
1839     my ($orig_file) = @_;
1840     my $file = map_filename($orig_file);
1841
1842     if (!open(IN,"<$file")) {
1843         print STDERR "Error: Cannot open file $file\n";
1844         ++$errors;
1845         return;
1846     }
1847
1848     while (<IN>) {
1849         if (/$export_symbol/) {
1850             $function_table{$2} = 1;
1851         }
1852     }
1853
1854     close(IN);
1855 }
1856
1857 #
1858 # Parsers for the various processing states.
1859 #
1860 # STATE_NORMAL: looking for the /** to begin everything.
1861 #
1862 sub process_normal() {
1863     if (/$doc_start/o) {
1864         $state = STATE_NAME;    # next line is always the function name
1865         $in_doc_sect = 0;
1866         $declaration_start_line = $. + 1;
1867     }
1868 }
1869
1870 #
1871 # STATE_NAME: Looking for the "name - description" line
1872 #
1873 sub process_name($$) {
1874     my $file = shift;
1875     my $identifier;
1876     my $descr;
1877
1878     if (/$doc_block/o) {
1879         $state = STATE_DOCBLOCK;
1880         $contents = "";
1881         $new_start_line = $. + 1;
1882
1883         if ( $1 eq "" ) {
1884             $section = $section_intro;
1885         } else {
1886             $section = $1;
1887         }
1888     }
1889     elsif (/$doc_decl/o) {
1890         $identifier = $1;
1891         if (/\s*([\w\s]+?)(\(\))?\s*-/) {
1892             $identifier = $1;
1893         }
1894
1895         $state = STATE_BODY;
1896         # if there's no @param blocks need to set up default section
1897         # here
1898         $contents = "";
1899         $section = $section_default;
1900         $new_start_line = $. + 1;
1901         if (/-(.*)/) {
1902             # strip leading/trailing/multiple spaces
1903             $descr= $1;
1904             $descr =~ s/^\s*//;
1905             $descr =~ s/\s*$//;
1906             $descr =~ s/\s+/ /g;
1907             $declaration_purpose = $descr;
1908             $state = STATE_BODY_MAYBE;
1909         } else {
1910             $declaration_purpose = "";
1911         }
1912
1913         if (($declaration_purpose eq "") && $verbose) {
1914             print STDERR "${file}:$.: warning: missing initial short description on line:\n";
1915             print STDERR $_;
1916             ++$warnings;
1917         }
1918
1919         if ($identifier =~ m/^struct\b/) {
1920             $decl_type = 'struct';
1921         } elsif ($identifier =~ m/^union\b/) {
1922             $decl_type = 'union';
1923         } elsif ($identifier =~ m/^enum\b/) {
1924             $decl_type = 'enum';
1925         } elsif ($identifier =~ m/^typedef\b/) {
1926             $decl_type = 'typedef';
1927         } else {
1928             $decl_type = 'function';
1929         }
1930
1931         if ($verbose) {
1932             print STDERR "${file}:$.: info: Scanning doc for $identifier\n";
1933         }
1934     } else {
1935         print STDERR "${file}:$.: warning: Cannot understand $_ on line $.",
1936             " - I thought it was a doc line\n";
1937         ++$warnings;
1938         $state = STATE_NORMAL;
1939     }
1940 }
1941
1942
1943 #
1944 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
1945 #
1946 sub process_body($$) {
1947     my $file = shift;
1948
1949     # Until all named variable macro parameters are
1950     # documented using the bare name (`x`) rather than with
1951     # dots (`x...`), strip the dots:
1952     if ($section =~ /\w\.\.\.$/) {
1953         $section =~ s/\.\.\.$//;
1954
1955         if ($verbose) {
1956             print STDERR "${file}:$.: warning: Variable macro arguments should be documented without dots\n";
1957             ++$warnings;
1958         }
1959     }
1960
1961     if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
1962         dump_section($file, $section, $contents);
1963         $section = $section_default;
1964         $contents = "";
1965     }
1966
1967     if (/$doc_sect/i) { # case insensitive for supported section names
1968         $newsection = $1;
1969         $newcontents = $2;
1970
1971         # map the supported section names to the canonical names
1972         if ($newsection =~ m/^description$/i) {
1973             $newsection = $section_default;
1974         } elsif ($newsection =~ m/^context$/i) {
1975             $newsection = $section_context;
1976         } elsif ($newsection =~ m/^returns?$/i) {
1977             $newsection = $section_return;
1978         } elsif ($newsection =~ m/^\@return$/) {
1979             # special: @return is a section, not a param description
1980             $newsection = $section_return;
1981         }
1982
1983         if (($contents ne "") && ($contents ne "\n")) {
1984             if (!$in_doc_sect && $verbose) {
1985                 print STDERR "${file}:$.: warning: contents before sections\n";
1986                 ++$warnings;
1987             }
1988             dump_section($file, $section, $contents);
1989             $section = $section_default;
1990         }
1991
1992         $in_doc_sect = 1;
1993         $state = STATE_BODY;
1994         $contents = $newcontents;
1995         $new_start_line = $.;
1996         while (substr($contents, 0, 1) eq " ") {
1997             $contents = substr($contents, 1);
1998         }
1999         if ($contents ne "") {
2000             $contents .= "\n";
2001         }
2002         $section = $newsection;
2003         $leading_space = undef;
2004     } elsif (/$doc_end/) {
2005         if (($contents ne "") && ($contents ne "\n")) {
2006             dump_section($file, $section, $contents);
2007             $section = $section_default;
2008             $contents = "";
2009         }
2010         # look for doc_com + <text> + doc_end:
2011         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2012             print STDERR "${file}:$.: warning: suspicious ending line: $_";
2013             ++$warnings;
2014         }
2015
2016         $prototype = "";
2017         $state = STATE_PROTO;
2018         $brcount = 0;
2019     } elsif (/$doc_content/) {
2020         if ($1 eq "") {
2021             if ($section eq $section_context) {
2022                 dump_section($file, $section, $contents);
2023                 $section = $section_default;
2024                 $contents = "";
2025                 $new_start_line = $.;
2026                 $state = STATE_BODY;
2027             } else {
2028                 if ($section ne $section_default) {
2029                     $state = STATE_BODY_WITH_BLANK_LINE;
2030                 } else {
2031                     $state = STATE_BODY;
2032                 }
2033                 $contents .= "\n";
2034             }
2035         } elsif ($state == STATE_BODY_MAYBE) {
2036             # Continued declaration purpose
2037             chomp($declaration_purpose);
2038             $declaration_purpose .= " " . $1;
2039             $declaration_purpose =~ s/\s+/ /g;
2040         } else {
2041             my $cont = $1;
2042             if ($section =~ m/^@/ || $section eq $section_context) {
2043                 if (!defined $leading_space) {
2044                     if ($cont =~ m/^(\s+)/) {
2045                         $leading_space = $1;
2046                     } else {
2047                         $leading_space = "";
2048                     }
2049                 }
2050                 $cont =~ s/^$leading_space//;
2051             }
2052             $contents .= $cont . "\n";
2053         }
2054     } else {
2055         # i dont know - bad line?  ignore.
2056         print STDERR "${file}:$.: warning: bad line: $_";
2057         ++$warnings;
2058     }
2059 }
2060
2061
2062 #
2063 # STATE_PROTO: reading a function/whatever prototype.
2064 #
2065 sub process_proto($$) {
2066     my $file = shift;
2067
2068     if (/$doc_inline_oneline/) {
2069         $section = $1;
2070         $contents = $2;
2071         if ($contents ne "") {
2072             $contents .= "\n";
2073             dump_section($file, $section, $contents);
2074             $section = $section_default;
2075             $contents = "";
2076         }
2077     } elsif (/$doc_inline_start/) {
2078         $state = STATE_INLINE;
2079         $inline_doc_state = STATE_INLINE_NAME;
2080     } elsif ($decl_type eq 'function') {
2081         process_proto_function($_, $file);
2082     } else {
2083         process_proto_type($_, $file);
2084     }
2085 }
2086
2087 #
2088 # STATE_DOCBLOCK: within a DOC: block.
2089 #
2090 sub process_docblock($$) {
2091     my $file = shift;
2092
2093     if (/$doc_end/) {
2094         dump_doc_section($file, $section, $contents);
2095         $section = $section_default;
2096         $contents = "";
2097         $function = "";
2098         %parameterdescs = ();
2099         %parametertypes = ();
2100         @parameterlist = ();
2101         %sections = ();
2102         @sectionlist = ();
2103         $prototype = "";
2104         $state = STATE_NORMAL;
2105     } elsif (/$doc_content/) {
2106         if ( $1 eq "" ) {
2107             $contents .= $blankline;
2108         } else {
2109             $contents .= $1 . "\n";
2110         }
2111     }
2112 }
2113
2114 #
2115 # STATE_INLINE: docbook comments within a prototype.
2116 #
2117 sub process_inline($$) {
2118     my $file = shift;
2119
2120     # First line (state 1) needs to be a @parameter
2121     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2122         $section = $1;
2123         $contents = $2;
2124         $new_start_line = $.;
2125         if ($contents ne "") {
2126             while (substr($contents, 0, 1) eq " ") {
2127                 $contents = substr($contents, 1);
2128             }
2129             $contents .= "\n";
2130         }
2131         $inline_doc_state = STATE_INLINE_TEXT;
2132         # Documentation block end */
2133     } elsif (/$doc_inline_end/) {
2134         if (($contents ne "") && ($contents ne "\n")) {
2135             dump_section($file, $section, $contents);
2136             $section = $section_default;
2137             $contents = "";
2138         }
2139         $state = STATE_PROTO;
2140         $inline_doc_state = STATE_INLINE_NA;
2141         # Regular text
2142     } elsif (/$doc_content/) {
2143         if ($inline_doc_state == STATE_INLINE_TEXT) {
2144             $contents .= $1 . "\n";
2145             # nuke leading blank lines
2146             if ($contents =~ /^\s*$/) {
2147                 $contents = "";
2148             }
2149         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2150             $inline_doc_state = STATE_INLINE_ERROR;
2151             print STDERR "${file}:$.: warning: ";
2152             print STDERR "Incorrect use of kernel-doc format: $_";
2153             ++$warnings;
2154         }
2155     }
2156 }
2157
2158
2159 sub process_file($) {
2160     my $file;
2161     my $initial_section_counter = $section_counter;
2162     my ($orig_file) = @_;
2163
2164     $file = map_filename($orig_file);
2165
2166     if (!open(IN,"<$file")) {
2167         print STDERR "Error: Cannot open file $file\n";
2168         ++$errors;
2169         return;
2170     }
2171
2172     $. = 1;
2173
2174     $section_counter = 0;
2175     while (<IN>) {
2176         while (s/\\\s*$//) {
2177             $_ .= <IN>;
2178         }
2179         # Replace tabs by spaces
2180         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2181         # Hand this line to the appropriate state handler
2182         if ($state == STATE_NORMAL) {
2183             process_normal();
2184         } elsif ($state == STATE_NAME) {
2185             process_name($file, $_);
2186         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2187                  $state == STATE_BODY_WITH_BLANK_LINE) {
2188             process_body($file, $_);
2189         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2190             process_inline($file, $_);
2191         } elsif ($state == STATE_PROTO) {
2192             process_proto($file, $_);
2193         } elsif ($state == STATE_DOCBLOCK) {
2194             process_docblock($file, $_);
2195         }
2196     }
2197
2198     # Make sure we got something interesting.
2199     if ($initial_section_counter == $section_counter && $
2200         output_mode ne "none") {
2201         if ($output_selection == OUTPUT_INCLUDE) {
2202             print STDERR "${file}:1: warning: '$_' not found\n"
2203                 for keys %function_table;
2204         }
2205         else {
2206             print STDERR "${file}:1: warning: no structured comments found\n";
2207         }
2208     }
2209 }
2210
2211
2212 $kernelversion = get_kernel_version();
2213
2214 # generate a sequence of code that will splice in highlighting information
2215 # using the s// operator.
2216 for (my $k = 0; $k < @highlights; $k++) {
2217     my $pattern = $highlights[$k][0];
2218     my $result = $highlights[$k][1];
2219 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2220     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2221 }
2222
2223 # Read the file that maps relative names to absolute names for
2224 # separate source and object directories and for shadow trees.
2225 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2226         my ($relname, $absname);
2227         while(<SOURCE_MAP>) {
2228                 chop();
2229                 ($relname, $absname) = (split())[0..1];
2230                 $relname =~ s:^/+::;
2231                 $source_map{$relname} = $absname;
2232         }
2233         close(SOURCE_MAP);
2234 }
2235
2236 if ($output_selection == OUTPUT_EXPORTED ||
2237     $output_selection == OUTPUT_INTERNAL) {
2238
2239     push(@export_file_list, @ARGV);
2240
2241     foreach (@export_file_list) {
2242         chomp;
2243         process_export_file($_);
2244     }
2245 }
2246
2247 foreach (@ARGV) {
2248     chomp;
2249     process_file($_);
2250 }
2251 if ($verbose && $errors) {
2252   print STDERR "$errors errors\n";
2253 }
2254 if ($verbose && $warnings) {
2255   print STDERR "$warnings warnings\n";
2256 }
2257
2258 exit($output_mode eq "none" ? 0 : $errors);