src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14 use PVE::Network;
  15
  16 use PMG::Utils;
  17 use PMG::Config;
  18 use PMG::ClusterConfig;
  19 use PMG::RuleDB;
  20 use PMG::RuleCache;
  21 use PMG::MailQueue;
  22 use PMG::Fetchmail;
  23 use PMG::Ticket;
  24
  25 sub remote_node_ip {
  26     my ($nodename, $noerr) = @_;
  27
  28     my $cinfo = PMG::ClusterConfig->new();
  29
  30     foreach my $entry (values %{$cinfo->{ids}}) {
  31         if ($entry->{name} eq $nodename) {
  32             my $ip = $entry->{ip};
  33             return $ip if !wantarray;
  34             my $family = PVE::Tools::get_host_address_family($ip);
  35             return ($ip, $family);
  36         }
  37     }
  38
  39     # fallback: try to get IP by other means
  40     if ($nodename eq 'localhost' || $nodename eq PVE::INotify::nodename()) {
  41         return PVE::Network::get_local_ip();
  42     } else {
  43         return PVE::Network::get_ip_from_hostname($nodename, $noerr);
  44     }
  45 }
  46
  47 sub get_master_node {
  48     my ($cinfo) = @_;
  49
  50     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  51
  52     return $cinfo->{master}->{name} if defined($cinfo->{master});
  53
  54     return 'localhost';
  55 }
  56
  57 sub read_local_ssl_cert_fingerprint {
  58     my $cert_path = "/etc/pmg/pmg-api.pem";
  59
  60     my $cert;
  61     eval {
  62         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  63         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  64         Net::SSLeay::BIO_free($bio);
  65     };
  66     if (my $err = $@) {
  67         die "unable to read certificate '$cert_path' - $err\n";
  68     }
  69
  70     if (!defined($cert)) {
  71         die "unable to read certificate '$cert_path' - got empty value\n";
  72     }
  73
  74     my $fp;
  75     eval {
  76         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  77     };
  78     if (my $err = $@) {
  79         die "unable to get fingerprint for '$cert_path' - $err\n";
  80     }
  81
  82     if (!defined($fp) || $fp eq '') {
  83         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  84     }
  85
  86     return $fp;
  87 }
  88
  89 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  90 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  91 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  92
  93 sub read_local_cluster_info {
  94
  95     my $res = {};
  96
  97     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  98     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  99     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
 100
 101     my $sshpubkeypattern = PMG::ClusterConfig::Node::valid_ssh_pubkey_regex();
 102     die "unable to parse ${hostrsapubkey_fn}\n"
 103         if $hostrsapubkey !~ m/$sshpubkeypattern/;
 104
 105     my $nodename = PVE::INotify::nodename();
 106
 107     $res->{name} = $nodename;
 108
 109     $res->{ip} = PVE::Network::get_local_ip();
 110
 111     $res->{hostrsapubkey} = $hostrsapubkey;
 112
 113     if (! -f $rootrsapubkey_fn) {
 114         unlink $rootrsakey_fn;
 115         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 116                    '-f', $rootrsakey_fn];
 117         PMG::Utils::run_silent_cmd($cmd);
 118     }
 119
 120     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 121     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 122     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 123
 124     die "unable to parse ${rootrsapubkey_fn}\n"
 125         if $rootrsapubkey !~ m/$sshpubkeypattern/;
 126
 127     $res->{rootrsapubkey} = $rootrsapubkey;
 128
 129     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 130
 131     return $res;
 132 }
 133
 134 # X509 Certificate cache helper
 135
 136 my $cert_cache_nodes = {};
 137 my $cert_cache_timestamp = time();
 138 my $cert_cache_fingerprints = {};
 139
 140 sub update_cert_cache {
 141
 142     $cert_cache_timestamp = time();
 143
 144     $cert_cache_fingerprints = {};
 145     $cert_cache_nodes = {};
 146
 147     my $cinfo = PMG::ClusterConfig->new();
 148
 149     foreach my $entry (values %{$cinfo->{ids}}) {
 150         my $node = $entry->{name};
 151         my $fp = $entry->{fingerprint};
 152         if ($node && $fp) {
 153             $cert_cache_fingerprints->{$fp} = 1;
 154             $cert_cache_nodes->{$node} = $fp;
 155         }
 156     }
 157 }
 158
 159 # load and cache cert fingerprint once
 160 sub initialize_cert_cache {
 161     my ($node) = @_;
 162
 163     update_cert_cache()
 164         if defined($node) && !defined($cert_cache_nodes->{$node});
 165 }
 166
 167 sub check_cert_fingerprint {
 168     my ($cert) = @_;
 169
 170     # clear cache every 30 minutes at least
 171     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 172
 173     # get fingerprint of server certificate
 174     my $fp;
 175     eval {
 176         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 177     };
 178     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 179
 180     my $check = sub {
 181         for my $expected (keys %$cert_cache_fingerprints) {
 182             return 1 if $fp eq $expected;
 183         }
 184         return 0;
 185     };
 186
 187     return 1 if $check->();
 188
 189     # clear cache and retry at most once every minute
 190     if (time() - $cert_cache_timestamp >= 60) {
 191         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 192         update_cert_cache();
 193         return $check->();
 194     }
 195
 196     return 0;
 197 }
 198
 199 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 200 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 201 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 202
 203 sub update_ssh_keys {
 204     my ($cinfo) = @_;
 205
 206     my $old = '';
 207     my $data = '';
 208
 209     foreach my $node (values %{$cinfo->{ids}}) {
 210         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 211         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 212     }
 213
 214     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 215         if -f $sshglobalknownhosts;
 216
 217     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 218         if $old ne $data;
 219
 220     $data = '';
 221     $old = '';
 222
 223     # always add ourself
 224     if (-f $ssh_rsa_id) {
 225         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 226         chomp($pub);
 227         $data .= "$pub\n";
 228     }
 229
 230     foreach my $node (values %{$cinfo->{ids}}) {
 231         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 232     }
 233
 234     if (-f $rootsshauthkeys) {
 235         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 236         chomp($mykey);
 237         $data .= "$mykey\n";
 238     }
 239
 240     my $newdata = "";
 241     my $vhash = {};
 242     my @lines = split(/\n/, $data);
 243     foreach my $line (@lines) {
 244         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 245             next if $vhash->{$3}++;
 246         }
 247         $newdata .= "$line\n";
 248     }
 249
 250     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 251         if -f $rootsshauthkeys;
 252
 253     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 254         if $old ne $newdata;
 255 }
 256
 257 my $cfgdir = '/etc/pmg';
 258 my $syncdir = "$cfgdir/master";
 259
 260 my $cond_commit_synced_file = sub {
 261     my ($filename, $dstfn) = @_;
 262
 263     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 264     my $srcfn = "$syncdir/$filename";
 265
 266     if (! -f $srcfn) {
 267         unlink $dstfn;
 268         return;
 269     }
 270
 271     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 272
 273     if (-f $dstfn) {
 274         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 275         return 0 if $new eq $old;
 276     }
 277
 278     # set mtime (touch) to avoid time drift problems
 279     utime(undef, undef, $srcfn);
 280
 281     rename($srcfn, $dstfn) ||
 282         die "cond_rename_file '$filename' failed - $!\n";
 283
 284     print STDERR "updated $dstfn\n";
 285
 286     return 1;
 287 };
 288
 289 my $ssh_command = sub {
 290     my ($host_key_alias, @args) = @_;
 291
 292     my $cmd = ['ssh', '-l', 'root', '-o', 'BatchMode=yes'];
 293     push @$cmd, '-o', "HostKeyAlias=${host_key_alias}" if $host_key_alias;
 294     push @$cmd, @args if @args;
 295     return $cmd;
 296 };
 297
 298 sub get_remote_cert_fingerprint {
 299     my ($ni) = @_;
 300
 301     my $ssh_cmd = $ssh_command->(
 302         $ni->{name},
 303         $ni->{ip},
 304         'openssl x509 -noout -fingerprint -sha256 -in /etc/pmg/pmg-api.pem'
 305     );
 306     my $fp;
 307     eval {
 308         PVE::Tools::run_command($ssh_cmd, outfunc => sub {
 309             my ($line) = @_;
 310             if ($line =~ m/SHA256 Fingerprint=((?:[A-Fa-f0-9]{2}:){31}[A-Fa-f0-9]{2})/) {
 311                 $fp = $1;
 312             }
 313         });
 314         die "parsing failed\n" if !$fp;
 315     };
 316     die "unable to get remote node fingerprint from '$ni->{name}': $@\n" if $@;
 317
 318     return $fp;
 319 }
 320
 321 sub trigger_update_fingerprints {
 322     my ($cinfo) = @_;
 323
 324     my $master = $cinfo->{master} || die "unable to lookup master node\n";
 325     my $cached_fp = { $master->{fingerprint} => 1 };
 326
 327     # if running on master the current fingerprint for the API-connection is needed
 328     # in addition (to prevent races with restarting pmgproxy
 329     if ($cinfo->{local}->{type} eq 'master') {
 330         my $new_fp = PMG::Cluster::read_local_ssl_cert_fingerprint();
 331         $cached_fp->{$new_fp} = 1;
 332     }
 333
 334     my $ticket = PMG::Ticket::assemble_ticket('root@pam');
 335     my $csrftoken = PMG::Ticket::assemble_csrf_prevention_token('root@pam');
 336     my $conn = PVE::APIClient::LWP->new(
 337         ticket => $ticket,
 338         csrftoken => $csrftoken,
 339         cookie_name => 'PMGAuthCookie',
 340         host => $master->{ip},
 341         cached_fingerprints => $cached_fp,
 342         );
 343
 344     $conn->post("/config/cluster/update-fingerprints", {});
 345     return undef;
 346 }
 347
 348 my $rsync_command = sub {
 349     my ($host_key_alias, @args) = @_;
 350
 351     my $ssh_cmd = join(' ', @{$ssh_command->($host_key_alias)});
 352
 353     my $cmd = ['rsync', "--rsh=$ssh_cmd",  '-q', @args];
 354
 355     return $cmd;
 356 };
 357
 358 sub sync_quarantine_files {
 359     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 360
 361     my $spooldir = $PMG::MailQueue::spooldir;
 362
 363     mkdir "$spooldir/cluster/";
 364     my $syncdir = "$spooldir/cluster/$rcid";
 365     mkdir $syncdir;
 366
 367     my $cmd = $rsync_command->(
 368         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 369         '--files-from', $flistname);
 370
 371     PVE::Tools::run_command($cmd);
 372 }
 373
 374 sub sync_spooldir {
 375     my ($host_ip, $host_name, $rcid) = @_;
 376
 377     my $spooldir = $PMG::MailQueue::spooldir;
 378
 379     mkdir "$spooldir/cluster/";
 380     my $syncdir = "$spooldir/cluster/$rcid";
 381     mkdir $syncdir;
 382
 383     my $cmd = $rsync_command->(
 384         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 385
 386     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 387         push @$cmd, '--include', $incl;
 388     }
 389
 390     push @$cmd, '--exclude', '*';
 391
 392     PVE::Tools::run_command($cmd);
 393 }
 394
 395 sub sync_master_quar {
 396     my ($host_ip, $host_name) = @_;
 397
 398     my $spooldir = $PMG::MailQueue::spooldir;
 399
 400     my $syncdir = "$spooldir/cluster/";
 401     mkdir $syncdir;
 402
 403     my $cmd = $rsync_command->(
 404         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 405
 406     PVE::Tools::run_command($cmd);
 407 }
 408
 409 sub sync_config_from_master {
 410     my ($master_name, $master_ip, $noreload) = @_;
 411
 412     mkdir $syncdir;
 413     File::Path::remove_tree($syncdir, {keep_root => 1});
 414
 415     my $sa_conf_dir = "/etc/mail/spamassassin";
 416     my $sa_custom_cf = "custom.cf";
 417     my $sa_rules_cf = "pmg-scores.cf";
 418
 419     my $cmd = $rsync_command->(
 420         $master_name, '-aq',
 421         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf} ${sa_conf_dir}/${sa_rules_cf}",
 422         "$syncdir/",
 423         '--exclude', 'master/',
 424         '--exclude', '*~',
 425         '--exclude', '*.db',
 426         '--exclude', 'pmg-api.pem',
 427         '--exclude', 'pmg-tls.pem',
 428         );
 429
 430     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 431     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 432
 433     # verify that the remote host is cluster master
 434     open (my $fh, '<', "$syncdir/cluster.conf") ||
 435         die "unable to open synced cluster.conf - $!\n";
 436
 437     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 438
 439     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 440         die "host '$master_ip' is not cluster master\n";
 441     }
 442
 443     my $role = $cinfo->{'local'}->{type} // '-';
 444     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 445         if $role eq '-';
 446
 447     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 448         if $role eq 'master';
 449
 450     $cond_commit_synced_file->('cluster.conf');
 451
 452     update_ssh_keys($cinfo); # rewrite ssh keys
 453
 454     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 455
 456     my $files = [
 457         'pmg-authkey.key',
 458         'pmg-authkey.pub',
 459         'pmg-csrf.key',
 460         'ldap.conf',
 461         'user.conf',
 462         'domains',
 463         'mynetworks',
 464         'transport',
 465         'tls_policy',
 466         'fetchmailrc',
 467         ];
 468
 469     foreach my $filename (@$files) {
 470         $cond_commit_synced_file->($filename);
 471     }
 472
 473     my $dirs = [
 474         'templates',
 475         'dkim',
 476         'pbs',
 477         'acme',
 478     ];
 479
 480     foreach my $dir (@$dirs) {
 481         my $srcdir = "$syncdir/$dir";
 482
 483         if ( -d $srcdir ) {
 484             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 485             PVE::Tools::run_command($cmd);
 486         }
 487
 488     }
 489
 490     my $force_restart = {};
 491
 492     for my $file (($sa_custom_cf, $sa_rules_cf)) {
 493         if ($cond_commit_synced_file->($file, "${sa_conf_dir}/${file}")) {
 494             $force_restart->{'pmg-smtp-filter'} = 1;
 495         }
 496     }
 497
 498     $cond_commit_synced_file->('pmg.conf');
 499
 500     return $force_restart;
 501 }
 502
 503 sub sync_ruledb_from_master {
 504     my ($ldb, $rdb, $ni, $ticket) = @_;
 505
 506     my $ruledb = PMG::RuleDB->new($ldb);
 507     my $rulecache = PMG::RuleCache->new($ruledb);
 508
 509     my $conn = PVE::APIClient::LWP->new(
 510         ticket => $ticket,
 511         cookie_name => 'PMGAuthCookie',
 512         host => $ni->{ip},
 513         cached_fingerprints => {
 514             $ni->{fingerprint} => 1,
 515         });
 516
 517     my $digest = $conn->get("/config/ruledb/digest", {});
 518
 519     return if $digest eq $rulecache->{digest}; # no changes
 520
 521     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 522
 523     eval {
 524         $ldb->begin_work;
 525
 526         $ldb->do("DELETE FROM Rule");
 527         $ldb->do("DELETE FROM RuleGroup");
 528         $ldb->do("DELETE FROM ObjectGroup");
 529         $ldb->do("DELETE FROM Object");
 530         $ldb->do("DELETE FROM Attribut");
 531
 532         eval {
 533             $rdb->begin_work;
 534
 535             # read a consistent snapshot
 536             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 537
 538             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 539             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 540             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 541             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 542             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 543         };
 544
 545         $rdb->rollback; # end transaction
 546
 547         die $@ if $@;
 548
 549         # update sequences
 550
 551         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 552         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 553         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 554
 555         $ldb->commit;
 556     };
 557     if (my $err = $@) {
 558         $ldb->rollback;
 559         die $err;
 560     }
 561
 562     PMG::DBTools::reload_ruledb();
 563
 564     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 565 }
 566
 567 sub sync_quarantine_db {
 568     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 569
 570     my $rcid = $ni->{cid};
 571
 572     my $maxmails = 100000;
 573
 574     my $mscount = 0;
 575
 576     my $ctime = PMG::DBTools::get_remote_time($rdb);
 577
 578     my $maxcount = 1000;
 579
 580     my $count;
 581
 582     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 583
 584     do { # get new values
 585
 586         $count = 0;
 587
 588         my $flistname = "/tmp/quarantinefilelist.$$";
 589
 590         eval {
 591             $ldb->begin_work;
 592
 593             open(my $flistfh, '>', $flistname) ||
 594                 die "unable to open file '$flistname' - $!\n";
 595
 596             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 597
 598             # sync CMailStore
 599
 600             my $sth = $rdb->prepare(
 601                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 602                 "ORDER BY cid,rid LIMIT ?");
 603             $sth->execute($rcid, $lastid, $maxcount);
 604
 605             my $maxid;
 606             my $callback = sub {
 607                 my $ref = shift;
 608                 $maxid = $ref->{rid};
 609                 my $filename = $ref->{file};
 610                  # skip files generated before cluster was created
 611                 return if $filename !~ m!^cluster/!;
 612                 print $flistfh "$filename\n";
 613             };
 614
 615             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 616             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 617
 618             close($flistfh);
 619
 620             my $starttime = [ gettimeofday() ];
 621             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 622             $$rsynctime_ref += tv_interval($starttime);
 623
 624             if ($maxid) {
 625                 # sync CMSReceivers
 626
 627                 $sth = $rdb->prepare(
 628                     "SELECT * from CMSReceivers WHERE " .
 629                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 630                     "AND CMailStore_RID <= ?");
 631                 $sth->execute($rcid, $lastid, $maxid);
 632
 633                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 634                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 635
 636                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 637             }
 638
 639             $ldb->commit;
 640         };
 641         my $err = $@;
 642
 643         unlink $flistname;
 644
 645         if ($err) {
 646             $ldb->rollback;
 647             die $err;
 648         }
 649
 650         $mscount += $count;
 651
 652     } while (($count >= $maxcount) && ($mscount < $maxmails));
 653
 654     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 655
 656     eval { # synchronize status updates
 657         $ldb->begin_work;
 658
 659         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 660
 661         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 662         $sth->execute($lastmt);
 663
 664         my $update_sth = $ldb->prepare(
 665             "UPDATE CMSReceivers SET status = ? WHERE " .
 666             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 667         while (my $ref = $sth->fetchrow_hashref()) {
 668             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 669                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 670         }
 671
 672         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 673
 674         $ldb->commit;
 675     };
 676     if (my $err = $@) {
 677         $ldb->rollback;
 678         die $err;
 679     }
 680
 681     return $mscount;
 682 }
 683
 684 sub sync_statistic_db {
 685     my ($ldb, $rdb, $ni) = @_;
 686
 687     my $rcid = $ni->{cid};
 688
 689     my $maxmails = 100000;
 690
 691     my $mscount = 0;
 692
 693     my $maxcount = 1000;
 694
 695     my $count;
 696
 697     PMG::DBTools::create_clusterinfo_default(
 698         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 699
 700     do { # get new values
 701
 702         $count = 0;
 703
 704         eval {
 705             $ldb->begin_work;
 706
 707             my $lastid = PMG::DBTools::read_int_clusterinfo(
 708                 $ldb, $rcid, 'lastid_CStatistic');
 709
 710             # sync CStatistic
 711
 712             my $sth = $rdb->prepare(
 713                 "SELECT * from CStatistic " .
 714                 "WHERE cid = ? AND rid > ? " .
 715                 "ORDER BY cid, rid LIMIT ?");
 716             $sth->execute($rcid, $lastid, $maxcount);
 717
 718             my $maxid;
 719             my $callback = sub {
 720                 my $ref = shift;
 721                 $maxid = $ref->{rid};
 722             };
 723
 724             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 725             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 726
 727             if ($maxid) {
 728                 # sync CReceivers
 729
 730                 $sth = $rdb->prepare(
 731                     "SELECT * from CReceivers WHERE " .
 732                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 733                 $sth->execute($rcid, $lastid, $maxid);
 734
 735                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 736                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 737             }
 738
 739             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 740
 741             $ldb->commit;
 742         };
 743         if (my $err = $@) {
 744             $ldb->rollback;
 745             die $err;
 746         }
 747
 748         $mscount += $count;
 749
 750     } while (($count >= $maxcount) && ($mscount < $maxmails));
 751
 752     return $mscount;
 753 }
 754
 755 my $sync_generic_mtime_db = sub {
 756     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 757
 758     my $ctime = PMG::DBTools::get_remote_time($rdb);
 759
 760     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 761
 762     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 763
 764     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 765
 766     my $sth = $rdb->prepare($sql_cmd);
 767
 768     $sth->execute();
 769
 770     my $updates = 0;
 771
 772     eval {
 773         # use transaction to speedup things
 774         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 775         my $count = 0;
 776         while (my $ref = $sth->fetchrow_hashref()) {
 777             $ldb->begin_work if !$count;
 778             $mergefunc->($ref);
 779             if (++$count >= $max) {
 780                 $count = 0;
 781                 $ldb->commit;
 782             }
 783             $updates++;
 784         }
 785
 786         $ldb->commit if $count;
 787     };
 788     if (my $err = $@) {
 789         $ldb->rollback;
 790         die $err;
 791     }
 792
 793     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 794
 795     return $updates;
 796 };
 797
 798 sub sync_localstat_db {
 799     my ($dbh, $rdb, $ni) = @_;
 800
 801     my $rcid = $ni->{cid};
 802
 803     my $selectfunc = sub {
 804         my ($ctime, $lastmt) = @_;
 805         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 806     };
 807
 808     my $merge_sth = $dbh->prepare(
 809         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 810         'VALUES (?, ?, ?, ?, ?) ' .
 811         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 812         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 813
 814     my $mergefunc = sub {
 815         my ($ref) = @_;
 816
 817         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 818     };
 819
 820     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 821 }
 822
 823 sub sync_greylist_db {
 824     my ($dbh, $rdb, $ni) = @_;
 825
 826     my $selectfunc = sub {
 827         my ($ctime, $lastmt) = @_;
 828         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 829             "mtime >= $lastmt AND CID != 0";
 830     };
 831
 832     my $merge_sth = $dbh->prepare(PMG::DBTools::cgreylist_merge_sql());
 833     my $mergefunc = sub {
 834         my ($ref) = @_;
 835
 836         my $ipnet = $ref->{ipnet};
 837         $ipnet .= '.0/24' if $ipnet !~ /\/\d+$/;
 838         $merge_sth->execute(
 839             $ipnet, $ref->{sender}, $ref->{receiver},
 840             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 841             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 842     };
 843
 844     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 845 }
 846
 847 sub sync_userprefs_db {
 848     my ($dbh, $rdb, $ni) = @_;
 849
 850     my $selectfunc = sub {
 851         my ($ctime, $lastmt) = @_;
 852
 853         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 854     };
 855
 856     my $merge_sth = $dbh->prepare(
 857         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 858         'VALUES (?, ?, ?, ?) ' .
 859         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 860         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 861         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 862         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 863
 864     my $mergefunc = sub {
 865         my ($ref) = @_;
 866
 867         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 868     };
 869
 870     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 871 }
 872
 873 sub sync_domainstat_db {
 874     my ($dbh, $rdb, $ni) = @_;
 875
 876     my $selectfunc = sub {
 877         my ($ctime, $lastmt) = @_;
 878         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 879     };
 880
 881     my $merge_sth = $dbh->prepare(
 882         'INSERT INTO Domainstat ' .
 883         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 884         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 885         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 886         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 887         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 888         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 889         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 890         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 891         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 892         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 893
 894     my $mergefunc = sub {
 895         my ($ref) = @_;
 896
 897         $merge_sth->execute(
 898             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 899             $ref->{bytesin}, $ref->{bytesout},
 900             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 901             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 902     };
 903
 904     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 905 }
 906
 907 sub sync_dailystat_db {
 908     my ($dbh, $rdb, $ni) = @_;
 909
 910     my $selectfunc = sub {
 911         my ($ctime, $lastmt) = @_;
 912         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 913     };
 914
 915     my $merge_sth = $dbh->prepare(
 916         'INSERT INTO DailyStat ' .
 917         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 918         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 919         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 920         'ON CONFLICT (Time) DO UPDATE SET ' .
 921         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 922         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 923         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 924         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 925         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 926         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 927         'RBLCount = excluded.RBLCount, ' .
 928         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 929
 930     my $mergefunc = sub {
 931         my ($ref) = @_;
 932
 933         $merge_sth->execute(
 934             $ref->{time}, $ref->{countin}, $ref->{countout},
 935             $ref->{bytesin}, $ref->{bytesout},
 936             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 937             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 938             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 939     };
 940
 941     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 942 }
 943
 944 sub sync_virusinfo_db {
 945     my ($dbh, $rdb, $ni) = @_;
 946
 947     my $selectfunc = sub {
 948         my ($ctime, $lastmt) = @_;
 949         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 950     };
 951
 952     my $merge_sth = $dbh->prepare(
 953         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 954         'VALUES (?,?,?,?) ' .
 955         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 956         'Count = excluded.Count , MTime = excluded.MTime');
 957
 958     my $mergefunc = sub {
 959         my ($ref) = @_;
 960
 961         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 962     };
 963
 964     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 965 }
 966
 967 sub sync_deleted_nodes_from_master {
 968     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 969
 970     my $rsynctime = 0;
 971
 972     my $cid_hash = {}; # fast lookup
 973     foreach my $ni (values %{$cinfo->{ids}}) {
 974         $cid_hash->{$ni->{cid}} = $ni;
 975     }
 976
 977     my $spooldir = $PMG::MailQueue::spooldir;
 978
 979     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 980
 981     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 982         next if $cid_hash->{$rcid};
 983
 984         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 985
 986         next if -f $done_marker; # already synced
 987
 988         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 989
 990         my $starttime = [ gettimeofday() ];
 991         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 992         $$rsynctime_ref += tv_interval($starttime);
 993
 994         my $fake_ni = {
 995             ip => $masterni->{ip},
 996             name => $masterni->{name},
 997             cid => $rcid,
 998         };
 999
1000         sync_quarantine_db($ldb, $masterdb, $fake_ni);
1001
1002         sync_statistic_db ($ldb, $masterdb, $fake_ni);
1003
1004         open(my $fh, ">>",  $done_marker);
1005    }
1006 }
1007
1008
1009 1;