src/PMG/Service/pmgproxy.pm

   1 package PMG::Service::pmgproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use URI;
  10 use URI::Escape;
  11
  12 use URI::QueryParam;
  13 use Data::Dumper;
  14
  15 use PVE::Tools;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::APIServer::Utils;
  21
  22 use PMG::HTTPServer;
  23 use PMG::API2;
  24 use PMG::Config;
  25
  26 use Template;
  27
  28 use base qw(PVE::Daemon);
  29
  30 my $cmdline = [$0, @ARGV];
  31
  32 my %daemon_options = (
  33     max_workers => 3,
  34     restart_on_error => 5,
  35     stop_wait_time => 15,
  36     leave_children_open_on_reload => 1,
  37     setuid => 'www-data',
  38     setgid => 'www-data',
  39     pidfile => '/run/pmgproxy/pmgproxy.pid',
  40 );
  41
  42 my $daemon = __PACKAGE__->new('pmgproxy', $cmdline, %daemon_options);
  43
  44 sub add_dirs {
  45     my ($result_hash, $alias, $subdir) = @_;
  46
  47     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  48 }
  49
  50 my $gui_base_dir = "/usr/share/javascript/pmg-gui";
  51 my $extjs_dir = "/usr/share/javascript/extjs/";
  52 my $fontawesome_dir = "/usr/share/fonts-font-awesome";
  53 my $xtermjs_dir = '/usr/share/pve-xtermjs';
  54 my $framework7_dir = '/usr/share/javascript/framework7';
  55 my $widgettoolkit_dir = '/usr/share/javascript/proxmox-widget-toolkit';
  56
  57 sub init {
  58     my ($self) = @_;
  59
  60     my $proxyconf = PVE::APIServer::Utils::read_proxy_config($self->{name});
  61
  62     my $accept_lock_fn = "/var/lock/pmgproxy.lck";
  63
  64     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  65         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  66
  67     my $listen_ip = $proxyconf->{LISTEN_IP};
  68     my $socket = $self->create_reusable_socket(8006, $listen_ip);
  69
  70     my $dirs = {};
  71
  72     add_dirs($dirs, '/pve2/locale/', '/usr/share/pmg-i18n/');
  73     add_dirs($dirs, '/pve2/ext6/', $extjs_dir);
  74     add_dirs($dirs, '/pve2/images/' => "$gui_base_dir/images/");
  75     add_dirs($dirs, '/pve2/css/' => "$gui_base_dir/css/");
  76     add_dirs($dirs, '/pve2/js/' => "$gui_base_dir/js/");
  77     add_dirs($dirs, '/fontawesome/css/' => "$fontawesome_dir/css/");
  78     add_dirs($dirs, '/fontawesome/fonts/' => "$fontawesome_dir/fonts/");
  79     add_dirs($dirs, '/framework7/fonts/' => "$framework7_dir/fonts/");
  80     add_dirs($dirs, '/framework7/css/' => "$framework7_dir/css/");
  81     add_dirs($dirs, '/framework7/js/' => "$framework7_dir/js/");
  82     add_dirs($dirs, '/xtermjs/' => "$xtermjs_dir/");
  83     add_dirs($dirs, '/pmg-docs/' => '/usr/share/pmg-docs/');
  84     add_dirs($dirs, '/pmg-docs/api-viewer/extjs/' => $extjs_dir);
  85     add_dirs($dirs, '/pwt/css/' => "$widgettoolkit_dir/css/");
  86     add_dirs($dirs, '/pwt/images/' =>  "$widgettoolkit_dir/images/");
  87     add_dirs($dirs, '/pwt/themes/' => "$widgettoolkit_dir/themes/");
  88
  89     $self->{server_config} = {
  90         title => 'Proxmox Mail Gateway API',
  91         cookie_name => 'PMGAuthCookie',
  92         keep_alive => 100,
  93         max_conn => 500,
  94         max_requests => 1000,
  95         lockfile => $accept_lock_fn,
  96         socket => $socket,
  97         lockfh => $lockfh,
  98         debug => $self->{debug},
  99         trusted_env => 0, # not trusted, anyone can connect
 100         logfile => '/var/log/pmgproxy/pmgproxy.log',
 101         allow_from => $proxyconf->{ALLOW_FROM},
 102         deny_from => $proxyconf->{DENY_FROM},
 103         policy => $proxyconf->{POLICY},
 104         ssl => {
 105             cert_file => '/etc/pmg/pmg-api.pem',
 106             dh => 'skip2048',
 107             cipher_list => $proxyconf->{CIPHERS},
 108             ciphersuites => $proxyconf->{CIPHERSUITES},
 109             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER},
 110         },
 111         compression => $proxyconf->{COMPRESSION},
 112         # Note: there is no authentication for those pages and dirs!
 113         pages => {
 114             '/' => sub { get_index($self->{nodename}, @_) },
 115             '/quarantine' => sub { get_index($self->{nodename}, @_) },
 116             # avoid authentication when accessing favicon
 117             '/favicon.ico' => {
 118                 file => '/usr/share/doc/pmg-api/favicon.ico',
 119             },
 120             '/proxmoxlib.js' => {
 121                 file => '/usr/share/javascript/proxmox-widget-toolkit/proxmoxlib.js',
 122             },
 123             '/qrcode.min.js' => {
 124                 file => '/usr/share/javascript/qrcodejs/qrcode.min.js',
 125             },
 126         },
 127         dirs => $dirs,
 128     };
 129
 130     if (defined($proxyconf->{DHPARAMS})) {
 131         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 132     }
 133     if (defined($proxyconf->{DISABLE_TLS_1_2})) {
 134         $self->{server_config}->{ssl}->{tlsv1_2} = !$proxyconf->{DISABLE_TLS_1_2};
 135     }
 136     if (defined($proxyconf->{DISABLE_TLS_1_3})) {
 137         $self->{server_config}->{ssl}->{tlsv1_3} = !$proxyconf->{DISABLE_TLS_1_3};
 138     }
 139 }
 140
 141 sub run {
 142     my ($self) = @_;
 143
 144     my $server = PMG::HTTPServer->new(%{$self->{server_config}});
 145     $server->run();
 146 }
 147
 148 $daemon->register_start_command();
 149 $daemon->register_restart_command(1);
 150 $daemon->register_stop_command();
 151 $daemon->register_status_command();
 152
 153 our $cmddef = {
 154     start => [ __PACKAGE__, 'start', []],
 155     restart => [ __PACKAGE__, 'restart', []],
 156     stop => [ __PACKAGE__, 'stop', []],
 157     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 158 };
 159
 160 my $template_toolkit;
 161
 162 sub get_template_toolkit {
 163
 164     return $template_toolkit if $template_toolkit;
 165
 166     $template_toolkit = Template->new(
 167         { INCLUDE_PATH => [$gui_base_dir, $xtermjs_dir]});
 168
 169     return $template_toolkit;
 170 }
 171
 172 sub is_phone {
 173     my ($ua) = @_;
 174
 175     return 0 if !$ua;
 176
 177     if ($ua =~ m/(
 178         iPhone|
 179         iPod|
 180         Windows\ Phone|
 181         Android|
 182         BlackBerry
 183         )/xi) {
 184         return 1;
 185     }
 186
 187     return 0;
 188 }
 189
 190 sub get_index {
 191     my ($nodename, $server, $r, $args) = @_;
 192
 193     my $lang = 'en';
 194     my $username;
 195     my $token = 'null';
 196     my $quarantine = ($r->uri->path() =~ m/quarantine$/);
 197     my $mobile = is_phone($r->header('User-Agent'));
 198     if (defined($args->{mobile})) {
 199         $mobile = $args->{mobile} ? 1 : 0;
 200     }
 201
 202     my $theme = "";
 203
 204     if (my $cookie = $r->header('Cookie')) {
 205         if (my $newlang = ($cookie =~ /(?:^|\s)PMGLangCookie=([^;]*)/)[0]) {
 206             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 207                 $lang = $newlang;
 208             }
 209         }
 210
 211         if (my $newtheme = ($cookie =~ /(?:^|\s)PMGThemeCookie=([^;]*)/)[0]) {
 212             # theme names need to be kebab case, with each segment a maximum of 10 characters long
 213             # and at most 6 segments
 214             if ($newtheme =~ m/^[a-z]{1,10}(-[a-z]{1,10}){0,5}$/) {
 215                 $theme = $newtheme;
 216             }
 217         }
 218
 219         my $ticket = PVE::APIServer::Formatter::extract_auth_value($cookie, $server->{cookie_name});
 220
 221         if ($ticket =~ m/^PMGQUAR:/) {
 222             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 223         } else {
 224             $username = PMG::Ticket::verify_ticket($ticket, undef, 1);
 225         }
 226     } else {
 227         if (defined($args->{ticket})) {
 228             my $ticket = uri_unescape($args->{ticket});
 229             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 230         }
 231     }
 232
 233     if ($theme eq "") {
 234         $theme = "auto"
 235     }
 236
 237     $token = PMG::Ticket::assemble_csrf_prevention_token($username)
 238         if defined($username);
 239
 240     my $langfile = 0;
 241
 242     if (-f  "/usr/share/pmg-i18n/pmg-lang-$lang.js") {
 243         $langfile = 1;
 244     }
 245
 246     my $wtversionraw = PVE::Tools::file_read_firstline("$widgettoolkit_dir/proxmoxlib.js");
 247     my $wtversion = '';
 248     if ($wtversionraw =~ m|^// (.*)$|) {
 249         $wtversion = $1;
 250     };
 251
 252     my $versionraw = PVE::Tools::file_read_firstline("$gui_base_dir/js/pmgmanagerlib.js");
 253     my $version = '';
 254     if ($versionraw =~ m|^// (.*)$|) {
 255         $version = $1;
 256     };
 257
 258     my $cfg = PMG::Config->new();
 259     my $quarantinelink = $cfg->get('spamquar', 'quarantinelink');
 260
 261     $username = '' if !$username;
 262
 263     my $page = '';
 264
 265     my $vars = {
 266         lang => $lang,
 267         langfile => $langfile,
 268         username => $username,
 269         token => $token,
 270         console => $args->{console},
 271         nodename => $nodename,
 272         debug => $args->{debug} || $server->{debug},
 273         version => $version,
 274         wtversion => $wtversion,
 275         quarantinelink => $quarantinelink,
 276         theme => $theme,
 277     };
 278
 279     my $template_name;
 280     if (defined($args->{console}) && $args->{xtermjs}) {
 281         $template_name = "index.html.tpl"; # fixme: use better name
 282     } elsif ($mobile && $quarantine) {
 283         $template_name = "pmg-mobile-index.html.tt";
 284     } else {
 285         $template_name = "pmg-index.html.tt";
 286     }
 287
 288     my $tt = get_template_toolkit();
 289
 290     $tt->process($template_name, $vars, \$page) ||
 291         die $tt->error() . "\n";
 292
 293     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 294     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 295
 296     return $resp;
 297 }
 298
 299 1;