src/PMG/Cluster.pm

   1 package PMG::Cluster;
   2
   3 use strict;
   4 use warnings;
   5 use Data::Dumper;
   6 use Socket;
   7 use File::Path;
   8 use Time::HiRes qw (gettimeofday tv_interval);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::INotify;
  13 use PVE::APIClient::LWP;
  14 use PVE::Network;
  15
  16 use PMG::Utils;
  17 use PMG::Config;
  18 use PMG::ClusterConfig;
  19 use PMG::RuleDB;
  20 use PMG::RuleCache;
  21 use PMG::MailQueue;
  22 use PMG::Fetchmail;
  23
  24 sub remote_node_ip {
  25     my ($nodename, $noerr) = @_;
  26
  27     my $cinfo = PMG::ClusterConfig->new();
  28
  29     foreach my $entry (values %{$cinfo->{ids}}) {
  30         if ($entry->{name} eq $nodename) {
  31             my $ip = $entry->{ip};
  32             return $ip if !wantarray;
  33             my $family = PVE::Tools::get_host_address_family($ip);
  34             return ($ip, $family);
  35         }
  36     }
  37
  38     # fallback: try to get IP by other means
  39     return PVE::Network::get_ip_from_hostname($nodename, $noerr);
  40 }
  41
  42 sub get_master_node {
  43     my ($cinfo) = @_;
  44
  45     $cinfo = PMG::ClusterConfig->new() if !$cinfo;
  46
  47     return $cinfo->{master}->{name} if defined($cinfo->{master});
  48
  49     return 'localhost';
  50 }
  51
  52 sub read_local_ssl_cert_fingerprint {
  53     my $cert_path = "/etc/pmg/pmg-api.pem";
  54
  55     my $cert;
  56     eval {
  57         my $bio = Net::SSLeay::BIO_new_file($cert_path, 'r');
  58         $cert = Net::SSLeay::PEM_read_bio_X509($bio);
  59         Net::SSLeay::BIO_free($bio);
  60     };
  61     if (my $err = $@) {
  62         die "unable to read certificate '$cert_path' - $err\n";
  63     }
  64
  65     if (!defined($cert)) {
  66         die "unable to read certificate '$cert_path' - got empty value\n";
  67     }
  68
  69     my $fp;
  70     eval {
  71         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
  72     };
  73     if (my $err = $@) {
  74         die "unable to get fingerprint for '$cert_path' - $err\n";
  75     }
  76
  77     if (!defined($fp) || $fp eq '') {
  78         die "unable to get fingerprint for '$cert_path' - got empty value\n";
  79     }
  80
  81     return $fp;
  82 }
  83
  84 my $hostrsapubkey_fn = '/etc/ssh/ssh_host_rsa_key.pub';
  85 my $rootrsakey_fn = '/root/.ssh/id_rsa';
  86 my $rootrsapubkey_fn = '/root/.ssh/id_rsa.pub';
  87
  88 sub read_local_cluster_info {
  89
  90     my $res = {};
  91
  92     my $hostrsapubkey = PVE::Tools::file_read_firstline($hostrsapubkey_fn);
  93     $hostrsapubkey =~ s/^.*ssh-rsa\s+//i;
  94     $hostrsapubkey =~ s/\s+root\@\S+\s*$//i;
  95
  96     die "unable to parse ${hostrsapubkey_fn}\n"
  97         if $hostrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
  98
  99     my $nodename = PVE::INotify::nodename();
 100
 101     $res->{name} = $nodename;
 102
 103     $res->{ip} = PVE::Network::get_ip_from_hostname($nodename);
 104
 105     $res->{hostrsapubkey} = $hostrsapubkey;
 106
 107     if (! -f $rootrsapubkey_fn) {
 108         unlink $rootrsakey_fn;
 109         my $cmd = ['ssh-keygen', '-t', 'rsa', '-N', '', '-b', '2048',
 110                    '-f', $rootrsakey_fn];
 111         PMG::Utils::run_silent_cmd($cmd);
 112     }
 113
 114     my $rootrsapubkey = PVE::Tools::file_read_firstline($rootrsapubkey_fn);
 115     $rootrsapubkey =~ s/^.*ssh-rsa\s+//i;
 116     $rootrsapubkey =~ s/\s+root\@\S+\s*$//i;
 117
 118     die "unable to parse ${rootrsapubkey_fn}\n"
 119         if $rootrsapubkey !~ m/^[A-Za-z0-9\.\/\+]{200,}$/;
 120
 121     $res->{rootrsapubkey} = $rootrsapubkey;
 122
 123     $res->{fingerprint} = read_local_ssl_cert_fingerprint();
 124
 125     return $res;
 126 }
 127
 128 # X509 Certificate cache helper
 129
 130 my $cert_cache_nodes = {};
 131 my $cert_cache_timestamp = time();
 132 my $cert_cache_fingerprints = {};
 133
 134 sub update_cert_cache {
 135
 136     $cert_cache_timestamp = time();
 137
 138     $cert_cache_fingerprints = {};
 139     $cert_cache_nodes = {};
 140
 141     my $cinfo = PMG::ClusterConfig->new();
 142
 143     foreach my $entry (values %{$cinfo->{ids}}) {
 144         my $node = $entry->{name};
 145         my $fp = $entry->{fingerprint};
 146         if ($node && $fp) {
 147             $cert_cache_fingerprints->{$fp} = 1;
 148             $cert_cache_nodes->{$node} = $fp;
 149         }
 150     }
 151 }
 152
 153 # load and cache cert fingerprint once
 154 sub initialize_cert_cache {
 155     my ($node) = @_;
 156
 157     update_cert_cache()
 158         if defined($node) && !defined($cert_cache_nodes->{$node});
 159 }
 160
 161 sub check_cert_fingerprint {
 162     my ($cert) = @_;
 163
 164     # clear cache every 30 minutes at least
 165     update_cert_cache() if time() - $cert_cache_timestamp >= 60*30;
 166
 167     # get fingerprint of server certificate
 168     my $fp;
 169     eval {
 170         $fp = Net::SSLeay::X509_get_fingerprint($cert, 'sha256');
 171     };
 172     return 0 if $@ || !defined($fp) || $fp eq ''; # error
 173
 174     my $check = sub {
 175         for my $expected (keys %$cert_cache_fingerprints) {
 176             return 1 if $fp eq $expected;
 177         }
 178         return 0;
 179     };
 180
 181     return 1 if $check->();
 182
 183     # clear cache and retry at most once every minute
 184     if (time() - $cert_cache_timestamp >= 60) {
 185         syslog ('info', "Could not verify remote node certificate '$fp' with list of pinned certificates, refreshing cache");
 186         update_cert_cache();
 187         return $check->();
 188     }
 189
 190     return 0;
 191 }
 192
 193 my $sshglobalknownhosts = "/etc/ssh/ssh_known_hosts2";
 194 my $rootsshauthkeys = "/root/.ssh/authorized_keys";
 195 my $ssh_rsa_id = "/root/.ssh/id_rsa.pub";
 196
 197 sub update_ssh_keys {
 198     my ($cinfo) = @_;
 199
 200     my $old = '';
 201     my $data = '';
 202
 203     foreach my $node (values %{$cinfo->{ids}}) {
 204         $data .= "$node->{ip} ssh-rsa $node->{hostrsapubkey}\n";
 205         $data .= "$node->{name} ssh-rsa $node->{hostrsapubkey}\n";
 206     }
 207
 208     $old = PVE::Tools::file_get_contents($sshglobalknownhosts, 1024*1024)
 209         if -f $sshglobalknownhosts;
 210
 211     PVE::Tools::file_set_contents($sshglobalknownhosts, $data)
 212         if $old ne $data;
 213
 214     $data = '';
 215     $old = '';
 216
 217     # always add ourself
 218     if (-f $ssh_rsa_id) {
 219         my $pub = PVE::Tools::file_get_contents($ssh_rsa_id);
 220         chomp($pub);
 221         $data .= "$pub\n";
 222     }
 223
 224     foreach my $node (values %{$cinfo->{ids}}) {
 225         $data .= "ssh-rsa $node->{rootrsapubkey} root\@$node->{name}\n";
 226     }
 227
 228     if (-f $rootsshauthkeys) {
 229         my $mykey = PVE::Tools::file_get_contents($rootsshauthkeys, 128*1024);
 230         chomp($mykey);
 231         $data .= "$mykey\n";
 232     }
 233
 234     my $newdata = "";
 235     my $vhash = {};
 236     my @lines = split(/\n/, $data);
 237     foreach my $line (@lines) {
 238         if ($line !~ /^#/ && $line =~ m/(^|\s)ssh-(rsa|dsa)\s+(\S+)\s+\S+$/) {
 239             next if $vhash->{$3}++;
 240         }
 241         $newdata .= "$line\n";
 242     }
 243
 244     $old = PVE::Tools::file_get_contents($rootsshauthkeys, 1024*1024)
 245         if -f $rootsshauthkeys;
 246
 247     PVE::Tools::file_set_contents($rootsshauthkeys, $newdata, 0600)
 248         if $old ne $newdata;
 249 }
 250
 251 my $cfgdir = '/etc/pmg';
 252 my $syncdir = "$cfgdir/master";
 253
 254 my $cond_commit_synced_file = sub {
 255     my ($filename, $dstfn) = @_;
 256
 257     $dstfn = "$cfgdir/$filename" if !defined($dstfn);
 258     my $srcfn = "$syncdir/$filename";
 259
 260     if (! -f $srcfn) {
 261         unlink $dstfn;
 262         return;
 263     }
 264
 265     my $new = PVE::Tools::file_get_contents($srcfn, 1024*1024);
 266
 267     if (-f $dstfn) {
 268         my $old = PVE::Tools::file_get_contents($dstfn, 1024*1024);
 269         return 0 if $new eq $old;
 270     }
 271
 272     # set mtime (touch) to avoid time drift problems
 273     utime(undef, undef, $srcfn);
 274
 275     rename($srcfn, $dstfn) ||
 276         die "cond_rename_file '$filename' failed - $!\n";
 277
 278     print STDERR "updated $dstfn\n";
 279
 280     return 1;
 281 };
 282
 283 my $rsync_command = sub {
 284     my ($host_key_alias, @args) = @_;
 285
 286     my $ssh_cmd = '--rsh=ssh -l root -o BatchMode=yes';
 287     $ssh_cmd .=  " -o HostKeyAlias=${host_key_alias}" if $host_key_alias;
 288
 289     my $cmd = ['rsync', $ssh_cmd,  '-q', @args];
 290
 291     return $cmd;
 292 };
 293
 294 sub sync_quarantine_files {
 295     my ($host_ip, $host_name, $flistname, $rcid) = @_;
 296
 297     my $spooldir = $PMG::MailQueue::spooldir;
 298
 299     mkdir "$spooldir/cluster/";
 300     my $syncdir = "$spooldir/cluster/$rcid";
 301     mkdir $syncdir;
 302
 303     my $cmd = $rsync_command->(
 304         $host_name, '--timeout', '10', "[${host_ip}]:$spooldir", $spooldir,
 305         '--files-from', $flistname);
 306
 307     PVE::Tools::run_command($cmd);
 308 }
 309
 310 sub sync_spooldir {
 311     my ($host_ip, $host_name, $rcid) = @_;
 312
 313     my $spooldir = $PMG::MailQueue::spooldir;
 314
 315     mkdir "$spooldir/cluster/";
 316     my $syncdir = "$spooldir/cluster/$rcid";
 317     mkdir $syncdir;
 318
 319     my $cmd = $rsync_command->(
 320         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir/", $syncdir);
 321
 322     foreach my $incl (('spam/', 'spam/*', 'spam/*/*', 'virus/', 'virus/*', 'virus/*/*')) {
 323         push @$cmd, '--include', $incl;
 324     }
 325
 326     push @$cmd, '--exclude', '*';
 327
 328     PVE::Tools::run_command($cmd);
 329 }
 330
 331 sub sync_master_quar {
 332     my ($host_ip, $host_name) = @_;
 333
 334     my $spooldir = $PMG::MailQueue::spooldir;
 335
 336     my $syncdir = "$spooldir/cluster/";
 337     mkdir $syncdir;
 338
 339     my $cmd = $rsync_command->(
 340         $host_name, '-aq', '--timeout', '10', "[${host_ip}]:$syncdir", $syncdir);
 341
 342     PVE::Tools::run_command($cmd);
 343 }
 344
 345 sub sync_config_from_master {
 346     my ($master_name, $master_ip, $noreload) = @_;
 347
 348     mkdir $syncdir;
 349     File::Path::remove_tree($syncdir, {keep_root => 1});
 350
 351     my $sa_conf_dir = "/etc/mail/spamassassin";
 352     my $sa_custom_cf = "custom.cf";
 353     my $sa_rules_cf = "pmg-scores.cf";
 354
 355     my $cmd = $rsync_command->(
 356         $master_name, '-aq',
 357         "[${master_ip}]:$cfgdir/* ${sa_conf_dir}/${sa_custom_cf} ${sa_conf_dir}/${sa_rules_cf}",
 358         "$syncdir/",
 359         '--exclude', 'master/',
 360         '--exclude', '*~',
 361         '--exclude', '*.db',
 362         '--exclude', 'pmg-api.pem',
 363         '--exclude', 'pmg-tls.pem',
 364         );
 365
 366     my $errmsg = "syncing master configuration from '${master_ip}' failed";
 367     PVE::Tools::run_command($cmd, errmsg => $errmsg);
 368
 369     # verify that the remote host is cluster master
 370     open (my $fh, '<', "$syncdir/cluster.conf") ||
 371         die "unable to open synced cluster.conf - $!\n";
 372
 373     my $cinfo = PMG::ClusterConfig::read_cluster_conf('cluster.conf', $fh);
 374
 375     if (!$cinfo->{master} || ($cinfo->{master}->{ip} ne $master_ip)) {
 376         die "host '$master_ip' is not cluster master\n";
 377     }
 378
 379     my $role = $cinfo->{'local'}->{type} // '-';
 380     die "local node '$cinfo->{local}->{name}' not part of cluster\n"
 381         if $role eq '-';
 382
 383     die "local node '$cinfo->{local}->{name}' is new cluster master\n"
 384         if $role eq 'master';
 385
 386     $cond_commit_synced_file->('cluster.conf');
 387
 388     update_ssh_keys($cinfo); # rewrite ssh keys
 389
 390     PMG::Fetchmail::update_fetchmail_default(0); # disable on slave
 391
 392     my $files = [
 393         'pmg-authkey.key',
 394         'pmg-authkey.pub',
 395         'pmg-csrf.key',
 396         'ldap.conf',
 397         'user.conf',
 398         'domains',
 399         'mynetworks',
 400         'transport',
 401         'tls_policy',
 402         'fetchmailrc',
 403         ];
 404
 405     foreach my $filename (@$files) {
 406         $cond_commit_synced_file->($filename);
 407     }
 408
 409     my $dirs = [
 410         'templates',
 411         'dkim',
 412         'pbs',
 413     ];
 414
 415     foreach my $dir (@$dirs) {
 416         my $srcdir = "$syncdir/$dir";
 417
 418         if ( -d $srcdir ) {
 419             my $cmd = ['rsync', '-aq', '--delete-after', "$srcdir/", "$cfgdir/$dir"];
 420             PVE::Tools::run_command($cmd);
 421         }
 422
 423     }
 424
 425     my $force_restart = {};
 426
 427     for my $file (($sa_custom_cf, $sa_rules_cf)) {
 428         if ($cond_commit_synced_file->($file, "${sa_conf_dir}/${file}")) {
 429             $force_restart->{'pmg-smtp-filter'} = 1;
 430         }
 431     }
 432
 433     $cond_commit_synced_file->('pmg.conf');
 434
 435     return $force_restart;
 436 }
 437
 438 sub sync_ruledb_from_master {
 439     my ($ldb, $rdb, $ni, $ticket) = @_;
 440
 441     my $ruledb = PMG::RuleDB->new($ldb);
 442     my $rulecache = PMG::RuleCache->new($ruledb);
 443
 444     my $conn = PVE::APIClient::LWP->new(
 445         ticket => $ticket,
 446         cookie_name => 'PMGAuthCookie',
 447         host => $ni->{ip},
 448         cached_fingerprints => {
 449             $ni->{fingerprint} => 1,
 450         });
 451
 452     my $digest = $conn->get("/config/ruledb/digest", {});
 453
 454     return if $digest eq $rulecache->{digest}; # no changes
 455
 456     syslog('info', "detected rule database changes - starting sync from '$ni->{ip}'");
 457
 458     eval {
 459         $ldb->begin_work;
 460
 461         $ldb->do("DELETE FROM Rule");
 462         $ldb->do("DELETE FROM RuleGroup");
 463         $ldb->do("DELETE FROM ObjectGroup");
 464         $ldb->do("DELETE FROM Object");
 465         $ldb->do("DELETE FROM Attribut");
 466
 467         eval {
 468             $rdb->begin_work;
 469
 470             # read a consistent snapshot
 471             $rdb->do("SET TRANSACTION ISOLATION LEVEL SERIALIZABLE");
 472
 473             PMG::DBTools::copy_table($ldb, $rdb, "Rule");
 474             PMG::DBTools::copy_table($ldb, $rdb, "RuleGroup");
 475             PMG::DBTools::copy_table($ldb, $rdb, "ObjectGroup");
 476             PMG::DBTools::copy_table($ldb, $rdb, "Object", 'value');
 477             PMG::DBTools::copy_table($ldb, $rdb, "Attribut", 'value');
 478         };
 479
 480         $rdb->rollback; # end transaction
 481
 482         die $@ if $@;
 483
 484         # update sequences
 485
 486         $ldb->do("SELECT setval('rule_id_seq', max(id)+1) FROM Rule");
 487         $ldb->do("SELECT setval('object_id_seq', max(id)+1) FROM Object");
 488         $ldb->do("SELECT setval('objectgroup_id_seq', max(id)+1) FROM ObjectGroup");
 489
 490         $ldb->commit;
 491     };
 492     if (my $err = $@) {
 493         $ldb->rollback;
 494         die $err;
 495     }
 496
 497     PMG::DBTools::reload_ruledb();
 498
 499     syslog('info', "finished rule database sync from host '$ni->{ip}'");
 500 }
 501
 502 sub sync_quarantine_db {
 503     my ($ldb, $rdb, $ni, $rsynctime_ref) = @_;
 504
 505     my $rcid = $ni->{cid};
 506
 507     my $maxmails = 100000;
 508
 509     my $mscount = 0;
 510
 511     my $ctime = PMG::DBTools::get_remote_time($rdb);
 512
 513     my $maxcount = 1000;
 514
 515     my $count;
 516
 517     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastid_CMailStore', -1, undef);
 518
 519     do { # get new values
 520
 521         $count = 0;
 522
 523         my $flistname = "/tmp/quarantinefilelist.$$";
 524
 525         eval {
 526             $ldb->begin_work;
 527
 528             open(my $flistfh, '>', $flistname) ||
 529                 die "unable to open file '$flistname' - $!\n";
 530
 531             my $lastid = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastid_CMailStore');
 532
 533             # sync CMailStore
 534
 535             my $sth = $rdb->prepare(
 536                 "SELECT * from CMailstore WHERE cid = ? AND rid > ? " .
 537                 "ORDER BY cid,rid LIMIT ?");
 538             $sth->execute($rcid, $lastid, $maxcount);
 539
 540             my $maxid;
 541             my $callback = sub {
 542                 my $ref = shift;
 543                 $maxid = $ref->{rid};
 544                 my $filename = $ref->{file};
 545                  # skip files generated before cluster was created
 546                 return if $filename !~ m!^cluster/!;
 547                 print $flistfh "$filename\n";
 548             };
 549
 550             my $attrs = [qw(cid rid time qtype bytes spamlevel info sender header file)];
 551             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CMailStore', $attrs, $callback);
 552
 553             close($flistfh);
 554
 555             my $starttime = [ gettimeofday() ];
 556             sync_quarantine_files($ni->{ip}, $ni->{name}, $flistname, $rcid);
 557             $$rsynctime_ref += tv_interval($starttime);
 558
 559             if ($maxid) {
 560                 # sync CMSReceivers
 561
 562                 $sth = $rdb->prepare(
 563                     "SELECT * from CMSReceivers WHERE " .
 564                     "CMailStore_CID = ? AND CMailStore_RID > ?  " .
 565                     "AND CMailStore_RID <= ?");
 566                 $sth->execute($rcid, $lastid, $maxid);
 567
 568                 $attrs = [qw(cmailstore_cid cmailstore_rid pmail receiver ticketid status mtime)];
 569                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CMSReceivers', $attrs);
 570
 571                 PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastid_CMailStore', $maxid);
 572             }
 573
 574             $ldb->commit;
 575         };
 576         my $err = $@;
 577
 578         unlink $flistname;
 579
 580         if ($err) {
 581             $ldb->rollback;
 582             die $err;
 583         }
 584
 585         $mscount += $count;
 586
 587     } while (($count >= $maxcount) && ($mscount < $maxmails));
 588
 589     PMG::DBTools::create_clusterinfo_default($ldb, $rcid, 'lastmt_CMSReceivers', 0, undef);
 590
 591     eval { # synchronize status updates
 592         $ldb->begin_work;
 593
 594         my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers');
 595
 596         my $sth = $rdb->prepare ("SELECT * from CMSReceivers WHERE mtime >= ? AND status != 'N'");
 597         $sth->execute($lastmt);
 598
 599         my $update_sth = $ldb->prepare(
 600             "UPDATE CMSReceivers SET status = ? WHERE " .
 601             "CMailstore_CID = ? AND CMailstore_RID = ? AND TicketID = ?");
 602         while (my $ref = $sth->fetchrow_hashref()) {
 603             $update_sth->execute($ref->{status}, $ref->{cmailstore_cid},
 604                                  $ref->{cmailstore_rid}, $ref->{ticketid});
 605         }
 606
 607         PMG::DBTools::write_maxint_clusterinfo($ldb, $rcid, 'lastmt_CMSReceivers', $ctime);
 608
 609         $ldb->commit;
 610     };
 611     if (my $err = $@) {
 612         $ldb->rollback;
 613         die $err;
 614     }
 615
 616     return $mscount;
 617 }
 618
 619 sub sync_statistic_db {
 620     my ($ldb, $rdb, $ni) = @_;
 621
 622     my $rcid = $ni->{cid};
 623
 624     my $maxmails = 100000;
 625
 626     my $mscount = 0;
 627
 628     my $maxcount = 1000;
 629
 630     my $count;
 631
 632     PMG::DBTools::create_clusterinfo_default(
 633         $ldb, $rcid, 'lastid_CStatistic', -1, undef);
 634
 635     do { # get new values
 636
 637         $count = 0;
 638
 639         eval {
 640             $ldb->begin_work;
 641
 642             my $lastid = PMG::DBTools::read_int_clusterinfo(
 643                 $ldb, $rcid, 'lastid_CStatistic');
 644
 645             # sync CStatistic
 646
 647             my $sth = $rdb->prepare(
 648                 "SELECT * from CStatistic " .
 649                 "WHERE cid = ? AND rid > ? " .
 650                 "ORDER BY cid, rid LIMIT ?");
 651             $sth->execute($rcid, $lastid, $maxcount);
 652
 653             my $maxid;
 654             my $callback = sub {
 655                 my $ref = shift;
 656                 $maxid = $ref->{rid};
 657             };
 658
 659             my $attrs = [qw(cid rid time bytes direction spamlevel ptime virusinfo sender)];
 660             $count += PMG::DBTools::copy_selected_data($ldb, $sth, 'CStatistic', $attrs, $callback);
 661
 662             if ($maxid) {
 663                 # sync CReceivers
 664
 665                 $sth = $rdb->prepare(
 666                     "SELECT * from CReceivers WHERE " .
 667                     "CStatistic_CID = ? AND CStatistic_RID > ? AND CStatistic_RID <= ?");
 668                 $sth->execute($rcid, $lastid, $maxid);
 669
 670                 $attrs = [qw(cstatistic_cid cstatistic_rid blocked receiver)];
 671                 PMG::DBTools::copy_selected_data($ldb, $sth, 'CReceivers', $attrs);
 672             }
 673
 674             PMG::DBTools::write_maxint_clusterinfo ($ldb, $rcid, 'lastid_CStatistic', $maxid);
 675
 676             $ldb->commit;
 677         };
 678         if (my $err = $@) {
 679             $ldb->rollback;
 680             die $err;
 681         }
 682
 683         $mscount += $count;
 684
 685     } while (($count >= $maxcount) && ($mscount < $maxmails));
 686
 687     return $mscount;
 688 }
 689
 690 my $sync_generic_mtime_db = sub {
 691     my ($ldb, $rdb, $ni, $table, $selectfunc, $mergefunc) = @_;
 692
 693     my $ctime = PMG::DBTools::get_remote_time($rdb);
 694
 695     PMG::DBTools::create_clusterinfo_default($ldb, $ni->{cid}, "lastmt_$table", 0, undef);
 696
 697     my $lastmt = PMG::DBTools::read_int_clusterinfo($ldb, $ni->{cid}, "lastmt_$table");
 698
 699     my $sql_cmd = $selectfunc->($ctime, $lastmt);
 700
 701     my $sth = $rdb->prepare($sql_cmd);
 702
 703     $sth->execute();
 704
 705     my $updates = 0;
 706
 707     eval {
 708         # use transaction to speedup things
 709         my $max = 1000; # UPDATE MAX ENTRIES AT ONCE
 710         my $count = 0;
 711         while (my $ref = $sth->fetchrow_hashref()) {
 712             $ldb->begin_work if !$count;
 713             $mergefunc->($ref);
 714             if (++$count >= $max) {
 715                 $count = 0;
 716                 $ldb->commit;
 717             }
 718             $updates++;
 719         }
 720
 721         $ldb->commit if $count;
 722     };
 723     if (my $err = $@) {
 724         $ldb->rollback;
 725         die $err;
 726     }
 727
 728     PMG::DBTools::write_maxint_clusterinfo($ldb, $ni->{cid}, "lastmt_$table", $ctime);
 729
 730     return $updates;
 731 };
 732
 733 sub sync_localstat_db {
 734     my ($dbh, $rdb, $ni) = @_;
 735
 736     my $rcid = $ni->{cid};
 737
 738     my $selectfunc = sub {
 739         my ($ctime, $lastmt) = @_;
 740         return "SELECT * from LocalStat WHERE mtime >= $lastmt AND cid = $rcid";
 741     };
 742
 743     my $merge_sth = $dbh->prepare(
 744         'INSERT INTO LocalStat (Time, RBLCount, PregreetCount, CID, MTime) ' .
 745         'VALUES (?, ?, ?, ?, ?) ' .
 746         'ON CONFLICT (Time, CID) DO UPDATE SET ' .
 747         'RBLCount = excluded.RBLCount, PregreetCount = excluded.PregreetCount, MTime = excluded.MTime');
 748
 749     my $mergefunc = sub {
 750         my ($ref) = @_;
 751
 752         $merge_sth->execute($ref->{time}, $ref->{rblcount}, $ref->{pregreetcount}, $ref->{cid}, $ref->{mtime});
 753     };
 754
 755     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'LocalStat', $selectfunc, $mergefunc);
 756 }
 757
 758 sub sync_greylist_db {
 759     my ($dbh, $rdb, $ni) = @_;
 760
 761     my $selectfunc = sub {
 762         my ($ctime, $lastmt) = @_;
 763         return "SELECT * from CGreylist WHERE extime >= $ctime AND " .
 764             "mtime >= $lastmt AND CID != 0";
 765     };
 766
 767     # FIXME: drop Host column with PMG 7.0
 768     my $merge_sth = $dbh->prepare(PMG::DBTools::cgreylist_merge_sql());
 769     my $mergefunc = sub {
 770         my ($ref) = @_;
 771
 772         my $ipnet = $ref->{ipnet};
 773         $ipnet .= '.0/24' if $ipnet !~ /\/\d+$/;
 774         $merge_sth->execute(
 775             $ipnet, 0, $ref->{sender}, $ref->{receiver},
 776             $ref->{instance}, $ref->{rctime}, $ref->{extime}, $ref->{delay},
 777             $ref->{blocked}, $ref->{passed}, 0, $ref->{cid});
 778     };
 779
 780     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'CGreylist', $selectfunc, $mergefunc);
 781 }
 782
 783 sub sync_userprefs_db {
 784     my ($dbh, $rdb, $ni) = @_;
 785
 786     my $selectfunc = sub {
 787         my ($ctime, $lastmt) = @_;
 788
 789         return "SELECT * from UserPrefs WHERE mtime >= $lastmt";
 790     };
 791
 792     my $merge_sth = $dbh->prepare(
 793         "INSERT INTO UserPrefs (PMail, Name, Data, MTime) " .
 794         'VALUES (?, ?, ?, ?) ' .
 795         'ON CONFLICT (PMail, Name) DO UPDATE SET ' .
 796         # Note: MTime = 0 ==> this is just a copy from somewhere else, not modified
 797         'MTime = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN 0 ELSE UserPrefs.MTime END, ' .
 798         'Data = CASE WHEN excluded.MTime >= UserPrefs.MTime THEN excluded.Data ELSE UserPrefs.Data END');
 799
 800     my $mergefunc = sub {
 801         my ($ref) = @_;
 802
 803         $merge_sth->execute($ref->{pmail}, $ref->{name}, $ref->{data}, $ref->{mtime});
 804     };
 805
 806     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'UserPrefs', $selectfunc, $mergefunc);
 807 }
 808
 809 sub sync_domainstat_db {
 810     my ($dbh, $rdb, $ni) = @_;
 811
 812     my $selectfunc = sub {
 813         my ($ctime, $lastmt) = @_;
 814         return "SELECT * from DomainStat WHERE mtime >= $lastmt";
 815     };
 816
 817     my $merge_sth = $dbh->prepare(
 818         'INSERT INTO Domainstat ' .
 819         '(Time,Domain,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 820         'BouncesIn,BouncesOut,PTimeSum,Mtime) ' .
 821         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 822         'ON CONFLICT (Time, Domain) DO UPDATE SET ' .
 823         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 824         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 825         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 826         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 827         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 828         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 829
 830     my $mergefunc = sub {
 831         my ($ref) = @_;
 832
 833         $merge_sth->execute(
 834             $ref->{time}, $ref->{domain}, $ref->{countin}, $ref->{countout},
 835             $ref->{bytesin}, $ref->{bytesout},
 836             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 837             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{ptimesum}, $ref->{mtime});
 838     };
 839
 840     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DomainStat', $selectfunc, $mergefunc);
 841 }
 842
 843 sub sync_dailystat_db {
 844     my ($dbh, $rdb, $ni) = @_;
 845
 846     my $selectfunc = sub {
 847         my ($ctime, $lastmt) = @_;
 848         return "SELECT * from DailyStat WHERE mtime >= $lastmt";
 849     };
 850
 851     my $merge_sth = $dbh->prepare(
 852         'INSERT INTO DailyStat ' .
 853         '(Time,CountIn,CountOut,BytesIn,BytesOut,VirusIn,VirusOut,SpamIn,SpamOut,' .
 854         'BouncesIn,BouncesOut,GreylistCount,SPFCount,RBLCount,PTimeSum,Mtime) ' .
 855         'VALUES (?,?,?,?,?,?,?,?,?,?,?,?,?,?,?,?) ' .
 856         'ON CONFLICT (Time) DO UPDATE SET ' .
 857         'CountIn = excluded.CountIn, CountOut = excluded.CountOut, ' .
 858         'BytesIn = excluded.BytesIn, BytesOut = excluded.BytesOut, ' .
 859         'VirusIn = excluded.VirusIn, VirusOut = excluded.VirusOut, ' .
 860         'SpamIn = excluded.SpamIn, SpamOut = excluded.SpamOut, ' .
 861         'BouncesIn = excluded.BouncesIn, BouncesOut = excluded.BouncesOut, ' .
 862         'GreylistCount = excluded.GreylistCount, SPFCount = excluded.SpfCount, ' .
 863         'RBLCount = excluded.RBLCount, ' .
 864         'PTimeSum = excluded.PTimeSum, MTime = excluded.MTime');
 865
 866     my $mergefunc = sub {
 867         my ($ref) = @_;
 868
 869         $merge_sth->execute(
 870             $ref->{time}, $ref->{countin}, $ref->{countout},
 871             $ref->{bytesin}, $ref->{bytesout},
 872             $ref->{virusin}, $ref->{virusout}, $ref->{spamin}, $ref->{spamout},
 873             $ref->{bouncesin}, $ref->{bouncesout}, $ref->{greylistcount},
 874             $ref->{spfcount}, $ref->{rblcount}, $ref->{ptimesum}, $ref->{mtime});
 875     };
 876
 877     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'DailyStat', $selectfunc, $mergefunc);
 878 }
 879
 880 sub sync_virusinfo_db {
 881     my ($dbh, $rdb, $ni) = @_;
 882
 883     my $selectfunc = sub {
 884         my ($ctime, $lastmt) = @_;
 885         return "SELECT * from VirusInfo WHERE mtime >= $lastmt";
 886     };
 887
 888     my $merge_sth = $dbh->prepare(
 889         'INSERT INTO VirusInfo (Time,Name,Count,MTime) ' .
 890         'VALUES (?,?,?,?) ' .
 891         'ON CONFLICT (Time,Name) DO UPDATE SET ' .
 892         'Count = excluded.Count , MTime = excluded.MTime');
 893
 894     my $mergefunc = sub {
 895         my ($ref) = @_;
 896
 897         $merge_sth->execute($ref->{time}, $ref->{name}, $ref->{count}, $ref->{mtime});
 898     };
 899
 900     return $sync_generic_mtime_db->($dbh, $rdb, $ni, 'VirusInfo', $selectfunc, $mergefunc);
 901 }
 902
 903 sub sync_deleted_nodes_from_master {
 904     my ($ldb, $masterdb, $cinfo, $masterni, $rsynctime_ref) = @_;
 905
 906     my $rsynctime = 0;
 907
 908     my $cid_hash = {}; # fast lookup
 909     foreach my $ni (values %{$cinfo->{ids}}) {
 910         $cid_hash->{$ni->{cid}} = $ni;
 911     }
 912
 913     my $spooldir = $PMG::MailQueue::spooldir;
 914
 915     my $maxcid = $cinfo->{master}->{maxcid} // 0;
 916
 917     for (my $rcid = 1; $rcid <= $maxcid; $rcid++) {
 918         next if $cid_hash->{$rcid};
 919
 920         my $done_marker = "$spooldir/cluster/$rcid/.synced-deleted-node";
 921
 922         next if -f $done_marker; # already synced
 923
 924         syslog('info', "syncing deleted node $rcid from master '$masterni->{ip}'");
 925
 926         my $starttime = [ gettimeofday() ];
 927         sync_spooldir($masterni->{ip}, $masterni->{name}, $rcid);
 928         $$rsynctime_ref += tv_interval($starttime);
 929
 930         my $fake_ni = {
 931             ip => $masterni->{ip},
 932             name => $masterni->{name},
 933             cid => $rcid,
 934         };
 935
 936         sync_quarantine_db($ldb, $masterdb, $fake_ni);
 937
 938         sync_statistic_db ($ldb, $masterdb, $fake_ni);
 939
 940         open(my $fh, ">>",  $done_marker);
 941    }
 942 }
 943
 944
 945 1;