src/PVE/HA/LRM.pm

   1 package PVE::HA::LRM;
   2
   3 # Local Resource Manager
   4
   5 use strict;
   6 use warnings;
   7 use Data::Dumper;
   8 use POSIX qw(:sys_wait_h);
   9
  10 use PVE::SafeSyslog;
  11 use PVE::Tools;
  12 use PVE::HA::Tools ':exit_codes';
  13 use PVE::HA::Resources;
  14
  15 # Server can have several states:
  16
  17 my $valid_states = {
  18     wait_for_agent_lock => "waiting for agent lock",
  19     active => "got agent_lock",
  20     lost_agent_lock => "lost agent_lock",
  21 };
  22
  23 sub new {
  24     my ($this, $haenv) = @_;
  25
  26     my $class = ref($this) || $this;
  27
  28     my $self = bless {
  29         haenv => $haenv,
  30         status => { state => 'startup' },
  31         workers => {},
  32         results => {},
  33         restart_tries => {},
  34         shutdown_request => 0,
  35         shutdown_errors => 0,
  36         # mode can be: active, reboot, shutdown, restart
  37         mode => 'active',
  38     }, $class;
  39
  40     $self->set_local_status({ state =>  'wait_for_agent_lock' });
  41
  42     return $self;
  43 }
  44
  45 sub shutdown_request {
  46     my ($self) = @_;
  47
  48     return if $self->{shutdown_request}; # already in shutdown mode
  49
  50     my $haenv = $self->{haenv};
  51
  52     my $nodename = $haenv->nodename();
  53
  54     my $shutdown = $haenv->is_node_shutdown();
  55
  56     if ($shutdown) {
  57         $haenv->log('info', "shutdown LRM, stop all services");
  58         $self->{mode} = 'shutdown';
  59
  60         # queue stop jobs for all services
  61
  62         my $ss = $self->{service_status};
  63
  64         foreach my $sid (keys %$ss) {
  65             my $sd = $ss->{$sid};
  66             next if !$sd->{node};
  67             next if $sd->{node} ne $nodename;
  68             # Note: use undef uid to mark shutdown/stop jobs
  69             $self->queue_resource_command($sid, undef, 'request_stop');
  70         }
  71
  72     } else {
  73         $haenv->log('info', "restart LRM, freeze all services");
  74         $self->{mode} = 'restart';
  75     }
  76
  77     $self->{shutdown_request} = 1;
  78
  79     eval { $self->update_lrm_status(); };
  80     if (my $err = $@) {
  81         $self->log('err', "unable to update lrm status file - $err");
  82     }
  83 }
  84
  85 sub get_local_status {
  86     my ($self) = @_;
  87
  88     return $self->{status};
  89 }
  90
  91 sub set_local_status {
  92     my ($self, $new) = @_;
  93
  94     die "invalid state '$new->{state}'" if !$valid_states->{$new->{state}};
  95
  96     my $haenv = $self->{haenv};
  97
  98     my $old = $self->{status};
  99
 100     # important: only update if if really changed
 101     return if $old->{state} eq $new->{state};
 102
 103     $haenv->log('info', "status change $old->{state} => $new->{state}");
 104
 105     $new->{state_change_time} = $haenv->get_time();
 106
 107     $self->{status} = $new;
 108 }
 109
 110 sub update_lrm_status {
 111     my ($self) = @_;
 112
 113     my $haenv = $self->{haenv};
 114
 115     return 0 if !$haenv->quorate();
 116
 117     my $lrm_status = {
 118         state => $self->{status}->{state},
 119         mode => $self->{mode},
 120         results => $self->{results},
 121         timestamp => $haenv->get_time(),
 122     };
 123
 124     eval { $haenv->write_lrm_status($lrm_status); };
 125     if (my $err = $@) {
 126         $haenv->log('err', "unable to write lrm status file - $err");
 127         return 0;
 128     }
 129
 130     return 1;
 131 }
 132
 133 sub get_protected_ha_agent_lock {
 134     my ($self) = @_;
 135
 136     my $haenv = $self->{haenv};
 137
 138     my $count = 0;
 139     my $starttime = $haenv->get_time();
 140
 141     for (;;) {
 142
 143         if ($haenv->get_ha_agent_lock()) {
 144             if ($self->{ha_agent_wd}) {
 145                 $haenv->watchdog_update($self->{ha_agent_wd});
 146             } else {
 147                 my $wfh = $haenv->watchdog_open();
 148                 $self->{ha_agent_wd} = $wfh;
 149             }
 150             return 1;
 151         }
 152
 153         last if ++$count > 5; # try max 5 time
 154
 155         my $delay = $haenv->get_time() - $starttime;
 156         last if $delay > 5; # for max 5 seconds
 157
 158         $haenv->sleep(1);
 159     }
 160
 161     return 0;
 162 }
 163
 164 sub active_service_count {
 165     my ($self) = @_;
 166
 167     my $haenv = $self->{haenv};
 168
 169     my $nodename = $haenv->nodename();
 170
 171     my $ss = $self->{service_status};
 172
 173     my $count = 0;
 174
 175     foreach my $sid (keys %$ss) {
 176         my $sd = $ss->{$sid};
 177         next if !$sd->{node};
 178         next if $sd->{node} ne $nodename;
 179         my $req_state = $sd->{state};
 180         next if !defined($req_state);
 181         next if $req_state eq 'stopped';
 182         next if $req_state eq 'freeze';
 183
 184         $count++;
 185     }
 186
 187     return $count;
 188 }
 189
 190 my $wrote_lrm_status_at_startup = 0;
 191
 192 sub do_one_iteration {
 193     my ($self) = @_;
 194
 195     my $haenv = $self->{haenv};
 196
 197     if (!$wrote_lrm_status_at_startup) {
 198         if ($self->update_lrm_status()) {
 199             $wrote_lrm_status_at_startup = 1;
 200         } else {
 201             # do nothing
 202             $haenv->sleep(5);
 203             return $self->{shutdown_request} ? 0 : 1;
 204         }
 205     }
 206
 207     my $status = $self->get_local_status();
 208     my $state = $status->{state};
 209
 210     my $ms = $haenv->read_manager_status();
 211     $self->{service_status} =  $ms->{service_status} || {};
 212
 213     my $fence_request = PVE::HA::Tools::count_fenced_services($self->{service_status}, $haenv->nodename());
 214
 215     # do state changes first
 216
 217     my $ctime = $haenv->get_time();
 218
 219     if ($state eq 'wait_for_agent_lock') {
 220
 221         my $service_count = $self->active_service_count();
 222
 223         if (!$fence_request && $service_count && $haenv->quorate()) {
 224             if ($self->get_protected_ha_agent_lock()) {
 225                 $self->set_local_status({ state => 'active' });
 226             }
 227         }
 228
 229     } elsif ($state eq 'lost_agent_lock') {
 230
 231         if (!$fence_request && $haenv->quorate()) {
 232             if ($self->get_protected_ha_agent_lock()) {
 233                 $self->set_local_status({ state => 'active' });
 234             }
 235         }
 236
 237     } elsif ($state eq 'active') {
 238
 239         if ($fence_request) {
 240             $haenv->log('err', "node need to be fenced - releasing agent_lock\n");
 241             $self->set_local_status({ state => 'lost_agent_lock'});
 242         } elsif (!$self->get_protected_ha_agent_lock()) {
 243             $self->set_local_status({ state => 'lost_agent_lock'});
 244         }
 245     }
 246
 247     $status = $self->get_local_status();
 248     $state = $status->{state};
 249
 250     # do work
 251
 252     if ($state eq 'wait_for_agent_lock') {
 253
 254         return 0 if $self->{shutdown_request};
 255
 256         $self->update_lrm_status();
 257
 258         $haenv->sleep(5);
 259
 260     } elsif ($state eq 'active') {
 261
 262         my $startime = $haenv->get_time();
 263
 264         my $max_time = 10;
 265
 266         my $shutdown = 0;
 267
 268         # do work (max_time seconds)
 269         eval {
 270             # fixme: set alert timer
 271
 272             if ($self->{shutdown_request}) {
 273
 274                 if ($self->{mode} eq 'restart') {
 275
 276                     my $service_count = $self->active_service_count();
 277
 278                     if ($service_count == 0) {
 279
 280                         if ($self->run_workers() == 0) {
 281                             if ($self->{ha_agent_wd}) {
 282                                 $haenv->watchdog_close($self->{ha_agent_wd});
 283                                 delete $self->{ha_agent_wd};
 284                             }
 285
 286                             $shutdown = 1;
 287
 288                             # restart with no or freezed services, release the lock
 289                             $haenv->release_ha_agent_lock();
 290                         }
 291                     }
 292                 } else {
 293
 294                     if ($self->run_workers() == 0) {
 295                         if ($self->{shutdown_errors} == 0) {
 296                             if ($self->{ha_agent_wd}) {
 297                                 $haenv->watchdog_close($self->{ha_agent_wd});
 298                                 delete $self->{ha_agent_wd};
 299                             }
 300
 301                             # shutdown with all services stopped thus release the lock
 302                             $haenv->release_ha_agent_lock();
 303                         }
 304
 305                         $shutdown = 1;
 306                     }
 307                 }
 308             } else {
 309
 310                 $self->manage_resources();
 311
 312             }
 313         };
 314         if (my $err = $@) {
 315             $haenv->log('err', "got unexpected error - $err");
 316         }
 317
 318         $self->update_lrm_status();
 319
 320         return 0 if $shutdown;
 321
 322         $haenv->sleep_until($startime + $max_time);
 323
 324     } elsif ($state eq 'lost_agent_lock') {
 325
 326         # Note: watchdog is active an will triger soon!
 327
 328         # so we hope to get the lock back soon!
 329
 330         if ($self->{shutdown_request}) {
 331
 332             my $service_count = $self->active_service_count();
 333
 334             if ($service_count > 0) {
 335                 $haenv->log('err', "get shutdown request in state 'lost_agent_lock' - " .
 336                             "detected $service_count running services");
 337
 338             } else {
 339
 340                 # all services are stopped, so we can close the watchdog
 341
 342                 if ($self->{ha_agent_wd}) {
 343                     $haenv->watchdog_close($self->{ha_agent_wd});
 344                     delete $self->{ha_agent_wd};
 345                 }
 346
 347                 return 0;
 348             }
 349         }
 350
 351         $haenv->sleep(5);
 352
 353     } else {
 354
 355         die "got unexpected status '$state'\n";
 356
 357     }
 358
 359     return 1;
 360 }
 361
 362 sub run_workers {
 363     my ($self) = @_;
 364
 365     my $haenv = $self->{haenv};
 366
 367     my $starttime = $haenv->get_time();
 368
 369     # start workers
 370     my $max_workers = 4;
 371
 372     my $sc = $haenv->read_service_config();
 373
 374     while (($haenv->get_time() - $starttime) < 5) {
 375         my $count =  $self->check_active_workers();
 376
 377         foreach my $sid (keys %{$self->{workers}}) {
 378             last if $count >= $max_workers;
 379             my $w = $self->{workers}->{$sid};
 380             if (!$w->{pid}) {
 381                 if ($haenv->can_fork()) {
 382                     my $pid = fork();
 383                     if (!defined($pid)) {
 384                         $haenv->log('err', "fork worker failed");
 385                         $count = 0; last; # abort, try later
 386                     } elsif ($pid == 0) {
 387                         $haenv->after_fork(); # cleanup
 388
 389                         # do work
 390                         my $res = -1;
 391                         eval {
 392                             $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{target});
 393                         };
 394                         if (my $err = $@) {
 395                             $haenv->log('err', $err);
 396                             POSIX::_exit(-1);
 397                         }
 398                         POSIX::_exit($res);
 399                     } else {
 400                         $count++;
 401                         $w->{pid} = $pid;
 402                     }
 403                 } else {
 404                     my $res = -1;
 405                     eval {
 406                         $res = $self->exec_resource_agent($sid, $sc->{$sid}, $w->{state}, $w->{target});
 407                         $res = $res << 8 if $res > 0;
 408                     };
 409                     if (my $err = $@) {
 410                         $haenv->log('err', $err);
 411                     }
 412                     if (defined($w->{uid})) {
 413                         $self->resource_command_finished($sid, $w->{uid}, $res);
 414                     } else {
 415                         $self->stop_command_finished($sid, $res);
 416                     }
 417                 }
 418             }
 419         }
 420
 421         last if !$count;
 422
 423         $haenv->sleep(1);
 424     }
 425
 426     return scalar(keys %{$self->{workers}});
 427 }
 428
 429 sub manage_resources {
 430     my ($self) = @_;
 431
 432     my $haenv = $self->{haenv};
 433
 434     my $nodename = $haenv->nodename();
 435
 436     my $ss = $self->{service_status};
 437
 438     foreach my $sid (keys %$ss) {
 439         my $sd = $ss->{$sid};
 440         next if !$sd->{node};
 441         next if !$sd->{uid};
 442         next if $sd->{node} ne $nodename;
 443         my $req_state = $sd->{state};
 444         next if !defined($req_state);
 445         next if $req_state eq 'freeze';
 446         $self->queue_resource_command($sid, $sd->{uid}, $req_state, $sd->{target});
 447     }
 448
 449     return $self->run_workers();
 450 }
 451
 452 sub queue_resource_command {
 453     my ($self, $sid, $uid, $state, $target) = @_;
 454
 455     if (my $w = $self->{workers}->{$sid}) {
 456         return if $w->{pid}; # already started
 457         # else, delete and overwrite queue entry with new command
 458         delete $self->{workers}->{$sid};
 459     }
 460
 461     $self->{workers}->{$sid} = {
 462         sid => $sid,
 463         uid => $uid,
 464         state => $state,
 465     };
 466
 467     $self->{workers}->{$sid}->{target} = $target if $target;
 468 }
 469
 470 sub check_active_workers {
 471     my ($self) = @_;
 472
 473     # finish/count workers
 474     my $count = 0;
 475     foreach my $sid (keys %{$self->{workers}}) {
 476         my $w = $self->{workers}->{$sid};
 477         if (my $pid = $w->{pid}) {
 478             # check status
 479             my $waitpid = waitpid($pid, WNOHANG);
 480             if (defined($waitpid) && ($waitpid == $pid)) {
 481                 if (defined($w->{uid})) {
 482                     $self->resource_command_finished($sid, $w->{uid}, $?);
 483                 } else {
 484                     $self->stop_command_finished($sid, $?);
 485                 }
 486             } else {
 487                 $count++;
 488             }
 489         }
 490     }
 491
 492     return $count;
 493 }
 494
 495 sub stop_command_finished {
 496     my ($self, $sid, $status) = @_;
 497
 498     my $haenv = $self->{haenv};
 499
 500     my $w = delete $self->{workers}->{$sid};
 501     return if !$w; # should not happen
 502
 503     my $exit_code = -1;
 504
 505     if ($status == -1) {
 506         $haenv->log('err', "resource agent $sid finished - failed to execute");
 507     }  elsif (my $sig = ($status & 127)) {
 508         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 509     } else {
 510         $exit_code = ($status >> 8);
 511     }
 512
 513     if ($exit_code != 0) {
 514         $self->{shutdown_errors}++;
 515     }
 516 }
 517
 518 sub resource_command_finished {
 519     my ($self, $sid, $uid, $status) = @_;
 520
 521     my $haenv = $self->{haenv};
 522
 523     my $w = delete $self->{workers}->{$sid};
 524     return if !$w; # should not happen
 525
 526     my $exit_code = -1;
 527
 528     if ($status == -1) {
 529         $haenv->log('err', "resource agent $sid finished - failed to execute");
 530     }  elsif (my $sig = ($status & 127)) {
 531         $haenv->log('err', "resource agent $sid finished - got signal $sig");
 532     } else {
 533         $exit_code = ($status >> 8);
 534     }
 535
 536     $exit_code = $self->handle_service_exitcode($sid, $w->{state}, $exit_code);
 537
 538     $self->{results}->{$uid} = {
 539         sid => $w->{sid},
 540         state => $w->{state},
 541         exit_code => $exit_code,
 542     };
 543
 544     my $ss = $self->{service_status};
 545
 546     # compute hash of valid/existing uids
 547     my $valid_uids = {};
 548     foreach my $sid (keys %$ss) {
 549         my $sd = $ss->{$sid};
 550         next if !$sd->{uid};
 551         $valid_uids->{$sd->{uid}} = 1;
 552     }
 553
 554     my $results = {};
 555     foreach my $id (keys %{$self->{results}}) {
 556         next if !$valid_uids->{$id};
 557         $results->{$id} = $self->{results}->{$id};
 558     }
 559     $self->{results} = $results;
 560 }
 561
 562 # processes the exit code from a finished resource agent, so that the CRM knows
 563 # if the LRM wants to retry an action based on the current recovery policies for
 564 # the failed service, or the CRM itself must try to recover from the failure.
 565 sub handle_service_exitcode {
 566     my ($self, $sid, $cmd, $exit_code) = @_;
 567
 568     my $haenv = $self->{haenv};
 569     my $tries = $self->{restart_tries};
 570
 571     my $sc = $haenv->read_service_config();
 572
 573     my $max_restart = 0;
 574
 575     if (my $cd = $sc->{$sid}) {
 576         $max_restart = $cd->{max_restart};
 577     }
 578
 579     if ($cmd eq 'started') {
 580
 581         if ($exit_code == SUCCESS) {
 582
 583             $tries->{$sid} = 0;
 584
 585             return $exit_code;
 586
 587         } elsif ($exit_code == ERROR) {
 588
 589             $tries->{$sid} = 0 if !defined($tries->{$sid});
 590
 591             $tries->{$sid}++;
 592             if ($tries->{$sid} >= $max_restart) {
 593                 $haenv->log('err', "unable to start service $sid on local node".
 594                            " after $tries->{$sid} retries");
 595                 $tries->{$sid} = 0;
 596                 return ERROR;
 597             }
 598
 599             # tell CRM that we retry the start
 600             return ETRY_AGAIN;
 601         }
 602     }
 603
 604     return $exit_code;
 605
 606 }
 607
 608 sub exec_resource_agent {
 609     my ($self, $sid, $service_config, $cmd, @params) = @_;
 610
 611     # setup execution environment
 612
 613     $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 614
 615     my $haenv = $self->{haenv};
 616
 617     my $nodename = $haenv->nodename();
 618
 619     my (undef, $service_type, $service_name) = PVE::HA::Tools::parse_sid($sid);
 620
 621     my $plugin = PVE::HA::Resources->lookup($service_type);
 622     if (!$plugin) {
 623         $haenv->log('err', "service type '$service_type' not implemented");
 624         return EUNKNOWN_SERVICE_TYPE;
 625     }
 626
 627     if (!$service_config) {
 628         $haenv->log('err', "missing resource configuration for '$sid'");
 629         return EUNKNOWN_SERVICE;
 630     }
 631
 632     if ($service_config->{node} ne $nodename) {
 633         $haenv->log('err', "service '$sid' not on this node");
 634         return EWRONG_NODE;
 635     }
 636
 637     my $id = $service_name;
 638
 639     my $running = $plugin->check_running($haenv, $id);
 640
 641     if ($cmd eq 'started') {
 642
 643         return SUCCESS if $running;
 644
 645         $haenv->log("info", "starting service $sid");
 646
 647         $plugin->start($haenv, $id);
 648
 649         $running = $plugin->check_running($haenv, $id);
 650
 651         if ($running) {
 652             $haenv->log("info", "service status $sid started");
 653             return SUCCESS;
 654         } else {
 655             $haenv->log("warning", "unable to start service $sid");
 656             return ERROR;
 657         }
 658
 659     } elsif ($cmd eq 'request_stop' || $cmd eq 'stopped') {
 660
 661         return SUCCESS if !$running;
 662
 663         $haenv->log("info", "stopping service $sid");
 664
 665         $plugin->shutdown($haenv, $id);
 666
 667         $running = $plugin->check_running($haenv, $id);
 668
 669         if (!$running) {
 670             $haenv->log("info", "service status $sid stopped");
 671             return SUCCESS;
 672         } else {
 673             $haenv->log("info", "unable to stop stop service $sid (still running)");
 674             return ERROR;
 675         }
 676
 677     } elsif ($cmd eq 'migrate' || $cmd eq 'relocate') {
 678
 679         my $target = $params[0];
 680         if (!defined($target)) {
 681             die "$cmd '$sid' failed - missing target\n" if !defined($target);
 682             return EINVALID_PARAMETER;
 683         }
 684
 685         if ($service_config->{node} eq $target) {
 686             # already there
 687             return SUCCESS;
 688         }
 689
 690         my $online = ($cmd eq 'migrate') ? 1 : 0;
 691
 692         my $res = $plugin->migrate($haenv, $id, $target, $online);
 693
 694         # something went wrong if service is still on this node
 695         if (!$res) {
 696             $haenv->log("err", "service $sid not moved (migration error)");
 697             return ERROR;
 698         }
 699
 700         return SUCCESS;
 701
 702     } elsif ($cmd eq 'error') {
 703
 704         if ($running) {
 705             $haenv->log("err", "service $sid is in an error state while running");
 706         } else {
 707             $haenv->log("warning", "service $sid is not running and in an error state");
 708         }
 709         return SUCCESS; # error always succeeds
 710
 711     }
 712
 713     $haenv->log("err", "implement me (cmd '$cmd')");
 714     return EUNKNOWN_COMMAND;
 715 }
 716
 717
 718 1;