src/PVE/HA/LRM.pm

   1 package PVE::HA::LRM;
   2
   3 # Local Resource Manager
   4
   5 use strict;
   6 use warnings;
   7 use Data::Dumper;
   8 use POSIX qw(:sys_wait_h);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::HA::Tools ':exit_codes';
  13 use PVE::HA::Resources;
  14
  15 # Server can have several states:
  16
  17 my $valid_states = {
  18     wait_for_agent_lock => "waiting for agent lock",
  19     active => "got agent_lock",
  20     lost_agent_lock => "lost agent_lock",
  21 };
  22
  23 sub new {
  24     my ($this, $haenv) = @_;
  25
  26     my $class = ref($this) || $this;
  27
  28     my $self = bless {
  29         haenv => $haenv,
  30         status => { state => 'startup' },
  31         workers => {},
  32         results => {},
  33         restart_tries => {},
  34         shutdown_request => 0,
  35         shutdown_errors => 0,
  36         # mode can be: active, reboot, shutdown, restart
  37         mode => 'active',
  38     }, $class;
  39
  40     $self->set_local_status({ state =>  'wait_for_agent_lock' });
  41
  42     return $self;
  43 }
  44
  45 sub shutdown_request {
  46     my ($self) = @_;
  47
  48     return if $self->{shutdown_request}; # already in shutdown mode
  49
  50     my $haenv = $self->{haenv};
  51
  52     my $nodename = $haenv->nodename();
  53
  54     my $shutdown = $haenv->is_node_shutdown();
  55
  56     if ($shutdown) {
  57         $haenv->log('info', "shutdown LRM, stop all services");
  58         $self->{mode} = 'shutdown';
  59
  60         # queue stop jobs for all services
  61
  62         my $ss = $self->{service_status};
  63
  64         foreach my $sid (keys %$ss) {
  65             my $sd = $ss->{$sid};
  66             next if !$sd->{node};
  67             next if $sd->{node} ne $nodename;
  68             # Note: use undef uid to mark shutdown/stop jobs
  69             $self->queue_resource_command($sid, undef, 'request_stop');
  70         }
  71
  72     } else {
  73         $haenv->log('info', "restart LRM, freeze all services");
  74         $self->{mode} = 'restart';
  75     }
  76
  77     $self->{shutdown_request} = 1;
  78
  79     eval { $self->update_lrm_status(); };
  80     if (my $err = $@) {
  81         $self->log('err', "unable to update lrm status file - $err");
  82     }
  83 }
  84
  85 sub get_local_status {
  86     my ($self) = @_;
  87
  88     return $self->{status};
  89 }
  90
  91 sub set_local_status {
  92     my ($self, $new) = @_;
  93
  94     die "invalid state '$new->{state}'" if !$valid_states->{$new->{state}};
  95
  96     my $haenv = $self->{haenv};
  97
  98     my $old = $self->{status};
  99
 100     # important: only update if if really changed
 101     return if $old->{state} eq $new->{state};
 102
 103     $haenv->log('info', "status change $old->{state} => $new->{state}");
 104
 105     $new->{state_change_time} = $haenv->get_time();
 106
 107     $self->{status} = $new;
 108 }
 109
 110 sub update_lrm_status {
 111     my ($self) = @_;
 112
 113     my $haenv = $self->{haenv};
 114
 115     return 0 if !$haenv->quorate();
 116
 117     my $lrm_status = {
 118         state => $self->{status}->{state},
 119         mode => $self->{mode},
 120         results => $self->{results},
 121         timestamp => $haenv->get_time(),
 122     };
 123
 124     eval { $haenv->write_lrm_status($lrm_status); };
 125     if (my $err = $@) {
 126         $haenv->log('err', "unable to write lrm status file - $err");
 127         return 0;
 128     }
 129
 130     return 1;
 131 }
 132
 133 sub get_protected_ha_agent_lock {
 134     my ($self) = @_;
 135
 136     my $haenv = $self->{haenv};
 137
 138     my $count = 0;
 139     my $starttime = $haenv->get_time();
 140
 141     for (;;) {
 142
 143         if ($haenv->get_ha_agent_lock()) {
 144             if ($self->{ha_agent_wd}) {
 145                 $haenv->watchdog_update($self->{ha_agent_wd});
 146             } else {
 147                 my $wfh = $haenv->watchdog_open();
 148                 $self->{ha_agent_wd} = $wfh;
 149             }
 150             return 1;
 151         }
 152
 153         last if ++$count > 5; # try max 5 time
 154
 155         my $delay = $haenv->get_time() - $starttime;
 156         last if $delay > 5; # for max 5 seconds
 157
 158         $haenv->sleep(1);
 159     }
 160
 161     return 0;
 162 }
 163
 164 sub active_service_count {
 165     my ($self) = @_;
 166
 167     my $haenv = $self->{haenv};
 168
 169     my $nodename = $haenv->nodename();
 170
 171     my $ss = $self->{service_status};
 172
 173     my $count = 0;
 174
 175     foreach my $sid (keys %$ss) {
 176         my $sd = $ss->{$sid};
 177         next if !$sd->{node};
 178         next if $sd->{node} ne $nodename;
 179         my $req_state = $sd->{state};
 180         next if !defined($req_state);
 181         next if $req_state eq 'stopped';
 182         next if $req_state eq 'freeze';
 183
 184         $count++;
 185     }
 186
 187     return $count;
 188 }
 189
 190 my $wrote_lrm_status_at_startup = 0;
 191
 192 sub do_one_iteration {
 193     my ($self) = @_;
 194
 195     my $haenv = $self->{haenv};
 196
 197     if (!$wrote_lrm_status_at_startup) {
 198         if ($self->update_lrm_status()) {
 199             $wrote_lrm_status_at_startup = 1;
 200         } else {
 201             # do nothing
 202             $haenv->sleep(5);
 203             return $self->{shutdown_request} ? 0 : 1;
 204         }
 205     }
 206
 207     my $status = $self->get_local_status();
 208     my $state = $status->{state};
 209
 210     my $ms = $haenv->read_manager_status();
 211     $self->{service_status} =  $ms->{service_status} || {};
 212
 213     my $fence_request = PVE::HA::Tools::count_fenced_services($self->{service_status}, $haenv->nodename());
 214
 215     # do state changes first
 216
 217     my $ctime = $haenv->get_time();
 218
 219     if ($state eq 'wait_for_agent_lock') {
 220
 221         my $service_count = $self->active_service_count();
 222
 223         if (!$fence_request && $service_count && $haenv->quorate()) {
 224             if ($self->get_protected_ha_agent_lock()) {
 225                 $self->set_local_status({ state => 'active' });
 226             }
 227         }
 228
 229     } elsif ($state eq 'lost_agent_lock') {
 230
 231         if (!$fence_request && $haenv->quorate()) {
 232             if ($self->get_protected_ha_agent_lock()) {
 233                 $self->set_local_status({ state => 'active' });
 234             }
 235         }
 236
 237     } elsif ($state eq 'active') {
 238
 239         if ($fence_request) {
 240             $haenv->log('err', "node need to be fenced - releasing agent_lock\n");
 241             $self->set_local_status({ state => 'lost_agent_lock'});
 242         } elsif (!$self->get_protected_ha_agent_lock()) {
 243             $self->set_local_status({ state => 'lost_agent_lock'});
 244         }
 245     }
 246
 247     $status = $self->get_local_status();
 248     $state = $status->{state};
 249
 250     # do work
 251
 252     if ($state eq 'wait_for_agent_lock') {
 253
 254         return 0 if $self->{shutdown_request};
 255
 256         $self->update_lrm_status();
 257
 258         $haenv->sleep(5);
 259
 260     } elsif ($state eq 'active') {
 261
 262         my $startime = $haenv->get_time();
 263
 264         my $max_time = 10;
 265
 266         my $shutdown = 0;
 267
 268         # do work (max_time seconds)
 269         eval {
 270             # fixme: set alert timer
 271
 272             if ($self->{shutdown_request}) {
 273
 274                 if ($self->{mode} eq 'restart') {
 275
 276                     my $service_count = $self->active_service_count();
 277
 278                     if ($service_count == 0) {
 279
 280                         if ($self->run_workers() == 0) {
 281                             if ($self->{ha_agent_wd}) {
 282                                 $haenv->watchdog_close($self->{ha_agent_wd});
 283                                 delete $self->{ha_agent_wd};
 284                             }
 285
 286                             $shutdown = 1;
 287
 288                             # restart with no or freezed services, release the lock
 289                             $haenv->release_ha_agent_lock();
 290                         }
 291                     }
 292                 } else {
 293
 294                     if ($self->run_workers() == 0) {
 295                         if ($self->{shutdown_errors} == 0) {
 296                             if ($self->{ha_agent_wd}) {
 297                                 $haenv->watchdog_close($self->{ha_agent_wd});
 298                                 delete $self->{ha_agent_wd};
 299                             }
 300
 301                             # shutdown with all services stopped thus release the lock
 302                             $haenv->release_ha_agent_lock();
 303                         }
 304
 305                         $shutdown = 1;
 306                     }
 307                 }
 308             } else {
 309
 310                 $self->manage_resources();
 311
 312             }
 313         };
 314         if (my $err = $@) {
 315             $haenv->log('err', "got unexpected error - $err");
 316         }
 317
 318         $self->update_lrm_status();
 319
 320         return 0 if $shutdown;
 321
 322         $haenv->sleep_until($startime + $max_time);
 323
 324     } elsif ($state eq 'lost_agent_lock') {
 325
 326         # Note: watchdog is active an will triger soon!
 327
 328         # so we hope to get the lock back soon!
 329
 330         if ($self->{shutdown_request}) {
 331
 332             my $service_count = $self->active_service_count();
 333
 334             if ($service_count > 0) {
 335                 $haenv->log('err', "get shutdown request in state 'lost_agent_lock' - " .
 336                             "detected $service_count running services");
 337
 338             } else {
 339
 340                 # all services are stopped, so we can close the watchdog
 341
 342                 if ($self->{ha_agent_wd}) {
 343                     $haenv->watchdog_close($self->{ha_agent_wd});
 344                     delete $self->{ha_agent_wd};
 345                 }
 346
 347                 return 0;
 348             }
 349         }
 350
 351         $haenv->sleep(5);
 352
 353     } else {
 354
 355         die "got unexpected status '$state'\n";
 356
 357     }
 358
 359     return 1;
 360 }
 361
 362 sub run_workers {
 363     my ($self) = @_;
 364
 365     my $haenv = $self->{haenv};
 366
 367     my $starttime = $haenv->get_time();
 368
 369     # number of workers to start, if 0 we exec the command directly witouth forking
 370     my $max_workers = $haenv->get_max_workers();
 371
 372     my $sc = $haenv->read_service_config();
 373
 374     while (($haenv->get_time() - $starttime) < 5) {
 375         my $count =  $self->check_active_workers();
 376
 377         foreach my $sid (keys %{$self->{workers}}) {
 378             last if $count >= $max_workers && $max_workers > 0;
 379
 380             my $w = $self->{workers}->{$sid};
 381             if (!$w->{pid}) {
 382                 # only fork if we may else call exec_resource_agent
 383                 # directly (e.g. for regression tests)
 384                 if ($max_workers > 0) {
 385                     my $pid = fork();
 386                     if (!defined($pid)) {
 387                         $haenv->log('err', "fork worker failed");
 388                         $count = 0; last; # abort, try later
 389                     } elsif ($pid == 0) {
 390                         $haenv->after_fork(); # cleanup
 391
 392                         # do work
 393                         my $res = -1;
 394                         eval {
 395                             $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{target});
 396                         };
 397                         if (my $err = $@) {
 398                             $haenv->log('err', $err);
 399                             POSIX::_exit(-1);
 400                         }
 401                         POSIX::_exit($res);
 402                     } else {
 403                         $count++;
 404                         $w->{pid} = $pid;
 405                     }
 406                 } else {
 407                     my $res = -1;
 408                     eval {
 409                         $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{target});
 410                         $res = $res << 8 if $res > 0;
 411                     };
 412                     if (my $err = $@) {
 413                         $haenv->log('err', $err);
 414                     }
 415                     if (defined($w->{uid})) {
 416                         $self->resource_command_finished($sid, $w->{uid}, $res);
 417                     } else {
 418                         $self->stop_command_finished($sid, $res);
 419                     }
 420                 }
 421             }
 422         }
 423
 424         last if !$count;
 425
 426         $haenv->sleep(1);
 427     }
 428
 429     return scalar(keys %{$self->{workers}});
 430 }
 431
 432 sub manage_resources {
 433     my ($self) = @_;
 434
 435     my $haenv = $self->{haenv};
 436
 437     my $nodename = $haenv->nodename();
 438
 439     my $ss = $self->{service_status};
 440
 441     foreach my $sid (keys %$ss) {
 442         my $sd = $ss->{$sid};
 443         next if !$sd->{node};
 444         next if !$sd->{uid};
 445         next if $sd->{node} ne $nodename;
 446         my $req_state = $sd->{state};
 447         next if !defined($req_state);
 448         next if $req_state eq 'freeze';
 449         $self->queue_resource_command($sid, $sd->{uid}, $req_state, $sd->{target});
 450     }
 451
 452     return $self->run_workers();
 453 }
 454
 455 sub queue_resource_command {
 456     my ($self, $sid, $uid, $state, $target) = @_;
 457
 458     if (my $w = $self->{workers}->{$sid}) {
 459         return if $w->{pid}; # already started
 460         # else, delete and overwrite queue entry with new command
 461         delete $self->{workers}->{$sid};
 462     }
 463
 464     $self->{workers}->{$sid} = {
 465         sid => $sid,
 466         uid => $uid,
 467         state => $state,
 468     };
 469
 470     $self->{workers}->{$sid}->{target} = $target if $target;
 471 }
 472
 473 sub check_active_workers {
 474     my ($self) = @_;
 475
 476     # finish/count workers
 477     my $count = 0;
 478     foreach my $sid (keys %{$self->{workers}}) {
 479         my $w = $self->{workers}->{$sid};
 480         if (my $pid = $w->{pid}) {
 481             # check status
 482             my $waitpid = waitpid($pid, WNOHANG);
 483             if (defined($waitpid) && ($waitpid == $pid)) {
 484                 if (defined($w->{uid})) {
 485                     $self->resource_command_finished($sid, $w->{uid}, $?);
 486                 } else {
 487                     $self->stop_command_finished($sid, $?);
 488                 }
 489             } else {
 490                 $count++;
 491             }
 492         }
 493     }
 494
 495     return $count;
 496 }
 497
 498 sub stop_command_finished {
 499     my ($self, $sid, $status) = @_;
 500
 501     my $haenv = $self->{haenv};
 502
 503     my $w = delete $self->{workers}->{$sid};
 504     return if !$w; # should not happen
 505
 506     my $exit_code = -1;
 507
 508     if ($status == -1) {
 509         $haenv->log('err', "resource agent $sid finished - failed to execute");
 510     }  elsif (my $sig = ($status & 127)) {
 511         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 512     } else {
 513         $exit_code = ($status >> 8);
 514     }
 515
 516     if ($exit_code != 0) {
 517         $self->{shutdown_errors}++;
 518     }
 519 }
 520
 521 sub resource_command_finished {
 522     my ($self, $sid, $uid, $status) = @_;
 523
 524     my $haenv = $self->{haenv};
 525
 526     my $w = delete $self->{workers}->{$sid};
 527     return if !$w; # should not happen
 528
 529     my $exit_code = -1;
 530
 531     if ($status == -1) {
 532         $haenv->log('err', "resource agent $sid finished - failed to execute");
 533     }  elsif (my $sig = ($status & 127)) {
 534         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 535     } else {
 536         $exit_code = ($status >> 8);
 537     }
 538
 539     $exit_code = $self->handle_service_exitcode($sid, $w->{state}, $exit_code);
 540
 541     $self->{results}->{$uid} = {
 542         sid => $w->{sid},
 543         state => $w->{state},
 544         exit_code => $exit_code,
 545     };
 546
 547     my $ss = $self->{service_status};
 548
 549     # compute hash of valid/existing uids
 550     my $valid_uids = {};
 551     foreach my $sid (keys %$ss) {
 552         my $sd = $ss->{$sid};
 553         next if !$sd->{uid};
 554         $valid_uids->{$sd->{uid}} = 1;
 555     }
 556
 557     my $results = {};
 558     foreach my $id (keys %{$self->{results}}) {
 559         next if !$valid_uids->{$id};
 560         $results->{$id} = $self->{results}->{$id};
 561     }
 562     $self->{results} = $results;
 563 }
 564
 565 # processes the exit code from a finished resource agent, so that the CRM knows
 566 # if the LRM wants to retry an action based on the current recovery policies for
 567 # the failed service, or the CRM itself must try to recover from the failure.
 568 sub handle_service_exitcode {
 569     my ($self, $sid, $cmd, $exit_code) = @_;
 570
 571     my $haenv = $self->{haenv};
 572     my $tries = $self->{restart_tries};
 573
 574     my $sc = $haenv->read_service_config();
 575
 576     my $max_restart = 0;
 577
 578     if (my $cd = $sc->{$sid}) {
 579         $max_restart = $cd->{max_restart};
 580     }
 581
 582     if ($cmd eq 'started') {
 583
 584         if ($exit_code == SUCCESS) {
 585
 586             $tries->{$sid} = 0;
 587
 588             return $exit_code;
 589
 590         } elsif ($exit_code == ERROR) {
 591
 592             $tries->{$sid} = 0 if !defined($tries->{$sid});
 593
 594             $tries->{$sid}++;
 595             if ($tries->{$sid} >= $max_restart) {
 596                 $haenv->log('err', "unable to start service $sid on local node".
 597                            " after $tries->{$sid} retries");
 598                 $tries->{$sid} = 0;
 599                 return ERROR;
 600             }
 601
 602             # tell CRM that we retry the start
 603             return ETRY_AGAIN;
 604         }
 605     }
 606
 607     return $exit_code;
 608
 609 }
 610
 611 sub exec_resource_agent {
 612     my ($self, $sid, $service_config, $cmd, @params) = @_;
 613
 614     # setup execution environment
 615
 616     $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 617
 618     my $haenv = $self->{haenv};
 619
 620     my $nodename = $haenv->nodename();
 621
 622     my (undef, $service_type, $service_name) = PVE::HA::Tools::parse_sid($sid);
 623
 624     my $plugin = PVE::HA::Resources->lookup($service_type);
 625     if (!$plugin) {
 626         $haenv->log('err', "service type '$service_type' not implemented");
 627         return EUNKNOWN_SERVICE_TYPE;
 628     }
 629
 630     if (!$service_config) {
 631         $haenv->log('err', "missing resource configuration for '$sid'");
 632         return EUNKNOWN_SERVICE;
 633     }
 634
 635     if ($service_config->{node} ne $nodename) {
 636         $haenv->log('err', "service '$sid' not on this node");
 637         return EWRONG_NODE;
 638     }
 639
 640     my $id = $service_name;
 641
 642     my $running = $plugin->check_running($haenv, $id);
 643
 644     if ($cmd eq 'started') {
 645
 646         return SUCCESS if $running;
 647
 648         $haenv->log("info", "starting service $sid");
 649
 650         $plugin->start($haenv, $id);
 651
 652         $running = $plugin->check_running($haenv, $id);
 653
 654         if ($running) {
 655             $haenv->log("info", "service status $sid started");
 656             return SUCCESS;
 657         } else {
 658             $haenv->log("warning", "unable to start service $sid");
 659             return ERROR;
 660         }
 661
 662     } elsif ($cmd eq 'request_stop' || $cmd eq 'stopped') {
 663
 664         return SUCCESS if !$running;
 665
 666         $haenv->log("info", "stopping service $sid");
 667
 668         $plugin->shutdown($haenv, $id);
 669
 670         $running = $plugin->check_running($haenv, $id);
 671
 672         if (!$running) {
 673             $haenv->log("info", "service status $sid stopped");
 674             return SUCCESS;
 675         } else {
 676             $haenv->log("info", "unable to stop stop service $sid (still running)");
 677             return ERROR;
 678         }
 679
 680     } elsif ($cmd eq 'migrate' || $cmd eq 'relocate') {
 681
 682         my $target = $params[0];
 683         if (!defined($target)) {
 684             die "$cmd '$sid' failed - missing target\n" if !defined($target);
 685             return EINVALID_PARAMETER;
 686         }
 687
 688         if ($service_config->{node} eq $target) {
 689             # already there
 690             return SUCCESS;
 691         }
 692
 693         my $online = ($cmd eq 'migrate') ? 1 : 0;
 694
 695         my $res = $plugin->migrate($haenv, $id, $target, $online);
 696
 697         # something went wrong if service is still on this node
 698         if (!$res) {
 699             $haenv->log("err", "service $sid not moved (migration error)");
 700             return ERROR;
 701         }
 702
 703         return SUCCESS;
 704
 705     } elsif ($cmd eq 'error') {
 706
 707         if ($running) {
 708             $haenv->log("err", "service $sid is in an error state while running");
 709         } else {
 710             $haenv->log("warning", "service $sid is not running and in an error state");
 711         }
 712         return SUCCESS; # error always succeeds
 713
 714     }
 715
 716     $haenv->log("err", "implement me (cmd '$cmd')");
 717     return EUNKNOWN_COMMAND;
 718 }
 719
 720
 721 1;