src/PMG/Utils.pm

   1 package PMG::Utils;
   2
   3 use strict;
   4 use warnings;
   5 use DBI;
   6 use Net::Cmd;
   7 use Net::SMTP;
   8 use IO::File;
   9 use File::stat;
  10 use POSIX qw(strftime);
  11 use File::stat;
  12 use File::Basename;
  13 use MIME::Entity;
  14 use MIME::Words;
  15 use MIME::Parser;
  16 use Time::HiRes qw (gettimeofday);
  17 use Time::Local;
  18 use Xdgmime;
  19 use Data::Dumper;
  20 use Digest::SHA;
  21 use Digest::MD5;
  22 use Net::IP;
  23 use Socket;
  24 use RRDs;
  25 use Filesys::Df;
  26 use Encode;
  27 use utf8;
  28 no utf8;
  29
  30 use HTML::Entities;
  31 use JSON;
  32
  33 use PVE::ProcFSTools;
  34 use PVE::Network;
  35 use PVE::Tools;
  36 use PVE::SafeSyslog;
  37 use PVE::ProcFSTools;
  38 use PMG::AtomicFile;
  39 use PMG::MailQueue;
  40 use PMG::SMTPPrinter;
  41 use PMG::MIMEUtils;
  42
  43 use base 'Exporter';
  44
  45 our @EXPORT_OK = qw(
  46 postgres_admin_cmd
  47 );
  48
  49 my $valid_pmg_realms = ['pam', 'pmg', 'quarantine'];
  50
  51 PVE::JSONSchema::register_standard_option('realm', {
  52     description => "Authentication domain ID",
  53     type => 'string',
  54     enum => $valid_pmg_realms,
  55     maxLength => 32,
  56 });
  57
  58 PVE::JSONSchema::register_standard_option('pmg-starttime', {
  59     description => "Only consider entries newer than 'starttime' (unix epoch). Default is 'now - 1day'.",
  60     type => 'integer',
  61     minimum => 0,
  62     optional => 1,
  63 });
  64
  65 PVE::JSONSchema::register_standard_option('pmg-endtime', {
  66     description => "Only consider entries older than 'endtime' (unix epoch). This is set to '<start> + 1day' by default.",
  67     type => 'integer',
  68     minimum => 1,
  69     optional => 1,
  70 });
  71
  72 PVE::JSONSchema::register_format('pmg-userid', \&verify_username);
  73 sub verify_username {
  74     my ($username, $noerr) = @_;
  75
  76     $username = '' if !$username;
  77     my $len = length($username);
  78     if ($len < 3) {
  79         die "user name '$username' is too short\n" if !$noerr;
  80         return undef;
  81     }
  82     if ($len > 64) {
  83         die "user name '$username' is too long ($len > 64)\n" if !$noerr;
  84         return undef;
  85     }
  86
  87     # we only allow a limited set of characters
  88     # colon is not allowed, because we store usernames in
  89     # colon separated lists)!
  90     # slash is not allowed because it is used as pve API delimiter
  91     # also see "man useradd"
  92     my $realm_list = join('|', @$valid_pmg_realms);
  93     if ($username =~ m!^([^\s:/]+)\@(${realm_list})$!) {
  94         return wantarray ? ($username, $1, $2) : $username;
  95     }
  96
  97     die "value '$username' does not look like a valid user name\n" if !$noerr;
  98
  99     return undef;
 100 }
 101
 102 PVE::JSONSchema::register_standard_option('userid', {
 103     description => "User ID",
 104     type => 'string', format => 'pmg-userid',
 105     minLength => 4,
 106     maxLength => 64,
 107 });
 108
 109 PVE::JSONSchema::register_standard_option('username', {
 110     description => "Username (without realm)",
 111     type => 'string',
 112     pattern => '[^\s:\/\@]{3,60}',
 113     minLength => 4,
 114     maxLength => 64,
 115 });
 116
 117 PVE::JSONSchema::register_standard_option('pmg-email-address', {
 118     description => "Email Address (allow most characters).",
 119     type => 'string',
 120     pattern => '(?:[^\s\/\\\@]+\@[^\s\/\\\@]+)',
 121     maxLength => 512,
 122     minLength => 3,
 123 });
 124
 125 PVE::JSONSchema::register_standard_option('pmg-whiteblacklist-entry-list', {
 126     description => "White/Blacklist entry list (allow most characters). Can contain globs",
 127     type => 'string',
 128     pattern => '(?:[^\s\/\\\;\,]+)(?:\,[^\s\/\\\;\,]+)*',
 129     minLength => 3,
 130 });
 131
 132 sub lastid {
 133     my ($dbh, $seq) = @_;
 134
 135     return $dbh->last_insert_id(
 136         undef, undef, undef, undef, { sequence => $seq});
 137 }
 138
 139 # quote all regex operators
 140 sub quote_regex {
 141     my $val = shift;
 142
 143     $val =~ s/([\(\)\[\]\/\}\+\*\?\.\|\^\$\\])/\\$1/g;
 144
 145     return $val;
 146 }
 147
 148 sub file_older_than {
 149     my ($filename, $lasttime) = @_;
 150
 151     my $st = stat($filename);
 152
 153     return 0 if !defined($st);
 154
 155     return ($lasttime >= $st->ctime);
 156 }
 157
 158 sub extract_filename {
 159     my ($head) = @_;
 160
 161     if (my $value = $head->recommended_filename()) {
 162         chomp $value;
 163         if (my $decvalue = MIME::Words::decode_mimewords($value)) {
 164             $decvalue =~ s/\0/ /g;
 165             $decvalue = PVE::Tools::trim($decvalue);
 166             return $decvalue;
 167         }
 168     }
 169
 170     return undef;
 171 }
 172
 173 sub remove_marks {
 174     my ($entity, $add_id) = @_;
 175
 176     my $id = 1;
 177
 178     PMG::MIMEUtils::traverse_mime_parts($entity, sub {
 179         my ($part) = @_;
 180         foreach my $tag (grep {/^x-proxmox-tmp/i} $part->head->tags) {
 181             $part->head->delete($tag);
 182         }
 183
 184         $part->head->replace('X-Proxmox-tmp-AID', $id) if $add_id;
 185
 186         $id++;
 187     });
 188 }
 189
 190 sub subst_values {
 191     my ($body, $dh) = @_;
 192
 193     return if !$body;
 194
 195     foreach my $k (keys %$dh) {
 196         my $v = $dh->{$k};
 197         if (defined($v)) {
 198             $body =~ s/__\Q${k}\E__/$v/gs;
 199         }
 200     }
 201
 202     return $body;
 203 }
 204
 205 sub reinject_mail {
 206     my ($entity, $sender, $targets, $xforward, $me, $nodsn) = @_;
 207
 208     my $smtp;
 209     my $resid;
 210     my $rescode;
 211     my $resmess;
 212
 213     eval {
 214         my $smtp = Net::SMTP->new('127.0.0.1', Port => 10025, Hello => $me) ||
 215             die "unable to connect to localhost at port 10025";
 216
 217         if (defined($xforward)) {
 218             my $xfwd;
 219
 220             foreach my $attr (keys %{$xforward}) {
 221                 $xfwd .= " $attr=$xforward->{$attr}";
 222             }
 223
 224             if ($xfwd && $smtp->command("XFORWARD", $xfwd)->response() != CMD_OK) {
 225                 syslog('err', "xforward error - got: %s %s", $smtp->code, scalar($smtp->message));
 226             }
 227         }
 228
 229         my $has_utf8_targets = 0;
 230         foreach my $target (@$targets) {
 231             if (utf8::is_utf8($target)) {
 232                 $has_utf8_targets = 1;
 233                 last;
 234             }
 235         }
 236
 237         my $mail_opts = " BODY=8BITMIME";
 238         my $sender_addr;
 239         if (utf8::is_utf8($sender)) {
 240             $sender_addr = encode('UTF-8', $smtp->_addr($sender));
 241             $mail_opts .= " SMTPUTF8";
 242         } else {
 243             $sender_addr = $smtp->_addr($sender);
 244             $mail_opts .= " SMTPUTF8" if $has_utf8_targets;
 245         }
 246
 247         if (!$smtp->_MAIL("FROM:" . $sender_addr . $mail_opts)) {
 248             syslog('err', "smtp error - got: %s %s", $smtp->code, scalar ($smtp->message));
 249             die "smtp from: ERROR";
 250         }
 251
 252         my $rcpt_opts = $nodsn ? " NOTIFY=NEVER" : "";
 253
 254         foreach my $target (@$targets) {
 255             my $rcpt_addr;
 256             if (utf8::is_utf8($target)) {
 257                 $rcpt_addr = encode('UTF-8', $smtp->_addr($target));
 258             } else {
 259                 $rcpt_addr = $smtp->_addr($target);
 260             }
 261             if (!$smtp->_RCPT("TO:" . $rcpt_addr . $rcpt_opts)) {
 262                 syslog ('err', "smtp error - got: %s %s", $smtp->code, scalar($smtp->message));
 263                 die "smtp to: ERROR";
 264             }
 265         }
 266
 267         # Output the head:
 268         #$entity->sync_headers ();
 269         $smtp->data();
 270
 271         my $out = PMG::SMTPPrinter->new($smtp);
 272         $entity->print($out);
 273
 274         # make sure we always have a newline at the end of the mail
 275         # else dataend() fails
 276         $smtp->datasend("\n");
 277
 278         if ($smtp->dataend()) {
 279             my @msgs = $smtp->message;
 280             $resmess = $msgs[$#msgs];
 281             ($resid) = $resmess =~ m/Ok: queued as ([0-9A-Z]+)/;
 282             $rescode = $smtp->code;
 283             if (!$resid) {
 284                 die sprintf("unexpected SMTP result - got: %s %s : WARNING", $smtp->code, $resmess);
 285             }
 286         } else {
 287             my @msgs = $smtp->message;
 288             $resmess = $msgs[$#msgs];
 289             $rescode = $smtp->code;
 290             die sprintf("sending data failed - got: %s %s : ERROR", $smtp->code, $resmess);
 291         }
 292     };
 293     my $err = $@;
 294
 295     $smtp->quit if $smtp;
 296
 297     if ($err) {
 298         syslog ('err', $err);
 299     }
 300
 301     return wantarray ? ($resid, $rescode, $resmess) : $resid;
 302 }
 303
 304 sub analyze_custom_check {
 305     my ($queue, $dname, $pmg_cfg) = @_;
 306
 307     my $enable_custom_check = $pmg_cfg->get('admin', 'custom_check');
 308     return undef if !$enable_custom_check;
 309
 310     my $timeout = 60*5;
 311     my $customcheck_exe = $pmg_cfg->get('admin', 'custom_check_path');
 312     my $customcheck_apiver = 'v1';
 313     my ($csec, $usec) = gettimeofday();
 314
 315     my $vinfo;
 316     my $spam_score;
 317
 318     eval {
 319
 320         my $log_err = sub {
 321             my ($errmsg) = @_;
 322             $errmsg =~ s/%/%%/;
 323             syslog('err', $errmsg);
 324         };
 325
 326         my $customcheck_output_apiver;
 327         my $have_result;
 328         my $parser = sub {
 329             my ($line) = @_;
 330
 331             my $result_flag;
 332             if ($line =~ /^v\d$/) {
 333                 die "api version already defined!\n" if defined($customcheck_output_apiver);
 334                 $customcheck_output_apiver = $line;
 335                 die "api version mismatch - expected $customcheck_apiver, got $customcheck_output_apiver !\n"
 336                     if ($customcheck_output_apiver ne $customcheck_apiver);
 337             } elsif ($line =~ /^SCORE: (-?[0-9]+|.[0-9]+|[0-9]+.[0-9]+)$/) {
 338                 $spam_score = $1;
 339                 $result_flag = 1;
 340             } elsif ($line =~ /^VIRUS: (.+)$/) {
 341                 $vinfo = $1;
 342                 $result_flag = 1;
 343             } elsif ($line =~ /^OK$/) {
 344                 $result_flag = 1;
 345             } else {
 346                 die "got unexpected output!\n";
 347             }
 348             die "got more than 1 result outputs\n" if ( $have_result && $result_flag);
 349             $have_result = $result_flag;
 350         };
 351
 352         PVE::Tools::run_command([$customcheck_exe, $customcheck_apiver, $dname],
 353             errmsg => "$queue->{logid} custom check error",
 354             errfunc => $log_err, outfunc => $parser, timeout => $timeout);
 355
 356         die "no api version returned\n" if !defined($customcheck_output_apiver);
 357         die "no result output!\n" if !$have_result;
 358     };
 359     my $err = $@;
 360
 361     if ($vinfo) {
 362         syslog('info', "$queue->{logid}: virus detected: $vinfo (custom)");
 363     }
 364
 365     my ($csec_end, $usec_end) = gettimeofday();
 366     $queue->{ptime_custom} =
 367         int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 368
 369     if ($err) {
 370         syslog ('err', $err);
 371         $vinfo = undef;
 372         $queue->{errors} = 1;
 373     }
 374
 375     $queue->{vinfo_custom} = $vinfo;
 376     $queue->{spam_custom} = $spam_score;
 377
 378     return ($vinfo, $spam_score);
 379 }
 380
 381 sub analyze_virus_clam {
 382     my ($queue, $dname, $pmg_cfg) = @_;
 383
 384     my $timeout = 60*5;
 385     my $vinfo;
 386
 387     my $clamdscan_opts = "--stdout";
 388
 389     my ($csec, $usec) = gettimeofday();
 390
 391     my $previous_alarm;
 392
 393     eval {
 394
 395         $previous_alarm = alarm($timeout);
 396
 397         $SIG{ALRM} = sub {
 398             die "$queue->{logid}: Maximum time ($timeout sec) exceeded. " .
 399                 "virus analyze (clamav) failed: ERROR";
 400         };
 401
 402         open(CMD, "/usr/bin/clamdscan $clamdscan_opts '$dname'|") ||
 403             die "$queue->{logid}: can't exec clamdscan: $! : ERROR";
 404
 405         my $ifiles;
 406
 407         my $response = '';
 408         while (defined(my $line = <CMD>)) {
 409             if ($line =~ m/^$dname.*:\s+([^ :]*)\s+FOUND$/) {
 410                 # we just use the first detected virus name
 411                 $vinfo = $1 if !$vinfo;
 412             } elsif ($line =~ m/^Infected files:\s(\d*)$/i) {
 413                 $ifiles = $1;
 414             }
 415
 416             $response .= $line;
 417         }
 418
 419         close(CMD);
 420
 421         alarm(0); # avoid race conditions
 422
 423         if (!defined($ifiles)) {
 424             die "$queue->{logid}: got undefined output from " .
 425                 "virus detector: $response : ERROR";
 426         }
 427
 428         if ($vinfo) {
 429             syslog('info', "$queue->{logid}: virus detected: $vinfo (clamav)");
 430         }
 431     };
 432     my $err = $@;
 433
 434     alarm($previous_alarm);
 435
 436     my ($csec_end, $usec_end) = gettimeofday();
 437     $queue->{ptime_clam} =
 438         int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 439
 440     if ($err) {
 441         syslog ('err', $err);
 442         $vinfo = undef;
 443         $queue->{errors} = 1;
 444     }
 445
 446     $queue->{vinfo_clam} = $vinfo;
 447
 448     return $vinfo ? "$vinfo (clamav)" : undef;
 449 }
 450
 451 sub analyze_virus_avast {
 452     my ($queue, $dname, $pmg_cfg) = @_;
 453
 454     my $timeout = 60*5;
 455     my $vinfo;
 456
 457     my ($csec, $usec) = gettimeofday();
 458
 459     my $previous_alarm;
 460
 461     eval {
 462
 463         $previous_alarm = alarm($timeout);
 464
 465         $SIG{ALRM} = sub {
 466             die "$queue->{logid}: Maximum time ($timeout sec) exceeded. " .
 467                 "virus analyze (avast) failed: ERROR";
 468         };
 469
 470         open(my $cmd, '-|', 'scan', $dname) ||
 471             die "$queue->{logid}: can't exec avast scan: $! : ERROR";
 472
 473         my $response = '';
 474         while (defined(my $line = <$cmd>)) {
 475             if ($line =~ m/^$dname\s+(.*\S)\s*$/) {
 476                 # we just use the first detected virus name
 477                 $vinfo = $1 if !$vinfo;
 478             }
 479
 480             $response .= $line;
 481         }
 482
 483         close($cmd);
 484
 485         alarm(0); # avoid race conditions
 486
 487         if ($vinfo) {
 488             syslog('info', "$queue->{logid}: virus detected: $vinfo (avast)");
 489         }
 490     };
 491     my $err = $@;
 492
 493     alarm($previous_alarm);
 494
 495     my ($csec_end, $usec_end) = gettimeofday();
 496     $queue->{ptime_clam} =
 497         int (($csec_end-$csec)*1000 + ($usec_end - $usec)/1000);
 498
 499     if ($err) {
 500         syslog ('err', $err);
 501         $vinfo = undef;
 502         $queue->{errors} = 1;
 503     }
 504
 505     return undef if !$vinfo;
 506
 507     $queue->{vinfo_avast} = $vinfo;
 508
 509     return "$vinfo (avast)";
 510 }
 511
 512 sub analyze_virus {
 513     my ($queue, $filename, $pmg_cfg, $testmode) = @_;
 514
 515     # TODO: support other virus scanners?
 516
 517     if ($testmode) {
 518         my $vinfo_clam = analyze_virus_clam($queue, $filename, $pmg_cfg);
 519         my $vinfo_avast = analyze_virus_avast($queue, $filename, $pmg_cfg);
 520
 521         return $vinfo_avast || $vinfo_clam;
 522     }
 523
 524     my $enable_avast  = $pmg_cfg->get('admin', 'avast');
 525
 526     if ($enable_avast) {
 527         if (my $vinfo = analyze_virus_avast($queue, $filename, $pmg_cfg)) {
 528             return $vinfo;
 529         }
 530     }
 531
 532     my $enable_clamav = $pmg_cfg->get('admin', 'clamav');
 533
 534     if ($enable_clamav) {
 535         if (my $vinfo = analyze_virus_clam($queue, $filename, $pmg_cfg)) {
 536             return $vinfo;
 537         }
 538     }
 539
 540     return undef;
 541 }
 542
 543 sub magic_mime_type_for_file {
 544     my ($filename) = @_;
 545
 546     # we do not use get_mime_type_for_file, because that considers
 547     # filename extensions - we only want magic type detection
 548
 549     my $bufsize = Xdgmime::xdg_mime_get_max_buffer_extents();
 550     die "got strange value for max_buffer_extents" if $bufsize > 4096*10;
 551
 552     my $ct = "application/octet-stream";
 553
 554     my $fh = IO::File->new("<$filename") ||
 555         die "unable to open file '$filename' - $!";
 556
 557     my ($buf, $len);
 558     if (($len = $fh->read($buf, $bufsize)) > 0) {
 559         $ct = xdg_mime_get_mime_type_for_data($buf, $len);
 560     }
 561     $fh->close();
 562
 563     die "unable to read file '$filename' - $!" if ($len < 0);
 564
 565     return $ct;
 566 }
 567
 568 sub add_ct_marks {
 569     my ($entity) = @_;
 570
 571     if (my $path = $entity->{PMX_decoded_path}) {
 572
 573         # set a reasonable default if magic does not give a result
 574         $entity->{PMX_magic_ct} = $entity->head->mime_attr('content-type');
 575
 576         if (my $ct = magic_mime_type_for_file($path)) {
 577             if ($ct ne 'application/octet-stream' || !$entity->{PMX_magic_ct}) {
 578                 $entity->{PMX_magic_ct} = $ct;
 579             }
 580         }
 581
 582         my $filename = $entity->head->recommended_filename;
 583         $filename = basename($path) if !defined($filename) || $filename eq '';
 584
 585         if (my $ct = xdg_mime_get_mime_type_from_file_name($filename)) {
 586             $entity->{PMX_glob_ct} = $ct;
 587         }
 588     }
 589
 590     foreach my $part ($entity->parts)  {
 591         add_ct_marks ($part);
 592     }
 593 }
 594
 595 # x509 certificate utils
 596
 597 # only write output if something fails
 598 sub run_silent_cmd {
 599     my ($cmd) = @_;
 600
 601     my $outbuf = '';
 602
 603     my $record_output = sub {
 604         $outbuf .= shift;
 605         $outbuf .= "\n";
 606     };
 607
 608     eval {
 609         PVE::Tools::run_command($cmd, outfunc => $record_output,
 610                                 errfunc => $record_output);
 611     };
 612     my $err = $@;
 613
 614     if ($err) {
 615         print STDERR $outbuf;
 616         die $err;
 617     }
 618 }
 619
 620 my $proxmox_tls_cert_fn = "/etc/pmg/pmg-tls.pem";
 621
 622 sub gen_proxmox_tls_cert {
 623     my ($force) = @_;
 624
 625     my $resolv = PVE::INotify::read_file('resolvconf');
 626     my $domain = $resolv->{search};
 627
 628     my $company = $domain; # what else ?
 629     my $cn = "*.$domain";
 630
 631    return if !$force && -f $proxmox_tls_cert_fn;
 632
 633     my $sslconf = <<__EOD__;
 634 RANDFILE = /root/.rnd
 635 extensions = v3_req
 636
 637 [ req ]
 638 default_bits = 4096
 639 distinguished_name = req_distinguished_name
 640 req_extensions = v3_req
 641 prompt = no
 642 string_mask = nombstr
 643
 644 [ req_distinguished_name ]
 645 organizationalUnitName = Proxmox Mail Gateway
 646 organizationName = $company
 647 commonName = $cn
 648
 649 [ v3_req ]
 650 basicConstraints = CA:FALSE
 651 nsCertType = server
 652 keyUsage = nonRepudiation, digitalSignature, keyEncipherment
 653 __EOD__
 654
 655     my $cfgfn = "/tmp/pmgtlsconf-$$.tmp";
 656     my $fh = IO::File->new ($cfgfn, "w");
 657     print $fh $sslconf;
 658     close ($fh);
 659
 660     eval {
 661         my $cmd = ['openssl', 'req', '-batch', '-x509', '-new', '-sha256',
 662                    '-config', $cfgfn, '-days', 3650, '-nodes',
 663                    '-out', $proxmox_tls_cert_fn,
 664                    '-keyout', $proxmox_tls_cert_fn];
 665         run_silent_cmd($cmd);
 666     };
 667
 668     if (my $err = $@) {
 669         unlink $proxmox_tls_cert_fn;
 670         unlink $cfgfn;
 671         die "unable to generate proxmox certificate request:\n$err";
 672     }
 673
 674     unlink $cfgfn;
 675 }
 676
 677 sub find_local_network_for_ip {
 678     my ($ip, $noerr) = @_;
 679
 680     my $testip = Net::IP->new($ip);
 681
 682     my $isv6 = $testip->version == 6;
 683     my $routes = $isv6 ?
 684         PVE::ProcFSTools::read_proc_net_ipv6_route() :
 685         PVE::ProcFSTools::read_proc_net_route();
 686
 687     foreach my $entry (@$routes) {
 688         my $mask;
 689         if ($isv6) {
 690             $mask = $entry->{prefix};
 691             next if !$mask; # skip the default route...
 692         } else {
 693             $mask = $PVE::Network::ipv4_mask_hash_localnet->{$entry->{mask}};
 694             next if !defined($mask);
 695         }
 696         my $cidr = "$entry->{dest}/$mask";
 697         my $testnet = Net::IP->new($cidr);
 698         my $overlap = $testnet->overlaps($testip);
 699         if ($overlap == $Net::IP::IP_B_IN_A_OVERLAP ||
 700             $overlap == $Net::IP::IP_IDENTICAL)
 701         {
 702             return $cidr;
 703         }
 704     }
 705
 706     return undef if $noerr;
 707
 708     die "unable to detect local network for ip '$ip'\n";
 709 }
 710
 711 my $service_aliases = {
 712     'postfix' =>  'postfix@-',
 713     'postgres' => 'postgresql@11-main',
 714 };
 715
 716 sub lookup_real_service_name {
 717     my $alias = shift;
 718
 719     return $service_aliases->{$alias} // $alias;
 720 }
 721
 722 sub get_full_service_state {
 723     my ($service) = @_;
 724
 725     my $res;
 726
 727     my $parser = sub {
 728         my $line = shift;
 729         if ($line =~ m/^([^=\s]+)=(.*)$/) {
 730             $res->{$1} = $2;
 731         }
 732     };
 733
 734     $service = $service_aliases->{$service} // $service;
 735     PVE::Tools::run_command(['systemctl', 'show', $service], outfunc => $parser);
 736
 737     return $res;
 738 }
 739
 740 our $db_service_list = [
 741     'pmgpolicy', 'pmgmirror', 'pmgtunnel', 'pmg-smtp-filter' ];
 742
 743 sub service_wait_stopped {
 744     my ($timeout, $service_list) = @_;
 745
 746     my $starttime = time();
 747
 748     foreach my $service (@$service_list) {
 749         PVE::Tools::run_command(['systemctl', 'stop', $service]);
 750     }
 751
 752     while (1) {
 753         my $wait = 0;
 754
 755         foreach my $service (@$service_list) {
 756             my $ss = get_full_service_state($service);
 757             my $state = $ss->{ActiveState} // 'unknown';
 758
 759             if ($state ne 'inactive') {
 760                 if ((time() - $starttime) > $timeout) {
 761                     syslog('err', "unable to stop services (got timeout)");
 762                     $wait = 0;
 763                     last;
 764                 }
 765                 $wait = 1;
 766             }
 767         }
 768
 769         last if !$wait;
 770
 771         sleep(1);
 772     }
 773 }
 774
 775 sub service_cmd {
 776     my ($service, $cmd) = @_;
 777
 778     die "unknown service command '$cmd'\n"
 779         if $cmd !~ m/^(start|stop|restart|reload|reload-or-restart)$/;
 780
 781     if ($service eq 'pmgdaemon' || $service eq 'pmgproxy') {
 782         die "invalid service cmd '$service $cmd': ERROR" if $cmd eq 'stop';
 783     } elsif ($service eq 'fetchmail') {
 784         # use restart instead of start - else it does not start 'exited' unit
 785         # after setting START_DAEMON=yes in /etc/default/fetchmail
 786         $cmd = 'restart' if $cmd eq 'start';
 787     }
 788
 789     $service = $service_aliases->{$service} // $service;
 790     PVE::Tools::run_command(['systemctl', $cmd, $service]);
 791 };
 792
 793 sub run_postmap {
 794     my ($filename) = @_;
 795
 796     # make sure the file exists (else postmap fails)
 797     IO::File->new($filename, 'a', 0644);
 798
 799     my $mtime_src = (CORE::stat($filename))[9] //
 800         die "unbale to read mtime of $filename\n";
 801
 802     my $mtime_dst = (CORE::stat("$filename.db"))[9] // 0;
 803
 804     # if not changed, do nothing
 805     return if $mtime_src <= $mtime_dst;
 806
 807     eval {
 808         PVE::Tools::run_command(
 809             ['/usr/sbin/postmap', $filename],
 810             errmsg => "unable to update postfix table $filename");
 811     };
 812     my $err = $@;
 813
 814     warn $err if $err;
 815 }
 816
 817 sub clamav_dbstat {
 818
 819     my $res = [];
 820
 821     my $read_cvd_info = sub {
 822         my ($dbname, $dbfile) = @_;
 823
 824         my $header;
 825         my $fh = IO::File->new("<$dbfile");
 826         if (!$fh) {
 827             warn "cant open ClamAV Database $dbname ($dbfile) - $!\n";
 828             return;
 829         }
 830         $fh->read($header, 512);
 831         $fh->close();
 832
 833         ## ClamAV-VDB:16 Mar 2016 23-17 +0000:57:4218790:60:06386f34a16ebeea2733ab037f0536be:
 834         if ($header =~ m/^(ClamAV-VDB):([^:]+):(\d+):(\d+):/) {
 835             my ($ftype, $btime, $version, $nsigs) = ($1, $2, $3, $4);
 836             push @$res, {
 837                 name => $dbname,
 838                 type => $ftype,
 839                 build_time => $btime,
 840                 version => $version,
 841                 nsigs => $nsigs,
 842             };
 843         } else {
 844             warn "unable to parse ClamAV Database $dbname ($dbfile)\n";
 845         }
 846     };
 847
 848     # main database
 849     my $filename = "/var/lib/clamav/main.inc/main.info";
 850     $filename = "/var/lib/clamav/main.cvd" if ! -f $filename;
 851
 852     $read_cvd_info->('main', $filename) if -f $filename;
 853
 854     # daily database
 855     $filename = "/var/lib/clamav/daily.inc/daily.info";
 856     $filename = "/var/lib/clamav/daily.cvd" if ! -f $filename;
 857     $filename = "/var/lib/clamav/daily.cld" if ! -f $filename;
 858
 859     $read_cvd_info->('daily', $filename) if -f $filename;
 860
 861     $filename = "/var/lib/clamav/bytecode.cvd";
 862     $read_cvd_info->('bytecode', $filename) if -f $filename;
 863
 864     $filename = "/var/lib/clamav/safebrowsing.cvd";
 865     $read_cvd_info->('safebrowsing', $filename) if -f $filename;
 866
 867     my $ss_dbs_fn = "/var/lib/clamav-unofficial-sigs/configs/ss-include-dbs.txt";
 868     my $ss_dbs_files = {};
 869     if (my $ssfh = IO::File->new("<${ss_dbs_fn}")) {
 870         while (defined(my $line = <$ssfh>)) {
 871             chomp $line;
 872             $ss_dbs_files->{$line} = 1;
 873         }
 874     }
 875     my $last = 0;
 876     my $nsigs = 0;
 877     foreach $filename (</var/lib/clamav/*>) {
 878         my $fn = basename($filename);
 879         next if !$ss_dbs_files->{$fn};
 880
 881         my $fh = IO::File->new("<$filename");
 882         next if !defined($fh);
 883         my $st = stat($fh);
 884         next if !$st;
 885         my $mtime = $st->mtime();
 886         $last = $mtime if $mtime > $last;
 887         while (defined(my $line = <$fh>)) { $nsigs++; }
 888     }
 889
 890     if ($nsigs > 0) {
 891         push @$res, {
 892             name => 'sanesecurity',
 893             type => 'unofficial',
 894             build_time => strftime("%d %b %Y %H-%M %z", localtime($last)),
 895             nsigs => $nsigs,
 896         };
 897     }
 898
 899     return $res;
 900 }
 901
 902 # RRD related code
 903 my $rrd_dir = "/var/lib/rrdcached/db";
 904 my $rrdcached_socket = "/var/run/rrdcached.sock";
 905
 906 my $rrd_def_node = [
 907     "DS:loadavg:GAUGE:120:0:U",
 908     "DS:maxcpu:GAUGE:120:0:U",
 909     "DS:cpu:GAUGE:120:0:U",
 910     "DS:iowait:GAUGE:120:0:U",
 911     "DS:memtotal:GAUGE:120:0:U",
 912     "DS:memused:GAUGE:120:0:U",
 913     "DS:swaptotal:GAUGE:120:0:U",
 914     "DS:swapused:GAUGE:120:0:U",
 915     "DS:roottotal:GAUGE:120:0:U",
 916     "DS:rootused:GAUGE:120:0:U",
 917     "DS:netin:DERIVE:120:0:U",
 918     "DS:netout:DERIVE:120:0:U",
 919
 920     "RRA:AVERAGE:0.5:1:70", # 1 min avg - one hour
 921     "RRA:AVERAGE:0.5:30:70", # 30 min avg - one day
 922     "RRA:AVERAGE:0.5:180:70", # 3 hour avg - one week
 923     "RRA:AVERAGE:0.5:720:70", # 12 hour avg - one month
 924     "RRA:AVERAGE:0.5:10080:70", # 7 day avg - ony year
 925
 926     "RRA:MAX:0.5:1:70", # 1 min max - one hour
 927     "RRA:MAX:0.5:30:70", # 30 min max - one day
 928     "RRA:MAX:0.5:180:70", # 3 hour max - one week
 929     "RRA:MAX:0.5:720:70", # 12 hour max - one month
 930     "RRA:MAX:0.5:10080:70", # 7 day max - ony year
 931 ];
 932
 933 sub cond_create_rrd_file {
 934     my ($filename, $rrddef) = @_;
 935
 936     return if -f $filename;
 937
 938     my @args = ($filename);
 939
 940     push @args, "--daemon" => "unix:${rrdcached_socket}"
 941         if -S $rrdcached_socket;
 942
 943     push @args, '--step', 60;
 944
 945     push @args, @$rrddef;
 946
 947     # print "TEST: " . join(' ', @args) . "\n";
 948
 949     RRDs::create(@args);
 950     my $err = RRDs::error;
 951     die "RRD error: $err\n" if $err;
 952 }
 953
 954 sub update_node_status_rrd {
 955
 956     my $filename = "$rrd_dir/pmg-node-v1.rrd";
 957     cond_create_rrd_file($filename, $rrd_def_node);
 958
 959     my ($avg1, $avg5, $avg15) = PVE::ProcFSTools::read_loadavg();
 960
 961     my $stat = PVE::ProcFSTools::read_proc_stat();
 962
 963     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 964
 965     my ($uptime) = PVE::ProcFSTools::read_proc_uptime();
 966
 967     my $cpuinfo = PVE::ProcFSTools::read_cpuinfo();
 968
 969     my $maxcpu = $cpuinfo->{cpus};
 970
 971     # traffic from/to physical interface cards
 972     my $netin = 0;
 973     my $netout = 0;
 974     foreach my $dev (keys %$netdev) {
 975         next if $dev !~ m/^$PVE::Network::PHYSICAL_NIC_RE$/;
 976         $netin += $netdev->{$dev}->{receive};
 977         $netout += $netdev->{$dev}->{transmit};
 978     }
 979
 980     my $meminfo = PVE::ProcFSTools::read_meminfo();
 981
 982     my $dinfo = df('/', 1); # output is bytes
 983
 984     my $ctime = time();
 985
 986     # everything not free is considered to be used
 987     my $dused = $dinfo->{blocks} - $dinfo->{bfree};
 988
 989     my $data = "$ctime:$avg1:$maxcpu:$stat->{cpu}:$stat->{wait}:" .
 990         "$meminfo->{memtotal}:$meminfo->{memused}:" .
 991         "$meminfo->{swaptotal}:$meminfo->{swapused}:" .
 992         "$dinfo->{blocks}:$dused:$netin:$netout";
 993
 994
 995     my @args = ($filename);
 996
 997     push @args, "--daemon" => "unix:${rrdcached_socket}"
 998         if -S $rrdcached_socket;
 999
1000     push @args, $data;
1001
1002     # print "TEST: " . join(' ', @args) . "\n";
1003
1004     RRDs::update(@args);
1005     my $err = RRDs::error;
1006     die "RRD error: $err\n" if $err;
1007 }
1008
1009 sub create_rrd_data {
1010     my ($rrdname, $timeframe, $cf) = @_;
1011
1012     my $rrd = "${rrd_dir}/$rrdname";
1013
1014     my $setup = {
1015         hour =>  [ 60, 70 ],
1016         day  =>  [ 60*30, 70 ],
1017         week =>  [ 60*180, 70 ],
1018         month => [ 60*720, 70 ],
1019         year =>  [ 60*10080, 70 ],
1020     };
1021
1022     my ($reso, $count) = @{$setup->{$timeframe}};
1023     my $ctime  = $reso*int(time()/$reso);
1024     my $req_start = $ctime - $reso*$count;
1025
1026     $cf = "AVERAGE" if !$cf;
1027
1028     my @args = (
1029         "-s" => $req_start,
1030         "-e" => $ctime - 1,
1031         "-r" => $reso,
1032         );
1033
1034     push @args, "--daemon" => "unix:${rrdcached_socket}"
1035         if -S $rrdcached_socket;
1036
1037     my ($start, $step, $names, $data) = RRDs::fetch($rrd, $cf, @args);
1038
1039     my $err = RRDs::error;
1040     die "RRD error: $err\n" if $err;
1041
1042     die "got wrong time resolution ($step != $reso)\n"
1043         if $step != $reso;
1044
1045     my $res = [];
1046     my $fields = scalar(@$names);
1047     for my $line (@$data) {
1048         my $entry = { 'time' => $start };
1049         $start += $step;
1050         for (my $i = 0; $i < $fields; $i++) {
1051             my $name = $names->[$i];
1052             if (defined(my $val = $line->[$i])) {
1053                 $entry->{$name} = $val;
1054             } else {
1055                 # leave empty fields undefined
1056                 # maybe make this configurable?
1057             }
1058         }
1059         push @$res, $entry;
1060     }
1061
1062     return $res;
1063 }
1064
1065 sub decode_to_html {
1066     my ($charset, $data) = @_;
1067
1068     my $res = $data;
1069
1070     eval { $res = encode_entities(decode($charset, $data)); };
1071
1072     return $res;
1073 }
1074
1075 sub decode_rfc1522 {
1076     my ($enc) = @_;
1077
1078     my $res = '';
1079
1080     return '' if !$enc;
1081
1082     eval {
1083         foreach my $r (MIME::Words::decode_mimewords($enc)) {
1084             my ($d, $cs) = @$r;
1085             if ($d) {
1086                 if ($cs) {
1087                     $res .= decode($cs, $d);
1088                 } else {
1089                     $res .= $d;
1090                 }
1091             }
1092         }
1093     };
1094
1095     $res = $enc if $@;
1096
1097     return $res;
1098 }
1099
1100 sub rfc1522_to_html {
1101     my ($enc) = @_;
1102
1103     my $res = '';
1104
1105     return '' if !$enc;
1106
1107     eval {
1108         foreach my $r (MIME::Words::decode_mimewords($enc)) {
1109             my ($d, $cs) = @$r;
1110             if ($d) {
1111                 if ($cs) {
1112                     $res .= encode_entities(decode($cs, $d));
1113                 } else {
1114                     $res .= encode_entities($d);
1115                 }
1116             }
1117         }
1118     };
1119
1120     $res = $enc if $@;
1121
1122     return $res;
1123 }
1124
1125 # RFC 2047 B-ENCODING http://rfc.net/rfc2047.html
1126 # (Q-Encoding is complex and error prone)
1127 sub bencode_header {
1128     my $txt = shift;
1129
1130     my $CRLF = "\015\012";
1131
1132     # Nonprintables (controls + x7F + 8bit):
1133     my $NONPRINT = "\\x00-\\x1F\\x7F-\\xFF";
1134
1135     # always use utf-8 (work with japanese character sets)
1136     $txt = encode("UTF-8", $txt);
1137
1138     return $txt if $txt !~ /[$NONPRINT]/o;
1139
1140     my $res = '';
1141
1142     while ($txt =~ s/^(.{1,42})//sm) {
1143         my $t = MIME::Words::encode_mimeword ($1, 'B', 'UTF-8');
1144         $res .= $res ? "\015\012\t$t" : $t;
1145     }
1146
1147     return $res;
1148 }
1149
1150 sub load_sa_descriptions {
1151     my ($additional_dirs) = @_;
1152
1153     my @dirs = ('/usr/share/spamassassin',
1154                 '/usr/share/spamassassin-extra');
1155
1156     push @dirs, @$additional_dirs if @$additional_dirs;
1157
1158     my $res = {};
1159
1160     my $parse_sa_file = sub {
1161         my ($file) = @_;
1162
1163         open(my $fh,'<', $file);
1164         return if !defined($fh);
1165
1166         while (defined(my $line = <$fh>)) {
1167             if ($line =~ m/^describe\s+(\S+)\s+(.*)\s*$/) {
1168                 my ($name, $desc) = ($1, $2);
1169                 next if $res->{$name};
1170                 $res->{$name}->{desc} = $desc;
1171                 if ($desc =~ m|[\(\s](http:\/\/\S+\.[^\s\.\)]+\.[^\s\.\)]+)|i) {
1172                     $res->{$name}->{url} = $1;
1173                 }
1174             }
1175         }
1176         close($fh);
1177     };
1178
1179     foreach my $dir (@dirs) {
1180         foreach my $file (<$dir/*.cf>) {
1181             $parse_sa_file->($file);
1182         }
1183     }
1184
1185     $res->{'ClamAVHeuristics'}->{desc} = "ClamAV heuristic tests";
1186
1187     return $res;
1188 }
1189
1190 sub format_uptime {
1191     my ($uptime) = @_;
1192
1193     my $days = int($uptime/86400);
1194     $uptime -= $days*86400;
1195
1196     my $hours = int($uptime/3600);
1197     $uptime -= $hours*3600;
1198
1199     my $mins = $uptime/60;
1200
1201     if ($days) {
1202         my $ds = $days > 1 ? 'days' : 'day';
1203         return sprintf "%d $ds %02d:%02d", $days, $hours, $mins;
1204     } else {
1205         return sprintf "%02d:%02d", $hours, $mins;
1206     }
1207 }
1208
1209 sub finalize_report {
1210     my ($tt, $template, $data, $mailfrom, $receiver, $debug) = @_;
1211
1212     my $html = '';
1213
1214     $tt->process($template, $data, \$html) ||
1215         die $tt->error() . "\n";
1216
1217     my $title;
1218     if ($html =~ m|^\s*<title>(.*)</title>|m) {
1219         $title = $1;
1220     } else {
1221         die "unable to extract template title\n";
1222     }
1223
1224     my $top = MIME::Entity->build(
1225         Type    => "multipart/related",
1226         To      => $data->{pmail},
1227         From    => $mailfrom,
1228         Subject => bencode_header(decode_entities($title)));
1229
1230     $top->attach(
1231         Data     => $html,
1232         Type     => "text/html",
1233         Encoding => $debug ? 'binary' : 'quoted-printable');
1234
1235     if ($debug) {
1236         $top->print();
1237         return;
1238     }
1239     # we use an empty envelope sender (we dont want to receive NDRs)
1240     PMG::Utils::reinject_mail ($top, '', [$receiver], undef, $data->{fqdn});
1241 }
1242
1243 sub lookup_timespan {
1244     my ($timespan) = @_;
1245
1246     my (undef, undef, undef, $mday, $mon, $year) = localtime(time());
1247     my $daystart = timelocal(0, 0, 0, $mday, $mon, $year);
1248
1249     my $start;
1250     my $end;
1251
1252     if ($timespan eq 'today') {
1253         $start = $daystart;
1254         $end = $start + 86400;
1255     } elsif ($timespan eq 'yesterday') {
1256         $end = $daystart;
1257         $start = $end - 86400;
1258     } elsif ($timespan eq 'week') {
1259         $end = $daystart;
1260         $start = $end - 7*86400;
1261     } else {
1262         die "internal error";
1263     }
1264
1265     return ($start, $end);
1266 }
1267
1268 my $rbl_scan_last_cursor;
1269 my $rbl_scan_start_time = time();
1270
1271 sub scan_journal_for_rbl_rejects {
1272
1273     # example postscreen log entry for RBL rejects
1274     # Aug 29 08:00:36 proxmox postfix/postscreen[11266]: NOQUEUE: reject: RCPT from [x.x.x.x]:1234: 550 5.7.1 Service unavailable; client [x.x.x.x] blocked using zen.spamhaus.org; from=<xxxx>, to=<yyyy>, proto=ESMTP, helo=<zzz>
1275
1276     # example for PREGREET reject
1277     # Dec  7 06:57:11 proxmox postfix/postscreen[32084]: PREGREET 14 after 0.23 from [x.x.x.x]:63492: EHLO yyyyy\r\n
1278
1279     my $identifier = 'postfix/postscreen';
1280
1281     my $rbl_count = 0;
1282     my $pregreet_count = 0;
1283
1284     my $parser = sub {
1285         my $log = decode_json(shift);
1286
1287         $rbl_scan_last_cursor = $log->{__CURSOR} if defined($log->{__CURSOR});
1288
1289         my $message = $log->{MESSAGE};
1290         return if !defined($message);
1291
1292         if ($message =~ m/^NOQUEUE:\sreject:.*550 5.7.1 Service unavailable/) {
1293             $rbl_count++;
1294         } elsif ($message =~ m/^PREGREET\s\d+\safter\s/) {
1295             $pregreet_count++;
1296         }
1297     };
1298
1299     # limit to last 5000 lines to avoid long delays
1300     my $cmd = ['journalctl', '-o', 'json', '--output-fields', '__CURSOR,MESSAGE',
1301         '--no-pager', '--identifier', $identifier, '-n', 5000];
1302
1303     if (defined($rbl_scan_last_cursor)) {
1304         push @$cmd, "--after-cursor=${rbl_scan_last_cursor}";
1305     } else {
1306         push @$cmd, "--since=@" . $rbl_scan_start_time;
1307     }
1308
1309     PVE::Tools::run_command($cmd, outfunc => $parser);
1310
1311     return ($rbl_count, $pregreet_count);
1312 }
1313
1314 my $hwaddress;
1315
1316 sub get_hwaddress {
1317
1318     return $hwaddress if defined ($hwaddress);
1319
1320     my $fn = '/etc/ssh/ssh_host_rsa_key.pub';
1321     my $sshkey = PVE::Tools::file_get_contents($fn);
1322     $hwaddress = uc(Digest::MD5::md5_hex($sshkey));
1323
1324     return $hwaddress;
1325 }
1326
1327 my $default_locale = "en_US.UTF-8 UTF-8";
1328
1329 sub cond_add_default_locale {
1330
1331     my $filename = "/etc/locale.gen";
1332
1333     open(my $infh, "<", $filename) || return;
1334
1335     while (defined(my $line = <$infh>)) {
1336         if ($line =~ m/^\Q${default_locale}\E/) {
1337             # already configured
1338             return;
1339         }
1340     }
1341
1342     seek($infh, 0, 0) // return; # seek failed
1343
1344     open(my $outfh, ">", "$filename.tmp") || return;
1345
1346     my $done;
1347     while (defined(my $line = <$infh>)) {
1348         if ($line =~ m/^#\s*\Q${default_locale}\E.*/) {
1349             print $outfh "${default_locale}\n" if !$done;
1350             $done = 1;
1351         } else {
1352             print $outfh $line;
1353         }
1354     }
1355
1356     print STDERR "generation pmg default locale\n";
1357
1358     rename("$filename.tmp", $filename) || return; # rename failed
1359
1360     system("dpkg-reconfigure locales -f noninteractive");
1361 }
1362
1363 sub postgres_admin_cmd {
1364     my ($cmd, $options, @params) = @_;
1365
1366     $cmd = ref($cmd) ? $cmd : [ $cmd ];
1367
1368     my $save_uid = POSIX::getuid();
1369     my $pg_uid = getpwnam('postgres') || die "getpwnam postgres failed\n";
1370
1371     PVE::Tools::setresuid(-1, $pg_uid, -1) ||
1372         die "setresuid postgres ($pg_uid) failed - $!\n";
1373
1374     PVE::Tools::run_command([@$cmd, '-U', 'postgres', @params], %$options);
1375
1376     PVE::Tools::setresuid(-1, $save_uid, -1) ||
1377         die "setresuid back failed - $!\n";
1378 }
1379
1380 sub get_pg_server_version {
1381     my $major_ver;
1382     my $parser = sub {
1383         my $line = shift;
1384         # example output:
1385         # 9.6.13
1386         # 11.4 (Debian 11.4-1)
1387         # see https://www.postgresql.org/support/versioning/
1388         my ($first_comp) = ($line =~ m/^\s*([0-9]+)/);
1389         if ($first_comp < 10) {
1390             ($major_ver) = ($line =~ m/^([0-9]+\.[0-9]+)\.[0-9]+/);
1391         } else {
1392             $major_ver = $first_comp;
1393         }
1394
1395     };
1396     eval {
1397         postgres_admin_cmd('psql', { outfunc => $parser }, '--quiet',
1398         '--tuples-only', '--no-align', '--command', 'show server_version;');
1399     };
1400
1401     die "Unable to determine currently running Postgresql server version\n"
1402         if ($@ || !defined($major_ver));
1403
1404     return $major_ver;
1405 }
1406
1407 sub reload_smtp_filter {
1408
1409     my $pid_file = '/run/pmg-smtp-filter.pid';
1410     my $pid = PVE::Tools::file_read_firstline($pid_file);
1411
1412     return 0 if !$pid;
1413
1414     return 0 if $pid !~ m/^(\d+)$/;
1415     $pid = $1; # untaint
1416
1417     return kill (10, $pid); # send SIGUSR1
1418 }
1419
1420 1;