scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 11) {
 117         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".ref.text" => 1,
 134      ".sched.text" => 1,
 135      ".spinlock.text" => 1,
 136      ".irqentry.text" => 1,
 137      ".softirqentry.text" => 1,
 138      ".kprobes.text" => 1,
 139      ".cpuidle.text" => 1,
 140      ".text.unlikely" => 1,
 141 );
 142
 143 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 144 $objdump = 'objdump' if (!$objdump);
 145 $objcopy = 'objcopy' if (!$objcopy);
 146 $cc = 'gcc' if (!$cc);
 147 $ld = 'ld' if (!$ld);
 148 $nm = 'nm' if (!$nm);
 149 $rm = 'rm' if (!$rm);
 150 $mv = 'mv' if (!$mv);
 151
 152 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 153 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 154
 155 my %locals;             # List of local (static) functions
 156 my %weak;               # List of weak functions
 157 my %convert;            # List of local functions used that needs conversion
 158
 159 my $type;
 160 my $local_regex;        # Match a local function (return function)
 161 my $weak_regex;         # Match a weak function (return function)
 162 my $section_regex;      # Find the start of a section
 163 my $function_regex;     # Find the name of a function
 164                         #    (return offset and func name)
 165 my $mcount_regex;       # Find the call site to mcount (return offset)
 166 my $mcount_adjust;      # Address adjustment to mcount offset
 167 my $alignment;          # The .align value to use for $mcount_section
 168 my $section_type;       # Section header plus possible alignment command
 169 my $can_use_local = 0;  # If we can use local function references
 170
 171 # Shut up recordmcount if user has older objcopy
 172 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 173 my $print_warning = 1;
 174 $print_warning = 0 if ( -f $quiet_recordmcount);
 175
 176 ##
 177 # check_objcopy - whether objcopy supports --globalize-symbols
 178 #
 179 #  --globalize-symbols came out in 2.17, we must test the version
 180 #  of objcopy, and if it is less than 2.17, then we can not
 181 #  record local functions.
 182 sub check_objcopy
 183 {
 184     open (IN, "$objcopy --version |") or die "error running $objcopy";
 185     while (<IN>) {
 186         if (/objcopy.*\s(\d+)\.(\d+)/) {
 187             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 188             last;
 189         }
 190     }
 191     close (IN);
 192
 193     if (!$can_use_local && $print_warning) {
 194         print STDERR "WARNING: could not find objcopy version or version " .
 195             "is less than 2.17.\n" .
 196             "\tLocal function references are disabled.\n";
 197         open (QUIET, ">$quiet_recordmcount");
 198         printf QUIET "Disables the warning from recordmcount.pl\n";
 199         close QUIET;
 200     }
 201 }
 202
 203 if ($arch =~ /(x86(_64)?)|(i386)/) {
 204     if ($bits == 64) {
 205         $arch = "x86_64";
 206     } else {
 207         $arch = "i386";
 208     }
 209 }
 210
 211 #
 212 # We base the defaults off of i386, the other archs may
 213 # feel free to change them in the below if statements.
 214 #
 215 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 216 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 217 $section_regex = "Disassembly of section\\s+(\\S+):";
 218 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 219 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 220 $section_type = '@progbits';
 221 $mcount_adjust = 0;
 222 $type = ".long";
 223
 224 if ($arch eq "x86_64") {
 225     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 226     $type = ".quad";
 227     $alignment = 8;
 228     $mcount_adjust = -1;
 229
 230     # force flags for this arch
 231     $ld .= " -m elf_x86_64";
 232     $objdump .= " -M x86-64";
 233     $objcopy .= " -O elf64-x86-64";
 234     $cc .= " -m64";
 235
 236 } elsif ($arch eq "i386") {
 237     $alignment = 4;
 238     $mcount_adjust = -1;
 239
 240     # force flags for this arch
 241     $ld .= " -m elf_i386";
 242     $objdump .= " -M i386";
 243     $objcopy .= " -O elf32-i386";
 244     $cc .= " -m32";
 245
 246 } elsif ($arch eq "s390" && $bits == 64) {
 247     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 248         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 249         $mcount_adjust = 0;
 250     } else {
 251         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 252         $mcount_adjust = -14;
 253     }
 254     $alignment = 8;
 255     $type = ".quad";
 256     $ld .= " -m elf64_s390";
 257     $cc .= " -m64";
 258
 259 } elsif ($arch eq "sh") {
 260     $alignment = 2;
 261
 262     # force flags for this arch
 263     $ld .= " -m shlelf_linux";
 264     $objcopy .= " -O elf32-sh-linux";
 265
 266 } elsif ($arch eq "powerpc") {
 267     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 268     # See comment in the sparc64 section for why we use '\w'.
 269     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 270     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 271
 272     if ($bits == 64) {
 273         $type = ".quad";
 274     }
 275
 276 } elsif ($arch eq "arm") {
 277     $alignment = 2;
 278     $section_type = '%progbits';
 279     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 280                         "\\s+(__gnu_mcount_nc|mcount)\$";
 281
 282 } elsif ($arch eq "arm64") {
 283     $alignment = 3;
 284     $section_type = '%progbits';
 285     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 286     $type = ".quad";
 287 } elsif ($arch eq "ia64") {
 288     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 289     $type = "data8";
 290
 291     if ($is_module eq "0") {
 292         $cc .= " -mconstant-gp";
 293     }
 294 } elsif ($arch eq "sparc64") {
 295     # In the objdump output there are giblets like:
 296     # 0000000000000000 <igmp_net_exit-0x18>:
 297     # As there's some data blobs that get emitted into the
 298     # text section before the first instructions and the first
 299     # real symbols.  We don't want to match that, so to combat
 300     # this we use '\w' so we'll match just plain symbol names,
 301     # and not those that also include hex offsets inside of the
 302     # '<>' brackets.  Actually the generic function_regex setting
 303     # could safely use this too.
 304     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 305
 306     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 307     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 308
 309     $alignment = 8;
 310     $type = ".xword";
 311     $ld .= " -m elf64_sparc";
 312     $cc .= " -m64";
 313     $objcopy .= " -O elf64-sparc";
 314 } elsif ($arch eq "mips") {
 315     # To enable module support, we need to enable the -mlong-calls option
 316     # of gcc for module, after using this option, we can not get the real
 317     # offset of the calling to _mcount, but the offset of the lui
 318     # instruction or the addiu one. herein, we record the address of the
 319     # first one, and then we can replace this instruction by a branch
 320     # instruction to jump over the profiling function to filter the
 321     # indicated functions, or swith back to the lui instruction to trace
 322     # them, which means dynamic tracing.
 323     #
 324     #       c:  3c030000        lui     v1,0x0
 325     #                   c: R_MIPS_HI16  _mcount
 326     #                   c: R_MIPS_NONE  *ABS*
 327     #                   c: R_MIPS_NONE  *ABS*
 328     #      10:  64630000        daddiu  v1,v1,0
 329     #                   10: R_MIPS_LO16 _mcount
 330     #                   10: R_MIPS_NONE *ABS*
 331     #                   10: R_MIPS_NONE *ABS*
 332     #      14:  03e0082d        move    at,ra
 333     #      18:  0060f809        jalr    v1
 334     #
 335     # for the kernel:
 336     #
 337     #     10:   03e0082d        move    at,ra
 338     #     14:   0c000000        jal     0 <loongson_halt>
 339     #                    14: R_MIPS_26   _mcount
 340     #                    14: R_MIPS_NONE *ABS*
 341     #                    14: R_MIPS_NONE *ABS*
 342     #    18:   00020021        nop
 343     if ($is_module eq "0") {
 344             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 345     } else {
 346             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 347     }
 348     $objdump .= " -Melf-trad".$endian."mips ";
 349
 350     if ($endian eq "big") {
 351             $endian = " -EB ";
 352             $ld .= " -melf".$bits."btsmip";
 353     } else {
 354             $endian = " -EL ";
 355             $ld .= " -melf".$bits."ltsmip";
 356     }
 357
 358     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 359     $ld .= $endian;
 360
 361     if ($bits == 64) {
 362             $function_regex =
 363                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 364             $type = ".dword";
 365     }
 366 } elsif ($arch eq "microblaze") {
 367     # Microblaze calls '_mcount' instead of plain 'mcount'.
 368     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 369 } elsif ($arch eq "blackfin") {
 370     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 371     $mcount_adjust = -4;
 372 } elsif ($arch eq "tilegx" || $arch eq "tile") {
 373     # Default to the newer TILE-Gx architecture if only "tile" is given.
 374     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$";
 375     $type = ".quad";
 376     $alignment = 8;
 377 } else {
 378     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 379 }
 380
 381 my $text_found = 0;
 382 my $read_function = 0;
 383 my $opened = 0;
 384 my $mcount_section = "__mcount_loc";
 385
 386 my $dirname;
 387 my $filename;
 388 my $prefix;
 389 my $ext;
 390
 391 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 392     $dirname = $1;
 393     $filename = $2;
 394 } else {
 395     $dirname = ".";
 396     $filename = $inputfile;
 397 }
 398
 399 if ($filename =~ m,^(.*)(\.\S),) {
 400     $prefix = $1;
 401     $ext = $2;
 402 } else {
 403     $prefix = $filename;
 404     $ext = "";
 405 }
 406
 407 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 408 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 409
 410 check_objcopy();
 411
 412 #
 413 # Step 1: find all the local (static functions) and weak symbols.
 414 #         't' is local, 'w/W' is weak
 415 #
 416 open (IN, "$nm $inputfile|") || die "error running $nm";
 417 while (<IN>) {
 418     if (/$local_regex/) {
 419         $locals{$1} = 1;
 420     } elsif (/$weak_regex/) {
 421         $weak{$2} = $1;
 422     }
 423 }
 424 close(IN);
 425
 426 my @offsets;            # Array of offsets of mcount callers
 427 my $ref_func;           # reference function to use for offsets
 428 my $offset = 0;         # offset of ref_func to section beginning
 429
 430 ##
 431 # update_funcs - print out the current mcount callers
 432 #
 433 #  Go through the list of offsets to callers and write them to
 434 #  the output file in a format that can be read by an assembler.
 435 #
 436 sub update_funcs
 437 {
 438     return unless ($ref_func and @offsets);
 439
 440     # Sanity check on weak function. A weak function may be overwritten by
 441     # another function of the same name, making all these offsets incorrect.
 442     if (defined $weak{$ref_func}) {
 443         die "$inputfile: ERROR: referencing weak function" .
 444             " $ref_func for mcount\n";
 445     }
 446
 447     # is this function static? If so, note this fact.
 448     if (defined $locals{$ref_func}) {
 449
 450         # only use locals if objcopy supports globalize-symbols
 451         if (!$can_use_local) {
 452             return;
 453         }
 454         $convert{$ref_func} = 1;
 455     }
 456
 457     # Loop through all the mcount caller offsets and print a reference
 458     # to the caller based from the ref_func.
 459     if (!$opened) {
 460         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 461         $opened = 1;
 462         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 463         print FILE "\t.align $alignment\n" if (defined($alignment));
 464     }
 465     foreach my $cur_offset (@offsets) {
 466         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 467     }
 468 }
 469
 470 #
 471 # Step 2: find the sections and mcount call sites
 472 #
 473 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 474
 475 my $text;
 476
 477
 478 # read headers first
 479 my $read_headers = 1;
 480
 481 while (<IN>) {
 482
 483     if ($read_headers && /$mcount_section/) {
 484         #
 485         # Somehow the make process can execute this script on an
 486         # object twice. If it does, we would duplicate the mcount
 487         # section and it will cause the function tracer self test
 488         # to fail. Check if the mcount section exists, and if it does,
 489         # warn and exit.
 490         #
 491         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 492             "\tThis may be an indication that your build is corrupted.\n" .
 493             "\tDelete $inputfile and try again. If the same object file\n" .
 494             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 495         exit(-1);
 496     }
 497
 498     # is it a section?
 499     if (/$section_regex/) {
 500         $read_headers = 0;
 501
 502         # Only record text sections that we know are safe
 503         $read_function = defined($text_sections{$1});
 504         # print out any recorded offsets
 505         update_funcs();
 506
 507         # reset all markers and arrays
 508         $text_found = 0;
 509         undef($ref_func);
 510         undef(@offsets);
 511
 512     # section found, now is this a start of a function?
 513     } elsif ($read_function && /$function_regex/) {
 514         $text_found = 1;
 515         $text = $2;
 516
 517         # if this is either a local function or a weak function
 518         # keep looking for functions that are global that
 519         # we can use safely.
 520         if (!defined($locals{$text}) && !defined($weak{$text})) {
 521             $ref_func = $text;
 522             $read_function = 0;
 523             $offset = hex $1;
 524         } else {
 525             # if we already have a function, and this is weak, skip it
 526             if (!defined($ref_func) && !defined($weak{$text}) &&
 527                  # PPC64 can have symbols that start with .L and
 528                  # gcc considers these special. Don't use them!
 529                  $text !~ /^\.L/) {
 530                 $ref_func = $text;
 531                 $offset = hex $1;
 532             }
 533         }
 534     }
 535     # is this a call site to mcount? If so, record it to print later
 536     if ($text_found && /$mcount_regex/) {
 537         push(@offsets, (hex $1) + $mcount_adjust);
 538     }
 539 }
 540
 541 # dump out anymore offsets that may have been found
 542 update_funcs();
 543
 544 # If we did not find any mcount callers, we are done (do nothing).
 545 if (!$opened) {
 546     exit(0);
 547 }
 548
 549 close(FILE);
 550
 551 #
 552 # Step 3: Compile the file that holds the list of call sites to mcount.
 553 #
 554 `$cc -o $mcount_o -c $mcount_s`;
 555
 556 my @converts = keys %convert;
 557
 558 #
 559 # Step 4: Do we have sections that started with local functions?
 560 #
 561 if ($#converts >= 0) {
 562     my $globallist = "";
 563     my $locallist = "";
 564
 565     foreach my $con (@converts) {
 566         $globallist .= " --globalize-symbol $con";
 567         $locallist .= " --localize-symbol $con";
 568     }
 569
 570     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 571     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 572
 573     #
 574     # Step 5: set up each local function as a global
 575     #
 576     `$objcopy $globallist $inputfile $globalobj`;
 577
 578     #
 579     # Step 6: Link the global version to our list.
 580     #
 581     `$ld -r $globalobj $mcount_o -o $globalmix`;
 582
 583     #
 584     # Step 7: Convert the local functions back into local symbols
 585     #
 586     `$objcopy $locallist $globalmix $inputfile`;
 587
 588     # Remove the temp files
 589     `$rm $globalobj $globalmix`;
 590
 591 } else {
 592
 593     my $mix = $dirname . "/.tmp_mx_" . $filename;
 594
 595     #
 596     # Step 8: Link the object with our list of call sites object.
 597     #
 598     `$ld -r $inputfile $mcount_o -o $mix`;
 599
 600     #
 601     # Step 9: Move the result back to the original object.
 602     #
 603     `$mv $mix $inputfile`;
 604 }
 605
 606 # Clean up the temp files
 607 `$rm $mcount_o $mcount_s`;
 608
 609 exit(0);