src/PVE/API2/LXC.pm

   1 package PVE::API2::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::SafeSyslog;
   7 use PVE::Tools qw(extract_param run_command);
   8 use PVE::Exception qw(raise raise_param_exc);
   9 use PVE::INotify;
  10 use PVE::Cluster qw(cfs_read_file);
  11 use PVE::AccessControl;
  12 use PVE::Firewall;
  13 use PVE::Storage;
  14 use PVE::RESTHandler;
  15 use PVE::RPCEnvironment;
  16 use PVE::ReplicationConfig;
  17 use PVE::LXC;
  18 use PVE::LXC::Create;
  19 use PVE::LXC::Migrate;
  20 use PVE::GuestHelpers;
  21 use PVE::API2::LXC::Config;
  22 use PVE::API2::LXC::Status;
  23 use PVE::API2::LXC::Snapshot;
  24 use PVE::JSONSchema qw(get_standard_option);
  25 use base qw(PVE::RESTHandler);
  26
  27 BEGIN {
  28     if (!$ENV{PVE_GENERATING_DOCS}) {
  29         require PVE::HA::Env::PVE2;
  30         import  PVE::HA::Env::PVE2;
  31         require PVE::HA::Config;
  32         import  PVE::HA::Config;
  33     }
  34 }
  35
  36 __PACKAGE__->register_method ({
  37     subclass => "PVE::API2::LXC::Config",
  38     path => '{vmid}/config',
  39 });
  40
  41 __PACKAGE__->register_method ({
  42     subclass => "PVE::API2::LXC::Status",
  43     path => '{vmid}/status',
  44 });
  45
  46 __PACKAGE__->register_method ({
  47     subclass => "PVE::API2::LXC::Snapshot",
  48     path => '{vmid}/snapshot',
  49 });
  50
  51 __PACKAGE__->register_method ({
  52     subclass => "PVE::API2::Firewall::CT",
  53     path => '{vmid}/firewall',
  54 });
  55
  56 __PACKAGE__->register_method({
  57     name => 'vmlist',
  58     path => '',
  59     method => 'GET',
  60     description => "LXC container index (per node).",
  61     permissions => {
  62         description => "Only list CTs where you have VM.Audit permissons on /vms/<vmid>.",
  63         user => 'all',
  64     },
  65     proxyto => 'node',
  66     protected => 1, # /proc files are only readable by root
  67     parameters => {
  68         additionalProperties => 0,
  69         properties => {
  70             node => get_standard_option('pve-node'),
  71         },
  72     },
  73     returns => {
  74         type => 'array',
  75         items => {
  76             type => "object",
  77             properties => {},
  78         },
  79         links => [ { rel => 'child', href => "{vmid}" } ],
  80     },
  81     code => sub {
  82         my ($param) = @_;
  83
  84         my $rpcenv = PVE::RPCEnvironment::get();
  85         my $authuser = $rpcenv->get_user();
  86
  87         my $vmstatus = PVE::LXC::vmstatus();
  88
  89         my $res = [];
  90         foreach my $vmid (keys %$vmstatus) {
  91             next if !$rpcenv->check($authuser, "/vms/$vmid", [ 'VM.Audit' ], 1);
  92
  93             my $data = $vmstatus->{$vmid};
  94             $data->{vmid} = $vmid;
  95             push @$res, $data;
  96         }
  97
  98         return $res;
  99
 100     }});
 101
 102 __PACKAGE__->register_method({
 103     name => 'create_vm',
 104     path => '',
 105     method => 'POST',
 106     description => "Create or restore a container.",
 107     permissions => {
 108         user => 'all', # check inside
 109         description => "You need 'VM.Allocate' permissions on /vms/{vmid} or on the VM pool /pool/{pool}. " .
 110             "For restore, it is enough if the user has 'VM.Backup' permission and the VM already exists. " .
 111             "You also need 'Datastore.AllocateSpace' permissions on the storage.",
 112     },
 113     protected => 1,
 114     proxyto => 'node',
 115     parameters => {
 116         additionalProperties => 0,
 117         properties => PVE::LXC::Config->json_config_properties({
 118             node => get_standard_option('pve-node'),
 119             vmid => get_standard_option('pve-vmid', { completion => \&PVE::Cluster::complete_next_vmid }),
 120             ostemplate => {
 121                 description => "The OS template or backup file.",
 122                 type => 'string',
 123                 maxLength => 255,
 124                 completion => \&PVE::LXC::complete_os_templates,
 125             },
 126             password => {
 127                 optional => 1,
 128                 type => 'string',
 129                 description => "Sets root password inside container.",
 130                 minLength => 5,
 131             },
 132             storage => get_standard_option('pve-storage-id', {
 133                 description => "Default Storage.",
 134                 default => 'local',
 135                 optional => 1,
 136                 completion => \&PVE::Storage::complete_storage_enabled,
 137             }),
 138             force => {
 139                 optional => 1,
 140                 type => 'boolean',
 141                 description => "Allow to overwrite existing container.",
 142             },
 143             restore => {
 144                 optional => 1,
 145                 type => 'boolean',
 146                 description => "Mark this as restore task.",
 147             },
 148             pool => {
 149                 optional => 1,
 150                 type => 'string', format => 'pve-poolid',
 151                 description => "Add the VM to the specified pool.",
 152             },
 153             'ignore-unpack-errors' => {
 154                 optional => 1,
 155                 type => 'boolean',
 156                 description => "Ignore errors when extracting the template.",
 157             },
 158             'ssh-public-keys' => {
 159                 optional => 1,
 160                 type => 'string',
 161                 description => "Setup public SSH keys (one key per line, " .
 162                                 "OpenSSH format).",
 163             },
 164         }),
 165     },
 166     returns => {
 167         type => 'string',
 168     },
 169     code => sub {
 170         my ($param) = @_;
 171
 172         my $rpcenv = PVE::RPCEnvironment::get();
 173
 174         my $authuser = $rpcenv->get_user();
 175
 176         my $node = extract_param($param, 'node');
 177
 178         my $vmid = extract_param($param, 'vmid');
 179
 180         my $ignore_unpack_errors = extract_param($param, 'ignore-unpack-errors');
 181
 182         my $basecfg_fn = PVE::LXC::Config->config_file($vmid);
 183
 184         my $same_container_exists = -f $basecfg_fn;
 185
 186         # 'unprivileged' is read-only, so we can't pass it to update_pct_config
 187         my $unprivileged = extract_param($param, 'unprivileged');
 188
 189         my $restore = extract_param($param, 'restore');
 190
 191         if ($restore) {
 192             # fixme: limit allowed parameters
 193
 194         }
 195
 196         my $force = extract_param($param, 'force');
 197
 198         if (!($same_container_exists && $restore && $force)) {
 199             PVE::Cluster::check_vmid_unused($vmid);
 200         } else {
 201             my $conf = PVE::LXC::Config->load_config($vmid);
 202             PVE::LXC::Config->check_protection($conf, "unable to restore CT $vmid");
 203         }
 204
 205         my $password = extract_param($param, 'password');
 206
 207         my $ssh_keys = extract_param($param, 'ssh-public-keys');
 208         PVE::Tools::validate_ssh_public_keys($ssh_keys) if defined($ssh_keys);
 209
 210         my $pool = extract_param($param, 'pool');
 211
 212         if (defined($pool)) {
 213             $rpcenv->check_pool_exist($pool);
 214             $rpcenv->check_perm_modify($authuser, "/pool/$pool");
 215         }
 216
 217         if ($rpcenv->check($authuser, "/vms/$vmid", ['VM.Allocate'], 1)) {
 218             # OK
 219         } elsif ($pool && $rpcenv->check($authuser, "/pool/$pool", ['VM.Allocate'], 1)) {
 220             # OK
 221         } elsif ($restore && $force && $same_container_exists &&
 222                  $rpcenv->check($authuser, "/vms/$vmid", ['VM.Backup'], 1)) {
 223             # OK: user has VM.Backup permissions, and want to restore an existing VM
 224         } else {
 225             raise_perm_exc();
 226         }
 227
 228         my $ostemplate = extract_param($param, 'ostemplate');
 229         my $storage = extract_param($param, 'storage') // 'local';
 230
 231         PVE::LXC::check_ct_modify_config_perm($rpcenv, $authuser, $vmid, $pool, $param, []);
 232
 233         my $storage_cfg = cfs_read_file("storage.cfg");
 234
 235
 236         my $archive;
 237
 238         if ($ostemplate eq '-') {
 239             die "pipe requires cli environment\n"
 240                 if $rpcenv->{type} ne 'cli';
 241             die "pipe can only be used with restore tasks\n"
 242                 if !$restore;
 243             $archive = '-';
 244             die "restore from pipe requires rootfs parameter\n" if !defined($param->{rootfs});
 245         } else {
 246             PVE::Storage::check_volume_access($rpcenv, $authuser, $storage_cfg, $vmid, $ostemplate);
 247             $archive = PVE::Storage::abs_filesystem_path($storage_cfg, $ostemplate);
 248         }
 249
 250         my $check_and_activate_storage = sub {
 251             my ($sid) = @_;
 252
 253             my $scfg = PVE::Storage::storage_check_node($storage_cfg, $sid, $node);
 254
 255             raise_param_exc({ storage => "storage '$sid' does not support container directories"})
 256                 if !$scfg->{content}->{rootdir};
 257
 258             $rpcenv->check($authuser, "/storage/$sid", ['Datastore.AllocateSpace']);
 259
 260             PVE::Storage::activate_storage($storage_cfg, $sid);
 261         };
 262
 263         my $conf = {};
 264
 265         my $no_disk_param = {};
 266         my $mp_param = {};
 267         my $storage_only_mode = 1;
 268         foreach my $opt (keys %$param) {
 269             my $value = $param->{$opt};
 270             if ($opt eq 'rootfs' || $opt =~ m/^mp\d+$/) {
 271                 # allow to use simple numbers (add default storage in that case)
 272                 if ($value =~ m/^\d+(\.\d+)?$/) {
 273                     $mp_param->{$opt} = "$storage:$value";
 274                 } else {
 275                     $mp_param->{$opt} = $value;
 276                 }
 277                 $storage_only_mode = 0;
 278             } elsif ($opt =~ m/^unused\d+$/) {
 279                 warn "ignoring '$opt', cannot create/restore with unused volume\n";
 280                 delete $param->{$opt};
 281             } else {
 282                 $no_disk_param->{$opt} = $value;
 283             }
 284         }
 285
 286         die "mount points configured, but 'rootfs' not set - aborting\n"
 287             if !$storage_only_mode && !defined($mp_param->{rootfs});
 288
 289         # check storage access, activate storage
 290         my $delayed_mp_param = {};
 291         PVE::LXC::Config->foreach_mountpoint($mp_param, sub {
 292             my ($ms, $mountpoint) = @_;
 293
 294             my $volid = $mountpoint->{volume};
 295             my $mp = $mountpoint->{mp};
 296
 297             if ($mountpoint->{type} ne 'volume') { # bind or device
 298                 die "Only root can pass arbitrary filesystem paths.\n"
 299                     if $authuser ne 'root@pam';
 300             } else {
 301                 my ($sid, $volname) = PVE::Storage::parse_volume_id($volid);
 302                 &$check_and_activate_storage($sid);
 303             }
 304         });
 305
 306         # check/activate default storage
 307         &$check_and_activate_storage($storage) if !defined($mp_param->{rootfs});
 308
 309         PVE::LXC::Config->update_pct_config($vmid, $conf, 0, $no_disk_param);
 310
 311         $conf->{unprivileged} = 1 if $unprivileged;
 312
 313         my $check_vmid_usage = sub {
 314             if ($force) {
 315                 die "can't overwrite running container\n"
 316                     if PVE::LXC::check_running($vmid);
 317             } else {
 318                 PVE::Cluster::check_vmid_unused($vmid);
 319             }
 320         };
 321
 322         my $code = sub {
 323             &$check_vmid_usage(); # final check after locking
 324             my $old_conf;
 325
 326             my $config_fn = PVE::LXC::Config->config_file($vmid);
 327             if (-f $config_fn) {
 328                 die "container exists" if !$restore; # just to be sure
 329                 $old_conf = PVE::LXC::Config->load_config($vmid);
 330             } else {
 331                 eval {
 332                     # try to create empty config on local node, we have an flock
 333                     PVE::LXC::Config->write_config($vmid, {});
 334                 };
 335
 336                 # another node was faster, abort
 337                 die "Could not reserve ID $vmid, already taken\n" if $@;
 338             }
 339
 340             PVE::Cluster::check_cfs_quorum();
 341             my $vollist = [];
 342
 343             eval {
 344                 if ($storage_only_mode) {
 345                     if ($restore) {
 346                         (undef, $mp_param) = PVE::LXC::Create::recover_config($archive);
 347                         die "rootfs configuration could not be recovered, please check and specify manually!\n"
 348                             if !defined($mp_param->{rootfs});
 349                         PVE::LXC::Config->foreach_mountpoint($mp_param, sub {
 350                             my ($ms, $mountpoint) = @_;
 351                             my $type = $mountpoint->{type};
 352                             if ($type eq 'volume') {
 353                                 die "unable to detect disk size - please specify $ms (size)\n"
 354                                     if !defined($mountpoint->{size});
 355                                 my $disksize = $mountpoint->{size} / (1024 * 1024 * 1024); # create_disks expects GB as unit size
 356                                 delete $mountpoint->{size};
 357                                 $mountpoint->{volume} = "$storage:$disksize";
 358                                 $mp_param->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
 359                             } else {
 360                                 my $type = $mountpoint->{type};
 361                                 die "restoring rootfs to $type mount is only possible by specifying -rootfs manually!\n"
 362                                     if ($ms eq 'rootfs');
 363                                 die "restoring '$ms' to $type mount is only possible for root\n"
 364                                     if $authuser ne 'root@pam';
 365
 366                                 if ($mountpoint->{backup}) {
 367                                     warn "WARNING - unsupported configuration!\n";
 368                                     warn "backup was enabled for $type mount point $ms ('$mountpoint->{mp}')\n";
 369                                     warn "mount point configuration will be restored after archive extraction!\n";
 370                                     warn "contained files will be restored to wrong directory!\n";
 371                                 }
 372                                 delete $mp_param->{$ms}; # actually delay bind/dev mps
 373                                 $delayed_mp_param->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
 374                             }
 375                         });
 376                     } else {
 377                         $mp_param->{rootfs} = "$storage:4"; # defaults to 4GB
 378                     }
 379                 }
 380
 381                 $vollist = PVE::LXC::create_disks($storage_cfg, $vmid, $mp_param, $conf);
 382
 383                 if (defined($old_conf)) {
 384                     # destroy old container volumes
 385                     PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $old_conf, {});
 386                 }
 387
 388                 eval {
 389                     my $rootdir = PVE::LXC::mount_all($vmid, $storage_cfg, $conf, 1);
 390                     PVE::LXC::Create::restore_archive($archive, $rootdir, $conf, $ignore_unpack_errors);
 391
 392                     if ($restore) {
 393                         PVE::LXC::Create::restore_configuration($vmid, $rootdir, $conf, $authuser ne 'root@pam');
 394                     } else {
 395                         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir); # detect OS
 396                         PVE::LXC::Config->write_config($vmid, $conf); # safe config (after OS detection)
 397                         $lxc_setup->post_create_hook($password, $ssh_keys);
 398                     }
 399                 };
 400                 my $err = $@;
 401                 PVE::LXC::umount_all($vmid, $storage_cfg, $conf, $err ? 1 : 0);
 402                 PVE::Storage::deactivate_volumes($storage_cfg, PVE::LXC::Config->get_vm_volumes($conf));
 403                 die $err if $err;
 404                 # set some defaults
 405                 $conf->{hostname} ||= "CT$vmid";
 406                 $conf->{memory} ||= 512;
 407                 $conf->{swap} //= 512;
 408                 foreach my $mp (keys %$delayed_mp_param) {
 409                     $conf->{$mp} = $delayed_mp_param->{$mp};
 410                 }
 411                 PVE::LXC::Config->write_config($vmid, $conf);
 412             };
 413             if (my $err = $@) {
 414                 PVE::LXC::destroy_disks($storage_cfg, $vollist);
 415                 PVE::LXC::destroy_config($vmid);
 416                 die $err;
 417             }
 418             PVE::AccessControl::add_vm_to_pool($vmid, $pool) if $pool;
 419         };
 420
 421         my $realcmd = sub { PVE::LXC::Config->lock_config($vmid, $code); };
 422
 423         &$check_vmid_usage(); # first check before locking
 424
 425         return $rpcenv->fork_worker($restore ? 'vzrestore' : 'vzcreate',
 426                                     $vmid, $authuser, $realcmd);
 427
 428     }});
 429
 430 __PACKAGE__->register_method({
 431     name => 'vmdiridx',
 432     path => '{vmid}',
 433     method => 'GET',
 434     proxyto => 'node',
 435     description => "Directory index",
 436     permissions => {
 437         user => 'all',
 438     },
 439     parameters => {
 440         additionalProperties => 0,
 441         properties => {
 442             node => get_standard_option('pve-node'),
 443             vmid => get_standard_option('pve-vmid'),
 444         },
 445     },
 446     returns => {
 447         type => 'array',
 448         items => {
 449             type => "object",
 450             properties => {
 451                 subdir => { type => 'string' },
 452             },
 453         },
 454         links => [ { rel => 'child', href => "{subdir}" } ],
 455     },
 456     code => sub {
 457         my ($param) = @_;
 458
 459         # test if VM exists
 460         my $conf = PVE::LXC::Config->load_config($param->{vmid});
 461
 462         my $res = [
 463             { subdir => 'config' },
 464             { subdir => 'status' },
 465             { subdir => 'vncproxy' },
 466             { subdir => 'vncwebsocket' },
 467             { subdir => 'spiceproxy' },
 468             { subdir => 'migrate' },
 469             { subdir => 'clone' },
 470 #           { subdir => 'initlog' },
 471             { subdir => 'rrd' },
 472             { subdir => 'rrddata' },
 473             { subdir => 'firewall' },
 474             { subdir => 'snapshot' },
 475             { subdir => 'resize' },
 476             ];
 477
 478         return $res;
 479     }});
 480
 481
 482 __PACKAGE__->register_method({
 483     name => 'rrd',
 484     path => '{vmid}/rrd',
 485     method => 'GET',
 486     protected => 1, # fixme: can we avoid that?
 487     permissions => {
 488         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 489     },
 490     description => "Read VM RRD statistics (returns PNG)",
 491     parameters => {
 492         additionalProperties => 0,
 493         properties => {
 494             node => get_standard_option('pve-node'),
 495             vmid => get_standard_option('pve-vmid'),
 496             timeframe => {
 497                 description => "Specify the time frame you are interested in.",
 498                 type => 'string',
 499                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 500             },
 501             ds => {
 502                 description => "The list of datasources you want to display.",
 503                 type => 'string', format => 'pve-configid-list',
 504             },
 505             cf => {
 506                 description => "The RRD consolidation function",
 507                 type => 'string',
 508                 enum => [ 'AVERAGE', 'MAX' ],
 509                 optional => 1,
 510             },
 511         },
 512     },
 513     returns => {
 514         type => "object",
 515         properties => {
 516             filename => { type => 'string' },
 517         },
 518     },
 519     code => sub {
 520         my ($param) = @_;
 521
 522         return PVE::Cluster::create_rrd_graph(
 523             "pve2-vm/$param->{vmid}", $param->{timeframe},
 524             $param->{ds}, $param->{cf});
 525
 526     }});
 527
 528 __PACKAGE__->register_method({
 529     name => 'rrddata',
 530     path => '{vmid}/rrddata',
 531     method => 'GET',
 532     protected => 1, # fixme: can we avoid that?
 533     permissions => {
 534         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 535     },
 536     description => "Read VM RRD statistics",
 537     parameters => {
 538         additionalProperties => 0,
 539         properties => {
 540             node => get_standard_option('pve-node'),
 541             vmid => get_standard_option('pve-vmid'),
 542             timeframe => {
 543                 description => "Specify the time frame you are interested in.",
 544                 type => 'string',
 545                 enum => [ 'hour', 'day', 'week', 'month', 'year' ],
 546             },
 547             cf => {
 548                 description => "The RRD consolidation function",
 549                 type => 'string',
 550                 enum => [ 'AVERAGE', 'MAX' ],
 551                 optional => 1,
 552             },
 553         },
 554     },
 555     returns => {
 556         type => "array",
 557         items => {
 558             type => "object",
 559             properties => {},
 560         },
 561     },
 562     code => sub {
 563         my ($param) = @_;
 564
 565         return PVE::Cluster::create_rrd_data(
 566             "pve2-vm/$param->{vmid}", $param->{timeframe}, $param->{cf});
 567     }});
 568
 569 __PACKAGE__->register_method({
 570     name => 'destroy_vm',
 571     path => '{vmid}',
 572     method => 'DELETE',
 573     protected => 1,
 574     proxyto => 'node',
 575     description => "Destroy the container (also delete all uses files).",
 576     permissions => {
 577         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
 578     },
 579     parameters => {
 580         additionalProperties => 0,
 581         properties => {
 582             node => get_standard_option('pve-node'),
 583             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid_stopped }),
 584         },
 585     },
 586     returns => {
 587         type => 'string',
 588     },
 589     code => sub {
 590         my ($param) = @_;
 591
 592         my $rpcenv = PVE::RPCEnvironment::get();
 593
 594         my $authuser = $rpcenv->get_user();
 595
 596         my $vmid = $param->{vmid};
 597
 598         # test if container exists
 599         my $conf = PVE::LXC::Config->load_config($vmid);
 600
 601         my $storage_cfg = cfs_read_file("storage.cfg");
 602
 603         PVE::LXC::Config->check_protection($conf, "can't remove CT $vmid");
 604
 605         die "unable to remove CT $vmid - used in HA resources\n"
 606             if PVE::HA::Config::vm_is_ha_managed($vmid);
 607
 608         # do not allow destroy if there are replication jobs
 609         my $repl_conf = PVE::ReplicationConfig->new();
 610         $repl_conf->check_for_existing_jobs($vmid);
 611
 612         my $running_error_msg = "unable to destroy CT $vmid - container is running\n";
 613
 614         die $running_error_msg if PVE::LXC::check_running($vmid); # check early
 615
 616         my $code = sub {
 617             # reload config after lock
 618             $conf = PVE::LXC::Config->load_config($vmid);
 619             PVE::LXC::Config->check_lock($conf);
 620
 621             die $running_error_msg if PVE::LXC::check_running($vmid);
 622
 623             PVE::LXC::destroy_lxc_container($storage_cfg, $vmid, $conf);
 624             PVE::AccessControl::remove_vm_access($vmid);
 625             PVE::Firewall::remove_vmfw_conf($vmid);
 626         };
 627
 628         my $realcmd = sub { PVE::LXC::Config->lock_config($vmid, $code); };
 629
 630         return $rpcenv->fork_worker('vzdestroy', $vmid, $authuser, $realcmd);
 631     }});
 632
 633 my $sslcert;
 634
 635 __PACKAGE__->register_method ({
 636     name => 'vncproxy',
 637     path => '{vmid}/vncproxy',
 638     method => 'POST',
 639     protected => 1,
 640     permissions => {
 641         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 642     },
 643     description => "Creates a TCP VNC proxy connections.",
 644     parameters => {
 645         additionalProperties => 0,
 646         properties => {
 647             node => get_standard_option('pve-node'),
 648             vmid => get_standard_option('pve-vmid'),
 649             websocket => {
 650                 optional => 1,
 651                 type => 'boolean',
 652                 description => "use websocket instead of standard VNC.",
 653             },
 654         },
 655     },
 656     returns => {
 657         additionalProperties => 0,
 658         properties => {
 659             user => { type => 'string' },
 660             ticket => { type => 'string' },
 661             cert => { type => 'string' },
 662             port => { type => 'integer' },
 663             upid => { type => 'string' },
 664         },
 665     },
 666     code => sub {
 667         my ($param) = @_;
 668
 669         my $rpcenv = PVE::RPCEnvironment::get();
 670
 671         my $authuser = $rpcenv->get_user();
 672
 673         my $vmid = $param->{vmid};
 674         my $node = $param->{node};
 675
 676         my $authpath = "/vms/$vmid";
 677
 678         my $ticket = PVE::AccessControl::assemble_vnc_ticket($authuser, $authpath);
 679
 680         $sslcert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192)
 681             if !$sslcert;
 682
 683         my ($remip, $family);
 684
 685         if ($node ne PVE::INotify::nodename()) {
 686             ($remip, $family) = PVE::Cluster::remote_node_ip($node);
 687         } else {
 688             $family = PVE::Tools::get_host_address_family($node);
 689         }
 690
 691         my $port = PVE::Tools::next_vnc_port($family);
 692
 693         # NOTE: vncterm VNC traffic is already TLS encrypted,
 694         # so we select the fastest chipher here (or 'none'?)
 695         my $remcmd = $remip ?
 696             ['/usr/bin/ssh', '-t', $remip] : [];
 697
 698         my $conf = PVE::LXC::Config->load_config($vmid, $node);
 699         my $concmd = PVE::LXC::get_console_command($vmid, $conf);
 700
 701         my $shcmd = [ '/usr/bin/dtach', '-A',
 702                       "/var/run/dtach/vzctlconsole$vmid",
 703                       '-r', 'winch', '-z', @$concmd];
 704
 705         my $realcmd = sub {
 706             my $upid = shift;
 707
 708             syslog ('info', "starting lxc vnc proxy $upid\n");
 709
 710             my $timeout = 10;
 711
 712             my $cmd = ['/usr/bin/vncterm', '-rfbport', $port,
 713                        '-timeout', $timeout, '-authpath', $authpath,
 714                        '-perm', 'VM.Console'];
 715
 716             if ($param->{websocket}) {
 717                 $ENV{PVE_VNC_TICKET} = $ticket; # pass ticket to vncterm
 718                 push @$cmd, '-notls', '-listen', 'localhost';
 719             }
 720
 721             push @$cmd, '-c', @$remcmd, @$shcmd;
 722
 723             run_command($cmd, keeplocale => 1);
 724
 725             return;
 726         };
 727
 728         my $upid = $rpcenv->fork_worker('vncproxy', $vmid, $authuser, $realcmd);
 729
 730         PVE::Tools::wait_for_vnc_port($port);
 731
 732         return {
 733             user => $authuser,
 734             ticket => $ticket,
 735             port => $port,
 736             upid => $upid,
 737             cert => $sslcert,
 738         };
 739     }});
 740
 741 __PACKAGE__->register_method({
 742     name => 'vncwebsocket',
 743     path => '{vmid}/vncwebsocket',
 744     method => 'GET',
 745     permissions => {
 746         description => "You also need to pass a valid ticket (vncticket).",
 747         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 748     },
 749     description => "Opens a weksocket for VNC traffic.",
 750     parameters => {
 751         additionalProperties => 0,
 752         properties => {
 753             node => get_standard_option('pve-node'),
 754             vmid => get_standard_option('pve-vmid'),
 755             vncticket => {
 756                 description => "Ticket from previous call to vncproxy.",
 757                 type => 'string',
 758                 maxLength => 512,
 759             },
 760             port => {
 761                 description => "Port number returned by previous vncproxy call.",
 762                 type => 'integer',
 763                 minimum => 5900,
 764                 maximum => 5999,
 765             },
 766         },
 767     },
 768     returns => {
 769         type => "object",
 770         properties => {
 771             port => { type => 'string' },
 772         },
 773     },
 774     code => sub {
 775         my ($param) = @_;
 776
 777         my $rpcenv = PVE::RPCEnvironment::get();
 778
 779         my $authuser = $rpcenv->get_user();
 780
 781         my $authpath = "/vms/$param->{vmid}";
 782
 783         PVE::AccessControl::verify_vnc_ticket($param->{vncticket}, $authuser, $authpath);
 784
 785         my $port = $param->{port};
 786
 787         return { port => $port };
 788     }});
 789
 790 __PACKAGE__->register_method ({
 791     name => 'spiceproxy',
 792     path => '{vmid}/spiceproxy',
 793     method => 'POST',
 794     protected => 1,
 795     proxyto => 'node',
 796     permissions => {
 797         check => ['perm', '/vms/{vmid}', [ 'VM.Console' ]],
 798     },
 799     description => "Returns a SPICE configuration to connect to the CT.",
 800     parameters => {
 801         additionalProperties => 0,
 802         properties => {
 803             node => get_standard_option('pve-node'),
 804             vmid => get_standard_option('pve-vmid'),
 805             proxy => get_standard_option('spice-proxy', { optional => 1 }),
 806         },
 807     },
 808     returns => get_standard_option('remote-viewer-config'),
 809     code => sub {
 810         my ($param) = @_;
 811
 812         my $vmid = $param->{vmid};
 813         my $node = $param->{node};
 814         my $proxy = $param->{proxy};
 815
 816         my $authpath = "/vms/$vmid";
 817         my $permissions = 'VM.Console';
 818
 819         my $conf = PVE::LXC::Config->load_config($vmid);
 820
 821         die "CT $vmid not running\n" if !PVE::LXC::check_running($vmid);
 822
 823         my $concmd = PVE::LXC::get_console_command($vmid, $conf);
 824
 825         my $shcmd = ['/usr/bin/dtach', '-A',
 826                      "/var/run/dtach/vzctlconsole$vmid",
 827                      '-r', 'winch', '-z', @$concmd];
 828
 829         my $title = "CT $vmid";
 830
 831         return PVE::API2Tools::run_spiceterm($authpath, $permissions, $vmid, $node, $proxy, $title, $shcmd);
 832     }});
 833
 834
 835 __PACKAGE__->register_method({
 836     name => 'migrate_vm',
 837     path => '{vmid}/migrate',
 838     method => 'POST',
 839     protected => 1,
 840     proxyto => 'node',
 841     description => "Migrate the container to another node. Creates a new migration task.",
 842     permissions => {
 843         check => ['perm', '/vms/{vmid}', [ 'VM.Migrate' ]],
 844     },
 845     parameters => {
 846         additionalProperties => 0,
 847         properties => {
 848             node => get_standard_option('pve-node'),
 849             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
 850             target => get_standard_option('pve-node', {
 851                 description => "Target node.",
 852                 completion => \&PVE::Cluster::complete_migration_target,
 853             }),
 854             online => {
 855                 type => 'boolean',
 856                 description => "Use online/live migration.",
 857                 optional => 1,
 858             },
 859             restart => {
 860                 type => 'boolean',
 861                 description => "Use restart migration",
 862                 optional => 1,
 863             },
 864             timeout => {
 865                 type => 'integer',
 866                 description => "Timeout in seconds for shutdown for restart migration",
 867                 optional => 1,
 868                 default => 180,
 869             },
 870             force => {
 871                 type => 'boolean',
 872                 description => "Force migration despite local bind / device" .
 873                     " mounts. NOTE: deprecated, use 'shared' property of mount point instead.",
 874                 optional => 1,
 875             },
 876         },
 877     },
 878     returns => {
 879         type => 'string',
 880         description => "the task ID.",
 881     },
 882     code => sub {
 883         my ($param) = @_;
 884
 885         my $rpcenv = PVE::RPCEnvironment::get();
 886
 887         my $authuser = $rpcenv->get_user();
 888
 889         my $target = extract_param($param, 'target');
 890
 891         my $localnode = PVE::INotify::nodename();
 892         raise_param_exc({ target => "target is local node."}) if $target eq $localnode;
 893
 894         PVE::Cluster::check_cfs_quorum();
 895
 896         PVE::Cluster::check_node_exists($target);
 897
 898         my $targetip = PVE::Cluster::remote_node_ip($target);
 899
 900         my $vmid = extract_param($param, 'vmid');
 901
 902         # test if VM exists
 903         PVE::LXC::Config->load_config($vmid);
 904
 905         # try to detect errors early
 906         if (PVE::LXC::check_running($vmid)) {
 907             die "can't migrate running container without --online or --restart\n"
 908                 if !$param->{online} && !$param->{restart};
 909         }
 910
 911         if (PVE::HA::Config::vm_is_ha_managed($vmid) && $rpcenv->{type} ne 'ha') {
 912
 913             my $hacmd = sub {
 914                 my $upid = shift;
 915
 916                 my $service = "ct:$vmid";
 917
 918                 my $cmd = ['ha-manager', 'migrate', $service, $target];
 919
 920                 print "Executing HA migrate for CT $vmid to node $target\n";
 921
 922                 PVE::Tools::run_command($cmd);
 923
 924                 return;
 925             };
 926
 927             return $rpcenv->fork_worker('hamigrate', $vmid, $authuser, $hacmd);
 928
 929         } else {
 930
 931             my $code = sub {
 932                 my $realcmd = sub {
 933                     my $upid = shift;
 934
 935                     PVE::LXC::Migrate->migrate($target, $targetip, $vmid, $param);
 936
 937                     return;
 938                 };
 939
 940                 return $rpcenv->fork_worker('vzmigrate', $vmid, $authuser, $realcmd);
 941             };
 942
 943             return PVE::GuestHelpers::guest_migration_lock($vmid, 10, $code);
 944         }
 945     }});
 946
 947 __PACKAGE__->register_method({
 948     name => 'vm_feature',
 949     path => '{vmid}/feature',
 950     method => 'GET',
 951     proxyto => 'node',
 952     protected => 1,
 953     description => "Check if feature for virtual machine is available.",
 954     permissions => {
 955         check => ['perm', '/vms/{vmid}', [ 'VM.Audit' ]],
 956     },
 957     parameters => {
 958         additionalProperties => 0,
 959         properties => {
 960             node => get_standard_option('pve-node'),
 961             vmid => get_standard_option('pve-vmid'),
 962             feature => {
 963                 description => "Feature to check.",
 964                 type => 'string',
 965                 enum => [ 'snapshot' ],
 966             },
 967             snapname => get_standard_option('pve-lxc-snapshot-name', {
 968                 optional => 1,
 969             }),
 970         },
 971     },
 972     returns => {
 973         type => "object",
 974         properties => {
 975             hasFeature => { type => 'boolean' },
 976             #nodes => {
 977                 #type => 'array',
 978                 #items => { type => 'string' },
 979             #}
 980         },
 981     },
 982     code => sub {
 983         my ($param) = @_;
 984
 985         my $node = extract_param($param, 'node');
 986
 987         my $vmid = extract_param($param, 'vmid');
 988
 989         my $snapname = extract_param($param, 'snapname');
 990
 991         my $feature = extract_param($param, 'feature');
 992
 993         my $conf = PVE::LXC::Config->load_config($vmid);
 994
 995         if($snapname){
 996             my $snap = $conf->{snapshots}->{$snapname};
 997             die "snapshot '$snapname' does not exist\n" if !defined($snap);
 998             $conf = $snap;
 999         }
1000         my $storage_cfg = PVE::Storage::config();
1001         #Maybe include later
1002         #my $nodelist = PVE::LXC::shared_nodes($conf, $storage_cfg);
1003         my $hasFeature = PVE::LXC::Config->has_feature($feature, $conf, $storage_cfg, $snapname);
1004
1005         return {
1006             hasFeature => $hasFeature,
1007             #nodes => [ keys %$nodelist ],
1008         };
1009     }});
1010
1011 __PACKAGE__->register_method({
1012     name => 'template',
1013     path => '{vmid}/template',
1014     method => 'POST',
1015     protected => 1,
1016     proxyto => 'node',
1017     description => "Create a Template.",
1018     permissions => {
1019         description => "You need 'VM.Allocate' permissions on /vms/{vmid}",
1020         check => [ 'perm', '/vms/{vmid}', ['VM.Allocate']],
1021     },
1022     parameters => {
1023         additionalProperties => 0,
1024         properties => {
1025             node => get_standard_option('pve-node'),
1026             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid_stopped }),
1027             experimental => {
1028                 type => 'boolean',
1029                 description => "The template feature is experimental, set this " .
1030                     "flag if you know what you are doing.",
1031                 default => 0,
1032             },
1033         },
1034     },
1035     returns => { type => 'null'},
1036     code => sub {
1037         my ($param) = @_;
1038
1039         my $rpcenv = PVE::RPCEnvironment::get();
1040
1041         my $authuser = $rpcenv->get_user();
1042
1043         my $node = extract_param($param, 'node');
1044
1045         my $vmid = extract_param($param, 'vmid');
1046
1047         my $updatefn =  sub {
1048
1049             my $conf = PVE::LXC::Config->load_config($vmid);
1050             PVE::LXC::Config->check_lock($conf);
1051
1052             die "unable to create template, because CT contains snapshots\n"
1053                 if $conf->{snapshots} && scalar(keys %{$conf->{snapshots}});
1054
1055             die "you can't convert a template to a template\n"
1056                 if PVE::LXC::Config->is_template($conf);
1057
1058             die "you can't convert a CT to template if the CT is running\n"
1059                 if PVE::LXC::check_running($vmid);
1060
1061             my $realcmd = sub {
1062                 PVE::LXC::template_create($vmid, $conf);
1063             };
1064
1065             $conf->{template} = 1;
1066
1067             PVE::LXC::Config->write_config($vmid, $conf);
1068             # and remove lxc config
1069             PVE::LXC::update_lxc_config($vmid, $conf);
1070
1071             return $rpcenv->fork_worker('vztemplate', $vmid, $authuser, $realcmd);
1072         };
1073
1074         PVE::LXC::Config->lock_config($vmid, $updatefn);
1075
1076         return undef;
1077     }});
1078
1079 __PACKAGE__->register_method({
1080     name => 'clone_vm',
1081     path => '{vmid}/clone',
1082     method => 'POST',
1083     protected => 1,
1084     proxyto => 'node',
1085     description => "Create a container clone/copy",
1086     permissions => {
1087         description => "You need 'VM.Clone' permissions on /vms/{vmid}, " .
1088             "and 'VM.Allocate' permissions " .
1089             "on /vms/{newid} (or on the VM pool /pool/{pool}). You also need " .
1090             "'Datastore.AllocateSpace' on any used storage.",
1091         check =>
1092         [ 'and',
1093           ['perm', '/vms/{vmid}', [ 'VM.Clone' ]],
1094           [ 'or',
1095             [ 'perm', '/vms/{newid}', ['VM.Allocate']],
1096             [ 'perm', '/pool/{pool}', ['VM.Allocate'], require_param => 'pool'],
1097           ],
1098         ]
1099     },
1100     parameters => {
1101         additionalProperties => 0,
1102         properties => {
1103             node => get_standard_option('pve-node'),
1104             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1105             newid => get_standard_option('pve-vmid', {
1106                 completion => \&PVE::Cluster::complete_next_vmid,
1107                 description => 'VMID for the clone.' }),
1108             hostname => {
1109                 optional => 1,
1110                 type => 'string', format => 'dns-name',
1111                 description => "Set a hostname for the new CT.",
1112             },
1113             description => {
1114                 optional => 1,
1115                 type => 'string',
1116                 description => "Description for the new CT.",
1117             },
1118             pool => {
1119                 optional => 1,
1120                 type => 'string', format => 'pve-poolid',
1121                 description => "Add the new CT to the specified pool.",
1122             },
1123             snapname => get_standard_option('pve-lxc-snapshot-name', {
1124                 optional => 1,
1125             }),
1126             storage => get_standard_option('pve-storage-id', {
1127                 description => "Target storage for full clone.",
1128                 requires => 'full',
1129                 optional => 1,
1130             }),
1131             full => {
1132                 optional => 1,
1133                 type => 'boolean',
1134                 description => "Create a full copy of all disk. This is always done when " .
1135                     "you clone a normal CT. For CT templates, we try to create a linked clone by default.",
1136                 default => 0,
1137             },
1138             experimental => {
1139                 type => 'boolean',
1140                 description => "The clone feature is experimental, set this " .
1141                     "flag if you know what you are doing.",
1142                 default => 0,
1143             },
1144 #           target => get_standard_option('pve-node', {
1145 #               description => "Target node. Only allowed if the original VM is on shared storage.",
1146 #               optional => 1,
1147 #           }),
1148         },
1149     },
1150     returns => {
1151         type => 'string',
1152     },
1153     code => sub {
1154         my ($param) = @_;
1155
1156         my $rpcenv = PVE::RPCEnvironment::get();
1157
1158         my $authuser = $rpcenv->get_user();
1159
1160         my $node = extract_param($param, 'node');
1161
1162         my $vmid = extract_param($param, 'vmid');
1163
1164         my $newid = extract_param($param, 'newid');
1165
1166         my $pool = extract_param($param, 'pool');
1167
1168         if (defined($pool)) {
1169             $rpcenv->check_pool_exist($pool);
1170         }
1171
1172         my $snapname = extract_param($param, 'snapname');
1173
1174         my $storage = extract_param($param, 'storage');
1175
1176         my $localnode = PVE::INotify::nodename();
1177
1178         my $storecfg = PVE::Storage::config();
1179
1180         if ($storage) {
1181             # check if storage is enabled on local node
1182             PVE::Storage::storage_check_enabled($storecfg, $storage);
1183         }
1184
1185         PVE::Cluster::check_cfs_quorum();
1186
1187         my $running = PVE::LXC::check_running($vmid) || 0;
1188
1189         my $clonefn = sub {
1190
1191             # do all tests after lock
1192             # we also try to do all tests before we fork the worker
1193             my $conf = PVE::LXC::Config->load_config($vmid);
1194
1195             PVE::LXC::Config->check_lock($conf);
1196
1197             my $verify_running = PVE::LXC::check_running($vmid) || 0;
1198
1199             die "unexpected state change\n" if $verify_running != $running;
1200
1201             die "snapshot '$snapname' does not exist\n"
1202                 if $snapname && !defined( $conf->{snapshots}->{$snapname});
1203
1204             my $oldconf = $snapname ? $conf->{snapshots}->{$snapname} : $conf;
1205
1206             my $conffile = PVE::LXC::Config->config_file($newid);
1207             die "unable to create CT $newid: config file already exists\n"
1208                 if -f $conffile;
1209
1210             my $newconf = { lock => 'clone' };
1211             my $mountpoints = {};
1212             my $fullclone = {};
1213             my $vollist = [];
1214
1215             foreach my $opt (keys %$oldconf) {
1216                 my $value = $oldconf->{$opt};
1217
1218                 # no need to copy unused images, because VMID(owner) changes anyways
1219                 next if $opt =~ m/^unused\d+$/;
1220
1221                 if (($opt eq 'rootfs') || ($opt =~ m/^mp\d+$/)) {
1222                     my $mp = $opt eq 'rootfs' ?
1223                         PVE::LXC::Config->parse_ct_rootfs($value) :
1224                         PVE::LXC::Config->parse_ct_mountpoint($value);
1225
1226                     if ($mp->{type} eq 'volume') {
1227                         my $volid = $mp->{volume};
1228                         if ($param->{full}) {
1229                             die "fixme: full clone not implemented";
1230
1231                             die "Full clone feature for '$volid' is not available\n"
1232                                 if !PVE::Storage::volume_has_feature($storecfg, 'copy', $volid, $snapname, $running);
1233                             $fullclone->{$opt} = 1;
1234                         } else {
1235                             # not full means clone instead of copy
1236                             die "Linked clone feature for '$volid' is not available\n"
1237                                 if !PVE::Storage::volume_has_feature($storecfg, 'clone', $volid, $snapname, $running);
1238                         }
1239
1240                         $mountpoints->{$opt} = $mp;
1241                         push @$vollist, $volid;
1242
1243                     } else {
1244                         # TODO: allow bind mounts?
1245                         die "unable to clone mountpint '$opt' (type $mp->{type})\n";
1246                     }
1247
1248                 } else {
1249                     # copy everything else
1250                     $newconf->{$opt} = $value;
1251                 }
1252             }
1253
1254             delete $newconf->{template};
1255             if ($param->{hostname}) {
1256                 $newconf->{hostname} = $param->{hostname};
1257             }
1258
1259             if ($param->{description}) {
1260                 $newconf->{description} = $param->{description};
1261             }
1262
1263             # create empty/temp config - this fails if CT already exists on other node
1264             PVE::Tools::file_set_contents($conffile, "# ctclone temporary file\nlock: clone\n");
1265
1266             my $realcmd = sub {
1267                 my $upid = shift;
1268
1269                 my $newvollist = [];
1270
1271                 eval {
1272                     local $SIG{INT} = $SIG{TERM} = $SIG{QUIT} = $SIG{HUP} = sub { die "interrupted by signal\n"; };
1273
1274                     PVE::Storage::activate_volumes($storecfg, $vollist, $snapname);
1275
1276                     foreach my $opt (keys %$mountpoints) {
1277                         my $mp = $mountpoints->{$opt};
1278                         my $volid = $mp->{volume};
1279
1280                         if ($fullclone->{$opt}) {
1281                             die "fixme: full clone not implemented\n";
1282                         } else {
1283                             print "create linked clone of mount point $opt ($volid)\n";
1284                             my $newvolid = PVE::Storage::vdisk_clone($storecfg, $volid, $newid, $snapname);
1285                             push @$newvollist, $newvolid;
1286                             $mp->{volume} = $newvolid;
1287
1288                             $newconf->{$opt} = PVE::LXC::Config->print_ct_mountpoint($mp, $opt eq 'rootfs');
1289                             PVE::LXC::Config->write_config($newid, $newconf);
1290                         }
1291                     }
1292
1293                     delete $newconf->{lock};
1294                     PVE::LXC::Config->write_config($newid, $newconf);
1295
1296                     PVE::AccessControl::add_vm_to_pool($newid, $pool) if $pool;
1297                 };
1298                 if (my $err = $@) {
1299                     unlink $conffile;
1300
1301                     sleep 1; # some storage like rbd need to wait before release volume - really?
1302
1303                     foreach my $volid (@$newvollist) {
1304                         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1305                         warn $@ if $@;
1306                     }
1307                     die "clone failed: $err";
1308                 }
1309
1310                 return;
1311             };
1312
1313             PVE::Firewall::clone_vmfw_conf($vmid, $newid);
1314
1315             return $rpcenv->fork_worker('vzclone', $vmid, $authuser, $realcmd);
1316
1317         };
1318
1319         return PVE::LXC::Config->lock_config($vmid, $clonefn);
1320     }});
1321
1322
1323 __PACKAGE__->register_method({
1324     name => 'resize_vm',
1325     path => '{vmid}/resize',
1326     method => 'PUT',
1327     protected => 1,
1328     proxyto => 'node',
1329     description => "Resize a container mount point.",
1330     permissions => {
1331         check => ['perm', '/vms/{vmid}', ['VM.Config.Disk'], any => 1],
1332     },
1333     parameters => {
1334         additionalProperties => 0,
1335         properties => {
1336             node => get_standard_option('pve-node'),
1337             vmid => get_standard_option('pve-vmid', { completion => \&PVE::LXC::complete_ctid }),
1338             disk => {
1339                 type => 'string',
1340                 description => "The disk you want to resize.",
1341                 enum => [PVE::LXC::Config->mountpoint_names()],
1342             },
1343             size => {
1344                 type => 'string',
1345                 pattern => '\+?\d+(\.\d+)?[KMGT]?',
1346                 description => "The new size. With the '+' sign the value is added to the actual size of the volume and without it, the value is taken as an absolute one. Shrinking disk size is not supported.",
1347             },
1348             digest => {
1349                 type => 'string',
1350                 description => 'Prevent changes if current configuration file has different SHA1 digest. This can be used to prevent concurrent modifications.',
1351                 maxLength => 40,
1352                 optional => 1,
1353             }
1354         },
1355     },
1356     returns => {
1357         type => 'string',
1358         description => "the task ID.",
1359     },
1360     code => sub {
1361         my ($param) = @_;
1362
1363         my $rpcenv = PVE::RPCEnvironment::get();
1364
1365         my $authuser = $rpcenv->get_user();
1366
1367         my $node = extract_param($param, 'node');
1368
1369         my $vmid = extract_param($param, 'vmid');
1370
1371         my $digest = extract_param($param, 'digest');
1372
1373         my $sizestr = extract_param($param, 'size');
1374         my $ext = ($sizestr =~ s/^\+//);
1375         my $newsize = PVE::JSONSchema::parse_size($sizestr);
1376         die "invalid size string" if !defined($newsize);
1377
1378         die "no options specified\n" if !scalar(keys %$param);
1379
1380         PVE::LXC::check_ct_modify_config_perm($rpcenv, $authuser, $vmid, undef, $param, []);
1381
1382         my $storage_cfg = cfs_read_file("storage.cfg");
1383
1384         my $code = sub {
1385
1386             my $conf = PVE::LXC::Config->load_config($vmid);
1387             PVE::LXC::Config->check_lock($conf);
1388
1389             PVE::Tools::assert_if_modified($digest, $conf->{digest});
1390
1391             my $running = PVE::LXC::check_running($vmid);
1392
1393             my $disk = $param->{disk};
1394             my $mp = $disk eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($conf->{$disk}) :
1395                 PVE::LXC::Config->parse_ct_mountpoint($conf->{$disk});
1396
1397             my $volid = $mp->{volume};
1398
1399             my (undef, undef, $owner, undef, undef, undef, $format) =
1400                 PVE::Storage::parse_volname($storage_cfg, $volid);
1401
1402             die "can't resize mount point owned by another container ($owner)"
1403                 if $vmid != $owner;
1404
1405             die "can't resize volume: $disk if snapshot exists\n"
1406                 if %{$conf->{snapshots}} && $format eq 'qcow2';
1407
1408             my ($storeid, $volname) = PVE::Storage::parse_volume_id($volid);
1409
1410             $rpcenv->check($authuser, "/storage/$storeid", ['Datastore.AllocateSpace']);
1411
1412             PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1413
1414             my $size = PVE::Storage::volume_size_info($storage_cfg, $volid, 5);
1415             $newsize += $size if $ext;
1416             $newsize = int($newsize);
1417
1418             die "unable to shrink disk size\n" if $newsize < $size;
1419
1420             return if $size == $newsize;
1421
1422             PVE::Cluster::log_msg('info', $authuser, "update CT $vmid: resize --disk $disk --size $sizestr");
1423             my $realcmd = sub {
1424                 # Note: PVE::Storage::volume_resize doesn't do anything if $running=1, so
1425                 # we pass 0 here (parameter only makes sense for qemu)
1426                 PVE::Storage::volume_resize($storage_cfg, $volid, $newsize, 0);
1427
1428                 $mp->{size} = $newsize;
1429                 $conf->{$disk} = PVE::LXC::Config->print_ct_mountpoint($mp, $disk eq 'rootfs');
1430
1431                 PVE::LXC::Config->write_config($vmid, $conf);
1432
1433                 if ($format eq 'raw') {
1434                     my $path = PVE::Storage::path($storage_cfg, $volid, undef);
1435                     if ($running) {
1436
1437                         $mp->{mp} = '/';
1438                         my $use_loopdev = (PVE::LXC::mountpoint_mount_path($mp, $storage_cfg))[1];
1439                         $path = PVE::LXC::query_loopdev($path) if $use_loopdev;
1440                         die "internal error: CT running but mount point not attached to a loop device"
1441                             if !$path;
1442                         PVE::Tools::run_command(['losetup', '--set-capacity', $path]) if $use_loopdev;
1443
1444                         # In order for resize2fs to know that we need online-resizing a mountpoint needs
1445                         # to be visible to it in its namespace.
1446                         # To not interfere with the rest of the system we unshare the current mount namespace,
1447                         # mount over /tmp and then run resize2fs.
1448
1449                         # interestingly we don't need to e2fsck on mounted systems...
1450                         my $quoted = PVE::Tools::shellquote($path);
1451                         my $cmd = "mount --make-rprivate / && mount $quoted /tmp && resize2fs $quoted";
1452                         eval {
1453                             PVE::Tools::run_command(['unshare', '-m', '--', 'sh', '-c', $cmd]);
1454                         };
1455                         warn "Failed to update the container's filesystem: $@\n" if $@;
1456                     } else {
1457                         eval {
1458                             PVE::Tools::run_command(['e2fsck', '-f', '-y', $path]);
1459                             PVE::Tools::run_command(['resize2fs', $path]);
1460                         };
1461                         warn "Failed to update the container's filesystem: $@\n" if $@;
1462                     }
1463                 }
1464             };
1465
1466             return $rpcenv->fork_worker('resize', $vmid, $authuser, $realcmd);
1467         };
1468
1469         return PVE::LXC::Config->lock_config($vmid, $code);;
1470     }});
1471
1472 1;