src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14
  15 use PMG::Utils;
  16 use PMG::Config;
  17 use PMG::ClusterConfig;
  18 use PMG::RuleDB;
  19 use PMG::RuleCache;
  20 use PMG::MailQueue;
  21 use PMG::Fetchmail;
  22
  23 sub remote_node_ip {
  24     my ($nodename, $noerr) = @_;
  25
  26     my $cinfo = PMG::ClusterConfig->new();
  27
  28     foreach my $entry (values %{$cinfo->{ids}}) {
  29         if ($entry->{name} eq $nodename) {
  30             my $ip = $entry->{ip};
  31             return $ip if !wantarray;
  32             my $family = PVE::Tools::get_host_address_family($ip);
  33             return ($ip, $family);
  34         }
  35     }
  36
  37     # fallback: try to get IP by other means
  38     return PMG::Utils::lookup_node_ip($nodename, $noerr);
  39 }
  40
  41 sub get_master_node {
  42     my ($cinfo) = @_;
  43
  44     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  45
  46     return $cinfo->{master}->{name} if defined($cinfo->{master});
  47
  48     return 'localhost';
  49 }
  50
  51 sub read_local_ssl_cert_fingerprint {
  52     my $cert_path = "/etc/pmg/pmg-api.pem";
  53
  54     my $cert;
  55     eval {
  56         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  57         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  58         Net::SSLeay::BIO_free($bio);
  59     };
  60     if (my $err = $@) {
  61         die "unable to read certificate '$cert_path' - $err\n";
  62     }
  63
  64     if (!defined($cert)) {
  65         die "unable to read certificate '$cert_path' - got empty value\n";
  66     }
  67
  68     my $fp;
  69     eval {
  70         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  71     };
  72     if (my $err = $@) {
  73         die "unable to get fingerprint for '$cert_path' - $err\n";
  74     }
  75
  76     if (!defined($fp) || $fp eq '') {
  77         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  78     }
  79
  80     return $fp;
  81 }
  82
  83 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  84 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  85 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  86
  87 sub read_local_cluster_info {
  88
  89     my $res = {};
  90
  91     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  92     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  93     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
  94
  95     die "unable to parse ${hostrsapubkey_fn}\n"
  96         if $hostrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
  97
  98     my $nodename = PVE::INotify::nodename();
  99
 100     $res->{name} = $nodename;
 101
 102     $res->{ip} = PMG::Utils::lookup_node_ip($nodename);
 103
 104     $res->{hostrsapubkey} = $hostrsapubkey;
 105
 106     if (! -f $rootrsapubkey_fn) {
 107         unlink $rootrsakey_fn;
 108         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 109                    '-f', $rootrsakey_fn];
 110         PMG::Utils::run_silent_cmd($cmd);
 111     }
 112
 113     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 114     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 115     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 116
 117     die "unable to parse ${rootrsapubkey_fn}\n"
 118         if $rootrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
 119
 120     $res->{rootrsapubkey} = $rootrsapubkey;
 121
 122     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 123
 124     return $res;
 125 }
 126
 127 # X509 Certificate cache helper
 128
 129 my $cert_cache_nodes = {};
 130 my $cert_cache_timestamp = time();
 131 my $cert_cache_fingerprints = {};
 132
 133 sub update_cert_cache {
 134
 135     $cert_cache_timestamp = time();
 136
 137     $cert_cache_fingerprints = {};
 138     $cert_cache_nodes = {};
 139
 140     my $cinfo = PMG::ClusterConfig->new();
 141
 142     foreach my $entry (values %{$cinfo->{ids}}) {
 143         my $node = $entry->{name};
 144         my $fp = $entry->{fingerprint};
 145         if ($node && $fp) {
 146             $cert_cache_fingerprints->{$fp} = 1;
 147             $cert_cache_nodes->{$node} = $fp;
 148         }
 149     }
 150 }
 151
 152 # load and cache cert fingerprint once
 153 sub initialize_cert_cache {
 154     my ($node) = @_;
 155
 156     update_cert_cache()
 157         if defined($node) && !defined($cert_cache_nodes->{$node});
 158 }
 159
 160 sub check_cert_fingerprint {
 161     my ($cert) = @_;
 162
 163     # clear cache every 30 minutes at least
 164     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 165
 166     # get fingerprint of server certificate
 167     my $fp;
 168     eval {
 169         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 170     };
 171     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 172
 173     my $check = sub {
 174         for my $expected (keys %$cert_cache_fingerprints) {
 175             return 1 if $fp eq $expected;
 176         }
 177         return 0;
 178     };
 179
 180     return 1 if $check->();
 181
 182     # clear cache and retry at most once every minute
 183     if (time() - $cert_cache_timestamp >= 60) {
 184         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 185         update_cert_cache();
 186         return $check->();
 187     }
 188
 189     return 0;
 190 }
 191
 192 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 193 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 194 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 195
 196 sub update_ssh_keys {
 197     my ($cinfo) = @_;
 198
 199     my $old = '';
 200     my $data = '';
 201
 202     foreach my $node (values %{$cinfo->{ids}}) {
 203         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 204         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 205     }
 206
 207     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 208         if -f $sshglobalknownhosts;
 209
 210     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 211         if $old ne $data;
 212
 213     $data = '';
 214     $old = '';
 215
 216     # always add ourself
 217     if (-f $ssh_rsa_id) {
 218         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 219         chomp($pub);
 220         $data .= "$pub\n";
 221     }
 222
 223     foreach my $node (values %{$cinfo->{ids}}) {
 224         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 225     }
 226
 227     if (-f $rootsshauthkeys) {
 228         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 229         chomp($mykey);
 230         $data .= "$mykey\n";
 231     }
 232
 233     my $newdata = "";
 234     my $vhash = {};
 235     my @lines = split(/\n/, $data);
 236     foreach my $line (@lines) {
 237         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 238             next if $vhash->{$3}++;
 239         }
 240         $newdata .= "$line\n";
 241     }
 242
 243     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 244         if -f $rootsshauthkeys;
 245
 246     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 247         if $old ne $newdata;
 248 }
 249
 250 my $cfgdir = '/etc/pmg';
 251 my $syncdir = "$cfgdir/master";
 252
 253 my $cond_commit_synced_file = sub {
 254     my ($filename, $dstfn) = @_;
 255
 256     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 257     my $srcfn = "$syncdir/$filename";
 258
 259     if (! -f $srcfn) {
 260         unlink $dstfn;
 261         return;
 262     }
 263
 264     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 265
 266     if (-f $dstfn) {
 267         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 268         return 0 if $new eq $old;
 269     }
 270
 271     # set mtime (touch) to avoid time drift problems
 272     utime(undef, undef, $srcfn);
 273
 274     rename($srcfn, $dstfn) ||
 275         die "cond_rename_file '$filename' failed - $!\n";
 276
 277     print STDERR "updated $dstfn\n";
 278
 279     return 1;
 280 };
 281
 282 my $rsync_command = sub {
 283     my ($host_key_alias, @args) = @_;
 284
 285     my $ssh_cmd = '--rsh=ssh -l root -o BatchMode=yes';
 286     $ssh_cmd .=  " -o HostKeyAlias=${host_key_alias}" if $host_key_alias;
 287
 288     my $cmd = ['rsync', $ssh_cmd,  '-q', @args];
 289
 290     return $cmd;
 291 };
 292
 293 sub sync_quarantine_files {
 294     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 295
 296     my $spooldir = $PMG::MailQueue::spooldir;
 297
 298     mkdir "$spooldir/cluster/";
 299     my $syncdir = "$spooldir/cluster/$rcid";
 300     mkdir $syncdir;
 301
 302     my $cmd = $rsync_command->(
 303         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 304         '--files-from', $flistname);
 305
 306     PVE::Tools::run_command($cmd);
 307 }
 308
 309 sub sync_spooldir {
 310     my ($host_ip, $host_name, $rcid) = @_;
 311
 312     my $spooldir = $PMG::MailQueue::spooldir;
 313
 314     mkdir "$spooldir/cluster/";
 315     my $syncdir = "$spooldir/cluster/$rcid";
 316     mkdir $syncdir;
 317
 318     my $cmd = $rsync_command->(
 319         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 320
 321     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 322         push @$cmd, '--include', $incl;
 323     }
 324
 325     push @$cmd, '--exclude', '*';
 326
 327     PVE::Tools::run_command($cmd);
 328 }
 329
 330 sub sync_master_quar {
 331     my ($host_ip, $host_name) = @_;
 332
 333     my $spooldir = $PMG::MailQueue::spooldir;
 334
 335     my $syncdir = "$spooldir/cluster/";
 336     mkdir $syncdir;
 337
 338     my $cmd = $rsync_command->(
 339         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 340
 341     PVE::Tools::run_command($cmd);
 342 }
 343
 344 sub sync_config_from_master {
 345     my ($master_name, $master_ip, $noreload) = @_;
 346
 347     mkdir $syncdir;
 348     File::Path::remove_tree($syncdir, {keep_root => 1});
 349
 350     my $sa_conf_dir = "/etc/mail/spamassassin";
 351     my $sa_custom_cf = "custom.cf";
 352
 353     my $cmd = $rsync_command->(
 354         $master_name, '-aq',
 355         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf}",
 356         "$syncdir/",
 357         '--exclude', 'master/',
 358         '--exclude', '*~',
 359         '--exclude', '*.db',
 360         '--exclude', 'pmg-api.pem',
 361         '--exclude', 'pmg-tls.pem',
 362         );
 363
 364     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 365     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 366
 367     # verify that the remote host is cluster master
 368     open (my $fh, '<', "$syncdir/cluster.conf") ||
 369         die "unable to open synced cluster.conf - $!\n";
 370
 371     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 372
 373     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 374         die "host '$master_ip' is not cluster master\n";
 375     }
 376
 377     my $role = $cinfo->{'local'}->{type} // '-';
 378     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 379         if $role eq '-';
 380
 381     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 382         if $role eq 'master';
 383
 384     $cond_commit_synced_file->('cluster.conf');
 385
 386     update_ssh_keys($cinfo); # rewrite ssh keys
 387
 388     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 389
 390     my $files = [
 391         'pmg-authkey.key',
 392         'pmg-authkey.pub',
 393         'pmg-csrf.key',
 394         'ldap.conf',
 395         'user.conf',
 396         'domains',
 397         'mynetworks',
 398         'transport',
 399         'tls_policy',
 400         'fetchmailrc',
 401         ];
 402
 403     foreach my $filename (@$files) {
 404         $cond_commit_synced_file->($filename);
 405     }
 406
 407     my $dirs = [
 408         'templates',
 409         'dkim',
 410     ];
 411
 412     foreach my $dir (@$dirs) {
 413         my $srcdir = "$syncdir/$dir";
 414
 415         if ( -d $srcdir ) {
 416             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 417             PVE::Tools::run_command($cmd);
 418         }
 419
 420     }
 421
 422     my $force_restart = {};
 423
 424     if ($cond_commit_synced_file->($sa_custom_cf, "${sa_conf_dir}/${sa_custom_cf}")) {
 425         $force_restart->{'pmg-smtp-filter'} = 1;
 426     }
 427
 428     $cond_commit_synced_file->('pmg.conf');
 429
 430     return $force_restart;
 431 }
 432
 433 sub sync_ruledb_from_master {
 434     my ($ldb, $rdb, $ni, $ticket) = @_;
 435
 436     my $ruledb = PMG::RuleDB->new($ldb);
 437     my $rulecache = PMG::RuleCache->new($ruledb);
 438
 439     my $conn = PVE::APIClient::LWP->new(
 440         ticket => $ticket,
 441         cookie_name => 'PMGAuthCookie',
 442         host => $ni->{ip},
 443         cached_fingerprints => {
 444             $ni->{fingerprint} => 1,
 445         });
 446
 447     my $digest = $conn->get("/config/ruledb/digest", {});
 448
 449     return if $digest eq $rulecache->{digest}; # no changes
 450
 451     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 452
 453     eval {
 454         $ldb->begin_work;
 455
 456         $ldb->do("DELETE FROM Rule");
 457         $ldb->do("DELETE FROM RuleGroup");
 458         $ldb->do("DELETE FROM ObjectGroup");
 459         $ldb->do("DELETE FROM Object");
 460         $ldb->do("DELETE FROM Attribut");
 461
 462         eval {
 463             $rdb->begin_work;
 464
 465             # read a consistent snapshot
 466             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 467
 468             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 469             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 470             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 471             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 472             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 473         };
 474
 475         $rdb->rollback; # end transaction
 476
 477         die $@ if $@;
 478
 479         # update sequences
 480
 481         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 482         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 483         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 484
 485         $ldb->commit;
 486     };
 487     if (my $err = $@) {
 488         $ldb->rollback;
 489         die $err;
 490     }
 491
 492     PMG::DBTools::reload_ruledb();
 493
 494     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 495 }
 496
 497 sub sync_quarantine_db {
 498     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 499
 500     my $rcid = $ni->{cid};
 501
 502     my $maxmails = 100000;
 503
 504     my $mscount = 0;
 505
 506     my $ctime = PMG::DBTools::get_remote_time($rdb);
 507
 508     my $maxcount = 1000;
 509
 510     my $count;
 511
 512     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 513
 514     do { # get new values
 515
 516         $count = 0;
 517
 518         my $flistname = "/tmp/quarantinefilelist.$$";
 519
 520         eval {
 521             $ldb->begin_work;
 522
 523             open(my $flistfh, '>', $flistname) ||
 524                 die "unable to open file '$flistname' - $!\n";
 525
 526             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 527
 528             # sync CMailStore
 529
 530             my $sth = $rdb->prepare(
 531                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 532                 "ORDER BY cid,rid LIMIT ?");
 533             $sth->execute($rcid, $lastid, $maxcount);
 534
 535             my $maxid;
 536             my $callback = sub {
 537                 my $ref = shift;
 538                 $maxid = $ref->{rid};
 539                 my $filename = $ref->{file};
 540                  # skip files generated before cluster was created
 541                 return if $filename !~ m!^cluster/!;
 542                 print $flistfh "$filename\n";
 543             };
 544
 545             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 546             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 547
 548             close($flistfh);
 549
 550             my $starttime = [ gettimeofday() ];
 551             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 552             $$rsynctime_ref += tv_interval($starttime);
 553
 554             if ($maxid) {
 555                 # sync CMSReceivers
 556
 557                 $sth = $rdb->prepare(
 558                     "SELECT * from CMSReceivers WHERE " .
 559                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 560                     "AND CMailStore_RID <= ?");
 561                 $sth->execute($rcid, $lastid, $maxid);
 562
 563                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 564                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 565
 566                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 567             }
 568
 569             $ldb->commit;
 570         };
 571         my $err = $@;
 572
 573         unlink $flistname;
 574
 575         if ($err) {
 576             $ldb->rollback;
 577             die $err;
 578         }
 579
 580         $mscount += $count;
 581
 582     } while (($count >= $maxcount) && ($mscount < $maxmails));
 583
 584     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 585
 586     eval { # synchronize status updates
 587         $ldb->begin_work;
 588
 589         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 590
 591         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 592         $sth->execute($lastmt);
 593
 594         my $update_sth = $ldb->prepare(
 595             "UPDATE CMSReceivers SET status = ? WHERE " .
 596             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 597         while (my $ref = $sth->fetchrow_hashref()) {
 598             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 599                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 600         }
 601
 602         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 603
 604         $ldb->commit;
 605     };
 606     if (my $err = $@) {
 607         $ldb->rollback;
 608         die $err;
 609     }
 610
 611     return $mscount;
 612 }
 613
 614 sub sync_statistic_db {
 615     my ($ldb, $rdb, $ni) = @_;
 616
 617     my $rcid = $ni->{cid};
 618
 619     my $maxmails = 100000;
 620
 621     my $mscount = 0;
 622
 623     my $maxcount = 1000;
 624
 625     my $count;
 626
 627     PMG::DBTools::create_clusterinfo_default(
 628         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 629
 630     do { # get new values
 631
 632         $count = 0;
 633
 634         eval {
 635             $ldb->begin_work;
 636
 637             my $lastid = PMG::DBTools::read_int_clusterinfo(
 638                 $ldb, $rcid, 'lastid_CStatistic');
 639
 640             # sync CStatistic
 641
 642             my $sth = $rdb->prepare(
 643                 "SELECT * from CStatistic " .
 644                 "WHERE cid = ? AND rid > ? " .
 645                 "ORDER BY cid, rid LIMIT ?");
 646             $sth->execute($rcid, $lastid, $maxcount);
 647
 648             my $maxid;
 649             my $callback = sub {
 650                 my $ref = shift;
 651                 $maxid = $ref->{rid};
 652             };
 653
 654             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 655             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 656
 657             if ($maxid) {
 658                 # sync CReceivers
 659
 660                 $sth = $rdb->prepare(
 661                     "SELECT * from CReceivers WHERE " .
 662                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 663                 $sth->execute($rcid, $lastid, $maxid);
 664
 665                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 666                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 667             }
 668
 669             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 670
 671             $ldb->commit;
 672         };
 673         if (my $err = $@) {
 674             $ldb->rollback;
 675             die $err;
 676         }
 677
 678         $mscount += $count;
 679
 680     } while (($count >= $maxcount) && ($mscount < $maxmails));
 681
 682     return $mscount;
 683 }
 684
 685 my $sync_generic_mtime_db = sub {
 686     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 687
 688     my $ctime = PMG::DBTools::get_remote_time($rdb);
 689
 690     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 691
 692     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 693
 694     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 695
 696     my $sth = $rdb->prepare($sql_cmd);
 697
 698     $sth->execute();
 699
 700     my $updates = 0;
 701
 702     eval {
 703         # use transaction to speedup things
 704         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 705         my $count = 0;
 706         while (my $ref = $sth->fetchrow_hashref()) {
 707             $ldb->begin_work if !$count;
 708             $mergefunc->($ref);
 709             if (++$count >= $max) {
 710                 $count = 0;
 711                 $ldb->commit;
 712             }
 713             $updates++;
 714         }
 715
 716         $ldb->commit if $count;
 717     };
 718     if (my $err = $@) {
 719         $ldb->rollback;
 720         die $err;
 721     }
 722
 723     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 724
 725     return $updates;
 726 };
 727
 728 sub sync_localstat_db {
 729     my ($dbh, $rdb, $ni) = @_;
 730
 731     my $rcid = $ni->{cid};
 732
 733     my $selectfunc = sub {
 734         my ($ctime, $lastmt) = @_;
 735         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 736     };
 737
 738     my $merge_sth = $dbh->prepare(
 739         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 740         'VALUES (?, ?, ?, ?, ?) ' .
 741         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 742         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 743
 744     my $mergefunc = sub {
 745         my ($ref) = @_;
 746
 747         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 748     };
 749
 750     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 751 }
 752
 753 sub sync_greylist_db {
 754     my ($dbh, $rdb, $ni) = @_;
 755
 756     my $selectfunc = sub {
 757         my ($ctime, $lastmt) = @_;
 758         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 759             "mtime >= $lastmt AND CID != 0";
 760     };
 761
 762     my $merge_sth = $dbh->prepare($PMG::DBTools::cgreylist_merge_sql);
 763     my $mergefunc = sub {
 764         my ($ref) = @_;
 765
 766         $merge_sth->execute(
 767             $ref->{ipnet}, $ref->{host}, $ref->{sender}, $ref->{receiver},
 768             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 769             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 770     };
 771
 772     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 773 }
 774
 775 sub sync_userprefs_db {
 776     my ($dbh, $rdb, $ni) = @_;
 777
 778     my $selectfunc = sub {
 779         my ($ctime, $lastmt) = @_;
 780
 781         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 782     };
 783
 784     my $merge_sth = $dbh->prepare(
 785         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 786         'VALUES (?, ?, ?, ?) ' .
 787         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 788         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 789         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 790         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 791
 792     my $mergefunc = sub {
 793         my ($ref) = @_;
 794
 795         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 796     };
 797
 798     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 799 }
 800
 801 sub sync_domainstat_db {
 802     my ($dbh, $rdb, $ni) = @_;
 803
 804     my $selectfunc = sub {
 805         my ($ctime, $lastmt) = @_;
 806         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 807     };
 808
 809     my $merge_sth = $dbh->prepare(
 810         'INSERT INTO Domainstat ' .
 811         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 812         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 813         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 814         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 815         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 816         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 817         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 818         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 819         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 820         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 821
 822     my $mergefunc = sub {
 823         my ($ref) = @_;
 824
 825         $merge_sth->execute(
 826             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 827             $ref->{bytesin}, $ref->{bytesout},
 828             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 829             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 830     };
 831
 832     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 833 }
 834
 835 sub sync_dailystat_db {
 836     my ($dbh, $rdb, $ni) = @_;
 837
 838     my $selectfunc = sub {
 839         my ($ctime, $lastmt) = @_;
 840         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 841     };
 842
 843     my $merge_sth = $dbh->prepare(
 844         'INSERT INTO DailyStat ' .
 845         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 846         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 847         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 848         'ON CONFLICT (Time) DO UPDATE SET ' .
 849         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 850         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 851         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 852         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 853         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 854         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 855         'RBLCount = excluded.RBLCount, ' .
 856         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 857
 858     my $mergefunc = sub {
 859         my ($ref) = @_;
 860
 861         $merge_sth->execute(
 862             $ref->{time}, $ref->{countin}, $ref->{countout},
 863             $ref->{bytesin}, $ref->{bytesout},
 864             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 865             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 866             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 867     };
 868
 869     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 870 }
 871
 872 sub sync_virusinfo_db {
 873     my ($dbh, $rdb, $ni) = @_;
 874
 875     my $selectfunc = sub {
 876         my ($ctime, $lastmt) = @_;
 877         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 878     };
 879
 880     my $merge_sth = $dbh->prepare(
 881         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 882         'VALUES (?,?,?,?) ' .
 883         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 884         'Count = excluded.Count , MTime = excluded.MTime');
 885
 886     my $mergefunc = sub {
 887         my ($ref) = @_;
 888
 889         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 890     };
 891
 892     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 893 }
 894
 895 sub sync_deleted_nodes_from_master {
 896     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 897
 898     my $rsynctime = 0;
 899
 900     my $cid_hash = {}; # fast lookup
 901     foreach my $ni (values %{$cinfo->{ids}}) {
 902         $cid_hash->{$ni->{cid}} = $ni;
 903     }
 904
 905     my $spooldir = $PMG::MailQueue::spooldir;
 906
 907     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 908
 909     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 910         next if $cid_hash->{$rcid};
 911
 912         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 913
 914         next if -f $done_marker; # already synced
 915
 916         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 917
 918         my $starttime = [ gettimeofday() ];
 919         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 920         $$rsynctime_ref += tv_interval($starttime);
 921
 922         my $fake_ni = {
 923             ip => $masterni->{ip},
 924             name => $masterni->{name},
 925             cid => $rcid,
 926         };
 927
 928         sync_quarantine_db($ldb, $masterdb, $fake_ni);
 929
 930         sync_statistic_db ($ldb, $masterdb, $fake_ni);
 931
 932         open(my $fh, ">>",  $done_marker);
 933    }
 934 }
 935
 936
 937 1;