src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14
  15 use PMG::Utils;
  16 use PMG::Config;
  17 use PMG::ClusterConfig;
  18 use PMG::RuleDB;
  19 use PMG::RuleCache;
  20 use PMG::MailQueue;
  21 use PMG::Fetchmail;
  22
  23 sub remote_node_ip {
  24     my ($nodename, $noerr) = @_;
  25
  26     my $cinfo = PMG::ClusterConfig->new();
  27
  28     foreach my $entry (values %{$cinfo->{ids}}) {
  29         if ($entry->{name} eq $nodename) {
  30             my $ip = $entry->{ip};
  31             return $ip if !wantarray;
  32             my $family = PVE::Tools::get_host_address_family($ip);
  33             return ($ip, $family);
  34         }
  35     }
  36
  37     # fallback: try to get IP by other means
  38     return PMG::Utils::lookup_node_ip($nodename, $noerr);
  39 }
  40
  41 sub get_master_node {
  42     my ($cinfo) = @_;
  43
  44     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  45
  46     return $cinfo->{master}->{name} if defined($cinfo->{master});
  47
  48     return 'localhost';
  49 }
  50
  51 sub read_local_ssl_cert_fingerprint {
  52     my $cert_path = "/etc/pmg/pmg-api.pem";
  53
  54     my $cert;
  55     eval {
  56         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  57         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  58         Net::SSLeay::BIO_free($bio);
  59     };
  60     if (my $err = $@) {
  61         die "unable to read certificate '$cert_path' - $err\n";
  62     }
  63
  64     if (!defined($cert)) {
  65         die "unable to read certificate '$cert_path' - got empty value\n";
  66     }
  67
  68     my $fp;
  69     eval {
  70         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  71     };
  72     if (my $err = $@) {
  73         die "unable to get fingerprint for '$cert_path' - $err\n";
  74     }
  75
  76     if (!defined($fp) || $fp eq '') {
  77         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  78     }
  79
  80     return $fp;
  81 }
  82
  83 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  84 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  85 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  86
  87 sub read_local_cluster_info {
  88
  89     my $res = {};
  90
  91     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  92     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  93     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
  94
  95     die "unable to parse ${hostrsapubkey_fn}\n"
  96         if $hostrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
  97
  98     my $nodename = PVE::INotify::nodename();
  99
 100     $res->{name} = $nodename;
 101
 102     $res->{ip} = PMG::Utils::lookup_node_ip($nodename);
 103
 104     $res->{hostrsapubkey} = $hostrsapubkey;
 105
 106     if (! -f $rootrsapubkey_fn) {
 107         unlink $rootrsakey_fn;
 108         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 109                    '-f', $rootrsakey_fn];
 110         PMG::Utils::run_silent_cmd($cmd);
 111     }
 112
 113     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 114     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 115     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 116
 117     die "unable to parse ${rootrsapubkey_fn}\n"
 118         if $rootrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
 119
 120     $res->{rootrsapubkey} = $rootrsapubkey;
 121
 122     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 123
 124     return $res;
 125 }
 126
 127 # X509 Certificate cache helper
 128
 129 my $cert_cache_nodes = {};
 130 my $cert_cache_timestamp = time();
 131 my $cert_cache_fingerprints = {};
 132
 133 sub update_cert_cache {
 134
 135     $cert_cache_timestamp = time();
 136
 137     $cert_cache_fingerprints = {};
 138     $cert_cache_nodes = {};
 139
 140     my $cinfo = PMG::ClusterConfig->new();
 141
 142     foreach my $entry (values %{$cinfo->{ids}}) {
 143         my $node = $entry->{name};
 144         my $fp = $entry->{fingerprint};
 145         if ($node && $fp) {
 146             $cert_cache_fingerprints->{$fp} = 1;
 147             $cert_cache_nodes->{$node} = $fp;
 148         }
 149     }
 150 }
 151
 152 # load and cache cert fingerprint once
 153 sub initialize_cert_cache {
 154     my ($node) = @_;
 155
 156     update_cert_cache()
 157         if defined($node) && !defined($cert_cache_nodes->{$node});
 158 }
 159
 160 sub check_cert_fingerprint {
 161     my ($cert) = @_;
 162
 163     # clear cache every 30 minutes at least
 164     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 165
 166     # get fingerprint of server certificate
 167     my $fp;
 168     eval {
 169         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 170     };
 171     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 172
 173     my $check = sub {
 174         for my $expected (keys %$cert_cache_fingerprints) {
 175             return 1 if $fp eq $expected;
 176         }
 177         return 0;
 178     };
 179
 180     return 1 if $check->();
 181
 182     # clear cache and retry at most once every minute
 183     if (time() - $cert_cache_timestamp >= 60) {
 184         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 185         update_cert_cache();
 186         return $check->();
 187     }
 188
 189     return 0;
 190 }
 191
 192 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 193 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 194 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 195
 196 sub update_ssh_keys {
 197     my ($cinfo) = @_;
 198
 199     my $old = '';
 200     my $data = '';
 201
 202     foreach my $node (values %{$cinfo->{ids}}) {
 203         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 204         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 205     }
 206
 207     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 208         if -f $sshglobalknownhosts;
 209
 210     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 211         if $old ne $data;
 212
 213     $data = '';
 214     $old = '';
 215
 216     # always add ourself
 217     if (-f $ssh_rsa_id) {
 218         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 219         chomp($pub);
 220         $data .= "$pub\n";
 221     }
 222
 223     foreach my $node (values %{$cinfo->{ids}}) {
 224         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 225     }
 226
 227     if (-f $rootsshauthkeys) {
 228         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 229         chomp($mykey);
 230         $data .= "$mykey\n";
 231     }
 232
 233     my $newdata = "";
 234     my $vhash = {};
 235     my @lines = split(/\n/, $data);
 236     foreach my $line (@lines) {
 237         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 238             next if $vhash->{$3}++;
 239         }
 240         $newdata .= "$line\n";
 241     }
 242
 243     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 244         if -f $rootsshauthkeys;
 245
 246     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 247         if $old ne $newdata;
 248 }
 249
 250 my $cfgdir = '/etc/pmg';
 251 my $syncdir = "$cfgdir/master";
 252
 253 my $cond_commit_synced_file = sub {
 254     my ($filename, $dstfn) = @_;
 255
 256     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 257     my $srcfn = "$syncdir/$filename";
 258
 259     if (! -f $srcfn) {
 260         unlink $dstfn;
 261         return;
 262     }
 263
 264     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 265
 266     if (-f $dstfn) {
 267         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 268         return 0 if $new eq $old;
 269     }
 270
 271     # set mtime (touch) to avoid time drift problems
 272     utime(undef, undef, $srcfn);
 273
 274     rename($srcfn, $dstfn) ||
 275         die "cond_rename_file '$filename' failed - $!\n";
 276
 277     print STDERR "updated $dstfn\n";
 278
 279     return 1;
 280 };
 281
 282 my $rsync_command = sub {
 283     my ($host_key_alias, @args) = @_;
 284
 285     my $ssh_cmd = '--rsh=ssh -l root -o BatchMode=yes';
 286     $ssh_cmd .=  " -o HostKeyAlias=${host_key_alias}" if $host_key_alias;
 287
 288     my $cmd = ['rsync', $ssh_cmd,  '-q', @args];
 289
 290     return $cmd;
 291 };
 292
 293 sub sync_quarantine_files {
 294     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 295
 296     my $spooldir = $PMG::MailQueue::spooldir;
 297
 298     mkdir "$spooldir/cluster/";
 299     my $syncdir = "$spooldir/cluster/$rcid";
 300     mkdir $syncdir;
 301
 302     my $cmd = $rsync_command->(
 303         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 304         '--files-from', $flistname);
 305
 306     PVE::Tools::run_command($cmd);
 307 }
 308
 309 sub sync_spooldir {
 310     my ($host_ip, $host_name, $rcid) = @_;
 311
 312     my $spooldir = $PMG::MailQueue::spooldir;
 313
 314     mkdir "$spooldir/cluster/";
 315     my $syncdir = "$spooldir/cluster/$rcid";
 316     mkdir $syncdir;
 317
 318     my $cmd = $rsync_command->(
 319         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 320
 321     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 322         push @$cmd, '--include', $incl;
 323     }
 324
 325     push @$cmd, '--exclude', '*';
 326
 327     PVE::Tools::run_command($cmd);
 328 }
 329
 330 sub sync_master_quar {
 331     my ($host_ip, $host_name) = @_;
 332
 333     my $spooldir = $PMG::MailQueue::spooldir;
 334
 335     my $syncdir = "$spooldir/cluster/";
 336     mkdir $syncdir;
 337
 338     my $cmd = $rsync_command->(
 339         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 340
 341     PVE::Tools::run_command($cmd);
 342 }
 343
 344 sub sync_config_from_master {
 345     my ($master_name, $master_ip, $noreload) = @_;
 346
 347     mkdir $syncdir;
 348     File::Path::remove_tree($syncdir, {keep_root => 1});
 349
 350     my $sa_conf_dir = "/etc/mail/spamassassin";
 351     my $sa_custom_cf = "custom.cf";
 352
 353     my $cmd = $rsync_command->(
 354         $master_name, '-aq',
 355         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf}",
 356         "$syncdir/",
 357         '--exclude', 'master/',
 358         '--exclude', '*~',
 359         '--exclude', '*.db',
 360         '--exclude', 'pmg-api.pem',
 361         '--exclude', 'pmg-tls.pem',
 362         );
 363
 364     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 365     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 366
 367     # verify that the remote host is cluster master
 368     open (my $fh, '<', "$syncdir/cluster.conf") ||
 369         die "unable to open synced cluster.conf - $!\n";
 370
 371     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 372
 373     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 374         die "host '$master_ip' is not cluster master\n";
 375     }
 376
 377     my $role = $cinfo->{'local'}->{type} // '-';
 378     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 379         if $role eq '-';
 380
 381     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 382         if $role eq 'master';
 383
 384     $cond_commit_synced_file->('cluster.conf');
 385
 386     update_ssh_keys($cinfo); # rewrite ssh keys
 387
 388     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 389
 390     my $files = [
 391         'pmg-authkey.key',
 392         'pmg-authkey.pub',
 393         'pmg-csrf.key',
 394         'ldap.conf',
 395         'user.conf',
 396         'domains',
 397         'mynetworks',
 398         'transport',
 399         'tls_policy',
 400         'fetchmailrc',
 401         ];
 402
 403     foreach my $filename (@$files) {
 404         $cond_commit_synced_file->($filename);
 405     }
 406
 407     my $dirs = [
 408         'templates',
 409         'dkim',
 410     ];
 411
 412     foreach my $dir (@$dirs) {
 413         my $srcdir = "$syncdir/$dir";
 414
 415         if ( -d $srcdir ) {
 416             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 417             PVE::Tools::run_command($cmd);
 418         }
 419
 420     }
 421
 422     my $force_restart = {};
 423
 424     if ($cond_commit_synced_file->($sa_custom_cf, "${sa_conf_dir}/${sa_custom_cf}")) {
 425         $force_restart->{spam} = 1;
 426     }
 427
 428     $cond_commit_synced_file->('pmg.conf');
 429
 430 }
 431
 432 sub sync_ruledb_from_master {
 433     my ($ldb, $rdb, $ni, $ticket) = @_;
 434
 435     my $ruledb = PMG::RuleDB->new($ldb);
 436     my $rulecache = PMG::RuleCache->new($ruledb);
 437
 438     my $conn = PVE::APIClient::LWP->new(
 439         ticket => $ticket,
 440         cookie_name => 'PMGAuthCookie',
 441         host => $ni->{ip},
 442         cached_fingerprints => {
 443             $ni->{fingerprint} => 1,
 444         });
 445
 446     my $digest = $conn->get("/config/ruledb/digest", {});
 447
 448     return if $digest eq $rulecache->{digest}; # no changes
 449
 450     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 451
 452     eval {
 453         $ldb->begin_work;
 454
 455         $ldb->do("DELETE FROM Rule");
 456         $ldb->do("DELETE FROM RuleGroup");
 457         $ldb->do("DELETE FROM ObjectGroup");
 458         $ldb->do("DELETE FROM Object");
 459         $ldb->do("DELETE FROM Attribut");
 460
 461         eval {
 462             $rdb->begin_work;
 463
 464             # read a consistent snapshot
 465             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 466
 467             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 468             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 469             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 470             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 471             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 472         };
 473
 474         $rdb->rollback; # end transaction
 475
 476         die $@ if $@;
 477
 478         # update sequences
 479
 480         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 481         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 482         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 483
 484         $ldb->commit;
 485     };
 486     if (my $err = $@) {
 487         $ldb->rollback;
 488         die $err;
 489     }
 490
 491     PMG::DBTools::reload_ruledb();
 492
 493     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 494 }
 495
 496 sub sync_quarantine_db {
 497     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 498
 499     my $rcid = $ni->{cid};
 500
 501     my $maxmails = 100000;
 502
 503     my $mscount = 0;
 504
 505     my $ctime = PMG::DBTools::get_remote_time($rdb);
 506
 507     my $maxcount = 1000;
 508
 509     my $count;
 510
 511     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 512
 513     do { # get new values
 514
 515         $count = 0;
 516
 517         my $flistname = "/tmp/quarantinefilelist.$$";
 518
 519         eval {
 520             $ldb->begin_work;
 521
 522             open(my $flistfh, '>', $flistname) ||
 523                 die "unable to open file '$flistname' - $!\n";
 524
 525             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 526
 527             # sync CMailStore
 528
 529             my $sth = $rdb->prepare(
 530                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 531                 "ORDER BY cid,rid LIMIT ?");
 532             $sth->execute($rcid, $lastid, $maxcount);
 533
 534             my $maxid;
 535             my $callback = sub {
 536                 my $ref = shift;
 537                 $maxid = $ref->{rid};
 538                 my $filename = $ref->{file};
 539                  # skip files generated before cluster was created
 540                 return if $filename !~ m!^cluster/!;
 541                 print $flistfh "$filename\n";
 542             };
 543
 544             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 545             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 546
 547             close($flistfh);
 548
 549             my $starttime = [ gettimeofday() ];
 550             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 551             $$rsynctime_ref += tv_interval($starttime);
 552
 553             if ($maxid) {
 554                 # sync CMSReceivers
 555
 556                 $sth = $rdb->prepare(
 557                     "SELECT * from CMSReceivers WHERE " .
 558                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 559                     "AND CMailStore_RID <= ?");
 560                 $sth->execute($rcid, $lastid, $maxid);
 561
 562                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 563                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 564
 565                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 566             }
 567
 568             $ldb->commit;
 569         };
 570         my $err = $@;
 571
 572         unlink $flistname;
 573
 574         if ($err) {
 575             $ldb->rollback;
 576             die $err;
 577         }
 578
 579         $mscount += $count;
 580
 581     } while (($count >= $maxcount) && ($mscount < $maxmails));
 582
 583     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 584
 585     eval { # synchronize status updates
 586         $ldb->begin_work;
 587
 588         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 589
 590         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 591         $sth->execute($lastmt);
 592
 593         my $update_sth = $ldb->prepare(
 594             "UPDATE CMSReceivers SET status = ? WHERE " .
 595             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 596         while (my $ref = $sth->fetchrow_hashref()) {
 597             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 598                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 599         }
 600
 601         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 602
 603         $ldb->commit;
 604     };
 605     if (my $err = $@) {
 606         $ldb->rollback;
 607         die $err;
 608     }
 609
 610     return $mscount;
 611 }
 612
 613 sub sync_statistic_db {
 614     my ($ldb, $rdb, $ni) = @_;
 615
 616     my $rcid = $ni->{cid};
 617
 618     my $maxmails = 100000;
 619
 620     my $mscount = 0;
 621
 622     my $maxcount = 1000;
 623
 624     my $count;
 625
 626     PMG::DBTools::create_clusterinfo_default(
 627         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 628
 629     do { # get new values
 630
 631         $count = 0;
 632
 633         eval {
 634             $ldb->begin_work;
 635
 636             my $lastid = PMG::DBTools::read_int_clusterinfo(
 637                 $ldb, $rcid, 'lastid_CStatistic');
 638
 639             # sync CStatistic
 640
 641             my $sth = $rdb->prepare(
 642                 "SELECT * from CStatistic " .
 643                 "WHERE cid = ? AND rid > ? " .
 644                 "ORDER BY cid, rid LIMIT ?");
 645             $sth->execute($rcid, $lastid, $maxcount);
 646
 647             my $maxid;
 648             my $callback = sub {
 649                 my $ref = shift;
 650                 $maxid = $ref->{rid};
 651             };
 652
 653             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 654             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 655
 656             if ($maxid) {
 657                 # sync CReceivers
 658
 659                 $sth = $rdb->prepare(
 660                     "SELECT * from CReceivers WHERE " .
 661                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 662                 $sth->execute($rcid, $lastid, $maxid);
 663
 664                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 665                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 666             }
 667
 668             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 669
 670             $ldb->commit;
 671         };
 672         if (my $err = $@) {
 673             $ldb->rollback;
 674             die $err;
 675         }
 676
 677         $mscount += $count;
 678
 679     } while (($count >= $maxcount) && ($mscount < $maxmails));
 680
 681     return $mscount;
 682 }
 683
 684 my $sync_generic_mtime_db = sub {
 685     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 686
 687     my $ctime = PMG::DBTools::get_remote_time($rdb);
 688
 689     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 690
 691     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 692
 693     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 694
 695     my $sth = $rdb->prepare($sql_cmd);
 696
 697     $sth->execute();
 698
 699     my $updates = 0;
 700
 701     eval {
 702         # use transaction to speedup things
 703         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 704         my $count = 0;
 705         while (my $ref = $sth->fetchrow_hashref()) {
 706             $ldb->begin_work if !$count;
 707             $mergefunc->($ref);
 708             if (++$count >= $max) {
 709                 $count = 0;
 710                 $ldb->commit;
 711             }
 712             $updates++;
 713         }
 714
 715         $ldb->commit if $count;
 716     };
 717     if (my $err = $@) {
 718         $ldb->rollback;
 719         die $err;
 720     }
 721
 722     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 723
 724     return $updates;
 725 };
 726
 727 sub sync_localstat_db {
 728     my ($dbh, $rdb, $ni) = @_;
 729
 730     my $rcid = $ni->{cid};
 731
 732     my $selectfunc = sub {
 733         my ($ctime, $lastmt) = @_;
 734         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 735     };
 736
 737     my $merge_sth = $dbh->prepare(
 738         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 739         'VALUES (?, ?, ?, ?, ?) ' .
 740         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 741         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 742
 743     my $mergefunc = sub {
 744         my ($ref) = @_;
 745
 746         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 747     };
 748
 749     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 750 }
 751
 752 sub sync_greylist_db {
 753     my ($dbh, $rdb, $ni) = @_;
 754
 755     my $selectfunc = sub {
 756         my ($ctime, $lastmt) = @_;
 757         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 758             "mtime >= $lastmt AND CID != 0";
 759     };
 760
 761     my $merge_sth = $dbh->prepare($PMG::DBTools::cgreylist_merge_sql);
 762     my $mergefunc = sub {
 763         my ($ref) = @_;
 764
 765         $merge_sth->execute(
 766             $ref->{ipnet}, $ref->{host}, $ref->{sender}, $ref->{receiver},
 767             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 768             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 769     };
 770
 771     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 772 }
 773
 774 sub sync_userprefs_db {
 775     my ($dbh, $rdb, $ni) = @_;
 776
 777     my $selectfunc = sub {
 778         my ($ctime, $lastmt) = @_;
 779
 780         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 781     };
 782
 783     my $merge_sth = $dbh->prepare(
 784         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 785         'VALUES (?, ?, ?, ?) ' .
 786         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 787         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 788         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 789         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 790
 791     my $mergefunc = sub {
 792         my ($ref) = @_;
 793
 794         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 795     };
 796
 797     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 798 }
 799
 800 sub sync_domainstat_db {
 801     my ($dbh, $rdb, $ni) = @_;
 802
 803     my $selectfunc = sub {
 804         my ($ctime, $lastmt) = @_;
 805         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 806     };
 807
 808     my $merge_sth = $dbh->prepare(
 809         'INSERT INTO Domainstat ' .
 810         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 811         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 812         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 813         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 814         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 815         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 816         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 817         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 818         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 819         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 820
 821     my $mergefunc = sub {
 822         my ($ref) = @_;
 823
 824         $merge_sth->execute(
 825             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 826             $ref->{bytesin}, $ref->{bytesout},
 827             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 828             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 829     };
 830
 831     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 832 }
 833
 834 sub sync_dailystat_db {
 835     my ($dbh, $rdb, $ni) = @_;
 836
 837     my $selectfunc = sub {
 838         my ($ctime, $lastmt) = @_;
 839         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 840     };
 841
 842     my $merge_sth = $dbh->prepare(
 843         'INSERT INTO DailyStat ' .
 844         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 845         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 846         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 847         'ON CONFLICT (Time) DO UPDATE SET ' .
 848         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 849         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 850         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 851         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 852         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 853         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 854         'RBLCount = excluded.RBLCount, ' .
 855         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 856
 857     my $mergefunc = sub {
 858         my ($ref) = @_;
 859
 860         $merge_sth->execute(
 861             $ref->{time}, $ref->{countin}, $ref->{countout},
 862             $ref->{bytesin}, $ref->{bytesout},
 863             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 864             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 865             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 866     };
 867
 868     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 869 }
 870
 871 sub sync_virusinfo_db {
 872     my ($dbh, $rdb, $ni) = @_;
 873
 874     my $selectfunc = sub {
 875         my ($ctime, $lastmt) = @_;
 876         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 877     };
 878
 879     my $merge_sth = $dbh->prepare(
 880         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 881         'VALUES (?,?,?,?) ' .
 882         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 883         'Count = excluded.Count , MTime = excluded.MTime');
 884
 885     my $mergefunc = sub {
 886         my ($ref) = @_;
 887
 888         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 889     };
 890
 891     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 892 }
 893
 894 sub sync_deleted_nodes_from_master {
 895     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 896
 897     my $rsynctime = 0;
 898
 899     my $cid_hash = {}; # fast lookup
 900     foreach my $ni (values %{$cinfo->{ids}}) {
 901         $cid_hash->{$ni->{cid}} = $ni;
 902     }
 903
 904     my $spooldir = $PMG::MailQueue::spooldir;
 905
 906     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 907
 908     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 909         next if $cid_hash->{$rcid};
 910
 911         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 912
 913         next if -f $done_marker; # already synced
 914
 915         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 916
 917         my $starttime = [ gettimeofday() ];
 918         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 919         $$rsynctime_ref += tv_interval($starttime);
 920
 921         my $fake_ni = {
 922             ip => $masterni->{ip},
 923             name => $masterni->{name},
 924             cid => $rcid,
 925         };
 926
 927         sync_quarantine_db($ldb, $masterdb, $fake_ni);
 928
 929         sync_statistic_db ($ldb, $masterdb, $fake_ni);
 930
 931         open(my $fh, ">>",  $done_marker);
 932    }
 933 }
 934
 935
 936 1;