scripts/module.lds.S

   1 /*
   2  * Common module linker script, always used when linking a module.
   3  * Archs are free to supply their own linker scripts.  ld will
   4  * combine them automatically.
   5  */
   6 SECTIONS {
   7         /DISCARD/ : {
   8                 *(.discard)
   9                 *(.discard.*)
  10         }
  11
  12         __ksymtab               0 : { *(SORT(___ksymtab+*)) }
  13         __ksymtab_gpl           0 : { *(SORT(___ksymtab_gpl+*)) }
  14         __kcrctab               0 : { *(SORT(___kcrctab+*)) }
  15         __kcrctab_gpl           0 : { *(SORT(___kcrctab_gpl+*)) }
  16
  17         .init_array             0 : ALIGN(8) { *(SORT(.init_array.*)) *(.init_array) }
  18
  19         __jump_table            0 : ALIGN(8) { KEEP(*(__jump_table)) }
  20
  21         __patchable_function_entries : { *(__patchable_function_entries) }
  22
  23         /*
  24          * With CONFIG_LTO_CLANG, LLD always enables -fdata-sections and
  25          * -ffunction-sections, which increases the size of the final module.
  26          * Merge the split sections in the final binary.
  27          */
  28         .bss : {
  29                 *(.bss .bss.[0-9a-zA-Z_]*)
  30                 *(.bss..L*)
  31         }
  32
  33         .data : {
  34                 *(.data .data.[0-9a-zA-Z_]*)
  35                 *(.data..L*)
  36         }
  37
  38         .rodata : {
  39                 *(.rodata .rodata.[0-9a-zA-Z_]*)
  40                 *(.rodata..L*)
  41         }
  42
  43         .text : { *(.text .text.[0-9a-zA-Z_]*) }
  44 }
  45
  46 /* bring in arch-specific sections */
  47 #include <asm/module.lds.h>