src/PMG/Service/pmgproxy.pm

   1 package PMG::Service::pmgproxy;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Daemon;
   8 use HTTP::Response;
   9 use URI;
  10 use URI::Escape;
  11
  12 use URI::QueryParam;
  13 use Data::Dumper;
  14
  15 use PVE::Tools;
  16 use PVE::APIServer::Formatter;
  17 use PVE::APIServer::Formatter::Standard;
  18 use PVE::APIServer::Formatter::HTML;
  19 use PVE::APIServer::AnyEvent;
  20 use PVE::APIServer::Utils;
  21
  22 use PMG::HTTPServer;
  23 use PMG::API2;
  24 use PMG::Config;
  25
  26 use Template;
  27
  28 use base qw(PVE::Daemon);
  29
  30 my $cmdline = [$0, @ARGV];
  31
  32 my %daemon_options = (
  33     max_workers => 3,
  34     restart_on_error => 5,
  35     stop_wait_time => 15,
  36     leave_children_open_on_reload => 1,
  37     setuid => 'www-data',
  38     setgid => 'www-data',
  39     pidfile => '/run/pmgproxy/pmgproxy.pid',
  40 );
  41
  42 my $daemon = __PACKAGE__->new('pmgproxy', $cmdline, %daemon_options);
  43
  44 sub add_dirs {
  45     my ($result_hash, $alias, $subdir) = @_;
  46
  47     PVE::APIServer::AnyEvent::add_dirs($result_hash, $alias, $subdir);
  48 }
  49
  50 my $gui_base_dir = "/usr/share/javascript/pmg-gui";
  51 my $extjs_dir = "/usr/share/javascript/extjs/";
  52 my $fontawesome_dir = "/usr/share/fonts-font-awesome";
  53 my $xtermjs_dir = '/usr/share/pve-xtermjs';
  54 my $framework7_dir = '/usr/share/javascript/framework7';
  55 my $widgettoolkit_dir = '/usr/share/javascript/proxmox-widget-toolkit';
  56
  57 sub init {
  58     my ($self) = @_;
  59
  60     my $proxyconf = PVE::APIServer::Utils::read_proxy_config($self->{name});
  61
  62     my $accept_lock_fn = "/var/lock/pmgproxy.lck";
  63
  64     my $lockfh = IO::File->new(">>${accept_lock_fn}") ||
  65         die "unable to open lock file '${accept_lock_fn}' - $!\n";
  66
  67     my $family = PVE::Tools::get_host_address_family($self->{nodename});
  68     my $socket = $self->create_reusable_socket(8006, undef, $family);
  69
  70     my $dirs = {};
  71
  72     add_dirs($dirs, '/pve2/locale/', '/usr/share/pmg-i18n/');
  73     add_dirs($dirs, '/pve2/ext6/', $extjs_dir);
  74     add_dirs($dirs, '/pve2/images/' => "$gui_base_dir/images/");
  75     add_dirs($dirs, '/pve2/css/' => "$gui_base_dir/css/");
  76     add_dirs($dirs, '/pve2/js/' => "$gui_base_dir/js/");
  77     add_dirs($dirs, '/fontawesome/css/' => "$fontawesome_dir/css/");
  78     add_dirs($dirs, '/fontawesome/fonts/' => "$fontawesome_dir/fonts/");
  79     add_dirs($dirs, '/framework7/fonts/' => "$framework7_dir/fonts/");
  80     add_dirs($dirs, '/framework7/css/' => "$framework7_dir/css/");
  81     add_dirs($dirs, '/framework7/js/' => "$framework7_dir/js/");
  82     add_dirs($dirs, '/xtermjs/' => "$xtermjs_dir/");
  83     add_dirs($dirs, '/pmg-docs/' => '/usr/share/pmg-docs/');
  84     add_dirs($dirs, '/pmg-docs/api-viewer/extjs/' => $extjs_dir);
  85     add_dirs($dirs, '/pwt/css/' => "$widgettoolkit_dir/css/");
  86
  87     $self->{server_config} = {
  88         title => 'Proxmox Mail Gateway API',
  89         cookie_name => 'PMGAuthCookie',
  90         keep_alive => 100,
  91         max_conn => 500,
  92         max_requests => 1000,
  93         lockfile => $accept_lock_fn,
  94         socket => $socket,
  95         lockfh => $lockfh,
  96         debug => $self->{debug},
  97         trusted_env => 0, # not trusted, anyone can connect
  98         logfile => '/var/log/pmgproxy/pmgproxy.log',
  99         allow_from => $proxyconf->{ALLOW_FROM},
 100         deny_from => $proxyconf->{DENY_FROM},
 101         policy => $proxyconf->{POLICY},
 102         ssl => {
 103             cert_file => '/etc/pmg/pmg-api.pem',
 104             dh => 'skip2048',
 105             cipher_list => $proxyconf->{CIPHERS},
 106             honor_cipher_order => $proxyconf->{HONOR_CIPHER_ORDER},
 107         },
 108         compression => $proxyconf->{COMPRESSION},
 109         # Note: there is no authentication for those pages and dirs!
 110         pages => {
 111             '/' => sub { get_index($self->{nodename}, @_) },
 112             '/quarantine' => sub { get_index($self->{nodename}, @_) },
 113             # avoid authentication when accessing favicon
 114             '/favicon.ico' => {
 115                 file => '/usr/share/doc/pmg-api/favicon.ico',
 116             },
 117             '/proxmoxlib.js' => {
 118                 file => '/usr/share/javascript/proxmox-widget-toolkit/proxmoxlib.js',
 119             },
 120         },
 121         dirs => $dirs,
 122     };
 123
 124     if (defined($proxyconf->{DHPARAMS})) {
 125         $self->{server_config}->{ssl}->{dh_file} = $proxyconf->{DHPARAMS};
 126     }
 127 }
 128
 129 sub run {
 130     my ($self) = @_;
 131
 132     my $server = PMG::HTTPServer->new(%{$self->{server_config}});
 133     $server->run();
 134 }
 135
 136 $daemon->register_start_command();
 137 $daemon->register_restart_command(1);
 138 $daemon->register_stop_command();
 139 $daemon->register_status_command();
 140
 141 our $cmddef = {
 142     start => [ __PACKAGE__, 'start', []],
 143     restart => [ __PACKAGE__, 'restart', []],
 144     stop => [ __PACKAGE__, 'stop', []],
 145     status => [ __PACKAGE__, 'status', [], undef, sub { print shift . "\n";} ],
 146 };
 147
 148 my $template_toolkit;
 149
 150 sub get_template_toolkit {
 151
 152     return $template_toolkit if $template_toolkit;
 153
 154     $template_toolkit = Template->new(
 155         { INCLUDE_PATH => [$gui_base_dir, $xtermjs_dir]});
 156
 157     return $template_toolkit;
 158 }
 159
 160 sub is_phone {
 161     my ($ua) = @_;
 162
 163     return 0 if !$ua;
 164
 165     if ($ua =~ m/(
 166         iPhone|
 167         iPod|
 168         Windows\ Phone|
 169         Android|
 170         BlackBerry
 171         )/xi) {
 172         return 1;
 173     }
 174
 175     return 0;
 176 }
 177
 178 sub get_index {
 179     my ($nodename, $server, $r, $args) = @_;
 180
 181     my $lang = 'en';
 182     my $username;
 183     my $token = 'null';
 184     my $quarantine = ($r->uri->path() =~ m/quarantine$/);
 185     my $mobile = is_phone($r->header('User-Agent'));
 186     if (defined($args->{mobile})) {
 187         $mobile = $args->{mobile} ? 1 : 0;
 188     }
 189
 190     if (my $cookie = $r->header('Cookie')) {
 191         if (my $newlang = ($cookie =~ /(?:^|\s)PMGLangCookie=([^;]*)/)[0]) {
 192             if ($newlang =~ m/^[a-z]{2,3}(_[A-Z]{2,3})?$/) {
 193                 $lang = $newlang;
 194             }
 195         }
 196         my $ticket = PVE::APIServer::Formatter::extract_auth_value($cookie, $server->{cookie_name});
 197
 198         if ($ticket =~ m/^PMGQUAR:/) {
 199             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 200         } else {
 201             $username = PMG::Ticket::verify_ticket($ticket, 1);
 202         }
 203     } else {
 204         if (defined($args->{ticket})) {
 205             my $ticket = uri_unescape($args->{ticket});
 206             $username = PMG::Ticket::verify_quarantine_ticket($ticket, 1);
 207         }
 208     }
 209
 210     $token = PMG::Ticket::assemble_csrf_prevention_token($username)
 211         if defined($username);
 212
 213     my $langfile = 0;
 214
 215     if (-f  "/usr/share/pmg-i18n/pmg-lang-$lang.js") {
 216         $langfile = 1;
 217     }
 218
 219     my $wtversionraw = PVE::Tools::file_read_firstline("$widgettoolkit_dir/proxmoxlib.js");
 220     my $wtversion = '';
 221     if ($wtversionraw =~ m|^// (.*)$|) {
 222         $wtversion = $1;
 223     };
 224
 225     my $versionraw = PVE::Tools::file_read_firstline("$gui_base_dir/js/pmgmanagerlib.js");
 226     my $version = '';
 227     if ($versionraw =~ m|^// (.*)$|) {
 228         $version = $1;
 229     };
 230
 231     my $cfg = PMG::Config->new();
 232     my $quarantinelink = $cfg->get('spamquar', 'quarantinelink');
 233
 234     $username = '' if !$username;
 235
 236     my $page = '';
 237
 238     my $vars = {
 239         lang => $lang,
 240         langfile => $langfile,
 241         username => $username,
 242         token => $token,
 243         console => $args->{console},
 244         nodename => $nodename,
 245         debug => $args->{debug} || $server->{debug},
 246         version => $version,
 247         wtversion => $wtversion,
 248         quarantinelink => $quarantinelink,
 249     };
 250
 251     my $template_name;
 252     if (defined($args->{console}) && $args->{xtermjs}) {
 253         $template_name = "index.html.tpl"; # fixme: use better name
 254     } elsif ($mobile && $quarantine) {
 255         $template_name = "pmg-mobile-index.html.tt";
 256     } else {
 257         $template_name = "pmg-index.html.tt";
 258     }
 259
 260     my $tt = get_template_toolkit();
 261
 262     $tt->process($template_name, $vars, \$page) ||
 263         die $tt->error() . "\n";
 264
 265     my $headers = HTTP::Headers->new(Content_Type => "text/html; charset=utf-8");
 266     my $resp = HTTP::Response->new(200, "OK", $headers, $page);
 267
 268     return $resp;
 269 }
 270
 271 1;