src/PVE/HA/Manager.pm

   1 package PVE::HA::Manager;
   2
   3 use strict;
   4 use warnings;
   5 use Digest::MD5 qw(md5_base64);
   6
   7 use Data::Dumper;
   8 use PVE::Tools;
   9 use PVE::HA::NodeStatus;
  10
  11 my $fence_delay = 60;
  12
  13 sub new {
  14     my ($this, $haenv) = @_;
  15
  16     my $class = ref($this) || $this;
  17
  18     my $ms = $haenv->read_manager_status();
  19
  20     $ms->{master_node} = $haenv->nodename();
  21
  22     my $ns = PVE::HA::NodeStatus->new($haenv, $ms->{node_status} || {});
  23
  24     # fixme: use separate class  PVE::HA::ServiceStatus
  25     my $ss = $ms->{service_status} || {};
  26
  27     my $self = bless {
  28         haenv => $haenv,
  29         ms => $ms, # master status
  30         ns => $ns, # PVE::HA::NodeStatus
  31         ss => $ss, # service status
  32     }, $class;
  33
  34     return $self;
  35 }
  36
  37 sub cleanup {
  38     my ($self) = @_;
  39
  40     # todo: ?
  41 }
  42
  43 sub flush_master_status {
  44     my ($self) = @_;
  45
  46     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
  47
  48     $ms->{node_status} = $ns->{status};
  49     $ms->{service_status} = $ss;
  50
  51     $haenv->write_manager_status($ms);
  52 }
  53
  54 sub select_service_node {
  55     my ($groups, $online_node_usage, $service_conf, $current_node, $try_next) = @_;
  56
  57     my $group = { 'nodes' => $service_conf->{node} }; # default group
  58
  59     $group =  $groups->{ids}->{$service_conf->{group}} if $service_conf->{group} &&
  60         $groups->{ids}->{$service_conf->{group}};
  61
  62     my $pri_groups = {};
  63     my $group_members = {};
  64     foreach my $entry (PVE::Tools::split_list($group->{nodes})) {
  65         my ($node, $pri) = ($entry, 0);
  66         if ($entry =~ m/^(\S+):(\d+)$/) {
  67             ($node, $pri) = ($1, $2);
  68         }
  69         next if !defined($online_node_usage->{$node}); # offline
  70         $pri_groups->{$pri}->{$node} = 1;
  71         $group_members->{$node} = $pri;
  72     }
  73
  74
  75     # add non-group members to unrestricted groups (priority -1)
  76     if (!$group->{restricted}) {
  77         my $pri = -1;
  78         foreach my $node (keys %$online_node_usage) {
  79             next if defined($group_members->{$node});
  80             $pri_groups->{$pri}->{$node} = 1;
  81             $group_members->{$node} = -1;
  82         }
  83     }
  84
  85
  86     my @pri_list = sort {$b <=> $a} keys %$pri_groups;
  87     return undef if !scalar(@pri_list);
  88
  89     if (!$try_next && $group->{nofailback} && defined($group_members->{$current_node})) {
  90         return $current_node;
  91     }
  92
  93     # select node from top priority node list
  94
  95     my $top_pri = $pri_list[0];
  96
  97     my @nodes = sort {
  98         $online_node_usage->{$a} <=> $online_node_usage->{$b} || $a cmp $b
  99     } keys %{$pri_groups->{$top_pri}};
 100
 101     my $found;
 102     for (my $i = scalar(@nodes) - 1; $i >= 0; $i--) {
 103         my $node = $nodes[$i];
 104         if ($node eq $current_node) {
 105             $found = $i;
 106             last;
 107         }
 108     }
 109
 110     if ($try_next) {
 111
 112         if (defined($found) && ($found < (scalar(@nodes) - 1))) {
 113             return $nodes[$found + 1];
 114         } else {
 115             return $nodes[0];
 116         }
 117
 118     } else {
 119
 120         return $nodes[$found] if defined($found);
 121
 122         return $nodes[0];
 123
 124     }
 125 }
 126
 127 my $uid_counter = 0;
 128
 129 sub compute_new_uuid {
 130     my ($state) = @_;
 131
 132     $uid_counter++;
 133     return md5_base64($state . $$ . time() . $uid_counter);
 134 }
 135
 136 my $valid_service_states = {
 137     stopped => 1,
 138     request_stop => 1,
 139     started => 1,
 140     fence => 1,
 141     migrate => 1,
 142     relocate => 1,
 143     freeze => 1,
 144     error => 1,
 145 };
 146
 147 sub recompute_online_node_usage {
 148     my ($self) = @_;
 149
 150     my $online_node_usage = {};
 151
 152     my $online_nodes = $self->{ns}->list_online_nodes();
 153
 154     foreach my $node (@$online_nodes) {
 155         $online_node_usage->{$node} = 0;
 156     }
 157
 158     foreach my $sid (keys %{$self->{ss}}) {
 159         my $sd = $self->{ss}->{$sid};
 160         my $state = $sd->{state};
 161         if (defined($online_node_usage->{$sd->{node}})) {
 162             if (($state eq 'started') || ($state eq 'request_stop') ||
 163                 ($state eq 'fence') || ($state eq 'freeze') || ($state eq 'error')) {
 164                 $online_node_usage->{$sd->{node}}++;
 165             } elsif (($state eq 'migrate') || ($state eq 'relocate')) {
 166                 $online_node_usage->{$sd->{target}}++;
 167             } elsif ($state eq 'stopped') {
 168                 # do nothing
 169             } else {
 170                 die "should not be reached";
 171             }
 172         }
 173     }
 174
 175     $self->{online_node_usage} = $online_node_usage;
 176 }
 177
 178 my $change_service_state = sub {
 179     my ($self, $sid, $new_state, %params) = @_;
 180
 181     my ($haenv, $ss) = ($self->{haenv}, $self->{ss});
 182
 183     my $sd = $ss->{$sid} || die "no such service '$sid";
 184
 185     my $old_state = $sd->{state};
 186     my $old_node = $sd->{node};
 187
 188     die "no state change" if $old_state eq $new_state; # just to be sure
 189
 190     die "invalid CRM service state '$new_state'\n" if !$valid_service_states->{$new_state};
 191
 192     foreach my $k (keys %$sd) { delete $sd->{$k}; };
 193
 194     $sd->{state} = $new_state;
 195     $sd->{node} = $old_node;
 196
 197     my $text_state = '';
 198     foreach my $k (keys %params) {
 199         my $v = $params{$k};
 200         $text_state .= ", " if $text_state;
 201         $text_state .= "$k = $v";
 202         $sd->{$k} = $v;
 203     }
 204
 205     $self->recompute_online_node_usage();
 206
 207     $sd->{uid} = compute_new_uuid($new_state);
 208
 209
 210     $text_state = " ($text_state)" if $text_state;
 211     $haenv->log('info', "service '$sid': state changed from '${old_state}' to '${new_state}' $text_state");
 212 };
 213
 214 # read LRM status for all nodes
 215 sub read_lrm_status {
 216     my ($self) = @_;
 217
 218     my $nodes = $self->{ns}->list_nodes();
 219     my $haenv = $self->{haenv};
 220
 221     my $results = {};
 222     my $modes = {};
 223     foreach my $node (@$nodes) {
 224         my $lrm_status = $haenv->read_lrm_status($node);
 225         $modes->{$node} = $lrm_status->{mode} || 'active';
 226         foreach my $uid (keys %{$lrm_status->{results}}) {
 227             next if $results->{$uid}; # should not happen
 228             $results->{$uid} = $lrm_status->{results}->{$uid};
 229         }
 230     }
 231
 232
 233     return ($results, $modes);
 234 }
 235
 236 # read new crm commands and save them into crm master status
 237 sub update_crm_commands {
 238     my ($self) = @_;
 239
 240     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 241
 242     my $cmdlist = $haenv->read_crm_commands();
 243
 244     foreach my $cmd (split(/\n/, $cmdlist)) {
 245         chomp $cmd;
 246
 247         if ($cmd =~ m/^(migrate|relocate)\s+(\S+)\s+(\S+)$/) {
 248             my ($task, $sid, $node) = ($1, $2, $3);
 249             if (my $sd = $ss->{$sid}) {
 250                 if (!$ns->node_is_online($node)) {
 251                     $haenv->log('err', "crm command error - node not online: $cmd");
 252                 } else {
 253                     if ($node eq $sd->{node}) {
 254                         $haenv->log('info', "ignore crm command - service already on target node: $cmd");
 255                     } else {
 256                         $haenv->log('info', "got crm command: $cmd");
 257                         $ss->{$sid}->{cmd} = [ $task, $node];
 258                     }
 259                 }
 260             } else {
 261                 $haenv->log('err', "crm command error - no such service: $cmd");
 262             }
 263
 264         } else {
 265             $haenv->log('err', "unable to parse crm command: $cmd");
 266         }
 267     }
 268
 269 }
 270
 271 sub manage {
 272     my ($self) = @_;
 273
 274     my ($haenv, $ms, $ns, $ss) = ($self->{haenv}, $self->{ms}, $self->{ns}, $self->{ss});
 275
 276     $ns->update($haenv->get_node_info());
 277
 278     if (!$ns->node_is_online($haenv->nodename())) {
 279         $haenv->log('info', "master seems offline");
 280         return;
 281     }
 282
 283     my ($lrm_results, $lrm_modes) = $self->read_lrm_status();
 284
 285     my $sc = $haenv->read_service_config();
 286
 287     $self->{groups} = $haenv->read_group_config(); # update
 288
 289     # compute new service status
 290
 291     # add new service
 292     foreach my $sid (sort keys %$sc) {
 293         next if $ss->{$sid}; # already there
 294         $haenv->log('info', "adding new service '$sid' on node '$sc->{$sid}->{node}'");
 295         # assume we are running to avoid relocate running service at add
 296         $ss->{$sid} = { state => 'started', node => $sc->{$sid}->{node},
 297                         uid => compute_new_uuid('started') };
 298     }
 299
 300     # remove stale service from manager state
 301     foreach my $sid (keys %$ss) {
 302         next if $sc->{$sid};
 303         $haenv->log('info', "removing stale service '$sid' (no config)");
 304         delete $ss->{$sid};
 305     }
 306
 307     $self->update_crm_commands();
 308
 309     for (;;) {
 310         my $repeat = 0;
 311
 312         $self->recompute_online_node_usage();
 313
 314         foreach my $sid (keys %$ss) {
 315             my $sd = $ss->{$sid};
 316             my $cd = $sc->{$sid} || { state => 'disabled' };
 317
 318             my $lrm_res = $sd->{uid} ? $lrm_results->{$sd->{uid}} : undef;
 319
 320             my $last_state = $sd->{state};
 321
 322             if ($last_state eq 'stopped') {
 323
 324                 $self->next_state_stopped($sid, $cd, $sd, $lrm_res);
 325
 326             } elsif ($last_state eq 'started') {
 327
 328                 $self->next_state_started($sid, $cd, $sd, $lrm_res);
 329
 330             } elsif ($last_state eq 'migrate' || $last_state eq 'relocate') {
 331
 332                 $self->next_state_migrate_relocate($sid, $cd, $sd, $lrm_res);
 333
 334             } elsif ($last_state eq 'fence') {
 335
 336                 # do nothing here - wait until fenced
 337
 338             } elsif ($last_state eq 'request_stop') {
 339
 340                 $self->next_state_request_stop($sid, $cd, $sd, $lrm_res);
 341
 342             } elsif ($last_state eq 'freeze') {
 343
 344                 my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 345                 # unfreeze
 346                 &$change_service_state($self, $sid, 'started')
 347                     if $lrm_mode && $lrm_mode eq 'active';
 348
 349             } elsif ($last_state eq 'error') {
 350
 351                 # fixme:
 352
 353             } else {
 354
 355                 die "unknown service state '$last_state'";
 356             }
 357
 358
 359             my $lrm_mode = $sd->{node} ? $lrm_modes->{$sd->{node}} : undef;
 360             $lrm_mode = 'unknown'if !$lrm_mode;
 361             if (($sd->{state} eq 'started' || $sd->{state} eq 'stopped' ||
 362                  $sd->{state} eq 'request_stop') && ($lrm_mode ne 'active')) {
 363                 &$change_service_state($self, $sid, 'freeze');
 364             }
 365
 366             $repeat = 1 if $sd->{state} ne $last_state;
 367         }
 368
 369         # handle fencing
 370         my $fenced_nodes = {};
 371         foreach my $sid (keys %$ss) {
 372             my $sd = $ss->{$sid};
 373             next if $sd->{state} ne 'fence';
 374
 375             if (!defined($fenced_nodes->{$sd->{node}})) {
 376                 $fenced_nodes->{$sd->{node}} = $ns->fence_node($sd->{node}) || 0;
 377             }
 378
 379             next if !$fenced_nodes->{$sd->{node}};
 380
 381             # node fence was sucessful - mark service as stopped
 382             &$change_service_state($self, $sid, 'stopped');
 383         }
 384
 385         last if !$repeat;
 386     }
 387
 388     $self->flush_master_status();
 389 }
 390
 391 # functions to compute next service states
 392 # $cd: service configuration data (read only)
 393 # $sd: service status data (read only)
 394 #
 395 # Note: use change_service_state() to alter state
 396 #
 397
 398 sub next_state_request_stop {
 399     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 400
 401     my $haenv = $self->{haenv};
 402     my $ns = $self->{ns};
 403
 404     # check result from LRM daemon
 405     if ($lrm_res) {
 406         my $exit_code = $lrm_res->{exit_code};
 407         if ($exit_code == 0) {
 408             &$change_service_state($self, $sid, 'stopped');
 409             return;
 410         } else {
 411             &$change_service_state($self, $sid, 'error'); # fixme: what state?
 412             return;
 413         }
 414     }
 415
 416     if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 417         &$change_service_state($self, $sid, 'fence');
 418         return;
 419     }
 420 }
 421
 422 sub next_state_migrate_relocate {
 423     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 424
 425     my $haenv = $self->{haenv};
 426     my $ns = $self->{ns};
 427
 428     # check result from LRM daemon
 429     if ($lrm_res) {
 430         my $exit_code = $lrm_res->{exit_code};
 431         if ($exit_code == 0) {
 432             &$change_service_state($self, $sid, 'started', node => $sd->{target});
 433             return;
 434         } else {
 435             $haenv->log('err', "service '$sid' - migration failed (exit code $exit_code)");
 436             &$change_service_state($self, $sid, 'started', node => $sd->{node});
 437             return;
 438         }
 439     }
 440
 441     if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 442         &$change_service_state($self, $sid, 'fence');
 443         return;
 444     }
 445 }
 446
 447
 448 sub next_state_stopped {
 449     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 450
 451     my $haenv = $self->{haenv};
 452     my $ns = $self->{ns};
 453
 454     if ($sd->{node} ne $cd->{node}) {
 455         # this can happen if we fence a node with active migrations
 456         # hack: modify $sd (normally this should be considered read-only)
 457         $haenv->log('info', "fixup service '$sid' location ($sd->{node} => $cd->{node}");
 458         $sd->{node} = $cd->{node};
 459     }
 460
 461     if ($sd->{cmd}) {
 462         my ($cmd, $target) = @{$sd->{cmd}};
 463         delete $sd->{cmd};
 464
 465         if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 466             if (!$ns->node_is_online($target)) {
 467                 $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 468             } elsif ($sd->{node} eq $target) {
 469                 $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 470             } else {
 471                 eval {
 472                     $haenv->change_service_location($sid, $sd->{node}, $target);
 473                     $cd->{node} = $sd->{node} = $target; # fixme: $sd is read-only??!!
 474                     $haenv->log('info', "$cmd service '$sid' to node '$target' (stopped)");
 475                 };
 476                 if (my $err = $@) {
 477                     $haenv->log('err', "$cmd service '$sid' to node '$target' failed - $err");
 478                 }
 479             }
 480         } else {
 481             $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 482         }
 483     }
 484
 485     if ($cd->{state} eq 'disabled') {
 486         # do nothing
 487         return;
 488     }
 489
 490     if ($cd->{state} eq 'enabled') {
 491         if (my $node = select_service_node($self->{groups}, $self->{online_node_usage}, $cd, $sd->{node})) {
 492             if ($node && ($sd->{node} ne $node)) {
 493                 eval {
 494                     $haenv->change_service_location($sid, $sd->{node}, $node);
 495                     $cd->{node} = $sd->{node} = $node; # fixme: $sd is read-only??!!
 496                 };
 497                 if (my $err = $@) {
 498                     $haenv->log('err', "move service '$sid' to node '$node' failed - $err");
 499                 } else {
 500                     &$change_service_state($self, $sid, 'started', node => $node);
 501                 }
 502             } else {
 503                 &$change_service_state($self, $sid, 'started', node => $node);
 504             }
 505         } else {
 506             # fixme: warn
 507         }
 508
 509         return;
 510     }
 511
 512     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 513 }
 514
 515 sub next_state_started {
 516     my ($self, $sid, $cd, $sd, $lrm_res) = @_;
 517
 518     my $haenv = $self->{haenv};
 519     my $ns = $self->{ns};
 520
 521     if (!$ns->node_is_online($sd->{node})) {
 522         if ($ns->node_is_offline_delayed($sd->{node}, $fence_delay)) {
 523             &$change_service_state($self, $sid, 'fence');
 524         }
 525         return;
 526     }
 527
 528     if ($cd->{state} eq 'disabled') {
 529         &$change_service_state($self, $sid, 'request_stop');
 530         return;
 531     }
 532
 533     if ($cd->{state} eq 'enabled') {
 534
 535         if ($sd->{cmd}) {
 536             my ($cmd, $target) = @{$sd->{cmd}};
 537             delete $sd->{cmd};
 538
 539             if ($cmd eq 'migrate' || $cmd eq 'relocate') {
 540                 if (!$ns->node_is_online($target)) {
 541                     $haenv->log('err', "ignore service '$sid' $cmd request - node '$target' not online");
 542                 } elsif ($sd->{node} eq $target) {
 543                     $haenv->log('info', "ignore service '$sid' $cmd request - service already on node '$target'");
 544                 } else {
 545                     $haenv->log('info', "$cmd service '$sid' to node '$target' (running)");
 546                     &$change_service_state($self, $sid, $cmd, node => $sd->{node}, target => $target);
 547                 }
 548             } else {
 549                 $haenv->log('err', "unknown command '$cmd' for service '$sid'");
 550             }
 551         } else {
 552
 553             my $try_next = 0;
 554             if ($lrm_res && ($lrm_res->{exit_code} != 0)) { # fixme: other exit codes?
 555                 $try_next = 1;
 556             }
 557
 558             my $node = select_service_node($self->{groups}, $self->{online_node_usage},
 559                                            $cd, $sd->{node}, $try_next);
 560
 561             if ($node && ($sd->{node} ne $node)) {
 562                 $haenv->log('info', "migrate service '$sid' to node '$node' (running)");
 563                 &$change_service_state($self, $sid, 'migrate', node => $sd->{node}, target => $node);
 564             } else {
 565                 # do nothing
 566             }
 567         }
 568
 569         return;
 570     }
 571
 572     $haenv->log('err', "service '$sid' - unknown state '$cd->{state}' in service configuration");
 573 }
 574
 575 1;