src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14
  15 use PMG::Utils;
  16 use PMG::Config;
  17 use PMG::ClusterConfig;
  18 use PMG::RuleDB;
  19 use PMG::RuleCache;
  20 use PMG::MailQueue;
  21 use PMG::Fetchmail;
  22
  23 sub remote_node_ip {
  24     my ($nodename, $noerr) = @_;
  25
  26     my $cinfo = PMG::ClusterConfig->new();
  27
  28     foreach my $entry (values %{$cinfo->{ids}}) {
  29         if ($entry->{name} eq $nodename) {
  30             my $ip = $entry->{ip};
  31             return $ip if !wantarray;
  32             my $family = PVE::Tools::get_host_address_family($ip);
  33             return ($ip, $family);
  34         }
  35     }
  36
  37     # fallback: try to get IP by other means
  38     return PMG::Utils::lookup_node_ip($nodename, $noerr);
  39 }
  40
  41 sub get_master_node {
  42     my ($cinfo) = @_;
  43
  44     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  45
  46     return $cinfo->{master}->{name} if defined($cinfo->{master});
  47
  48     return 'localhost';
  49 }
  50
  51 sub read_local_ssl_cert_fingerprint {
  52     my $cert_path = "/etc/pmg/pmg-api.pem";
  53
  54     my $cert;
  55     eval {
  56         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  57         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  58         Net::SSLeay::BIO_free($bio);
  59     };
  60     if (my $err = $@) {
  61         die "unable to read certificate '$cert_path' - $err\n";
  62     }
  63
  64     if (!defined($cert)) {
  65         die "unable to read certificate '$cert_path' - got empty value\n";
  66     }
  67
  68     my $fp;
  69     eval {
  70         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  71     };
  72     if (my $err = $@) {
  73         die "unable to get fingerprint for '$cert_path' - $err\n";
  74     }
  75
  76     if (!defined($fp) || $fp eq '') {
  77         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  78     }
  79
  80     return $fp;
  81 }
  82
  83 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  84 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  85 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  86
  87 sub read_local_cluster_info {
  88
  89     my $res = {};
  90
  91     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  92     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  93     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
  94
  95     die "unable to parse ${hostrsapubkey_fn}\n"
  96         if $hostrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
  97
  98     my $nodename = PVE::INotify::nodename();
  99
 100     $res->{name} = $nodename;
 101
 102     $res->{ip} = PMG::Utils::lookup_node_ip($nodename);
 103
 104     $res->{hostrsapubkey} = $hostrsapubkey;
 105
 106     if (! -f $rootrsapubkey_fn) {
 107         unlink $rootrsakey_fn;
 108         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 109                    '-f', $rootrsakey_fn];
 110         PMG::Utils::run_silent_cmd($cmd);
 111     }
 112
 113     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 114     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 115     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 116
 117     die "unable to parse ${rootrsapubkey_fn}\n"
 118         if $rootrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
 119
 120     $res->{rootrsapubkey} = $rootrsapubkey;
 121
 122     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 123
 124     return $res;
 125 }
 126
 127 # X509 Certificate cache helper
 128
 129 my $cert_cache_nodes = {};
 130 my $cert_cache_timestamp = time();
 131 my $cert_cache_fingerprints = {};
 132
 133 sub update_cert_cache {
 134
 135     $cert_cache_timestamp = time();
 136
 137     $cert_cache_fingerprints = {};
 138     $cert_cache_nodes = {};
 139
 140     my $cinfo = PMG::ClusterConfig->new();
 141
 142     foreach my $entry (values %{$cinfo->{ids}}) {
 143         my $node = $entry->{name};
 144         my $fp = $entry->{fingerprint};
 145         if ($node && $fp) {
 146             $cert_cache_fingerprints->{$fp} = 1;
 147             $cert_cache_nodes->{$node} = $fp;
 148         }
 149     }
 150 }
 151
 152 # load and cache cert fingerprint once
 153 sub initialize_cert_cache {
 154     my ($node) = @_;
 155
 156     update_cert_cache()
 157         if defined($node) && !defined($cert_cache_nodes->{$node});
 158 }
 159
 160 sub check_cert_fingerprint {
 161     my ($cert) = @_;
 162
 163     # clear cache every 30 minutes at least
 164     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 165
 166     # get fingerprint of server certificate
 167     my $fp;
 168     eval {
 169         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 170     };
 171     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 172
 173     my $check = sub {
 174         for my $expected (keys %$cert_cache_fingerprints) {
 175             return 1 if $fp eq $expected;
 176         }
 177         return 0;
 178     };
 179
 180     return 1 if $check->();
 181
 182     # clear cache and retry at most once every minute
 183     if (time() - $cert_cache_timestamp >= 60) {
 184         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 185         update_cert_cache();
 186         return $check->();
 187     }
 188
 189     return 0;
 190 }
 191
 192 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 193 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 194 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 195
 196 sub update_ssh_keys {
 197     my ($cinfo) = @_;
 198
 199     my $old = '';
 200     my $data = '';
 201
 202     foreach my $node (values %{$cinfo->{ids}}) {
 203         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 204         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 205     }
 206
 207     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 208         if -f $sshglobalknownhosts;
 209
 210     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 211         if $old ne $data;
 212
 213     $data = '';
 214     $old = '';
 215
 216     # always add ourself
 217     if (-f $ssh_rsa_id) {
 218         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 219         chomp($pub);
 220         $data .= "$pub\n";
 221     }
 222
 223     foreach my $node (values %{$cinfo->{ids}}) {
 224         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 225     }
 226
 227     if (-f $rootsshauthkeys) {
 228         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 229         chomp($mykey);
 230         $data .= "$mykey\n";
 231     }
 232
 233     my $newdata = "";
 234     my $vhash = {};
 235     my @lines = split(/\n/, $data);
 236     foreach my $line (@lines) {
 237         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 238             next if $vhash->{$3}++;
 239         }
 240         $newdata .= "$line\n";
 241     }
 242
 243     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 244         if -f $rootsshauthkeys;
 245
 246     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 247         if $old ne $newdata;
 248 }
 249
 250 my $cfgdir = '/etc/pmg';
 251 my $syncdir = "$cfgdir/master";
 252
 253 my $cond_commit_synced_file = sub {
 254     my ($filename, $dstfn) = @_;
 255
 256     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 257     my $srcfn = "$syncdir/$filename";
 258
 259     if (! -f $srcfn) {
 260         unlink $dstfn;
 261         return;
 262     }
 263
 264     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 265
 266     if (-f $dstfn) {
 267         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 268         return 0 if $new eq $old;
 269     }
 270
 271     # set mtime (touch) to avoid time drift problems
 272     utime(undef, undef, $srcfn);
 273
 274     rename($srcfn, $dstfn) ||
 275         die "cond_rename_file '$filename' failed - $!\n";
 276
 277     print STDERR "updated $dstfn\n";
 278
 279     return 1;
 280 };
 281
 282 my $rsync_command = sub {
 283     my ($host_key_alias, @args) = @_;
 284
 285     my $ssh_cmd = '--rsh=ssh -l root -o BatchMode=yes';
 286     $ssh_cmd .=  " -o HostKeyAlias=${host_key_alias}" if $host_key_alias;
 287
 288     my $cmd = ['rsync', $ssh_cmd,  '-q', @args];
 289
 290     return $cmd;
 291 };
 292
 293 sub sync_quarantine_files {
 294     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 295
 296     my $spooldir = $PMG::MailQueue::spooldir;
 297
 298     mkdir "$spooldir/cluster/";
 299     my $syncdir = "$spooldir/cluster/$rcid";
 300     mkdir $syncdir;
 301
 302     my $cmd = $rsync_command->(
 303         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 304         '--files-from', $flistname);
 305
 306     PVE::Tools::run_command($cmd);
 307 }
 308
 309 sub sync_spooldir {
 310     my ($host_ip, $host_name, $rcid) = @_;
 311
 312     my $spooldir = $PMG::MailQueue::spooldir;
 313
 314     mkdir "$spooldir/cluster/";
 315     my $syncdir = "$spooldir/cluster/$rcid";
 316     mkdir $syncdir;
 317
 318     my $cmd = $rsync_command->(
 319         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 320
 321     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 322         push @$cmd, '--include', $incl;
 323     }
 324
 325     push @$cmd, '--exclude', '*';
 326
 327     PVE::Tools::run_command($cmd);
 328 }
 329
 330 sub sync_master_quar {
 331     my ($host_ip, $host_name) = @_;
 332
 333     my $spooldir = $PMG::MailQueue::spooldir;
 334
 335     my $syncdir = "$spooldir/cluster/";
 336     mkdir $syncdir;
 337
 338     my $cmd = $rsync_command->(
 339         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 340
 341     PVE::Tools::run_command($cmd);
 342 }
 343
 344 sub sync_config_from_master {
 345     my ($master_name, $master_ip, $noreload) = @_;
 346
 347     mkdir $syncdir;
 348     File::Path::remove_tree($syncdir, {keep_root => 1});
 349
 350     my $sa_conf_dir = "/etc/mail/spamassassin";
 351     my $sa_custom_cf = "custom.cf";
 352     my $sa_rules_cf = "pmg-scores.cf";
 353
 354     my $cmd = $rsync_command->(
 355         $master_name, '-aq',
 356         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf} ${sa_conf_dir}/${sa_rules_cf}",
 357         "$syncdir/",
 358         '--exclude', 'master/',
 359         '--exclude', '*~',
 360         '--exclude', '*.db',
 361         '--exclude', 'pmg-api.pem',
 362         '--exclude', 'pmg-tls.pem',
 363         );
 364
 365     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 366     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 367
 368     # verify that the remote host is cluster master
 369     open (my $fh, '<', "$syncdir/cluster.conf") ||
 370         die "unable to open synced cluster.conf - $!\n";
 371
 372     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 373
 374     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 375         die "host '$master_ip' is not cluster master\n";
 376     }
 377
 378     my $role = $cinfo->{'local'}->{type} // '-';
 379     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 380         if $role eq '-';
 381
 382     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 383         if $role eq 'master';
 384
 385     $cond_commit_synced_file->('cluster.conf');
 386
 387     update_ssh_keys($cinfo); # rewrite ssh keys
 388
 389     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 390
 391     my $files = [
 392         'pmg-authkey.key',
 393         'pmg-authkey.pub',
 394         'pmg-csrf.key',
 395         'ldap.conf',
 396         'user.conf',
 397         'domains',
 398         'mynetworks',
 399         'transport',
 400         'tls_policy',
 401         'fetchmailrc',
 402         ];
 403
 404     foreach my $filename (@$files) {
 405         $cond_commit_synced_file->($filename);
 406     }
 407
 408     my $dirs = [
 409         'templates',
 410         'dkim',
 411     ];
 412
 413     foreach my $dir (@$dirs) {
 414         my $srcdir = "$syncdir/$dir";
 415
 416         if ( -d $srcdir ) {
 417             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 418             PVE::Tools::run_command($cmd);
 419         }
 420
 421     }
 422
 423     my $force_restart = {};
 424
 425     for my $file (($sa_custom_cf, $sa_rules_cf)) {
 426         if ($cond_commit_synced_file->($file, "${sa_conf_dir}/${file}")) {
 427             $force_restart->{'pmg-smtp-filter'} = 1;
 428         }
 429     }
 430
 431     $cond_commit_synced_file->('pmg.conf');
 432
 433     return $force_restart;
 434 }
 435
 436 sub sync_ruledb_from_master {
 437     my ($ldb, $rdb, $ni, $ticket) = @_;
 438
 439     my $ruledb = PMG::RuleDB->new($ldb);
 440     my $rulecache = PMG::RuleCache->new($ruledb);
 441
 442     my $conn = PVE::APIClient::LWP->new(
 443         ticket => $ticket,
 444         cookie_name => 'PMGAuthCookie',
 445         host => $ni->{ip},
 446         cached_fingerprints => {
 447             $ni->{fingerprint} => 1,
 448         });
 449
 450     my $digest = $conn->get("/config/ruledb/digest", {});
 451
 452     return if $digest eq $rulecache->{digest}; # no changes
 453
 454     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 455
 456     eval {
 457         $ldb->begin_work;
 458
 459         $ldb->do("DELETE FROM Rule");
 460         $ldb->do("DELETE FROM RuleGroup");
 461         $ldb->do("DELETE FROM ObjectGroup");
 462         $ldb->do("DELETE FROM Object");
 463         $ldb->do("DELETE FROM Attribut");
 464
 465         eval {
 466             $rdb->begin_work;
 467
 468             # read a consistent snapshot
 469             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 470
 471             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 472             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 473             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 474             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 475             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 476         };
 477
 478         $rdb->rollback; # end transaction
 479
 480         die $@ if $@;
 481
 482         # update sequences
 483
 484         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 485         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 486         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 487
 488         $ldb->commit;
 489     };
 490     if (my $err = $@) {
 491         $ldb->rollback;
 492         die $err;
 493     }
 494
 495     PMG::DBTools::reload_ruledb();
 496
 497     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 498 }
 499
 500 sub sync_quarantine_db {
 501     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 502
 503     my $rcid = $ni->{cid};
 504
 505     my $maxmails = 100000;
 506
 507     my $mscount = 0;
 508
 509     my $ctime = PMG::DBTools::get_remote_time($rdb);
 510
 511     my $maxcount = 1000;
 512
 513     my $count;
 514
 515     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 516
 517     do { # get new values
 518
 519         $count = 0;
 520
 521         my $flistname = "/tmp/quarantinefilelist.$$";
 522
 523         eval {
 524             $ldb->begin_work;
 525
 526             open(my $flistfh, '>', $flistname) ||
 527                 die "unable to open file '$flistname' - $!\n";
 528
 529             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 530
 531             # sync CMailStore
 532
 533             my $sth = $rdb->prepare(
 534                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 535                 "ORDER BY cid,rid LIMIT ?");
 536             $sth->execute($rcid, $lastid, $maxcount);
 537
 538             my $maxid;
 539             my $callback = sub {
 540                 my $ref = shift;
 541                 $maxid = $ref->{rid};
 542                 my $filename = $ref->{file};
 543                  # skip files generated before cluster was created
 544                 return if $filename !~ m!^cluster/!;
 545                 print $flistfh "$filename\n";
 546             };
 547
 548             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 549             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 550
 551             close($flistfh);
 552
 553             my $starttime = [ gettimeofday() ];
 554             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 555             $$rsynctime_ref += tv_interval($starttime);
 556
 557             if ($maxid) {
 558                 # sync CMSReceivers
 559
 560                 $sth = $rdb->prepare(
 561                     "SELECT * from CMSReceivers WHERE " .
 562                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 563                     "AND CMailStore_RID <= ?");
 564                 $sth->execute($rcid, $lastid, $maxid);
 565
 566                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 567                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 568
 569                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 570             }
 571
 572             $ldb->commit;
 573         };
 574         my $err = $@;
 575
 576         unlink $flistname;
 577
 578         if ($err) {
 579             $ldb->rollback;
 580             die $err;
 581         }
 582
 583         $mscount += $count;
 584
 585     } while (($count >= $maxcount) && ($mscount < $maxmails));
 586
 587     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 588
 589     eval { # synchronize status updates
 590         $ldb->begin_work;
 591
 592         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 593
 594         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 595         $sth->execute($lastmt);
 596
 597         my $update_sth = $ldb->prepare(
 598             "UPDATE CMSReceivers SET status = ? WHERE " .
 599             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 600         while (my $ref = $sth->fetchrow_hashref()) {
 601             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 602                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 603         }
 604
 605         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 606
 607         $ldb->commit;
 608     };
 609     if (my $err = $@) {
 610         $ldb->rollback;
 611         die $err;
 612     }
 613
 614     return $mscount;
 615 }
 616
 617 sub sync_statistic_db {
 618     my ($ldb, $rdb, $ni) = @_;
 619
 620     my $rcid = $ni->{cid};
 621
 622     my $maxmails = 100000;
 623
 624     my $mscount = 0;
 625
 626     my $maxcount = 1000;
 627
 628     my $count;
 629
 630     PMG::DBTools::create_clusterinfo_default(
 631         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 632
 633     do { # get new values
 634
 635         $count = 0;
 636
 637         eval {
 638             $ldb->begin_work;
 639
 640             my $lastid = PMG::DBTools::read_int_clusterinfo(
 641                 $ldb, $rcid, 'lastid_CStatistic');
 642
 643             # sync CStatistic
 644
 645             my $sth = $rdb->prepare(
 646                 "SELECT * from CStatistic " .
 647                 "WHERE cid = ? AND rid > ? " .
 648                 "ORDER BY cid, rid LIMIT ?");
 649             $sth->execute($rcid, $lastid, $maxcount);
 650
 651             my $maxid;
 652             my $callback = sub {
 653                 my $ref = shift;
 654                 $maxid = $ref->{rid};
 655             };
 656
 657             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 658             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 659
 660             if ($maxid) {
 661                 # sync CReceivers
 662
 663                 $sth = $rdb->prepare(
 664                     "SELECT * from CReceivers WHERE " .
 665                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 666                 $sth->execute($rcid, $lastid, $maxid);
 667
 668                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 669                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 670             }
 671
 672             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 673
 674             $ldb->commit;
 675         };
 676         if (my $err = $@) {
 677             $ldb->rollback;
 678             die $err;
 679         }
 680
 681         $mscount += $count;
 682
 683     } while (($count >= $maxcount) && ($mscount < $maxmails));
 684
 685     return $mscount;
 686 }
 687
 688 my $sync_generic_mtime_db = sub {
 689     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 690
 691     my $ctime = PMG::DBTools::get_remote_time($rdb);
 692
 693     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 694
 695     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 696
 697     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 698
 699     my $sth = $rdb->prepare($sql_cmd);
 700
 701     $sth->execute();
 702
 703     my $updates = 0;
 704
 705     eval {
 706         # use transaction to speedup things
 707         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 708         my $count = 0;
 709         while (my $ref = $sth->fetchrow_hashref()) {
 710             $ldb->begin_work if !$count;
 711             $mergefunc->($ref);
 712             if (++$count >= $max) {
 713                 $count = 0;
 714                 $ldb->commit;
 715             }
 716             $updates++;
 717         }
 718
 719         $ldb->commit if $count;
 720     };
 721     if (my $err = $@) {
 722         $ldb->rollback;
 723         die $err;
 724     }
 725
 726     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 727
 728     return $updates;
 729 };
 730
 731 sub sync_localstat_db {
 732     my ($dbh, $rdb, $ni) = @_;
 733
 734     my $rcid = $ni->{cid};
 735
 736     my $selectfunc = sub {
 737         my ($ctime, $lastmt) = @_;
 738         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 739     };
 740
 741     my $merge_sth = $dbh->prepare(
 742         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 743         'VALUES (?, ?, ?, ?, ?) ' .
 744         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 745         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 746
 747     my $mergefunc = sub {
 748         my ($ref) = @_;
 749
 750         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 751     };
 752
 753     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 754 }
 755
 756 sub sync_greylist_db {
 757     my ($dbh, $rdb, $ni) = @_;
 758
 759     my $selectfunc = sub {
 760         my ($ctime, $lastmt) = @_;
 761         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 762             "mtime >= $lastmt AND CID != 0";
 763     };
 764
 765     my $merge_sth = $dbh->prepare($PMG::DBTools::cgreylist_merge_sql);
 766     my $mergefunc = sub {
 767         my ($ref) = @_;
 768
 769         $merge_sth->execute(
 770             $ref->{ipnet}, $ref->{host}, $ref->{sender}, $ref->{receiver},
 771             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 772             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 773     };
 774
 775     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 776 }
 777
 778 sub sync_userprefs_db {
 779     my ($dbh, $rdb, $ni) = @_;
 780
 781     my $selectfunc = sub {
 782         my ($ctime, $lastmt) = @_;
 783
 784         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 785     };
 786
 787     my $merge_sth = $dbh->prepare(
 788         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 789         'VALUES (?, ?, ?, ?) ' .
 790         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 791         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 792         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 793         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 794
 795     my $mergefunc = sub {
 796         my ($ref) = @_;
 797
 798         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 799     };
 800
 801     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 802 }
 803
 804 sub sync_domainstat_db {
 805     my ($dbh, $rdb, $ni) = @_;
 806
 807     my $selectfunc = sub {
 808         my ($ctime, $lastmt) = @_;
 809         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 810     };
 811
 812     my $merge_sth = $dbh->prepare(
 813         'INSERT INTO Domainstat ' .
 814         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 815         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 816         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 817         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 818         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 819         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 820         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 821         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 822         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 823         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 824
 825     my $mergefunc = sub {
 826         my ($ref) = @_;
 827
 828         $merge_sth->execute(
 829             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 830             $ref->{bytesin}, $ref->{bytesout},
 831             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 832             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 833     };
 834
 835     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 836 }
 837
 838 sub sync_dailystat_db {
 839     my ($dbh, $rdb, $ni) = @_;
 840
 841     my $selectfunc = sub {
 842         my ($ctime, $lastmt) = @_;
 843         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 844     };
 845
 846     my $merge_sth = $dbh->prepare(
 847         'INSERT INTO DailyStat ' .
 848         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 849         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 850         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 851         'ON CONFLICT (Time) DO UPDATE SET ' .
 852         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 853         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 854         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 855         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 856         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 857         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 858         'RBLCount = excluded.RBLCount, ' .
 859         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 860
 861     my $mergefunc = sub {
 862         my ($ref) = @_;
 863
 864         $merge_sth->execute(
 865             $ref->{time}, $ref->{countin}, $ref->{countout},
 866             $ref->{bytesin}, $ref->{bytesout},
 867             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 868             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 869             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 870     };
 871
 872     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 873 }
 874
 875 sub sync_virusinfo_db {
 876     my ($dbh, $rdb, $ni) = @_;
 877
 878     my $selectfunc = sub {
 879         my ($ctime, $lastmt) = @_;
 880         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 881     };
 882
 883     my $merge_sth = $dbh->prepare(
 884         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 885         'VALUES (?,?,?,?) ' .
 886         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 887         'Count = excluded.Count , MTime = excluded.MTime');
 888
 889     my $mergefunc = sub {
 890         my ($ref) = @_;
 891
 892         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 893     };
 894
 895     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 896 }
 897
 898 sub sync_deleted_nodes_from_master {
 899     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 900
 901     my $rsynctime = 0;
 902
 903     my $cid_hash = {}; # fast lookup
 904     foreach my $ni (values %{$cinfo->{ids}}) {
 905         $cid_hash->{$ni->{cid}} = $ni;
 906     }
 907
 908     my $spooldir = $PMG::MailQueue::spooldir;
 909
 910     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 911
 912     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 913         next if $cid_hash->{$rcid};
 914
 915         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 916
 917         next if -f $done_marker; # already synced
 918
 919         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 920
 921         my $starttime = [ gettimeofday() ];
 922         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 923         $$rsynctime_ref += tv_interval($starttime);
 924
 925         my $fake_ni = {
 926             ip => $masterni->{ip},
 927             name => $masterni->{name},
 928             cid => $rcid,
 929         };
 930
 931         sync_quarantine_db($ldb, $masterdb, $fake_ni);
 932
 933         sync_statistic_db ($ldb, $masterdb, $fake_ni);
 934
 935         open(my $fh, ">>",  $done_marker);
 936    }
 937 }
 938
 939
 940 1;