scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".kprobes.text" => 1,
 138      ".text.unlikely" => 1,
 139 );
 140
 141 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 142 $objdump = 'objdump' if (!$objdump);
 143 $objcopy = 'objcopy' if (!$objcopy);
 144 $cc = 'gcc' if (!$cc);
 145 $ld = 'ld' if (!$ld);
 146 $nm = 'nm' if (!$nm);
 147 $rm = 'rm' if (!$rm);
 148 $mv = 'mv' if (!$mv);
 149
 150 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 151 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 152
 153 my %locals;             # List of local (static) functions
 154 my %weak;               # List of weak functions
 155 my %convert;            # List of local functions used that needs conversion
 156
 157 my $type;
 158 my $local_regex;        # Match a local function (return function)
 159 my $weak_regex;         # Match a weak function (return function)
 160 my $section_regex;      # Find the start of a section
 161 my $function_regex;     # Find the name of a function
 162                         #    (return offset and func name)
 163 my $mcount_regex;       # Find the call site to mcount (return offset)
 164 my $mcount_adjust;      # Address adjustment to mcount offset
 165 my $alignment;          # The .align value to use for $mcount_section
 166 my $section_type;       # Section header plus possible alignment command
 167 my $can_use_local = 0;  # If we can use local function references
 168
 169 # Shut up recordmcount if user has older objcopy
 170 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 171 my $print_warning = 1;
 172 $print_warning = 0 if ( -f $quiet_recordmcount);
 173
 174 ##
 175 # check_objcopy - whether objcopy supports --globalize-symbols
 176 #
 177 #  --globalize-symbols came out in 2.17, we must test the version
 178 #  of objcopy, and if it is less than 2.17, then we can not
 179 #  record local functions.
 180 sub check_objcopy
 181 {
 182     open (IN, "$objcopy --version |") or die "error running $objcopy";
 183     while (<IN>) {
 184         if (/objcopy.*\s(\d+)\.(\d+)/) {
 185             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 186             last;
 187         }
 188     }
 189     close (IN);
 190
 191     if (!$can_use_local && $print_warning) {
 192         print STDERR "WARNING: could not find objcopy version or version " .
 193             "is less than 2.17.\n" .
 194             "\tLocal function references are disabled.\n";
 195         open (QUIET, ">$quiet_recordmcount");
 196         printf QUIET "Disables the warning from recordmcount.pl\n";
 197         close QUIET;
 198     }
 199 }
 200
 201 if ($arch =~ /(x86(_64)?)|(i386)/) {
 202     if ($bits == 64) {
 203         $arch = "x86_64";
 204     } else {
 205         $arch = "i386";
 206     }
 207 }
 208
 209 #
 210 # We base the defaults off of i386, the other archs may
 211 # feel free to change them in the below if statements.
 212 #
 213 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 214 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 215 $section_regex = "Disassembly of section\\s+(\\S+):";
 216 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 217 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 218 $section_type = '@progbits';
 219 $mcount_adjust = 0;
 220 $type = ".long";
 221
 222 if ($arch eq "x86_64") {
 223     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 224     $type = ".quad";
 225     $alignment = 8;
 226     $mcount_adjust = -1;
 227
 228     # force flags for this arch
 229     $ld .= " -m elf_x86_64";
 230     $objdump .= " -M x86-64";
 231     $objcopy .= " -O elf64-x86-64";
 232     $cc .= " -m64";
 233
 234 } elsif ($arch eq "i386") {
 235     $alignment = 4;
 236     $mcount_adjust = -1;
 237
 238     # force flags for this arch
 239     $ld .= " -m elf_i386";
 240     $objdump .= " -M i386";
 241     $objcopy .= " -O elf32-i386";
 242     $cc .= " -m32";
 243
 244 } elsif ($arch eq "s390" && $bits == 64) {
 245     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 246     $mcount_adjust = -8;
 247     $alignment = 8;
 248     $type = ".quad";
 249     $ld .= " -m elf64_s390";
 250     $cc .= " -m64";
 251
 252 } elsif ($arch eq "sh") {
 253     $alignment = 2;
 254
 255     # force flags for this arch
 256     $ld .= " -m shlelf_linux";
 257     $objcopy .= " -O elf32-sh-linux";
 258     $cc .= " -m32";
 259
 260 } elsif ($arch eq "powerpc") {
 261     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 262     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 263     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 264
 265     if ($bits == 64) {
 266         $type = ".quad";
 267     }
 268
 269 } elsif ($arch eq "arm") {
 270     $alignment = 2;
 271     $section_type = '%progbits';
 272     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 273                         "\\s+(__gnu_mcount_nc|mcount)\$";
 274
 275 } elsif ($arch eq "arm64") {
 276     $alignment = 3;
 277     $section_type = '%progbits';
 278     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 279     $type = ".quad";
 280 } elsif ($arch eq "ia64") {
 281     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 282     $type = "data8";
 283
 284     if ($is_module eq "0") {
 285         $cc .= " -mconstant-gp";
 286     }
 287 } elsif ($arch eq "sparc64") {
 288     # In the objdump output there are giblets like:
 289     # 0000000000000000 <igmp_net_exit-0x18>:
 290     # As there's some data blobs that get emitted into the
 291     # text section before the first instructions and the first
 292     # real symbols.  We don't want to match that, so to combat
 293     # this we use '\w' so we'll match just plain symbol names,
 294     # and not those that also include hex offsets inside of the
 295     # '<>' brackets.  Actually the generic function_regex setting
 296     # could safely use this too.
 297     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 298
 299     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 300     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 301
 302     $alignment = 8;
 303     $type = ".xword";
 304     $ld .= " -m elf64_sparc";
 305     $cc .= " -m64";
 306     $objcopy .= " -O elf64-sparc";
 307 } elsif ($arch eq "mips") {
 308     # To enable module support, we need to enable the -mlong-calls option
 309     # of gcc for module, after using this option, we can not get the real
 310     # offset of the calling to _mcount, but the offset of the lui
 311     # instruction or the addiu one. herein, we record the address of the
 312     # first one, and then we can replace this instruction by a branch
 313     # instruction to jump over the profiling function to filter the
 314     # indicated functions, or swith back to the lui instruction to trace
 315     # them, which means dynamic tracing.
 316     #
 317     #       c:  3c030000        lui     v1,0x0
 318     #                   c: R_MIPS_HI16  _mcount
 319     #                   c: R_MIPS_NONE  *ABS*
 320     #                   c: R_MIPS_NONE  *ABS*
 321     #      10:  64630000        daddiu  v1,v1,0
 322     #                   10: R_MIPS_LO16 _mcount
 323     #                   10: R_MIPS_NONE *ABS*
 324     #                   10: R_MIPS_NONE *ABS*
 325     #      14:  03e0082d        move    at,ra
 326     #      18:  0060f809        jalr    v1
 327     #
 328     # for the kernel:
 329     #
 330     #     10:   03e0082d        move    at,ra
 331     #     14:   0c000000        jal     0 <loongson_halt>
 332     #                    14: R_MIPS_26   _mcount
 333     #                    14: R_MIPS_NONE *ABS*
 334     #                    14: R_MIPS_NONE *ABS*
 335     #    18:   00020021        nop
 336     if ($is_module eq "0") {
 337             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 338     } else {
 339             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 340     }
 341     $objdump .= " -Melf-trad".$endian."mips ";
 342
 343     if ($endian eq "big") {
 344             $endian = " -EB ";
 345             $ld .= " -melf".$bits."btsmip";
 346     } else {
 347             $endian = " -EL ";
 348             $ld .= " -melf".$bits."ltsmip";
 349     }
 350
 351     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 352     $ld .= $endian;
 353
 354     if ($bits == 64) {
 355             $function_regex =
 356                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 357             $type = ".dword";
 358     }
 359 } elsif ($arch eq "microblaze") {
 360     # Microblaze calls '_mcount' instead of plain 'mcount'.
 361     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 362 } elsif ($arch eq "blackfin") {
 363     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 364     $mcount_adjust = -4;
 365 } elsif ($arch eq "tilegx" || $arch eq "tile") {
 366     # Default to the newer TILE-Gx architecture if only "tile" is given.
 367     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 368     $type = ".quad";
 369     $alignment = 8;
 370 } else {
 371     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 372 }
 373
 374 my $text_found = 0;
 375 my $read_function = 0;
 376 my $opened = 0;
 377 my $mcount_section = "__mcount_loc";
 378
 379 my $dirname;
 380 my $filename;
 381 my $prefix;
 382 my $ext;
 383
 384 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 385     $dirname = $1;
 386     $filename = $2;
 387 } else {
 388     $dirname = ".";
 389     $filename = $inputfile;
 390 }
 391
 392 if ($filename =~ m,^(.*)(\.\S),) {
 393     $prefix = $1;
 394     $ext = $2;
 395 } else {
 396     $prefix = $filename;
 397     $ext = "";
 398 }
 399
 400 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 401 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 402
 403 check_objcopy();
 404
 405 #
 406 # Step 1: find all the local (static functions) and weak symbols.
 407 #         't' is local, 'w/W' is weak
 408 #
 409 open (IN, "$nm $inputfile|") || die "error running $nm";
 410 while (<IN>) {
 411     if (/$local_regex/) {
 412         $locals{$1} = 1;
 413     } elsif (/$weak_regex/) {
 414         $weak{$2} = $1;
 415     }
 416 }
 417 close(IN);
 418
 419 my @offsets;            # Array of offsets of mcount callers
 420 my $ref_func;           # reference function to use for offsets
 421 my $offset = 0;         # offset of ref_func to section beginning
 422
 423 ##
 424 # update_funcs - print out the current mcount callers
 425 #
 426 #  Go through the list of offsets to callers and write them to
 427 #  the output file in a format that can be read by an assembler.
 428 #
 429 sub update_funcs
 430 {
 431     return unless ($ref_func and @offsets);
 432
 433     # Sanity check on weak function. A weak function may be overwritten by
 434     # another function of the same name, making all these offsets incorrect.
 435     if (defined $weak{$ref_func}) {
 436         die "$inputfile: ERROR: referencing weak function" .
 437             " $ref_func for mcount\n";
 438     }
 439
 440     # is this function static? If so, note this fact.
 441     if (defined $locals{$ref_func}) {
 442
 443         # only use locals if objcopy supports globalize-symbols
 444         if (!$can_use_local) {
 445             return;
 446         }
 447         $convert{$ref_func} = 1;
 448     }
 449
 450     # Loop through all the mcount caller offsets and print a reference
 451     # to the caller based from the ref_func.
 452     if (!$opened) {
 453         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 454         $opened = 1;
 455         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 456         print FILE "\t.align $alignment\n" if (defined($alignment));
 457     }
 458     foreach my $cur_offset (@offsets) {
 459         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 460     }
 461 }
 462
 463 #
 464 # Step 2: find the sections and mcount call sites
 465 #
 466 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 467
 468 my $text;
 469
 470
 471 # read headers first
 472 my $read_headers = 1;
 473
 474 while (<IN>) {
 475
 476     if ($read_headers && /$mcount_section/) {
 477         #
 478         # Somehow the make process can execute this script on an
 479         # object twice. If it does, we would duplicate the mcount
 480         # section and it will cause the function tracer self test
 481         # to fail. Check if the mcount section exists, and if it does,
 482         # warn and exit.
 483         #
 484         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 485             "\tThis may be an indication that your build is corrupted.\n" .
 486             "\tDelete $inputfile and try again. If the same object file\n" .
 487             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 488         exit(-1);
 489     }
 490
 491     # is it a section?
 492     if (/$section_regex/) {
 493         $read_headers = 0;
 494
 495         # Only record text sections that we know are safe
 496         $read_function = defined($text_sections{$1});
 497         # print out any recorded offsets
 498         update_funcs();
 499
 500         # reset all markers and arrays
 501         $text_found = 0;
 502         undef($ref_func);
 503         undef(@offsets);
 504
 505     # section found, now is this a start of a function?
 506     } elsif ($read_function && /$function_regex/) {
 507         $text_found = 1;
 508         $text = $2;
 509
 510         # if this is either a local function or a weak function
 511         # keep looking for functions that are global that
 512         # we can use safely.
 513         if (!defined($locals{$text}) && !defined($weak{$text})) {
 514             $ref_func = $text;
 515             $read_function = 0;
 516             $offset = hex $1;
 517         } else {
 518             # if we already have a function, and this is weak, skip it
 519             if (!defined($ref_func) && !defined($weak{$text}) &&
 520                  # PPC64 can have symbols that start with .L and
 521                  # gcc considers these special. Don't use them!
 522                  $text !~ /^\.L/) {
 523                 $ref_func = $text;
 524                 $offset = hex $1;
 525             }
 526         }
 527     }
 528     # is this a call site to mcount? If so, record it to print later
 529     if ($text_found && /$mcount_regex/) {
 530         push(@offsets, (hex $1) + $mcount_adjust);
 531     }
 532 }
 533
 534 # dump out anymore offsets that may have been found
 535 update_funcs();
 536
 537 # If we did not find any mcount callers, we are done (do nothing).
 538 if (!$opened) {
 539     exit(0);
 540 }
 541
 542 close(FILE);
 543
 544 #
 545 # Step 3: Compile the file that holds the list of call sites to mcount.
 546 #
 547 `$cc -o $mcount_o -c $mcount_s`;
 548
 549 my @converts = keys %convert;
 550
 551 #
 552 # Step 4: Do we have sections that started with local functions?
 553 #
 554 if ($#converts >= 0) {
 555     my $globallist = "";
 556     my $locallist = "";
 557
 558     foreach my $con (@converts) {
 559         $globallist .= " --globalize-symbol $con";
 560         $locallist .= " --localize-symbol $con";
 561     }
 562
 563     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 564     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 565
 566     #
 567     # Step 5: set up each local function as a global
 568     #
 569     `$objcopy $globallist $inputfile $globalobj`;
 570
 571     #
 572     # Step 6: Link the global version to our list.
 573     #
 574     `$ld -r $globalobj $mcount_o -o $globalmix`;
 575
 576     #
 577     # Step 7: Convert the local functions back into local symbols
 578     #
 579     `$objcopy $locallist $globalmix $inputfile`;
 580
 581     # Remove the temp files
 582     `$rm $globalobj $globalmix`;
 583
 584 } else {
 585
 586     my $mix = $dirname . "/.tmp_mx_" . $filename;
 587
 588     #
 589     # Step 8: Link the object with our list of call sites object.
 590     #
 591     `$ld -r $inputfile $mcount_o -o $mix`;
 592
 593     #
 594     # Step 9: Move the result back to the original object.
 595     #
 596     `$mv $mix $inputfile`;
 597 }
 598
 599 # Clean up the temp files
 600 `$rm $mcount_o $mcount_s`;
 601
 602 exit(0);