src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5
   6 use POSIX qw(EINTR);
   7
   8 use Socket;
   9
  10 use File::Path;
  11 use File::Spec;
  12 use Cwd qw();
  13 use Fcntl qw(O_RDONLY O_NOFOLLOW O_DIRECTORY);
  14 use Errno qw(ELOOP ENOTDIR EROFS ECONNREFUSED);
  15 use IO::Socket::UNIX;
  16
  17 use PVE::Exception qw(raise_perm_exc);
  18 use PVE::Storage;
  19 use PVE::SafeSyslog;
  20 use PVE::INotify;
  21 use PVE::JSONSchema qw(get_standard_option);
  22 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach lock_file lock_file_full O_PATH);
  23 use PVE::CpuSet;
  24 use PVE::Network;
  25 use PVE::AccessControl;
  26 use PVE::ProcFSTools;
  27 use PVE::Syscall;
  28 use PVE::LXC::Config;
  29 use PVE::GuestHelpers;
  30
  31 use Time::HiRes qw (gettimeofday);
  32
  33 my $LXC_CONFIG_PATH = '/usr/share/lxc/config';
  34
  35 my $nodename = PVE::INotify::nodename();
  36
  37 my $cpuinfo= PVE::ProcFSTools::read_cpuinfo();
  38
  39 sub config_list {
  40     my $vmlist = PVE::Cluster::get_vmlist();
  41     my $res = {};
  42     return $res if !$vmlist || !$vmlist->{ids};
  43     my $ids = $vmlist->{ids};
  44
  45     foreach my $vmid (keys %$ids) {
  46         next if !$vmid; # skip CT0
  47         my $d = $ids->{$vmid};
  48         next if !$d->{node} || $d->{node} ne $nodename;
  49         next if !$d->{type} || $d->{type} ne 'lxc';
  50         $res->{$vmid} = { type => 'lxc', vmid => $vmid };
  51     }
  52     return $res;
  53 }
  54
  55 # container status helpers
  56
  57 sub list_active_containers {
  58
  59     my $filename = "/proc/net/unix";
  60
  61     # similar test is used by lcxcontainers.c: list_active_containers
  62     my $res = {};
  63
  64     my $fh = IO::File->new ($filename, "r");
  65     return $res if !$fh;
  66
  67     while (defined(my $line = <$fh>)) {
  68         if ($line =~ m/^[a-f0-9]+:\s+\S+\s+\S+\s+\S+\s+\S+\s+\S+\s+\d+\s+(\S+)$/) {
  69             my $path = $1;
  70             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
  71                 $res->{$1} = 1;
  72             }
  73         }
  74     }
  75
  76     close($fh);
  77
  78     return $res;
  79 }
  80
  81 # warning: this is slow
  82 sub check_running {
  83     my ($vmid) = @_;
  84
  85     my $active_hash = list_active_containers();
  86
  87     return 1 if defined($active_hash->{$vmid});
  88
  89     return undef;
  90 }
  91
  92 sub get_container_disk_usage {
  93     my ($vmid, $pid) = @_;
  94
  95     return PVE::Tools::df("/proc/$pid/root/", 1);
  96 }
  97
  98 my $last_proc_vmid_stat;
  99
 100 my $parse_cpuacct_stat = sub {
 101     my ($vmid, $unprivileged) = @_;
 102
 103     my $raw = read_cgroup_value('cpuacct', $vmid, $unprivileged, 'cpuacct.stat', 1);
 104
 105     my $stat = {};
 106
 107     if ($raw =~ m/^user (\d+)\nsystem (\d+)\n/) {
 108
 109         $stat->{utime} = $1;
 110         $stat->{stime} = $2;
 111
 112     }
 113
 114     return $stat;
 115 };
 116
 117 our $vmstatus_return_properties = {
 118     vmid => get_standard_option('pve-vmid'),
 119     status => {
 120         description => "LXC Container status.",
 121         type => 'string',
 122         enum => ['stopped', 'running'],
 123     },
 124     maxmem => {
 125         description => "Maximum memory in bytes.",
 126         type => 'integer',
 127         optional => 1,
 128         renderer => 'bytes',
 129     },
 130     maxswap => {
 131         description => "Maximum SWAP memory in bytes.",
 132         type => 'integer',
 133         optional => 1,
 134         renderer => 'bytes',
 135     },
 136     maxdisk => {
 137         description => "Root disk size in bytes.",
 138         type => 'integer',
 139         optional => 1,
 140         renderer => 'bytes',
 141     },
 142     name => {
 143         description => "Container name.",
 144         type => 'string',
 145         optional => 1,
 146     },
 147     uptime => {
 148         description => "Uptime.",
 149         type => 'integer',
 150         optional => 1,
 151         renderer => 'duration',
 152     },
 153     cpus => {
 154         description => "Maximum usable CPUs.",
 155         type => 'number',
 156         optional => 1,
 157     },
 158     lock => {
 159         description => "The current config lock, if any.",
 160         type => 'string',
 161         optional => 1,
 162     }
 163 };
 164
 165 sub vmstatus {
 166     my ($opt_vmid) = @_;
 167
 168     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc', vmid => $opt_vmid }} : config_list();
 169
 170     my $active_hash = list_active_containers();
 171
 172     my $cpucount = $cpuinfo->{cpus} || 1;
 173
 174     my $cdtime = gettimeofday;
 175
 176     my $uptime = (PVE::ProcFSTools::read_proc_uptime(1))[0];
 177     my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
 178
 179     my $unprivileged = {};
 180
 181     foreach my $vmid (keys %$list) {
 182         my $d = $list->{$vmid};
 183
 184         eval { $d->{pid} = find_lxc_pid($vmid) if defined($active_hash->{$vmid}); };
 185         warn $@ if $@; # ignore errors (consider them stopped)
 186
 187         $d->{status} = $active_hash->{$vmid} ? 'running' : 'stopped';
 188
 189         my $cfspath = PVE::LXC::Config->cfs_config_path($vmid);
 190         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 191
 192         $unprivileged->{$vmid} = $conf->{unprivileged};
 193
 194         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 195         $d->{name} =~ s/[\s]//g;
 196
 197         $d->{cpus} = $conf->{cores} || $conf->{cpulimit};
 198         $d->{cpus} = $cpucount if !$d->{cpus};
 199
 200         $d->{lock} = $conf->{lock} || '';
 201
 202         if ($d->{pid}) {
 203             my $res = get_container_disk_usage($vmid, $d->{pid});
 204             $d->{disk} = $res->{used};
 205             $d->{maxdisk} = $res->{total};
 206         } else {
 207             $d->{disk} = 0;
 208             # use 4GB by default ??
 209             if (my $rootfs = $conf->{rootfs}) {
 210                 my $rootinfo = PVE::LXC::Config->parse_ct_rootfs($rootfs);
 211                 $d->{maxdisk} = $rootinfo->{size} || (4*1024*1024*1024);
 212             } else {
 213                 $d->{maxdisk} = 4*1024*1024*1024;
 214             }
 215         }
 216
 217         $d->{mem} = 0;
 218         $d->{swap} = 0;
 219         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 220         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 221
 222         $d->{uptime} = 0;
 223         $d->{cpu} = 0;
 224
 225         $d->{netout} = 0;
 226         $d->{netin} = 0;
 227
 228         $d->{diskread} = 0;
 229         $d->{diskwrite} = 0;
 230
 231         $d->{template} = PVE::LXC::Config->is_template($conf);
 232         $d->{lock} = $conf->{lock} if $conf->{lock};
 233     }
 234
 235     foreach my $vmid (keys %$list) {
 236         my $d = $list->{$vmid};
 237         my $pid = $d->{pid};
 238
 239         next if !$pid; # skip stopped CTs
 240
 241         my $proc_pid_stat = PVE::ProcFSTools::read_proc_pid_stat($pid);
 242         $d->{uptime} = int(($uptime - $proc_pid_stat->{starttime}) / $clock_ticks); # the method lxcfs uses
 243
 244         my $unpriv = $unprivileged->{$vmid};
 245
 246         if (-d '/sys/fs/cgroup/memory') {
 247             my $memory_stat = read_cgroup_list('memory', $vmid, $unpriv, 'memory.stat');
 248             my $mem_usage_in_bytes = read_cgroup_value('memory', $vmid, $unpriv, 'memory.usage_in_bytes');
 249
 250             $d->{mem} = $mem_usage_in_bytes - $memory_stat->{total_cache};
 251             $d->{swap} = read_cgroup_value('memory', $vmid, $unpriv, 'memory.memsw.usage_in_bytes') - $mem_usage_in_bytes;
 252         } else {
 253             $d->{mem} = 0;
 254             $d->{swap} = 0;
 255         }
 256
 257         if (-d '/sys/fs/cgroup/blkio') {
 258             my $blkio_bytes = read_cgroup_value('blkio', $vmid, 0, 'blkio.throttle.io_service_bytes', 1); # don't check if unpriv
 259             my @bytes = split(/\n/, $blkio_bytes);
 260             foreach my $byte (@bytes) {
 261                 if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 262                     $d->{diskread} += $2 if $key eq 'Read';
 263                     $d->{diskwrite} += $2 if $key eq 'Write';
 264                 }
 265             }
 266         } else {
 267             $d->{diskread} = 0;
 268             $d->{diskwrite} = 0;
 269         }
 270
 271         if (-d '/sys/fs/cgroup/cpuacct') {
 272             my $pstat = $parse_cpuacct_stat->($vmid, $unpriv);
 273
 274             my $used = $pstat->{utime} + $pstat->{stime};
 275
 276             my $old = $last_proc_vmid_stat->{$vmid};
 277             if (!$old) {
 278                 $last_proc_vmid_stat->{$vmid} = {
 279                     time => $cdtime,
 280                     used => $used,
 281                     cpu => 0,
 282                 };
 283                 next;
 284             }
 285
 286             my $dtime = ($cdtime -  $old->{time}) * $cpucount * $cpuinfo->{user_hz};
 287
 288             if ($dtime > 1000) {
 289                 my $dutime = $used -  $old->{used};
 290
 291                 $d->{cpu} = (($dutime/$dtime)* $cpucount) / $d->{cpus};
 292                 $last_proc_vmid_stat->{$vmid} = {
 293                     time => $cdtime,
 294                     used => $used,
 295                     cpu => $d->{cpu},
 296                 };
 297             } else {
 298                 $d->{cpu} = $old->{cpu};
 299             }
 300         } else {
 301             $d->{cpu} = 0;
 302         }
 303     }
 304
 305     my $netdev = PVE::ProcFSTools::read_proc_net_dev();
 306
 307     foreach my $dev (keys %$netdev) {
 308         next if $dev !~ m/^veth([1-9]\d*)i/;
 309         my $vmid = $1;
 310         my $d = $list->{$vmid};
 311
 312         next if !$d;
 313
 314         $d->{netout} += $netdev->{$dev}->{receive};
 315         $d->{netin} += $netdev->{$dev}->{transmit};
 316
 317     }
 318
 319     return $list;
 320 }
 321
 322 sub read_cgroup_list($$$$) {
 323     my ($group, $vmid, $unprivileged, $name) = @_;
 324
 325     my $content = read_cgroup_value($group, $vmid, $unprivileged, $name, 1);
 326
 327     return { split(/\s+/, $content) };
 328 }
 329
 330 sub read_cgroup_value($$$$$) {
 331     my ($group, $vmid, $unprivileged, $name, $full) = @_;
 332
 333     my $nsdir = $unprivileged ? '' : 'ns/';
 334     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/${nsdir}$name";
 335
 336     return PVE::Tools::file_get_contents($path) if $full;
 337
 338     return PVE::Tools::file_read_firstline($path);
 339 }
 340
 341 sub write_cgroup_value {
 342    my ($group, $vmid, $name, $value) = @_;
 343
 344    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 345    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 346
 347 }
 348
 349 sub find_lxc_console_pids {
 350
 351     my $res = {};
 352
 353     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 354         my ($pid) = @_;
 355
 356         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 357         return if !$cmdline;
 358
 359         my @args = split(/\0/, $cmdline);
 360
 361         # search for lxc-console -n <vmid>
 362         return if scalar(@args) != 3;
 363         return if $args[1] ne '-n';
 364         return if $args[2] !~ m/^\d+$/;
 365         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 366
 367         my $vmid = $args[2];
 368
 369         push @{$res->{$vmid}}, $pid;
 370     });
 371
 372     return $res;
 373 }
 374
 375 sub find_lxc_pid {
 376     my ($vmid) = @_;
 377
 378     my $pid = undef;
 379     my $parser = sub {
 380         my $line = shift;
 381         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 382     };
 383     PVE::Tools::run_command(['lxc-info', '-n', $vmid, '-p'], outfunc => $parser);
 384
 385     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 386
 387     return $pid;
 388 }
 389
 390 # Note: we cannot use Net:IP, because that only allows strict
 391 # CIDR networks
 392 sub parse_ipv4_cidr {
 393     my ($cidr, $noerr) = @_;
 394
 395     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 <= 32)) {
 396         return { address => $1, netmask => $PVE::Network::ipv4_reverse_mask->[$2] };
 397     }
 398
 399     return undef if $noerr;
 400
 401     die "unable to parse ipv4 address/mask\n";
 402 }
 403
 404 sub get_cgroup_subsystems {
 405         my $v1 = {};
 406         my $v2 = 0;
 407         my $data = PVE::Tools::file_get_contents('/proc/self/cgroup');
 408         while ($data =~ /^\d+:([^:\n]*):.*$/gm) {
 409                 my $type = $1;
 410                 if (length($type)) {
 411                         $v1->{$_} = 1 foreach split(/,/, $type);
 412                 } else {
 413                         $v2 = 1;
 414                 }
 415         }
 416         return wantarray ? ($v1, $v2) : $v1;
 417 }
 418
 419 # Currently we do not need to create seccomp profile 'files' as the only
 420 # choice our configuration actually allows is "with or without keyctl()",
 421 # so we distinguish between using lxc's "default" seccomp profile and our
 422 # added pve-userns.seccomp file.
 423 #
 424 # This returns a configuration line added to the raw lxc config.
 425 sub make_seccomp_config {
 426     my ($conf, $unprivileged, $features) = @_;
 427     # User-configured profile has precedence, note that the user's entry would
 428     # be written 'after' this line anyway...
 429     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.seccomp.profile')) {
 430         # Warn the user if this conflicts with a feature:
 431         if ($features->{keyctl}) {
 432             warn "explicitly configured lxc.seccomp.profile overrides the following settings: features:keyctl\n";
 433         }
 434         return '';
 435     }
 436
 437     # Privileged containers keep using the default (which is already part of
 438     # the files included via lxc.include, so we don't need to write it out,
 439     # that way it stays admin-configurable via /usr/share/lxc/config/... as
 440     # well)
 441     return '' if !$unprivileged;
 442
 443     # Unprivileged containers will get keyctl() disabled by default as a
 444     # workaround for systemd-networkd behavior. But we have an option to
 445     # explicitly enable it:
 446     return '' if $features->{keyctl};
 447
 448     # Finally we're in an unprivileged container without `keyctl` set
 449     # explicitly. We have a file prepared for this:
 450     return "lxc.seccomp.profile = $LXC_CONFIG_PATH/pve-userns.seccomp\n";
 451 }
 452
 453 # Since lxc-3.0.2 we can have lxc generate a profile for the container
 454 # automatically. The default should be equivalent to the old
 455 # `lxc-container-default-cgns` profile.
 456 #
 457 # Additionally this also added `lxc.apparmor.raw` which can be used to inject
 458 # additional lines into the profile. We can use that to allow mounting specific
 459 # file systems.
 460 sub make_apparmor_config {
 461     my ($conf, $unprivileged, $features) = @_;
 462
 463     # user-configured profile has precedence, but first we go through our own
 464     # code to figure out whether we should warn the user:
 465
 466     my $raw = "lxc.apparmor.profile = generated\n";
 467     my @profile_uses;
 468
 469     if ($features->{fuse}) {
 470         # For the informational warning:
 471         push @profile_uses, 'features:fuse';
 472     }
 473
 474     # There's lxc.apparmor.allow_nesting now, which will add the necessary
 475     # apparmor lines, create an apparmor namespace for the container, but also
 476     # adds proc and sysfs mounts to /dev/.lxc/{proc,sys}. These do not have
 477     # lxcfs mounted over them, because that would prevent the container from
 478     # mounting new instances of them for nested containers.
 479     if ($features->{nesting}) {
 480         push @profile_uses, 'features:nesting';
 481         $raw .= "lxc.apparmor.allow_nesting = 1\n"
 482     } else {
 483         # In the default profile in /etc/apparmor.d we patch this in because
 484         # otherwise a container can for example run `chown` on /sys, breaking
 485         # access to it for non-CAP_DAC_OVERRIDE tools on the host:
 486         $raw .= "lxc.apparmor.raw = deny mount -> /proc/,\n";
 487         $raw .= "lxc.apparmor.raw = deny mount -> /sys/,\n";
 488         # Preferably we could use the 'remount' flag but this does not sit well
 489         # with apparmor_parser currently:
 490         #  mount options=(rw, nosuid, nodev, noexec, remount) -> /sys/,
 491     }
 492
 493     if (my $mount = $features->{mount}) {
 494         push @profile_uses, 'features:mount';
 495         foreach my $fs (PVE::Tools::split_list($mount)) {
 496             $raw .= "lxc.apparmor.raw = mount fstype=$fs,\n";
 497         }
 498     }
 499
 500     # More to come?
 501
 502     if (PVE::LXC::Config->has_lxc_entry($conf, 'lxc.apparmor.profile')) {
 503         if (length(my $used = join(', ', @profile_uses))) {
 504             warn "explicitly configured lxc.apparmor.profile overrides the following settings: $used\n";
 505         }
 506         return '';
 507     }
 508
 509     return $raw;
 510 }
 511
 512 sub update_lxc_config {
 513     my ($vmid, $conf) = @_;
 514
 515     my $dir = "/var/lib/lxc/$vmid";
 516
 517     if ($conf->{template}) {
 518
 519         unlink "$dir/config";
 520
 521         return;
 522     }
 523
 524     my $raw = '';
 525
 526     die "missing 'arch' - internal error" if !$conf->{arch};
 527     $raw .= "lxc.arch = $conf->{arch}\n";
 528
 529     my $custom_idmap = PVE::LXC::Config->has_lxc_entry($conf, 'lxc.idmap');
 530     my $unprivileged = $conf->{unprivileged} || $custom_idmap;
 531
 532     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 533
 534     my $cfgpath = '/usr/share/lxc/config';
 535     my $inc = "$cfgpath/$ostype.common.conf";
 536     $inc ="$cfgpath/common.conf" if !-f $inc;
 537     $raw .= "lxc.include = $inc\n";
 538     if ($unprivileged) {
 539         $inc = "$cfgpath/$ostype.userns.conf";
 540         $inc = "$cfgpath/userns.conf" if !-f $inc;
 541         $raw .= "lxc.include = $inc\n";
 542     }
 543
 544     my $features = PVE::LXC::Config->parse_features($conf->{features});
 545
 546     $raw .= make_seccomp_config($conf, $unprivileged, $features);
 547     $raw .= make_apparmor_config($conf, $unprivileged, $features);
 548     if ($features->{fuse}) {
 549         $raw .= "lxc.apparmor.raw = mount fstype=fuse,\n";
 550         $raw .= "lxc.mount.entry = /dev/fuse dev/fuse none bind,create=file 0 0\n";
 551     }
 552
 553     # WARNING: DO NOT REMOVE this without making sure that loop device nodes
 554     # cannot be exposed to the container with r/w access (cgroup perms).
 555     # When this is enabled mounts will still remain in the monitor's namespace
 556     # after the container unmounted them and thus will not detach from their
 557     # files while the container is running!
 558     $raw .= "lxc.monitor.unshare = 1\n";
 559
 560     my $cgv1 = get_cgroup_subsystems();
 561
 562     # Should we read them from /etc/subuid?
 563     if ($unprivileged && !$custom_idmap) {
 564         $raw .= "lxc.idmap = u 0 100000 65536\n";
 565         $raw .= "lxc.idmap = g 0 100000 65536\n";
 566     }
 567
 568     if (!PVE::LXC::Config->has_dev_console($conf)) {
 569         $raw .= "lxc.console.path = none\n";
 570         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n" if $cgv1->{devices};
 571     }
 572
 573     my $ttycount = PVE::LXC::Config->get_tty_count($conf);
 574     $raw .= "lxc.tty.max = $ttycount\n";
 575
 576     # some init scripts expect a linux terminal (turnkey).
 577     $raw .= "lxc.environment = TERM=linux\n";
 578
 579     my $utsname = $conf->{hostname} || "CT$vmid";
 580     $raw .= "lxc.uts.name = $utsname\n";
 581
 582     if ($cgv1->{memory}) {
 583         my $memory = $conf->{memory} || 512;
 584         my $swap = $conf->{swap} // 0;
 585
 586         my $lxcmem = int($memory*1024*1024);
 587         $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 588
 589         my $lxcswap = int(($memory + $swap)*1024*1024);
 590         $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 591     }
 592
 593     if ($cgv1->{cpu}) {
 594         if (my $cpulimit = $conf->{cpulimit}) {
 595             $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 596             my $value = int(100000*$cpulimit);
 597             $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 598         }
 599
 600         my $shares = $conf->{cpuunits} || 1024;
 601         $raw .= "lxc.cgroup.cpu.shares = $shares\n";
 602     }
 603
 604     die "missing 'rootfs' configuration\n"
 605         if !defined($conf->{rootfs});
 606
 607     my $mountpoint = PVE::LXC::Config->parse_ct_rootfs($conf->{rootfs});
 608
 609     $raw .= "lxc.rootfs.path = $dir/rootfs\n";
 610
 611     foreach my $k (sort keys %$conf) {
 612         next if $k !~ m/^net(\d+)$/;
 613         my $ind = $1;
 614         my $d = PVE::LXC::Config->parse_lxc_network($conf->{$k});
 615         $raw .= "lxc.net.$ind.type = veth\n";
 616         $raw .= "lxc.net.$ind.veth.pair = veth${vmid}i${ind}\n";
 617         $raw .= "lxc.net.$ind.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
 618         $raw .= "lxc.net.$ind.name = $d->{name}\n" if defined($d->{name});
 619         $raw .= "lxc.net.$ind.mtu = $d->{mtu}\n" if defined($d->{mtu});
 620     }
 621
 622     if ($cgv1->{cpuset}) {
 623         my $had_cpuset = 0;
 624         if (my $lxcconf = $conf->{lxc}) {
 625             foreach my $entry (@$lxcconf) {
 626                 my ($k, $v) = @$entry;
 627                 $had_cpuset = 1 if $k eq 'lxc.cgroup.cpuset.cpus';
 628                 $raw .= "$k = $v\n";
 629             }
 630         }
 631
 632         my $cores = $conf->{cores};
 633         if (!$had_cpuset && $cores) {
 634             my $cpuset = eval { PVE::CpuSet->new_from_cgroup('lxc', 'effective_cpus') };
 635             $cpuset = PVE::CpuSet->new_from_cgroup('', 'effective_cpus') if !$cpuset;
 636             my @members = $cpuset->members();
 637             while (scalar(@members) > $cores) {
 638                 my $randidx = int(rand(scalar(@members)));
 639                 $cpuset->delete($members[$randidx]);
 640                 splice(@members, $randidx, 1); # keep track of the changes
 641             }
 642             $raw .= "lxc.cgroup.cpuset.cpus = ".$cpuset->short_string()."\n";
 643         }
 644     }
 645
 646     File::Path::mkpath("$dir/rootfs");
 647
 648     PVE::Tools::file_set_contents("$dir/config", $raw);
 649 }
 650
 651 # verify and cleanup nameserver list (replace \0 with ' ')
 652 sub verify_nameserver_list {
 653     my ($nameserver_list) = @_;
 654
 655     my @list = ();
 656     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
 657         PVE::JSONSchema::pve_verify_ip($server);
 658         push @list, $server;
 659     }
 660
 661     return join(' ', @list);
 662 }
 663
 664 sub verify_searchdomain_list {
 665     my ($searchdomain_list) = @_;
 666
 667     my @list = ();
 668     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
 669         # todo: should we add checks for valid dns domains?
 670         push @list, $server;
 671     }
 672
 673     return join(' ', @list);
 674 }
 675
 676 sub get_console_command {
 677     my ($vmid, $conf, $escapechar) = @_;
 678
 679     # '-1' as $escapechar disables keyboard escape sequence
 680     # any other passed char (a-z) will result in <Ctrl+$escapechar q>
 681
 682     my $cmode = PVE::LXC::Config->get_cmode($conf);
 683
 684     my $cmd = [];
 685     if ($cmode eq 'console') {
 686         push @$cmd, 'lxc-console', '-n',  $vmid, '-t', 0;
 687         push @$cmd, '-e', $escapechar if $escapechar;
 688     } elsif ($cmode eq 'tty') {
 689         push @$cmd, 'lxc-console', '-n',  $vmid;
 690         push @$cmd, '-e', $escapechar if $escapechar;
 691     } elsif ($cmode eq 'shell') {
 692         push @$cmd, 'lxc-attach', '--clear-env', '-n', $vmid;
 693     } else {
 694         die "internal error";
 695     }
 696
 697     return $cmd;
 698 }
 699
 700 sub get_primary_ips {
 701     my ($conf) = @_;
 702
 703     # return data from net0
 704
 705     return undef if !defined($conf->{net0});
 706     my $net = PVE::LXC::Config->parse_lxc_network($conf->{net0});
 707
 708     my $ipv4 = $net->{ip};
 709     if ($ipv4) {
 710         if ($ipv4 =~ /^(dhcp|manual)$/) {
 711             $ipv4 = undef
 712         } else {
 713             $ipv4 =~ s!/\d+$!!;
 714         }
 715     }
 716     my $ipv6 = $net->{ip6};
 717     if ($ipv6) {
 718         if ($ipv6 =~ /^(auto|dhcp|manual)$/) {
 719             $ipv6 = undef;
 720         } else {
 721             $ipv6 =~ s!/\d+$!!;
 722         }
 723     }
 724
 725     return ($ipv4, $ipv6);
 726 }
 727
 728 sub delete_mountpoint_volume {
 729     my ($storage_cfg, $vmid, $volume) = @_;
 730
 731     return if PVE::LXC::Config->classify_mountpoint($volume) ne 'volume';
 732
 733     my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $volume);
 734
 735     if ($vmid == $owner) {
 736         PVE::Storage::vdisk_free($storage_cfg, $volume);
 737     } else {
 738         warn "ignore deletion of '$volume', CT $vmid isn't the owner!\n";
 739     }
 740 }
 741
 742 sub destroy_lxc_container {
 743     my ($storage_cfg, $vmid, $conf, $replacement_conf) = @_;
 744
 745     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 746         my ($ms, $mountpoint) = @_;
 747         delete_mountpoint_volume($storage_cfg, $vmid, $mountpoint->{volume});
 748     });
 749
 750     rmdir "/var/lib/lxc/$vmid/rootfs";
 751     unlink "/var/lib/lxc/$vmid/config";
 752     rmdir "/var/lib/lxc/$vmid";
 753     if (defined $replacement_conf) {
 754         PVE::LXC::Config->write_config($vmid, $replacement_conf);
 755     } else {
 756         PVE::LXC::Config->destroy_config($vmid);
 757     }
 758 }
 759
 760 sub vm_stop_cleanup {
 761     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
 762
 763     eval {
 764         if (!$keepActive) {
 765
 766             my $vollist = PVE::LXC::Config->get_vm_volumes($conf);
 767             PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
 768         }
 769     };
 770     warn $@ if $@; # avoid errors - just warn
 771 }
 772
 773 my $safe_num_ne = sub {
 774     my ($a, $b) = @_;
 775
 776     return 0 if !defined($a) && !defined($b);
 777     return 1 if !defined($a);
 778     return 1 if !defined($b);
 779
 780     return $a != $b;
 781 };
 782
 783 my $safe_string_ne = sub {
 784     my ($a, $b) = @_;
 785
 786     return 0 if !defined($a) && !defined($b);
 787     return 1 if !defined($a);
 788     return 1 if !defined($b);
 789
 790     return $a ne $b;
 791 };
 792
 793 sub update_net {
 794     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
 795
 796     if ($newnet->{type} ne 'veth') {
 797         # for when there are physical interfaces
 798         die "cannot update interface of type $newnet->{type}";
 799     }
 800
 801     my $veth = "veth${vmid}i${netid}";
 802     my $eth = $newnet->{name};
 803
 804     if (my $oldnetcfg = $conf->{$opt}) {
 805         my $oldnet = PVE::LXC::Config->parse_lxc_network($oldnetcfg);
 806
 807         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
 808             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
 809
 810             PVE::Network::veth_delete($veth);
 811             delete $conf->{$opt};
 812             PVE::LXC::Config->write_config($vmid, $conf);
 813
 814             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 815
 816         } else {
 817             if (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
 818                 &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
 819                 &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
 820
 821                 if ($oldnet->{bridge}) {
 822                     PVE::Network::tap_unplug($veth);
 823                     foreach (qw(bridge tag firewall)) {
 824                         delete $oldnet->{$_};
 825                     }
 826                     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 827                     PVE::LXC::Config->write_config($vmid, $conf);
 828                 }
 829
 830                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 831                 # This includes the rate:
 832                 foreach (qw(bridge tag firewall rate)) {
 833                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
 834                 }
 835             } elsif (&$safe_string_ne($oldnet->{rate}, $newnet->{rate})) {
 836                 # Rate can be applied on its own but any change above needs to
 837                 # include the rate in tap_plug since OVS resets everything.
 838                 PVE::Network::tap_rate_limit($veth, $newnet->{rate});
 839                 $oldnet->{rate} = $newnet->{rate}
 840             }
 841             $conf->{$opt} = PVE::LXC::Config->print_lxc_network($oldnet);
 842             PVE::LXC::Config->write_config($vmid, $conf);
 843         }
 844     } else {
 845         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
 846     }
 847
 848     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
 849 }
 850
 851 sub hotplug_net {
 852     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
 853
 854     my $veth = "veth${vmid}i${netid}";
 855     my $vethpeer = $veth . "p";
 856     my $eth = $newnet->{name};
 857
 858     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
 859     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall}, $newnet->{trunks}, $newnet->{rate});
 860
 861     # attach peer in container
 862     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
 863     PVE::Tools::run_command($cmd);
 864
 865     # link up peer in container
 866     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
 867     PVE::Tools::run_command($cmd);
 868
 869     my $done = { type => 'veth' };
 870     foreach (qw(bridge tag firewall hwaddr name)) {
 871         $done->{$_} = $newnet->{$_} if $newnet->{$_};
 872     }
 873     $conf->{$opt} = PVE::LXC::Config->print_lxc_network($done);
 874
 875     PVE::LXC::Config->write_config($vmid, $conf);
 876 }
 877
 878 sub update_ipconfig {
 879     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
 880
 881     my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 882
 883     my $optdata = PVE::LXC::Config->parse_lxc_network($conf->{$opt});
 884     my $deleted = [];
 885     my $added = [];
 886     my $nscmd = sub {
 887         my $cmdargs = shift;
 888         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
 889     };
 890     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
 891
 892     my $change_ip_config = sub {
 893         my ($ipversion) = @_;
 894
 895         my $family_opt = "-$ipversion";
 896         my $suffix = $ipversion == 4 ? '' : $ipversion;
 897         my $gw= "gw$suffix";
 898         my $ip= "ip$suffix";
 899
 900         my $newip = $newnet->{$ip};
 901         my $newgw = $newnet->{$gw};
 902         my $oldip = $optdata->{$ip};
 903         my $oldgw = $optdata->{$gw};
 904
 905         my $change_ip = &$safe_string_ne($oldip, $newip);
 906         my $change_gw = &$safe_string_ne($oldgw, $newgw);
 907
 908         return if !$change_ip && !$change_gw;
 909
 910         # step 1: add new IP, if this fails we cancel
 911         my $is_real_ip = ($newip && $newip !~ /^(?:auto|dhcp|manual)$/);
 912         if ($change_ip && $is_real_ip) {
 913             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
 914             if (my $err = $@) {
 915                 warn $err;
 916                 return;
 917             }
 918         }
 919
 920         # step 2: replace gateway
 921         #   If this fails we delete the added IP and cancel.
 922         #   If it succeeds we save the config and delete the old IP, ignoring
 923         #   errors. The config is then saved.
 924         # Note: 'ip route replace' can add
 925         if ($change_gw) {
 926             if ($newgw) {
 927                 eval {
 928                     if ($is_real_ip && !PVE::Network::is_ip_in_cidr($newgw, $newip, $ipversion)) {
 929                         &$ipcmd($family_opt, 'route', 'add', $newgw, 'dev', $eth);
 930                     }
 931                     &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw);
 932                 };
 933                 if (my $err = $@) {
 934                     warn $err;
 935                     # the route was not replaced, the old IP is still available
 936                     # rollback (delete new IP) and cancel
 937                     if ($change_ip) {
 938                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
 939                         warn $@ if $@; # no need to die here
 940                     }
 941                     return;
 942                 }
 943             } else {
 944                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
 945                 # if the route was not deleted, the guest might have deleted it manually
 946                 # warn and continue
 947                 warn $@ if $@;
 948             }
 949             if ($oldgw && $oldip && !PVE::Network::is_ip_in_cidr($oldgw, $oldip)) {
 950                 eval { &$ipcmd($family_opt, 'route', 'del', $oldgw, 'dev', $eth); };
 951                 # warn if the route was deleted manually
 952                 warn $@ if $@;
 953             }
 954         }
 955
 956         # from this point on we save the configuration
 957         # step 3: delete old IP ignoring errors
 958         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
 959             # We need to enable promote_secondaries, otherwise our newly added
 960             # address will be removed along with the old one.
 961             my $promote = 0;
 962             eval {
 963                 if ($ipversion == 4) {
 964                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
 965                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
 966                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
 967                 }
 968                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
 969             };
 970             warn $@ if $@; # no need to die here
 971
 972             if ($ipversion == 4) {
 973                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
 974             }
 975         }
 976
 977         foreach my $property ($ip, $gw) {
 978             if ($newnet->{$property}) {
 979                 $optdata->{$property} = $newnet->{$property};
 980             } else {
 981                 delete $optdata->{$property};
 982             }
 983         }
 984         $conf->{$opt} = PVE::LXC::Config->print_lxc_network($optdata);
 985         PVE::LXC::Config->write_config($vmid, $conf);
 986         $lxc_setup->setup_network($conf);
 987     };
 988
 989     &$change_ip_config(4);
 990     &$change_ip_config(6);
 991
 992 }
 993
 994 my $enter_namespace = sub {
 995     my ($vmid, $pid, $which, $type) = @_;
 996     sysopen my $fd, "/proc/$pid/ns/$which", O_RDONLY
 997         or die "failed to open $which namespace of container $vmid: $!\n";
 998     PVE::Tools::setns(fileno($fd), $type)
 999         or die "failed to enter $which namespace of container $vmid: $!\n";
1000     close $fd;
1001 };
1002
1003 my $do_syncfs = sub {
1004     my ($vmid, $pid, $socket) = @_;
1005
1006     &$enter_namespace($vmid, $pid, 'mnt', PVE::Tools::CLONE_NEWNS);
1007
1008     # Tell the parent process to start reading our /proc/mounts
1009     print {$socket} "go\n";
1010     $socket->flush();
1011
1012     # Receive /proc/self/mounts
1013     my $mountdata = do { local $/ = undef; <$socket> };
1014     close $socket;
1015
1016     # Now sync all mountpoints...
1017     my $mounts = PVE::ProcFSTools::parse_mounts($mountdata);
1018     foreach my $mp (@$mounts) {
1019         my ($what, $dir, $fs) = @$mp;
1020         next if $fs eq 'fuse.lxcfs';
1021         eval { PVE::Tools::sync_mountpoint($dir); };
1022         warn $@ if $@;
1023     }
1024 };
1025
1026 sub sync_container_namespace {
1027     my ($vmid) = @_;
1028     my $pid = find_lxc_pid($vmid);
1029
1030     # SOCK_DGRAM is nicer for barriers but cannot be slurped
1031     socketpair my $pfd, my $cfd, AF_UNIX, SOCK_STREAM, PF_UNSPEC
1032         or die "failed to create socketpair: $!\n";
1033
1034     my $child = fork();
1035     die "fork failed: $!\n" if !defined($child);
1036
1037     if (!$child) {
1038         eval {
1039             close $pfd;
1040             &$do_syncfs($vmid, $pid, $cfd);
1041         };
1042         if (my $err = $@) {
1043             warn $err;
1044             POSIX::_exit(1);
1045         }
1046         POSIX::_exit(0);
1047     }
1048     close $cfd;
1049     my $go = <$pfd>;
1050     die "failed to enter container namespace\n" if $go ne "go\n";
1051
1052     open my $mounts, '<', "/proc/$child/mounts"
1053         or die "failed to open container's /proc/mounts: $!\n";
1054     my $mountdata = do { local $/ = undef; <$mounts> };
1055     close $mounts;
1056     print {$pfd} $mountdata;
1057     close $pfd;
1058
1059     while (waitpid($child, 0) != $child) {}
1060     die "failed to sync container namespace\n" if $? != 0;
1061 }
1062
1063 sub template_create {
1064     my ($vmid, $conf) = @_;
1065
1066     my $storecfg = PVE::Storage::config();
1067
1068     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1069         my ($ms, $mountpoint) = @_;
1070
1071         my $volid = $mountpoint->{volume};
1072
1073         die "Template feature is not available for '$volid'\n"
1074             if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1075     });
1076
1077     PVE::LXC::Config->foreach_mountpoint($conf, sub {
1078         my ($ms, $mountpoint) = @_;
1079
1080         my $volid = $mountpoint->{volume};
1081
1082         PVE::Storage::activate_volumes($storecfg, [$volid]);
1083
1084         my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1085         $mountpoint->{volume} = $template_volid;
1086         $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq "rootfs");
1087     });
1088
1089     PVE::LXC::Config->write_config($vmid, $conf);
1090 }
1091
1092 sub check_ct_modify_config_perm {
1093     my ($rpcenv, $authuser, $vmid, $pool, $newconf, $delete) = @_;
1094
1095     return 1 if $authuser eq 'root@pam';
1096
1097     my $check = sub {
1098         my ($opt, $delete) = @_;
1099         if ($opt eq 'cores' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1100             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1101         } elsif ($opt eq 'rootfs' || $opt =~ /^mp\d+$/) {
1102             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1103             return if $delete;
1104             my $data = $opt eq 'rootfs' ? PVE::LXC::Config->parse_ct_rootfs($newconf->{$opt})
1105                                         : PVE::LXC::Config->parse_ct_mountpoint($newconf->{$opt});
1106             raise_perm_exc("mount point type $data->{type} is only allowed for root\@pam")
1107                 if $data->{type} ne 'volume';
1108         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1109             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1110         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1111                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1112             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1113         } elsif ($opt eq 'features') {
1114             # For now this is restricted to root@pam
1115             raise_perm_exc("changing feature flags is only allowed for root\@pam");
1116         } elsif ($opt eq 'hookscript') {
1117             # For now this is restricted to root@pam
1118             raise_perm_exc("changing the hookscript is only allowed for root\@pam");
1119         } else {
1120             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1121         }
1122     };
1123
1124     foreach my $opt (keys %$newconf) {
1125         &$check($opt, 0);
1126     }
1127     foreach my $opt (@$delete) {
1128         &$check($opt, 1);
1129     }
1130
1131     return 1;
1132 }
1133
1134 sub umount_all {
1135     my ($vmid, $storage_cfg, $conf, $noerr) = @_;
1136
1137     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1138     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1139
1140     my $res = 1;
1141
1142     PVE::LXC::Config->foreach_mountpoint_reverse($conf, sub {
1143         my ($ms, $mountpoint) = @_;
1144
1145         my $volid = $mountpoint->{volume};
1146         my $mount = $mountpoint->{mp};
1147
1148         return if !$volid || !$mount;
1149
1150         my $mount_path = "$rootdir/$mount";
1151         $mount_path =~ s!/+!/!g;
1152
1153         return if !PVE::ProcFSTools::is_mounted($mount_path);
1154
1155         eval {
1156             PVE::Tools::run_command(['umount', '-d', $mount_path]);
1157         };
1158         if (my $err = $@) {
1159             if ($noerr) {
1160                 $res = 0;
1161                 warn $err;
1162             } else {
1163                 die $err;
1164             }
1165         }
1166     });
1167
1168     return $res; # tell caller if (some) umounts failed for the noerr case
1169 }
1170
1171 sub mount_all {
1172     my ($vmid, $storage_cfg, $conf, $ignore_ro) = @_;
1173
1174     my $rootdir = "/var/lib/lxc/$vmid/rootfs";
1175     File::Path::make_path($rootdir);
1176
1177     my $volid_list = PVE::LXC::Config->get_vm_volumes($conf);
1178     PVE::Storage::activate_volumes($storage_cfg, $volid_list);
1179
1180     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
1181
1182     eval {
1183         PVE::LXC::Config->foreach_mountpoint($conf, sub {
1184             my ($ms, $mountpoint) = @_;
1185
1186             $mountpoint->{ro} = 0 if $ignore_ro;
1187
1188             mountpoint_mount($mountpoint, $rootdir, $storage_cfg, undef, $rootuid, $rootgid);
1189         });
1190     };
1191     if (my $err = $@) {
1192         warn "mounting container failed\n";
1193         umount_all($vmid, $storage_cfg, $conf, 1);
1194         die $err;
1195     }
1196
1197     return $rootdir;
1198 }
1199
1200
1201 sub mountpoint_mount_path {
1202     my ($mountpoint, $storage_cfg, $snapname) = @_;
1203
1204     return mountpoint_mount($mountpoint, undef, $storage_cfg, $snapname);
1205 }
1206
1207 sub query_loopdev {
1208     my ($path) = @_;
1209     my $found;
1210     my $parser = sub {
1211         my $line = shift;
1212         if ($line =~ m@^(/dev/loop\d+):@) {
1213             $found = $1;
1214         }
1215     };
1216     my $cmd = ['losetup', '--associated', $path];
1217     PVE::Tools::run_command($cmd, outfunc => $parser);
1218     return $found;
1219 }
1220
1221 # Run a function with a file attached to a loop device.
1222 # The loop device is always detached afterwards (or set to autoclear).
1223 # Returns the loop device.
1224 sub run_with_loopdev {
1225     my ($func, $file, $readonly) = @_;
1226     my $device = query_loopdev($file);
1227     # Try to reuse an existing device
1228     if ($device) {
1229         # We assume that whoever setup the loop device is responsible for
1230         # detaching it.
1231         &$func($device);
1232         return $device;
1233     }
1234
1235     my $parser = sub {
1236         my $line = shift;
1237         if ($line =~ m@^(/dev/loop\d+)$@) {
1238             $device = $1;
1239         }
1240     };
1241     my $losetup_cmd = [
1242         'losetup',
1243         '--show',
1244         '-f',
1245         $file,
1246     ];
1247     push @$losetup_cmd, '-r' if $readonly;
1248     PVE::Tools::run_command($losetup_cmd, outfunc => $parser);
1249     die "failed to setup loop device for $file\n" if !$device;
1250     eval { &$func($device); };
1251     my $err = $@;
1252     PVE::Tools::run_command(['losetup', '-d', $device]);
1253     die $err if $err;
1254     return $device;
1255 }
1256
1257 # In scalar mode: returns a file handle to the deepest directory node.
1258 # In list context: returns a list of:
1259 #   * the deepest directory node
1260 #   * the 2nd deepest directory (parent of the above)
1261 #   * directory name of the last directory
1262 # So that the path $2/$3 should lead to $1 afterwards.
1263 sub walk_tree_nofollow($$$;$$) {
1264     my ($start, $subdir, $mkdir, $rootuid, $rootgid) = @_;
1265
1266     # splitdir() returns '' for empty components including the leading /
1267     my @comps = grep { length($_)>0 } File::Spec->splitdir($subdir);
1268
1269     sysopen(my $fd, $start, O_PATH | O_DIRECTORY)
1270         or die "failed to open start directory $start: $!\n";
1271
1272     my $dir = $start;
1273     my $last_component = undef;
1274     my $second = $fd;
1275     foreach my $component (@comps) {
1276         $dir .= "/$component";
1277         my $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1278
1279         if (!$next) {
1280             # failed, check for symlinks and try to create the path
1281             die "symlink encountered at: $dir\n" if $! == ELOOP || $! == ENOTDIR;
1282             die "cannot open directory $dir: $!\n" if !$mkdir;
1283
1284             # We don't check for errors on mkdirat() here and just try to
1285             # openat() again, since at least one error (EEXIST) is an
1286             # expected possibility if multiple containers start
1287             # simultaneously. If someone else injects a symlink now then
1288             # the subsequent openat() will fail due to O_NOFOLLOW anyway.
1289             PVE::Tools::mkdirat(fileno($fd), $component, 0755);
1290
1291             $next = PVE::Tools::openat(fileno($fd), $component, O_NOFOLLOW | O_DIRECTORY);
1292             die "failed to create path: $dir: $!\n" if !$next;
1293
1294             PVE::Tools::fchownat(fileno($next), '', $rootuid, $rootgid, PVE::Tools::AT_EMPTY_PATH)
1295                 if defined($rootuid) && defined($rootgid);
1296         }
1297
1298         close $second if defined($last_component);
1299         $last_component = $component;
1300         $second = $fd;
1301         $fd = $next;
1302     }
1303
1304     return ($fd, defined($last_component) && $second, $last_component) if wantarray;
1305     close $second if defined($last_component);
1306     return $fd;
1307 }
1308
1309 # To guard against symlink attack races against other currently running
1310 # containers with shared recursive bind mount hierarchies we prepare a
1311 # directory handle for the directory we're mounting over to verify the
1312 # mountpoint afterwards.
1313 sub __bindmount_prepare {
1314     my ($hostroot, $dir) = @_;
1315     my $srcdh = walk_tree_nofollow($hostroot, $dir, 0);
1316     return $srcdh;
1317 }
1318
1319 # Assuming we mount to rootfs/a/b/c, verify with the directory handle to 'b'
1320 # ($parentfd) that 'b/c' (openat($parentfd, 'c')) really leads to the directory
1321 # we intended to bind mount.
1322 sub __bindmount_verify {
1323     my ($srcdh, $parentfd, $last_dir, $ro) = @_;
1324     my $destdh;
1325     if ($parentfd) {
1326         # Open the mount point path coming from the parent directory since the
1327         # filehandle we would have gotten as first result of walk_tree_nofollow
1328         # earlier is still a handle to the underlying directory instead of the
1329         # mounted path.
1330         $destdh = PVE::Tools::openat(fileno($parentfd), $last_dir, PVE::Tools::O_PATH | O_NOFOLLOW | O_DIRECTORY);
1331         die "failed to open mount point: $!\n" if !$destdh;
1332         if ($ro) {
1333             my $dot = '.';
1334             # no separate function because 99% of the time it's the wrong thing to use.
1335             if (syscall(PVE::Syscall::faccessat, fileno($destdh), $dot, &POSIX::W_OK, 0) != -1) {
1336                 die "failed to mark bind mount read only\n";
1337             }
1338             die "read-only check failed: $!\n" if $! != EROFS;
1339         }
1340     } else {
1341         # For the rootfs we don't have a parentfd so we open the path directly.
1342         # Note that this means bindmounting any prefix of the host's
1343         # /var/lib/lxc/$vmid path into another container is considered a grave
1344         # security error.
1345         sysopen $destdh, $last_dir, O_PATH | O_DIRECTORY;
1346         die "failed to open mount point: $!\n" if !$destdh;
1347     }
1348
1349     my ($srcdev, $srcinode) = stat($srcdh);
1350     my ($dstdev, $dstinode) = stat($destdh);
1351     close $srcdh;
1352     close $destdh;
1353
1354     return ($srcdev == $dstdev && $srcinode == $dstinode);
1355 }
1356
1357 # Perform the actual bind mounting:
1358 sub __bindmount_do {
1359     my ($dir, $dest, $ro, @extra_opts) = @_;
1360     PVE::Tools::run_command(['mount', '-o', 'bind', @extra_opts, $dir, $dest]);
1361     if ($ro) {
1362         eval { PVE::Tools::run_command(['mount', '-o', 'bind,remount,ro', $dest]); };
1363         if (my $err = $@) {
1364             warn "bindmount error\n";
1365             # don't leave writable bind-mounts behind...
1366             PVE::Tools::run_command(['umount', $dest]);
1367             die $err;
1368         }
1369     }
1370 }
1371
1372 sub bindmount {
1373     my ($dir, $parentfd, $last_dir, $dest, $ro, @extra_opts) = @_;
1374
1375     my $srcdh = __bindmount_prepare('/', $dir);
1376
1377     __bindmount_do($dir, $dest, $ro, @extra_opts);
1378
1379     if (!__bindmount_verify($srcdh, $parentfd, $last_dir, $ro)) {
1380         PVE::Tools::run_command(['umount', $dest]);
1381         die "detected mount path change at: $dir\n";
1382     }
1383 }
1384
1385 # Cleanup $rootdir a bit (double and trailing slashes), build the mount path
1386 # from $rootdir and $mount and walk the path from $rootdir to the final
1387 # directory to check for symlinks.
1388 sub __mount_prepare_rootdir {
1389     my ($rootdir, $mount, $rootuid, $rootgid) = @_;
1390     $rootdir =~ s!/+!/!g;
1391     $rootdir =~ s!/+$!!;
1392     my $mount_path = "$rootdir/$mount";
1393     my ($mpfd, $parentfd, $last_dir) = walk_tree_nofollow($rootdir, $mount, 1, $rootuid, $rootgid);
1394     return ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir);
1395 }
1396
1397 # use $rootdir = undef to just return the corresponding mount path
1398 sub mountpoint_mount {
1399     my ($mountpoint, $rootdir, $storage_cfg, $snapname, $rootuid, $rootgid) = @_;
1400
1401     my $volid = $mountpoint->{volume};
1402     my $mount = $mountpoint->{mp};
1403     my $type = $mountpoint->{type};
1404     my $quota = !$snapname && !$mountpoint->{ro} && $mountpoint->{quota};
1405     my $mounted_dev;
1406
1407     return if !$volid || !$mount;
1408
1409     $mount =~ s!/+!/!g;
1410
1411     my $mount_path;
1412     my ($mpfd, $parentfd, $last_dir);
1413
1414     if (defined($rootdir)) {
1415         ($rootdir, $mount_path, $mpfd, $parentfd, $last_dir) =
1416             __mount_prepare_rootdir($rootdir, $mount, $rootuid, $rootgid);
1417     }
1418
1419     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1420
1421     die "unknown snapshot path for '$volid'" if !$storage && defined($snapname);
1422
1423     my $optlist = [];
1424
1425     if (my $mountopts = $mountpoint->{mountoptions}) {
1426         my @opts = split(/;/, $mountpoint->{mountoptions});
1427         push @$optlist, grep { PVE::LXC::Config::is_valid_mount_option($_) } @opts;
1428     }
1429
1430     my $acl = $mountpoint->{acl};
1431     if (defined($acl)) {
1432         push @$optlist, ($acl ? 'acl' : 'noacl');
1433     }
1434
1435     my $optstring = join(',', @$optlist);
1436     my $readonly = $mountpoint->{ro};
1437
1438     my @extra_opts;
1439     @extra_opts = ('-o', $optstring) if $optstring;
1440
1441     if ($storage) {
1442
1443         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1444
1445         my $path = PVE::Storage::map_volume($storage_cfg, $volid, $snapname);
1446
1447         $path = PVE::Storage::path($storage_cfg, $volid, $snapname) if !defined($path);
1448
1449         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1450             PVE::Storage::parse_volname($storage_cfg, $volid);
1451
1452         $format = 'iso' if $vtype eq 'iso'; # allow to handle iso files
1453
1454         if ($format eq 'subvol') {
1455             if ($mount_path) {
1456                 if ($snapname) {
1457                     if ($scfg->{type} eq 'zfspool') {
1458                         my $path_arg = $path;
1459                         $path_arg =~ s!^/+!!;
1460                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, '-t', 'zfs', $path_arg, $mount_path]);
1461                     } else {
1462                         die "cannot mount subvol snapshots for storage type '$scfg->{type}'\n";
1463                     }
1464                 } else {
1465                     if (defined($acl) && $scfg->{type} eq 'zfspool') {
1466                         my $acltype = ($acl ? 'acltype=posixacl' : 'acltype=noacl');
1467                         my (undef, $name) = PVE::Storage::parse_volname($storage_cfg, $volid);
1468                         $name .= "\@$snapname" if defined($snapname);
1469                         PVE::Tools::run_command(['zfs', 'set', $acltype, "$scfg->{pool}/$name"]);
1470                     }
1471                     bindmount($path, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts);
1472                     warn "cannot enable quota control for bind mounted subvolumes\n" if $quota;
1473                 }
1474             }
1475             return wantarray ? ($path, 0, undef) : $path;
1476         } elsif ($format eq 'raw' || $format eq 'iso') {
1477             # NOTE: 'mount' performs canonicalization without the '-c' switch, which for
1478             # device-mapper devices is special-cased to use the /dev/mapper symlinks.
1479             # Our autodev hook expects the /dev/dm-* device currently
1480             # and will create the /dev/mapper symlink accordingly
1481             $path = Cwd::realpath($path);
1482             die "failed to get device path\n" if !$path;
1483             ($path) = ($path =~ /^(.*)$/s); #untaint
1484             my $domount = sub {
1485                 my ($path) = @_;
1486                 if ($mount_path) {
1487                     if ($format eq 'iso') {
1488                         PVE::Tools::run_command(['mount', '-o', 'ro', @extra_opts, $path, $mount_path]);
1489                     } elsif ($isBase || defined($snapname)) {
1490                         PVE::Tools::run_command(['mount', '-o', 'ro,noload', @extra_opts, $path, $mount_path]);
1491                     } else {
1492                         if ($quota) {
1493                             push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0';
1494                         }
1495                         push @extra_opts, '-o', 'ro' if $readonly;
1496                         PVE::Tools::run_command(['mount', @extra_opts, $path, $mount_path]);
1497                     }
1498                 }
1499             };
1500             my $use_loopdev = 0;
1501             if ($scfg->{path}) {
1502                 $mounted_dev = run_with_loopdev($domount, $path, $readonly);
1503                 $use_loopdev = 1;
1504             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' ||
1505                      $scfg->{type} eq 'rbd' || $scfg->{type} eq 'lvmthin') {
1506                 $mounted_dev = $path;
1507                 &$domount($path);
1508             } else {
1509                 die "unsupported storage type '$scfg->{type}'\n";
1510             }
1511             return wantarray ? ($path, $use_loopdev, $mounted_dev) : $path;
1512         } else {
1513             die "unsupported image format '$format'\n";
1514         }
1515     } elsif ($type eq 'device') {
1516         push @extra_opts, '-o', 'ro' if $readonly;
1517         push @extra_opts, '-o', 'usrjquota=aquota.user,grpjquota=aquota.group,jqfmt=vfsv0' if $quota;
1518         # See the NOTE above about devicemapper canonicalization
1519         my ($devpath) = (Cwd::realpath($volid) =~ /^(.*)$/s); # realpath() taints
1520         PVE::Tools::run_command(['mount', @extra_opts, $volid, $mount_path]) if $mount_path;
1521         return wantarray ? ($volid, 0, $devpath) : $volid;
1522     } elsif ($type eq 'bind') {
1523         die "directory '$volid' does not exist\n" if ! -d $volid;
1524         bindmount($volid, $parentfd, $last_dir//$rootdir, $mount_path, $readonly, @extra_opts) if $mount_path;
1525         warn "cannot enable quota control for bind mounts\n" if $quota;
1526         return wantarray ? ($volid, 0, undef) : $volid;
1527     }
1528
1529     die "unsupported storage";
1530 }
1531
1532 sub mkfs {
1533     my ($dev, $rootuid, $rootgid) = @_;
1534
1535     PVE::Tools::run_command(['mkfs.ext4', '-O', 'mmp',
1536                              '-E', "root_owner=$rootuid:$rootgid",
1537                              $dev]);
1538 }
1539
1540 sub format_disk {
1541     my ($storage_cfg, $volid, $rootuid, $rootgid) = @_;
1542
1543     if ($volid =~ m!^/dev/.+!) {
1544         mkfs($volid);
1545         return;
1546     }
1547
1548     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1549
1550     die "cannot format volume '$volid' with no storage\n" if !$storage;
1551
1552     PVE::Storage::activate_volumes($storage_cfg, [$volid]);
1553
1554     my $path = PVE::Storage::map_volume($storage_cfg, $volid);
1555
1556     $path = PVE::Storage::path($storage_cfg, $volid) if !defined($path);
1557
1558     my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1559         PVE::Storage::parse_volname($storage_cfg, $volid);
1560
1561     die "cannot format volume '$volid' (format == $format)\n"
1562         if $format ne 'raw';
1563
1564     mkfs($path, $rootuid, $rootgid);
1565 }
1566
1567 sub destroy_disks {
1568     my ($storecfg, $vollist) = @_;
1569
1570     foreach my $volid (@$vollist) {
1571         eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1572         warn $@ if $@;
1573     }
1574 }
1575
1576 sub alloc_disk {
1577     my ($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid) = @_;
1578
1579     my $needs_chown = 0;
1580     my $volid;
1581
1582     my $scfg = PVE::Storage::storage_config($storecfg, $storage);
1583     # fixme: use better naming ct-$vmid-disk-X.raw?
1584
1585     eval {
1586         my $do_format = 0;
1587         if ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs' || $scfg->{type} eq 'cifs' ) {
1588             if ($size_kb > 0) {
1589                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw',
1590                                                    undef, $size_kb);
1591                 $do_format = 1;
1592             } else {
1593                 $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1594                                                    undef, 0);
1595                 $needs_chown = 1;
1596             }
1597         } elsif ($scfg->{type} eq 'zfspool') {
1598
1599             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'subvol',
1600                                                undef, $size_kb);
1601             $needs_chown = 1;
1602         } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'lvm' || $scfg->{type} eq 'lvmthin') {
1603
1604             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1605             $do_format = 1;
1606
1607         } elsif ($scfg->{type} eq 'rbd') {
1608
1609             $volid = PVE::Storage::vdisk_alloc($storecfg, $storage, $vmid, 'raw', undef, $size_kb);
1610             $do_format = 1;
1611         } else {
1612             die "unable to create containers on storage type '$scfg->{type}'\n";
1613         }
1614         format_disk($storecfg, $volid, $rootuid, $rootgid) if $do_format;
1615     };
1616     if (my $err = $@) {
1617         # in case formatting got interrupted:
1618         if (defined($volid)) {
1619             eval { PVE::Storage::vdisk_free($storecfg, $volid); };
1620             warn $@ if $@;
1621         }
1622         die $err;
1623     }
1624
1625     return ($volid, $needs_chown);
1626 }
1627
1628 our $NEW_DISK_RE = qr/^([^:\s]+):(\d+(\.\d+)?)$/;
1629 sub create_disks {
1630     my ($storecfg, $vmid, $settings, $conf, $pending) = @_;
1631
1632     my $vollist = [];
1633
1634     eval {
1635         my (undef, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
1636         my $chown_vollist = [];
1637
1638         PVE::LXC::Config->foreach_mountpoint($settings, sub {
1639             my ($ms, $mountpoint) = @_;
1640
1641             my $volid = $mountpoint->{volume};
1642             my $mp = $mountpoint->{mp};
1643
1644             my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1645
1646             if ($storage && ($volid =~ $NEW_DISK_RE)) {
1647                 my ($storeid, $size_gb) = ($1, $2);
1648
1649                 my $size_kb = int(${size_gb}*1024) * 1024;
1650
1651                 my $needs_chown = 0;
1652                 ($volid, $needs_chown) = alloc_disk($storecfg, $vmid, $storage, $size_kb, $rootuid, $rootgid);
1653                 push @$chown_vollist, $volid if $needs_chown;
1654                 push @$vollist, $volid;
1655                 $mountpoint->{volume} = $volid;
1656                 $mountpoint->{size} = $size_kb * 1024;
1657                 if ($pending) {
1658                     $conf->{pending}->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1659                 } else {
1660                     $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1661                 }
1662             } else {
1663                 # use specified/existing volid/dir/device
1664                 $conf->{$ms} = PVE::LXC::Config->print_ct_mountpoint($mountpoint, $ms eq 'rootfs');
1665             }
1666         });
1667
1668         PVE::Storage::activate_volumes($storecfg, $chown_vollist, undef);
1669         foreach my $volid (@$chown_vollist) {
1670             my $path = PVE::Storage::path($storecfg, $volid, undef);
1671             chown($rootuid, $rootgid, $path);
1672         }
1673         PVE::Storage::deactivate_volumes($storecfg, $chown_vollist, undef);
1674     };
1675     # free allocated images on error
1676     if (my $err = $@) {
1677         destroy_disks($storecfg, $vollist);
1678         die $err;
1679     }
1680     return $vollist;
1681 }
1682
1683 sub update_disksize {
1684     my ($vmid, $conf, $all_volumes) = @_;
1685
1686     my $changes;
1687     my $prefix = "CT $vmid:";
1688
1689     my $update_mp = sub {
1690         my ($key, $mp, @param) = @_;
1691         my $size = $all_volumes->{$mp->{volume}}->{size} // 0;
1692
1693         if (!defined($mp->{size}) || $size != $mp->{size}) {
1694             $changes = 1;
1695             print "$prefix updated volume size of '$mp->{volume}' in config.\n";
1696             $mp->{size} = $size;
1697             my $nomp = 1 if ($key eq 'rootfs');
1698             $conf->{$key} = PVE::LXC::Config->print_ct_mountpoint($mp, $nomp);
1699         }
1700     };
1701
1702     PVE::LXC::Config->foreach_mountpoint($conf, $update_mp);
1703
1704     return $changes;
1705 }
1706
1707 sub update_unused {
1708     my ($vmid, $conf, $all_volumes) = @_;
1709
1710     my $changes;
1711     my $prefix = "CT $vmid:";
1712
1713     # Note: it is allowed to define multiple storage entries with the same path
1714     # (alias), so we need to check both 'volid' and real 'path' (two different
1715     # volid can point to the same path).
1716
1717     # used and unused disks
1718     my $refpath = {};
1719     my $orphans = {};
1720
1721     foreach my $opt (keys %$conf) {
1722         next if ($opt !~ m/^unused\d+$/);
1723         my $vol = $all_volumes->{$conf->{$opt}};
1724         $refpath->{$vol->{path}} = $vol->{volid};
1725     }
1726
1727     foreach my $key (keys %$all_volumes) {
1728         my $vol = $all_volumes->{$key};
1729         my $in_use = PVE::LXC::Config->is_volume_in_use($conf, $vol->{volid});
1730         my $path = $vol->{path};
1731
1732         if ($in_use) {
1733             $refpath->{$path} = $key;
1734             delete $orphans->{$path};
1735         } else {
1736             if ((!$orphans->{$path}) && (!$refpath->{$path})) {
1737                 $orphans->{$path} = $key;
1738             }
1739         }
1740     }
1741
1742     for my $key (keys %$orphans) {
1743         my $disk = $orphans->{$key};
1744         my $unused = PVE::LXC::Config->add_unused_volume($conf, $disk);
1745
1746         if ($unused) {
1747             $changes = 1;
1748             print "$prefix add unreferenced volume '$disk' as '$unused' to config.\n";
1749         }
1750     }
1751
1752     return $changes;
1753 }
1754
1755 sub scan_volids {
1756     my ($cfg, $vmid) = @_;
1757
1758     my $info = PVE::Storage::vdisk_list($cfg, undef, $vmid);
1759
1760     my $all_volumes = {};
1761     foreach my $storeid (keys %$info) {
1762         foreach my $item (@{$info->{$storeid}}) {
1763             my $volid = $item->{volid};
1764             next if !($volid && $item->{size});
1765             $item->{path} = PVE::Storage::path($cfg, $volid);
1766             $all_volumes->{$volid} = $item;
1767         }
1768     }
1769
1770     return $all_volumes;
1771 }
1772
1773 sub rescan {
1774     my ($vmid, $nolock, $dryrun) = @_;
1775
1776     my $cfg = PVE::Storage::config();
1777
1778     # FIXME: Remove once our RBD plugin can handle CT and VM on a single storage
1779     # see: https://pve.proxmox.com/pipermail/pve-devel/2018-July/032900.html
1780     foreach my $stor (keys %{$cfg->{ids}}) {
1781         delete($cfg->{ids}->{$stor}) if !$cfg->{ids}->{$stor}->{content}->{rootdir};
1782     }
1783
1784     print "rescan volumes...\n";
1785     my $all_volumes = scan_volids($cfg, $vmid);
1786
1787     my $updatefn =  sub {
1788         my ($vmid) = @_;
1789
1790         my $changes;
1791         my $conf = PVE::LXC::Config->load_config($vmid);
1792
1793         PVE::LXC::Config->check_lock($conf);
1794
1795         my $vm_volids = {};
1796         foreach my $volid (keys %$all_volumes) {
1797             my $info = $all_volumes->{$volid};
1798             $vm_volids->{$volid} = $info if $info->{vmid} == $vmid;
1799         }
1800
1801         my $upu = update_unused($vmid, $conf, $vm_volids);
1802         my $upd = update_disksize($vmid, $conf, $vm_volids);
1803         $changes = $upu || $upd;
1804
1805         PVE::LXC::Config->write_config($vmid, $conf) if $changes && !$dryrun;
1806     };
1807
1808     if (defined($vmid)) {
1809         if ($nolock) {
1810             &$updatefn($vmid);
1811         } else {
1812             PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
1813         }
1814     } else {
1815         my $vmlist = config_list();
1816         foreach my $vmid (keys %$vmlist) {
1817             if ($nolock) {
1818                 &$updatefn($vmid);
1819             } else {
1820                 PVE::LXC::Config->lock_config($vmid, $updatefn, $vmid);
1821             }
1822         }
1823     }
1824 }
1825
1826
1827 # bash completion helper
1828
1829 sub complete_os_templates {
1830     my ($cmdname, $pname, $cvalue) = @_;
1831
1832     my $cfg = PVE::Storage::config();
1833
1834     my $storeid;
1835
1836     if ($cvalue =~ m/^([^:]+):/) {
1837         $storeid = $1;
1838     }
1839
1840     my $vtype = $cmdname eq 'restore' ? 'backup' : 'vztmpl';
1841     my $data = PVE::Storage::template_list($cfg, $storeid, $vtype);
1842
1843     my $res = [];
1844     foreach my $id (keys %$data) {
1845         foreach my $item (@{$data->{$id}}) {
1846             push @$res, $item->{volid} if defined($item->{volid});
1847         }
1848     }
1849
1850     return $res;
1851 }
1852
1853 my $complete_ctid_full = sub {
1854     my ($running) = @_;
1855
1856     my $idlist = vmstatus();
1857
1858     my $active_hash = list_active_containers();
1859
1860     my $res = [];
1861
1862     foreach my $id (keys %$idlist) {
1863         my $d = $idlist->{$id};
1864         if (defined($running)) {
1865             next if $d->{template};
1866             next if $running && !$active_hash->{$id};
1867             next if !$running && $active_hash->{$id};
1868         }
1869         push @$res, $id;
1870
1871     }
1872     return $res;
1873 };
1874
1875 sub complete_ctid {
1876     return &$complete_ctid_full();
1877 }
1878
1879 sub complete_ctid_stopped {
1880     return &$complete_ctid_full(0);
1881 }
1882
1883 sub complete_ctid_running {
1884     return &$complete_ctid_full(1);
1885 }
1886
1887 sub parse_id_maps {
1888     my ($conf) = @_;
1889
1890     my $id_map = [];
1891     my $rootuid = 0;
1892     my $rootgid = 0;
1893
1894     my $lxc = $conf->{lxc};
1895     foreach my $entry (@$lxc) {
1896         my ($key, $value) = @$entry;
1897         # FIXME: remove the 'id_map' variant when lxc-3.0 arrives
1898         next if $key ne 'lxc.idmap' && $key ne 'lxc.id_map';
1899         if ($value =~ /^([ug])\s+(\d+)\s+(\d+)\s+(\d+)\s*$/) {
1900             my ($type, $ct, $host, $length) = ($1, $2, $3, $4);
1901             push @$id_map, [$type, $ct, $host, $length];
1902             if ($ct == 0) {
1903                 $rootuid = $host if $type eq 'u';
1904                 $rootgid = $host if $type eq 'g';
1905             }
1906         } else {
1907             die "failed to parse idmap: $value\n";
1908         }
1909     }
1910
1911     if (!@$id_map && $conf->{unprivileged}) {
1912         # Should we read them from /etc/subuid?
1913         $id_map = [ ['u', '0', '100000', '65536'],
1914                     ['g', '0', '100000', '65536'] ];
1915         $rootuid = $rootgid = 100000;
1916     }
1917
1918     return ($id_map, $rootuid, $rootgid);
1919 }
1920
1921 sub userns_command {
1922     my ($id_map) = @_;
1923     if (@$id_map) {
1924         return ['lxc-usernsexec', (map { ('-m', join(':', @$_)) } @$id_map), '--'];
1925     }
1926     return [];
1927 }
1928
1929 sub vm_start {
1930     my ($vmid, $conf, $skiplock) = @_;
1931
1932     # apply pending changes while starting
1933     if (scalar(keys %{$conf->{pending}})) {
1934         my $storecfg = PVE::Storage::config();
1935         PVE::LXC::Config->vmconfig_apply_pending($vmid, $conf, $storecfg);
1936         $conf = PVE::LXC::Config->load_config($vmid); # update/reload
1937     }
1938
1939     update_lxc_config($vmid, $conf);
1940
1941     my $skiplock_flag_fn = "/run/lxc/skiplock-$vmid";
1942
1943     if ($skiplock) {
1944         open(my $fh, '>', $skiplock_flag_fn) || die "failed to open $skiplock_flag_fn for writing: $!\n";
1945         close($fh);
1946     }
1947
1948     my $cmd = ['systemctl', 'start', "pve-container\@$vmid"];
1949
1950     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-start', 1);
1951     eval { PVE::Tools::run_command($cmd); };
1952     if (my $err = $@) {
1953         unlink $skiplock_flag_fn;
1954         die $err;
1955     }
1956     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'post-start');
1957
1958     return;
1959 }
1960
1961 # Helper to stop a container completely and make sure it has stopped completely.
1962 # This is necessary because we want the post-stop hook to have completed its
1963 # unmount-all step, but post-stop happens after lxc puts the container into the
1964 # STOPPED state.
1965 # $kill - if true it will always do an immediate hard-stop
1966 # $shutdown_timeout - the timeout to wait for a gracefull shutdown
1967 # $kill_after_timeout - if true, send a hardstop if shutdown timed out
1968 sub vm_stop {
1969     my ($vmid, $kill, $shutdown_timeout, $kill_after_timeout) = @_;
1970
1971     # Open the container's command socket.
1972     my $path = "\0/var/lib/lxc/$vmid/command";
1973     my $sock = IO::Socket::UNIX->new(
1974         Type => SOCK_STREAM(),
1975         Peer => $path,
1976     );
1977     if (!$sock) {
1978         return if $! == ECONNREFUSED; # The container is not running
1979         die "failed to open container ${vmid}'s command socket: $!\n";
1980     }
1981
1982     my $conf = PVE::LXC::Config->load_config($vmid);
1983     PVE::GuestHelpers::exec_hookscript($conf, $vmid, 'pre-stop');
1984
1985     # Stop the container:
1986
1987     my $cmd = ['lxc-stop', '-n', $vmid];
1988
1989     if ($kill) {
1990         push @$cmd, '--kill'; # doesn't allow timeouts
1991     } else {
1992         # lxc-stop uses a default timeout
1993         push @$cmd, '--nokill' if !$kill_after_timeout;
1994
1995         if (defined($shutdown_timeout)) {
1996             push @$cmd, '--timeout', $shutdown_timeout;
1997             # Give run_command 5 extra seconds
1998             $shutdown_timeout += 5;
1999         }
2000     }
2001
2002     eval { PVE::Tools::run_command($cmd, timeout => $shutdown_timeout) };
2003     if (my $err = $@) {
2004         warn $@ if $@;
2005     }
2006
2007     my $result = <$sock>;
2008
2009     return if !defined $result; # monitor is gone and the ct has stopped.
2010     die "container did not stop\n";
2011 }
2012
2013 sub run_unshared {
2014     my ($code) = @_;
2015
2016     return PVE::Tools::run_fork(sub {
2017         # Unshare the mount namespace
2018         die "failed to unshare mount namespace: $!\n"
2019             if !PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
2020         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
2021         return $code->();
2022     });
2023 }
2024
2025 my $copy_volume = sub {
2026     my ($src_volid, $src, $dst_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid,  $rootgid) = @_;
2027
2028     my $src_mp = { volume => $src_volid, mp => '/', ro => 1 };
2029     $src_mp->{type} = PVE::LXC::Config->classify_mountpoint($src_volid);
2030
2031     my $dst_mp = { volume => $dst_volid, mp => '/', ro => 0 };
2032     $dst_mp->{type} = PVE::LXC::Config->classify_mountpoint($dst_volid);
2033
2034     my @mounted;
2035     eval {
2036         # mount and copy
2037         mkdir $src;
2038         mountpoint_mount($src_mp, $src, $storage_cfg, $snapname, $rootuid, $rootgid);
2039         push @mounted, $src;
2040         mkdir $dest;
2041         mountpoint_mount($dst_mp, $dest, $storage_cfg, undef, $rootuid, $rootgid);
2042         push @mounted, $dest;
2043
2044         $bwlimit //= 0;
2045
2046         PVE::Tools::run_command(['/usr/bin/rsync', '--stats', '-X', '-A', '--numeric-ids',
2047                                  '-aH', '--whole-file', '--sparse', '--one-file-system',
2048                                  "--bwlimit=$bwlimit", "$src/", $dest]);
2049     };
2050     my $err = $@;
2051
2052     # Wait for rsync's children to release dest so that
2053     # consequent file operations (umount, remove) are possible
2054     while ((system {"fuser"} "fuser",  "-s", $dest) == 0) {sleep 1};
2055
2056     foreach my $mount (reverse @mounted) {
2057         eval { PVE::Tools::run_command(['/bin/umount', $mount], errfunc => sub{})};
2058         warn "Can't umount $mount\n" if $@;
2059     }
2060
2061     # If this fails they're used as mount points in a concurrent operation
2062     # (which should not happen but there's also no real need to get rid of them).
2063     rmdir $dest;
2064     rmdir $src;
2065
2066     die $err if $err;
2067 };
2068
2069 # Should not be called after unsharing the mount namespace!
2070 sub copy_volume {
2071     my ($mp, $vmid, $storage, $storage_cfg, $conf, $snapname, $bwlimit) = @_;
2072
2073     die "cannot copy volumes of type $mp->{type}\n" if $mp->{type} ne 'volume';
2074     File::Path::make_path("/var/lib/lxc/$vmid");
2075     my $dest = "/var/lib/lxc/$vmid/.copy-volume-1";
2076     my $src  = "/var/lib/lxc/$vmid/.copy-volume-2";
2077
2078     # get id's for unprivileged container
2079     my (undef, $rootuid, $rootgid) = parse_id_maps($conf);
2080
2081     # Allocate the disk before unsharing in order to make sure zfs subvolumes
2082     # are visible in this namespace, otherwise the host only sees the empty
2083     # (not-mounted) directory.
2084     my $new_volid;
2085     eval {
2086         # Make sure $mp contains a correct size.
2087         $mp->{size} = PVE::Storage::volume_size_info($storage_cfg, $mp->{volume});
2088         my $needs_chown;
2089         ($new_volid, $needs_chown) = alloc_disk($storage_cfg, $vmid, $storage, $mp->{size}/1024, $rootuid, $rootgid);
2090         if ($needs_chown) {
2091             PVE::Storage::activate_volumes($storage_cfg, [$new_volid], undef);
2092             my $path = PVE::Storage::path($storage_cfg, $new_volid, undef);
2093             chown($rootuid, $rootgid, $path);
2094         }
2095
2096         run_unshared(sub {
2097             $copy_volume->($mp->{volume}, $src, $new_volid, $dest, $storage_cfg, $snapname, $bwlimit, $rootuid, $rootgid);
2098         });
2099     };
2100     if (my $err = $@) {
2101         PVE::Storage::vdisk_free($storage_cfg, $new_volid)
2102             if defined($new_volid);
2103         die $err;
2104     }
2105
2106     return $new_volid;
2107 }
2108
2109 1;