src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14 use PVE::Network;
  15
  16 use PMG::Utils;
  17 use PMG::Config;
  18 use PMG::ClusterConfig;
  19 use PMG::RuleDB;
  20 use PMG::RuleCache;
  21 use PMG::MailQueue;
  22 use PMG::Fetchmail;
  23
  24 sub remote_node_ip {
  25     my ($nodename, $noerr) = @_;
  26
  27     my $cinfo = PMG::ClusterConfig->new();
  28
  29     foreach my $entry (values %{$cinfo->{ids}}) {
  30         if ($entry->{name} eq $nodename) {
  31             my $ip = $entry->{ip};
  32             return $ip if !wantarray;
  33             my $family = PVE::Tools::get_host_address_family($ip);
  34             return ($ip, $family);
  35         }
  36     }
  37
  38     # fallback: try to get IP by other means
  39     return PVE::Network::get_ip_from_hostname($nodename, $noerr);
  40 }
  41
  42 sub get_master_node {
  43     my ($cinfo) = @_;
  44
  45     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  46
  47     return $cinfo->{master}->{name} if defined($cinfo->{master});
  48
  49     return 'localhost';
  50 }
  51
  52 sub read_local_ssl_cert_fingerprint {
  53     my $cert_path = "/etc/pmg/pmg-api.pem";
  54
  55     my $cert;
  56     eval {
  57         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  58         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  59         Net::SSLeay::BIO_free($bio);
  60     };
  61     if (my $err = $@) {
  62         die "unable to read certificate '$cert_path' - $err\n";
  63     }
  64
  65     if (!defined($cert)) {
  66         die "unable to read certificate '$cert_path' - got empty value\n";
  67     }
  68
  69     my $fp;
  70     eval {
  71         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  72     };
  73     if (my $err = $@) {
  74         die "unable to get fingerprint for '$cert_path' - $err\n";
  75     }
  76
  77     if (!defined($fp) || $fp eq '') {
  78         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  79     }
  80
  81     return $fp;
  82 }
  83
  84 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  85 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  86 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  87
  88 sub read_local_cluster_info {
  89
  90     my $res = {};
  91
  92     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  93     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  94     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
  95
  96     die "unable to parse ${hostrsapubkey_fn}\n"
  97         if $hostrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
  98
  99     my $nodename = PVE::INotify::nodename();
 100
 101     $res->{name} = $nodename;
 102
 103     $res->{ip} = PVE::Network::get_ip_from_hostname($nodename);
 104
 105     $res->{hostrsapubkey} = $hostrsapubkey;
 106
 107     if (! -f $rootrsapubkey_fn) {
 108         unlink $rootrsakey_fn;
 109         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 110                    '-f', $rootrsakey_fn];
 111         PMG::Utils::run_silent_cmd($cmd);
 112     }
 113
 114     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 115     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 116     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 117
 118     die "unable to parse ${rootrsapubkey_fn}\n"
 119         if $rootrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
 120
 121     $res->{rootrsapubkey} = $rootrsapubkey;
 122
 123     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 124
 125     return $res;
 126 }
 127
 128 # X509 Certificate cache helper
 129
 130 my $cert_cache_nodes = {};
 131 my $cert_cache_timestamp = time();
 132 my $cert_cache_fingerprints = {};
 133
 134 sub update_cert_cache {
 135
 136     $cert_cache_timestamp = time();
 137
 138     $cert_cache_fingerprints = {};
 139     $cert_cache_nodes = {};
 140
 141     my $cinfo = PMG::ClusterConfig->new();
 142
 143     foreach my $entry (values %{$cinfo->{ids}}) {
 144         my $node = $entry->{name};
 145         my $fp = $entry->{fingerprint};
 146         if ($node && $fp) {
 147             $cert_cache_fingerprints->{$fp} = 1;
 148             $cert_cache_nodes->{$node} = $fp;
 149         }
 150     }
 151 }
 152
 153 # load and cache cert fingerprint once
 154 sub initialize_cert_cache {
 155     my ($node) = @_;
 156
 157     update_cert_cache()
 158         if defined($node) && !defined($cert_cache_nodes->{$node});
 159 }
 160
 161 sub check_cert_fingerprint {
 162     my ($cert) = @_;
 163
 164     # clear cache every 30 minutes at least
 165     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 166
 167     # get fingerprint of server certificate
 168     my $fp;
 169     eval {
 170         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 171     };
 172     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 173
 174     my $check = sub {
 175         for my $expected (keys %$cert_cache_fingerprints) {
 176             return 1 if $fp eq $expected;
 177         }
 178         return 0;
 179     };
 180
 181     return 1 if $check->();
 182
 183     # clear cache and retry at most once every minute
 184     if (time() - $cert_cache_timestamp >= 60) {
 185         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 186         update_cert_cache();
 187         return $check->();
 188     }
 189
 190     return 0;
 191 }
 192
 193 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 194 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 195 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 196
 197 sub update_ssh_keys {
 198     my ($cinfo) = @_;
 199
 200     my $old = '';
 201     my $data = '';
 202
 203     foreach my $node (values %{$cinfo->{ids}}) {
 204         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 205         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 206     }
 207
 208     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 209         if -f $sshglobalknownhosts;
 210
 211     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 212         if $old ne $data;
 213
 214     $data = '';
 215     $old = '';
 216
 217     # always add ourself
 218     if (-f $ssh_rsa_id) {
 219         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 220         chomp($pub);
 221         $data .= "$pub\n";
 222     }
 223
 224     foreach my $node (values %{$cinfo->{ids}}) {
 225         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 226     }
 227
 228     if (-f $rootsshauthkeys) {
 229         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 230         chomp($mykey);
 231         $data .= "$mykey\n";
 232     }
 233
 234     my $newdata = "";
 235     my $vhash = {};
 236     my @lines = split(/\n/, $data);
 237     foreach my $line (@lines) {
 238         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 239             next if $vhash->{$3}++;
 240         }
 241         $newdata .= "$line\n";
 242     }
 243
 244     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 245         if -f $rootsshauthkeys;
 246
 247     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 248         if $old ne $newdata;
 249 }
 250
 251 my $cfgdir = '/etc/pmg';
 252 my $syncdir = "$cfgdir/master";
 253
 254 my $cond_commit_synced_file = sub {
 255     my ($filename, $dstfn) = @_;
 256
 257     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 258     my $srcfn = "$syncdir/$filename";
 259
 260     if (! -f $srcfn) {
 261         unlink $dstfn;
 262         return;
 263     }
 264
 265     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 266
 267     if (-f $dstfn) {
 268         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 269         return 0 if $new eq $old;
 270     }
 271
 272     # set mtime (touch) to avoid time drift problems
 273     utime(undef, undef, $srcfn);
 274
 275     rename($srcfn, $dstfn) ||
 276         die "cond_rename_file '$filename' failed - $!\n";
 277
 278     print STDERR "updated $dstfn\n";
 279
 280     return 1;
 281 };
 282
 283 my $rsync_command = sub {
 284     my ($host_key_alias, @args) = @_;
 285
 286     my $ssh_cmd = '--rsh=ssh -l root -o BatchMode=yes';
 287     $ssh_cmd .=  " -o HostKeyAlias=${host_key_alias}" if $host_key_alias;
 288
 289     my $cmd = ['rsync', $ssh_cmd,  '-q', @args];
 290
 291     return $cmd;
 292 };
 293
 294 sub sync_quarantine_files {
 295     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 296
 297     my $spooldir = $PMG::MailQueue::spooldir;
 298
 299     mkdir "$spooldir/cluster/";
 300     my $syncdir = "$spooldir/cluster/$rcid";
 301     mkdir $syncdir;
 302
 303     my $cmd = $rsync_command->(
 304         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 305         '--files-from', $flistname);
 306
 307     PVE::Tools::run_command($cmd);
 308 }
 309
 310 sub sync_spooldir {
 311     my ($host_ip, $host_name, $rcid) = @_;
 312
 313     my $spooldir = $PMG::MailQueue::spooldir;
 314
 315     mkdir "$spooldir/cluster/";
 316     my $syncdir = "$spooldir/cluster/$rcid";
 317     mkdir $syncdir;
 318
 319     my $cmd = $rsync_command->(
 320         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 321
 322     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 323         push @$cmd, '--include', $incl;
 324     }
 325
 326     push @$cmd, '--exclude', '*';
 327
 328     PVE::Tools::run_command($cmd);
 329 }
 330
 331 sub sync_master_quar {
 332     my ($host_ip, $host_name) = @_;
 333
 334     my $spooldir = $PMG::MailQueue::spooldir;
 335
 336     my $syncdir = "$spooldir/cluster/";
 337     mkdir $syncdir;
 338
 339     my $cmd = $rsync_command->(
 340         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 341
 342     PVE::Tools::run_command($cmd);
 343 }
 344
 345 sub sync_config_from_master {
 346     my ($master_name, $master_ip, $noreload) = @_;
 347
 348     mkdir $syncdir;
 349     File::Path::remove_tree($syncdir, {keep_root => 1});
 350
 351     my $sa_conf_dir = "/etc/mail/spamassassin";
 352     my $sa_custom_cf = "custom.cf";
 353     my $sa_rules_cf = "pmg-scores.cf";
 354
 355     my $cmd = $rsync_command->(
 356         $master_name, '-aq',
 357         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf} ${sa_conf_dir}/${sa_rules_cf}",
 358         "$syncdir/",
 359         '--exclude', 'master/',
 360         '--exclude', '*~',
 361         '--exclude', '*.db',
 362         '--exclude', 'pmg-api.pem',
 363         '--exclude', 'pmg-tls.pem',
 364         );
 365
 366     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 367     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 368
 369     # verify that the remote host is cluster master
 370     open (my $fh, '<', "$syncdir/cluster.conf") ||
 371         die "unable to open synced cluster.conf - $!\n";
 372
 373     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 374
 375     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 376         die "host '$master_ip' is not cluster master\n";
 377     }
 378
 379     my $role = $cinfo->{'local'}->{type} // '-';
 380     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 381         if $role eq '-';
 382
 383     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 384         if $role eq 'master';
 385
 386     $cond_commit_synced_file->('cluster.conf');
 387
 388     update_ssh_keys($cinfo); # rewrite ssh keys
 389
 390     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 391
 392     my $files = [
 393         'pmg-authkey.key',
 394         'pmg-authkey.pub',
 395         'pmg-csrf.key',
 396         'ldap.conf',
 397         'user.conf',
 398         'domains',
 399         'mynetworks',
 400         'transport',
 401         'tls_policy',
 402         'fetchmailrc',
 403         ];
 404
 405     foreach my $filename (@$files) {
 406         $cond_commit_synced_file->($filename);
 407     }
 408
 409     my $dirs = [
 410         'templates',
 411         'dkim',
 412     ];
 413
 414     foreach my $dir (@$dirs) {
 415         my $srcdir = "$syncdir/$dir";
 416
 417         if ( -d $srcdir ) {
 418             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 419             PVE::Tools::run_command($cmd);
 420         }
 421
 422     }
 423
 424     my $force_restart = {};
 425
 426     for my $file (($sa_custom_cf, $sa_rules_cf)) {
 427         if ($cond_commit_synced_file->($file, "${sa_conf_dir}/${file}")) {
 428             $force_restart->{'pmg-smtp-filter'} = 1;
 429         }
 430     }
 431
 432     $cond_commit_synced_file->('pmg.conf');
 433
 434     return $force_restart;
 435 }
 436
 437 sub sync_ruledb_from_master {
 438     my ($ldb, $rdb, $ni, $ticket) = @_;
 439
 440     my $ruledb = PMG::RuleDB->new($ldb);
 441     my $rulecache = PMG::RuleCache->new($ruledb);
 442
 443     my $conn = PVE::APIClient::LWP->new(
 444         ticket => $ticket,
 445         cookie_name => 'PMGAuthCookie',
 446         host => $ni->{ip},
 447         cached_fingerprints => {
 448             $ni->{fingerprint} => 1,
 449         });
 450
 451     my $digest = $conn->get("/config/ruledb/digest", {});
 452
 453     return if $digest eq $rulecache->{digest}; # no changes
 454
 455     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 456
 457     eval {
 458         $ldb->begin_work;
 459
 460         $ldb->do("DELETE FROM Rule");
 461         $ldb->do("DELETE FROM RuleGroup");
 462         $ldb->do("DELETE FROM ObjectGroup");
 463         $ldb->do("DELETE FROM Object");
 464         $ldb->do("DELETE FROM Attribut");
 465
 466         eval {
 467             $rdb->begin_work;
 468
 469             # read a consistent snapshot
 470             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 471
 472             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 473             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 474             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 475             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 476             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 477         };
 478
 479         $rdb->rollback; # end transaction
 480
 481         die $@ if $@;
 482
 483         # update sequences
 484
 485         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 486         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 487         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 488
 489         $ldb->commit;
 490     };
 491     if (my $err = $@) {
 492         $ldb->rollback;
 493         die $err;
 494     }
 495
 496     PMG::DBTools::reload_ruledb();
 497
 498     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 499 }
 500
 501 sub sync_quarantine_db {
 502     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 503
 504     my $rcid = $ni->{cid};
 505
 506     my $maxmails = 100000;
 507
 508     my $mscount = 0;
 509
 510     my $ctime = PMG::DBTools::get_remote_time($rdb);
 511
 512     my $maxcount = 1000;
 513
 514     my $count;
 515
 516     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 517
 518     do { # get new values
 519
 520         $count = 0;
 521
 522         my $flistname = "/tmp/quarantinefilelist.$$";
 523
 524         eval {
 525             $ldb->begin_work;
 526
 527             open(my $flistfh, '>', $flistname) ||
 528                 die "unable to open file '$flistname' - $!\n";
 529
 530             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 531
 532             # sync CMailStore
 533
 534             my $sth = $rdb->prepare(
 535                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 536                 "ORDER BY cid,rid LIMIT ?");
 537             $sth->execute($rcid, $lastid, $maxcount);
 538
 539             my $maxid;
 540             my $callback = sub {
 541                 my $ref = shift;
 542                 $maxid = $ref->{rid};
 543                 my $filename = $ref->{file};
 544                  # skip files generated before cluster was created
 545                 return if $filename !~ m!^cluster/!;
 546                 print $flistfh "$filename\n";
 547             };
 548
 549             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 550             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 551
 552             close($flistfh);
 553
 554             my $starttime = [ gettimeofday() ];
 555             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 556             $$rsynctime_ref += tv_interval($starttime);
 557
 558             if ($maxid) {
 559                 # sync CMSReceivers
 560
 561                 $sth = $rdb->prepare(
 562                     "SELECT * from CMSReceivers WHERE " .
 563                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 564                     "AND CMailStore_RID <= ?");
 565                 $sth->execute($rcid, $lastid, $maxid);
 566
 567                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 568                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 569
 570                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 571             }
 572
 573             $ldb->commit;
 574         };
 575         my $err = $@;
 576
 577         unlink $flistname;
 578
 579         if ($err) {
 580             $ldb->rollback;
 581             die $err;
 582         }
 583
 584         $mscount += $count;
 585
 586     } while (($count >= $maxcount) && ($mscount < $maxmails));
 587
 588     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 589
 590     eval { # synchronize status updates
 591         $ldb->begin_work;
 592
 593         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 594
 595         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 596         $sth->execute($lastmt);
 597
 598         my $update_sth = $ldb->prepare(
 599             "UPDATE CMSReceivers SET status = ? WHERE " .
 600             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 601         while (my $ref = $sth->fetchrow_hashref()) {
 602             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 603                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 604         }
 605
 606         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 607
 608         $ldb->commit;
 609     };
 610     if (my $err = $@) {
 611         $ldb->rollback;
 612         die $err;
 613     }
 614
 615     return $mscount;
 616 }
 617
 618 sub sync_statistic_db {
 619     my ($ldb, $rdb, $ni) = @_;
 620
 621     my $rcid = $ni->{cid};
 622
 623     my $maxmails = 100000;
 624
 625     my $mscount = 0;
 626
 627     my $maxcount = 1000;
 628
 629     my $count;
 630
 631     PMG::DBTools::create_clusterinfo_default(
 632         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 633
 634     do { # get new values
 635
 636         $count = 0;
 637
 638         eval {
 639             $ldb->begin_work;
 640
 641             my $lastid = PMG::DBTools::read_int_clusterinfo(
 642                 $ldb, $rcid, 'lastid_CStatistic');
 643
 644             # sync CStatistic
 645
 646             my $sth = $rdb->prepare(
 647                 "SELECT * from CStatistic " .
 648                 "WHERE cid = ? AND rid > ? " .
 649                 "ORDER BY cid, rid LIMIT ?");
 650             $sth->execute($rcid, $lastid, $maxcount);
 651
 652             my $maxid;
 653             my $callback = sub {
 654                 my $ref = shift;
 655                 $maxid = $ref->{rid};
 656             };
 657
 658             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 659             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 660
 661             if ($maxid) {
 662                 # sync CReceivers
 663
 664                 $sth = $rdb->prepare(
 665                     "SELECT * from CReceivers WHERE " .
 666                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 667                 $sth->execute($rcid, $lastid, $maxid);
 668
 669                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 670                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 671             }
 672
 673             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 674
 675             $ldb->commit;
 676         };
 677         if (my $err = $@) {
 678             $ldb->rollback;
 679             die $err;
 680         }
 681
 682         $mscount += $count;
 683
 684     } while (($count >= $maxcount) && ($mscount < $maxmails));
 685
 686     return $mscount;
 687 }
 688
 689 my $sync_generic_mtime_db = sub {
 690     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 691
 692     my $ctime = PMG::DBTools::get_remote_time($rdb);
 693
 694     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 695
 696     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 697
 698     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 699
 700     my $sth = $rdb->prepare($sql_cmd);
 701
 702     $sth->execute();
 703
 704     my $updates = 0;
 705
 706     eval {
 707         # use transaction to speedup things
 708         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 709         my $count = 0;
 710         while (my $ref = $sth->fetchrow_hashref()) {
 711             $ldb->begin_work if !$count;
 712             $mergefunc->($ref);
 713             if (++$count >= $max) {
 714                 $count = 0;
 715                 $ldb->commit;
 716             }
 717             $updates++;
 718         }
 719
 720         $ldb->commit if $count;
 721     };
 722     if (my $err = $@) {
 723         $ldb->rollback;
 724         die $err;
 725     }
 726
 727     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 728
 729     return $updates;
 730 };
 731
 732 sub sync_localstat_db {
 733     my ($dbh, $rdb, $ni) = @_;
 734
 735     my $rcid = $ni->{cid};
 736
 737     my $selectfunc = sub {
 738         my ($ctime, $lastmt) = @_;
 739         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 740     };
 741
 742     my $merge_sth = $dbh->prepare(
 743         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 744         'VALUES (?, ?, ?, ?, ?) ' .
 745         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 746         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 747
 748     my $mergefunc = sub {
 749         my ($ref) = @_;
 750
 751         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 752     };
 753
 754     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 755 }
 756
 757 sub sync_greylist_db {
 758     my ($dbh, $rdb, $ni) = @_;
 759
 760     my $selectfunc = sub {
 761         my ($ctime, $lastmt) = @_;
 762         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 763             "mtime >= $lastmt AND CID != 0";
 764     };
 765
 766     # FIXME: drop Host column with PMG 7.0
 767     my $merge_sth = $dbh->prepare(PMG::DBTools::cgreylist_merge_sql());
 768     my $mergefunc = sub {
 769         my ($ref) = @_;
 770
 771         my $ipnet = $ref->{ipnet};
 772         $ipnet .= '.0/24' if $ipnet !~ /\/\d+$/;
 773         $merge_sth->execute(
 774             $ipnet, 0, $ref->{sender}, $ref->{receiver},
 775             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 776             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 777     };
 778
 779     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 780 }
 781
 782 sub sync_userprefs_db {
 783     my ($dbh, $rdb, $ni) = @_;
 784
 785     my $selectfunc = sub {
 786         my ($ctime, $lastmt) = @_;
 787
 788         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 789     };
 790
 791     my $merge_sth = $dbh->prepare(
 792         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 793         'VALUES (?, ?, ?, ?) ' .
 794         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 795         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 796         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 797         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 798
 799     my $mergefunc = sub {
 800         my ($ref) = @_;
 801
 802         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 803     };
 804
 805     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 806 }
 807
 808 sub sync_domainstat_db {
 809     my ($dbh, $rdb, $ni) = @_;
 810
 811     my $selectfunc = sub {
 812         my ($ctime, $lastmt) = @_;
 813         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 814     };
 815
 816     my $merge_sth = $dbh->prepare(
 817         'INSERT INTO Domainstat ' .
 818         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 819         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 820         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 821         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 822         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 823         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 824         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 825         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 826         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 827         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 828
 829     my $mergefunc = sub {
 830         my ($ref) = @_;
 831
 832         $merge_sth->execute(
 833             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 834             $ref->{bytesin}, $ref->{bytesout},
 835             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 836             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 837     };
 838
 839     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 840 }
 841
 842 sub sync_dailystat_db {
 843     my ($dbh, $rdb, $ni) = @_;
 844
 845     my $selectfunc = sub {
 846         my ($ctime, $lastmt) = @_;
 847         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 848     };
 849
 850     my $merge_sth = $dbh->prepare(
 851         'INSERT INTO DailyStat ' .
 852         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 853         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 854         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 855         'ON CONFLICT (Time) DO UPDATE SET ' .
 856         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 857         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 858         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 859         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 860         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 861         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 862         'RBLCount = excluded.RBLCount, ' .
 863         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 864
 865     my $mergefunc = sub {
 866         my ($ref) = @_;
 867
 868         $merge_sth->execute(
 869             $ref->{time}, $ref->{countin}, $ref->{countout},
 870             $ref->{bytesin}, $ref->{bytesout},
 871             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 872             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 873             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 874     };
 875
 876     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 877 }
 878
 879 sub sync_virusinfo_db {
 880     my ($dbh, $rdb, $ni) = @_;
 881
 882     my $selectfunc = sub {
 883         my ($ctime, $lastmt) = @_;
 884         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 885     };
 886
 887     my $merge_sth = $dbh->prepare(
 888         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 889         'VALUES (?,?,?,?) ' .
 890         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 891         'Count = excluded.Count , MTime = excluded.MTime');
 892
 893     my $mergefunc = sub {
 894         my ($ref) = @_;
 895
 896         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 897     };
 898
 899     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 900 }
 901
 902 sub sync_deleted_nodes_from_master {
 903     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 904
 905     my $rsynctime = 0;
 906
 907     my $cid_hash = {}; # fast lookup
 908     foreach my $ni (values %{$cinfo->{ids}}) {
 909         $cid_hash->{$ni->{cid}} = $ni;
 910     }
 911
 912     my $spooldir = $PMG::MailQueue::spooldir;
 913
 914     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 915
 916     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 917         next if $cid_hash->{$rcid};
 918
 919         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 920
 921         next if -f $done_marker; # already synced
 922
 923         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 924
 925         my $starttime = [ gettimeofday() ];
 926         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 927         $$rsynctime_ref += tv_interval($starttime);
 928
 929         my $fake_ni = {
 930             ip => $masterni->{ip},
 931             name => $masterni->{name},
 932             cid => $rcid,
 933         };
 934
 935         sync_quarantine_db($ldb, $masterdb, $fake_ni);
 936
 937         sync_statistic_db ($ldb, $masterdb, $fake_ni);
 938
 939         open(my $fh, ">>",  $done_marker);
 940    }
 941 }
 942
 943
 944 1;