src/PVE/HA/Manager.pm

   1 package PVE::HA::Manager;
   2
   3 use strict;
   4 use warnings;
   5 use Digest::MD5 qw(md5_base64);
   6
   7 use Data::Dumper;
   8 use PVE::Tools;
   9 use PVE::HA::NodeStatus;
  10
  11 my $fence_delay = 60;
  12
  13 sub new {
  14     my ($this, $haenv) = @_;
  15
  16     my $class = ref($this) || $this;
  17
  18     my $ms = $haenv->read_manager_status();
  19
  20     $ms->{master_node} = $haenv->nodename();
  21
  22     my $ns = PVE::HA::NodeStatus->new($haenv, $ms->{node_status} || {});
  23
  24     # fixme: use separate class  PVE::HA::ServiceStatus
  25     my $ss = $ms->{service_status} || {};
  26
  27     my $self = bless {
  28         haenv => $haenv,
  29         ms => $ms, # master status
  30         ns => $ns, # PVE::HA::NodeStatus
  31         ss => $ss, # service status
  32     }, $class;
  33
  34     return $self;
  35 }
  36
  37 sub cleanup {
  38     my ($self) = @_;
  39
  40     # todo: ?
  41 }
  42
  43 sub flush_master_status {
  44     my ($self) = @_;
  45
  46     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
  47
  48     $ms->{node_status} = $ns->{status};
  49     $ms->{service_status} = $ss;
  50     $ms->{timestamp} = $haenv->get_time();
  51
  52     $haenv->write_manager_status($ms);
  53 }
  54
  55 sub select_service_node {
  56     my ($groups, $online_node_usage, $service_conf, $current_node, $try_next) = @_;
  57
  58     my $group = { 'nodes' => { $service_conf->{node} => 1 } }; # default group
  59
  60     $group =  $groups->{ids}->{$service_conf->{group}} if $service_conf->{group} &&
  61         $groups->{ids}->{$service_conf->{group}};
  62
  63     my $pri_groups = {};
  64     my $group_members = {};
  65     foreach my $entry (keys %{$group->{nodes}}) {
  66         my ($node, $pri) = ($entry, 0);
  67         if ($entry =~ m/^(\S+):(\d+)$/) {
  68             ($node, $pri) = ($1, $2);
  69         }
  70         next if !defined($online_node_usage->{$node}); # offline
  71         $pri_groups->{$pri}->{$node} = 1;
  72         $group_members->{$node} = $pri;
  73     }
  74
  75
  76     # add non-group members to unrestricted groups (priority -1)
  77     if (!$group->{restricted}) {
  78         my $pri = -1;
  79         foreach my $node (keys %$online_node_usage) {
  80             next if defined($group_members->{$node});
  81             $pri_groups->{$pri}->{$node} = 1;
  82             $group_members->{$node} = -1;
  83         }
  84     }
  85
  86
  87     my @pri_list = sort {$b <=> $a} keys %$pri_groups;
  88     return undef if !scalar(@pri_list);
  89
  90     if (!$try_next && $group->{nofailback} && defined($group_members->{$current_node})) {
  91         return $current_node;
  92     }
  93
  94     # select node from top priority node list
  95
  96     my $top_pri = $pri_list[0];
  97
  98     my @nodes = sort {
  99         $online_node_usage->{$a} <=> $online_node_usage->{$b} || $a cmp $b
 100     } keys %{$pri_groups->{$top_pri}};
 101
 102     my $found;
 103     for (my $i = scalar(@nodes) - 1; $i >= 0; $i--) {
 104         my $node = $nodes[$i];
 105         if ($node eq $current_node) {
 106             $found = $i;
 107             last;
 108         }
 109     }
 110
 111     if ($try_next) {
 112
 113         if (defined($found) && ($found < (scalar(@nodes) - 1))) {
 114             return $nodes[$found + 1];
 115         } else {
 116             return $nodes[0];
 117         }
 118
 119     } else {
 120
 121         return $nodes[$found] if defined($found);
 122
 123         return $nodes[0];
 124
 125     }
 126 }
 127
 128 my $uid_counter = 0;
 129
 130 sub compute_new_uuid {
 131     my ($state) = @_;
 132
 133     $uid_counter++;
 134     return md5_base64($state . $$ . time() . $uid_counter);
 135 }
 136
 137 my $valid_service_states = {
 138     stopped => 1,
 139     request_stop => 1,
 140     started => 1,
 141     fence => 1,
 142     migrate => 1,
 143     relocate => 1,
 144     freeze => 1,
 145     error => 1,
 146 };
 147
 148 sub recompute_online_node_usage {
 149     my ($self) = @_;
 150
 151     my $online_node_usage = {};
 152
 153     my $online_nodes = $self->{ns}->list_online_nodes();
 154
 155     foreach my $node (@$online_nodes) {
 156         $online_node_usage->{$node} = 0;
 157     }
 158
 159     foreach my $sid (keys %{$self->{ss}}) {
 160         my $sd = $self->{ss}->{$sid};
 161         my $state = $sd->{state};
 162         if (defined($online_node_usage->{$sd->{node}})) {
 163             if (($state eq 'started') || ($state eq 'request_stop') ||
 164                 ($state eq 'fence') || ($state eq 'freeze') || ($state eq 'error')) {
 165                 $online_node_usage->{$sd->{node}}++;
 166             } elsif (($state eq 'migrate') || ($state eq 'relocate')) {
 167                 $online_node_usage->{$sd->{target}}++;
 168             } elsif ($state eq 'stopped') {
 169                 # do nothing
 170             } else {
 171                 die "should not be reached";
 172             }
 173         }
 174     }
 175
 176     $self->{online_node_usage} = $online_node_usage;
 177 }
 178
 179 my $change_service_state = sub {
 180     my ($self, $sid, $new_state, %params) = @_;
 181
 182     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 183
 184     my $sd = $ss->{$sid} || die "no such service '$sid";
 185
 186     my $old_state = $sd->{state};
 187     my $old_node = $sd->{node};
 188
 189     die "no state change" if $old_state eq $new_state; # just to be sure
 190
 191     die "invalid CRM service state '$new_state'\n" if !$valid_service_states->{$new_state};
 192
 193     foreach my $k (keys %$sd) { delete $sd->{$k}; };
 194
 195     $sd->{state} = $new_state;
 196     $sd->{node} = $old_node;
 197
 198     my $text_state = '';
 199     foreach my $k (sort keys %params) {
 200         my $v = $params{$k};
 201         $text_state .= ", " if $text_state;
 202         $text_state .= "$k = $v";
 203         $sd->{$k} = $v;
 204     }
 205
 206     $self->recompute_online_node_usage();
 207
 208     $sd->{uid} = compute_new_uuid($new_state);
 209
 210
 211     $text_state = " ($text_state)" if $text_state;
 212     $haenv->log('info', "service '$sid': state changed from '${old_state}' to '${new_state}' $text_state");
 213 };
 214
 215 # read LRM status for all nodes
 216 sub read_lrm_status {
 217     my ($self) = @_;
 218
 219     my $nodes = $self->{ns}->list_nodes();
 220     my $haenv = $self->{haenv};
 221
 222     my $results = {};
 223     my $modes = {};
 224     foreach my $node (@$nodes) {
 225         my $lrm_status = $haenv->read_lrm_status($node);
 226         $modes->{$node} = $lrm_status->{mode} || 'active';
 227         foreach my $uid (keys %{$lrm_status->{results}}) {
 228             next if $results->{$uid}; # should not happen
 229             $results->{$uid} = $lrm_status->{results}->{$uid};
 230         }
 231     }
 232
 233
 234     return ($results, $modes);
 235 }
 236
 237 # read new crm commands and save them into crm master status
 238 sub update_crm_commands {
 239     my ($self) = @_;
 240
 241     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 242
 243     my $cmdlist = $haenv->read_crm_commands();
 244
 245     foreach my $cmd (split(/\n/, $cmdlist)) {
 246         chomp $cmd;
 247
 248         if ($cmd =~ m/^(migrate|relocate)\s+(\S+)\s+(\S+)$/) {
 249             my ($task, $sid, $node) = ($1, $2, $3);
 250             if (my $sd = $ss->{$sid}) {
 251                 if (!$ns->node_is_online($node)) {
 252                     $haenv->log('err', "crm command error - node not online: $cmd");
 253                 } else {
 254                     if ($node eq $sd->{node}) {
 255                         $haenv->log('info', "ignore crm command - service already on target node: $cmd");
 256                     } else {
 257                         $haenv->log('info', "got crm command: $cmd");
 258                         $ss->{$sid}->{cmd} = [ $task, $node];
 259                     }
 260                 }
 261             } else {
 262                 $haenv->log('err', "crm command error - no such service: $cmd");
 263             }
 264
 265         } else {
 266             $haenv->log('err', "unable to parse crm command: $cmd");
 267         }
 268     }
 269
 270 }
 271
 272 sub manage {
 273     my ($self) = @_;
 274
 275     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 276
 277     $ns->update($haenv->get_node_info());
 278
 279     if (!$ns->node_is_online($haenv->nodename())) {
 280         $haenv->log('info', "master seems offline");
 281         return;
 282     }
 283
 284     my ($lrm_results, $lrm_modes) = $self->read_lrm_status();
 285
 286     my $sc = $haenv->read_service_config();
 287
 288     $self->{groups} = $haenv->read_group_config(); # update
 289
 290     # compute new service status
 291
 292     # add new service
 293     foreach my $sid (sort keys %$sc) {
 294         next if $ss->{$sid}; # already there
 295         $haenv->log('info', "adding new service '$sid' on node '$sc->{$sid}->{node}'");
 296         # assume we are running to avoid relocate running service at add
 297         $ss->{$sid} = { state => 'started', node => $sc->{$sid}->{node},
 298                         uid => compute_new_uuid('started') };
 299     }
 300
 301     # remove stale service from manager state
 302     foreach my $sid (keys %$ss) {
 303         next if $sc->{$sid};
 304         $haenv->log('info', "removing stale service '$sid' (no config)");
 305         delete $ss->{$sid};
 306     }
 307
 308     $self->update_crm_commands();
 309
 310     for (;;) {
 311         my $repeat = 0;
 312
 313         $self->recompute_online_node_usage();
 314
 315         foreach my $sid (keys %$ss) {
 316             my $sd = $ss->{$sid};
 317             my $cd = $sc->{$sid} || { state => 'disabled' };
 318
 319             my $lrm_res = $sd->{uid} ? $lrm_results->{$sd->{uid}} : undef;
 320
 321             my $last_state = $sd->{state};
 322
 323             if ($last_state eq 'stopped') {
 324
 325                 $self->next_state_stopped($sid, $cd, $sd, $lrm_res);
 326
 327             } elsif ($last_state eq 'started') {
 328
 329                 $self->next_state_started($sid, $cd, $sd, $lrm_res);
 330
 331             } elsif ($last_state eq 'migrate' || $last_state eq 'relocate') {
 332
 333                 $self->next_state_migrate_relocate($sid, $cd, $sd, $lrm_res);
 334
 335             } elsif ($last_state eq 'fence') {
 336
 337                 # do nothing here - wait until fenced
 338
 339             } elsif ($last_state eq 'request_stop') {
 340
 341                 $self->next_state_request_stop($sid, $cd, $sd, $lrm_res);
 342
 343             } elsif ($last_state eq 'freeze') {
 344
 345                 my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 346                 # unfreeze
 347                 &$change_service_state($self, $sid, 'started')
 348                     if $lrm_mode && $lrm_mode eq 'active';
 349
 350             } elsif ($last_state eq 'error') {
 351
 352                 $self->next_state_error($sid, $cd, $sd, $lrm_res);
 353
 354             } else {
 355
 356                 die "unknown service state '$last_state'";
 357             }
 358
 359
 360             my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 361             $lrm_mode = 'unknown'if !$lrm_mode;
 362             if (($sd->{state} eq 'started' || $sd->{state} eq 'stopped' ||
 363                  $sd->{state} eq 'request_stop') && ($lrm_mode ne 'active')) {
 364                 &$change_service_state($self, $sid, 'freeze');
 365             }
 366
 367             $repeat = 1 if $sd->{state} ne $last_state;
 368         }
 369
 370         # handle fencing
 371         my $fenced_nodes = {};
 372         foreach my $sid (keys %$ss) {
 373             my $sd = $ss->{$sid};
 374             next if $sd->{state} ne 'fence';
 375
 376             if (!defined($fenced_nodes->{$sd->{node}})) {
 377                 $fenced_nodes->{$sd->{node}} = $ns->fence_node($sd->{node}) || 0;
 378             }
 379
 380             next if !$fenced_nodes->{$sd->{node}};
 381
 382             # node fence was successful - mark service as stopped
 383             &$change_service_state($self, $sid, 'stopped');
 384         }
 385
 386         last if !$repeat;
 387     }
 388
 389     $self->flush_master_status();
 390 }
 391
 392 # functions to compute next service states
 393 # $cd: service configuration data (read only)
 394 # $sd: service status data (read only)
 395 #
 396 # Note: use change_service_state() to alter state
 397 #
 398
 399 sub next_state_request_stop {
 400     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 401
 402     my $haenv = $self->{haenv};
 403     my $ns = $self->{ns};
 404
 405     # check result from LRM daemon
 406     if ($lrm_res) {
 407         my $exit_code = $lrm_res->{exit_code};
 408         if ($exit_code == 0) {
 409             &$change_service_state($self, $sid, 'stopped');
 410             return;
 411         } else {
 412             &$change_service_state($self, $sid, 'error'); # fixme: what state?
 413             return;
 414         }
 415     }
 416
 417     if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 418         &$change_service_state($self, $sid, 'fence');
 419         return;
 420     }
 421 }
 422
 423 sub next_state_migrate_relocate {
 424     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 425
 426     my $haenv = $self->{haenv};
 427     my $ns = $self->{ns};
 428
 429     # check result from LRM daemon
 430     if ($lrm_res) {
 431         my $exit_code = $lrm_res->{exit_code};
 432         if ($exit_code == 0) {
 433             &$change_service_state($self, $sid, 'started', node => $sd->{target});
 434             return;
 435         } else {
 436             $haenv->log('err', "service '$sid' - migration failed (exit code $exit_code)");
 437             &$change_service_state($self, $sid, 'started', node => $sd->{node});
 438             return;
 439         }
 440     }
 441
 442     if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 443         &$change_service_state($self, $sid, 'fence');
 444         return;
 445     }
 446 }
 447
 448
 449 sub next_state_stopped {
 450     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 451
 452     my $haenv = $self->{haenv};
 453     my $ns = $self->{ns};
 454
 455     if ($sd->{node} ne $cd->{node}) {
 456         # this can happen if we fence a node with active migrations
 457         # hack: modify $sd (normally this should be considered read-only)
 458         $haenv->log('info', "fixup service '$sid' location ($sd->{node} => $cd->{node}");
 459         $sd->{node} = $cd->{node};
 460     }
 461
 462     if ($sd->{cmd}) {
 463         my ($cmd, $target) = @{$sd->{cmd}};
 464         delete $sd->{cmd};
 465
 466         if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 467             if (!$ns->node_is_online($target)) {
 468                 $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 469             } elsif ($sd->{node} eq $target) {
 470                 $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 471             } else {
 472                 eval {
 473                     $haenv->change_service_location($sid, $sd->{node}, $target);
 474                     $cd->{node} = $sd->{node} = $target; # fixme: $sd is read-only??!!
 475                     $haenv->log('info', "$cmd service '$sid' to node '$target' (stopped)");
 476                 };
 477                 if (my $err = $@) {
 478                     $haenv->log('err', "$cmd service '$sid' to node '$target' failed - $err");
 479                 }
 480             }
 481         } else {
 482             $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 483         }
 484     }
 485
 486     if ($cd->{state} eq 'disabled') {
 487         # do nothing
 488         return;
 489     }
 490
 491     if ($cd->{state} eq 'enabled') {
 492         if (my $node = select_service_node($self->{groups}, $self->{online_node_usage}, $cd, $sd->{node})) {
 493             if ($node && ($sd->{node} ne $node)) {
 494                 eval {
 495                     $haenv->change_service_location($sid, $sd->{node}, $node);
 496                     $cd->{node} = $sd->{node} = $node; # fixme: $sd is read-only??!!
 497                 };
 498                 if (my $err = $@) {
 499                     $haenv->log('err', "move service '$sid' to node '$node' failed - $err");
 500                 } else {
 501                     &$change_service_state($self, $sid, 'started', node => $node);
 502                 }
 503             } else {
 504                 &$change_service_state($self, $sid, 'started', node => $node);
 505             }
 506         } else {
 507             # fixme: warn
 508         }
 509
 510         return;
 511     }
 512
 513     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 514 }
 515
 516 sub next_state_started {
 517     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 518
 519     my $haenv = $self->{haenv};
 520     my $master_status = $self->{ms};
 521     my $ns = $self->{ns};
 522
 523     if (!$ns->node_is_online($sd->{node})) {
 524         if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 525             &$change_service_state($self, $sid, 'fence');
 526         }
 527         return;
 528     }
 529
 530     if ($cd->{state} eq 'disabled') {
 531         &$change_service_state($self, $sid, 'request_stop');
 532         return;
 533     }
 534
 535     if ($cd->{state} eq 'enabled') {
 536
 537         if ($sd->{cmd}) {
 538             my ($cmd, $target) = @{$sd->{cmd}};
 539             delete $sd->{cmd};
 540
 541             if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 542                 if (!$ns->node_is_online($target)) {
 543                     $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 544                 } elsif ($sd->{node} eq $target) {
 545                     $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 546                 } else {
 547                     $haenv->log('info', "$cmd service '$sid' to node '$target' (running)");
 548                     &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 549                 }
 550             } else {
 551                 $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 552             }
 553         } else {
 554
 555             my $try_next = 0;
 556             if ($lrm_res) {
 557                 if ($lrm_res->{exit_code} == 1) {
 558
 559                     my $try = $master_status->{relocate_trial}->{$sid} || 0;
 560
 561                     if ($try < $cd->{max_relocate}) {
 562
 563                         $try++;
 564                         $try_next = 1; # tell select_service_node to relocate
 565
 566                         $haenv->log('warning', "starting service $sid on node".
 567                                    " '$sd->{node}' failed, relocating service.");
 568                         $master_status->{relocate_trial}->{$sid} = $try;
 569
 570                     } else {
 571
 572                         $haenv->log('err', "recovery policy for service".
 573                                    " $sid failed, entering error state!");
 574                         &$change_service_state($self, $sid, 'error');
 575                         return;
 576
 577                     }
 578                 } elsif ($lrm_res->{exit_code} == 0) {
 579                     $master_status->{relocate_trial}->{$sid} = 0;
 580                 }
 581             }
 582
 583             my $node = select_service_node($self->{groups}, $self->{online_node_usage},
 584                                            $cd, $sd->{node}, $try_next);
 585
 586             if ($node && ($sd->{node} ne $node)) {
 587                 $haenv->log('info', "migrate service '$sid' to node '$node' (running)");
 588                 &$change_service_state($self, $sid, 'migrate', node => $sd->{node}, target => $node);
 589             } else {
 590                 # do nothing
 591             }
 592         }
 593
 594         return;
 595     }
 596
 597     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 598 }
 599
 600 sub next_state_error {
 601     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 602
 603     my $ns = $self->{ns};
 604
 605     if ($cd->{state} eq 'disabled') {
 606         &$change_service_state($self, $sid, 'stopped');
 607         return;
 608     }
 609
 610     if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 611         &$change_service_state($self, $sid, 'fence');
 612         return;
 613     }
 614
 615 }
 616
 617 1;