src/PVE/LXC.pm

   1 package PVE::LXC;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(EINTR);
   6
   7 use File::Path;
   8 use Fcntl ':flock';
   9
  10 use PVE::Cluster qw(cfs_register_file cfs_read_file);
  11 use PVE::Storage;
  12 use PVE::SafeSyslog;
  13 use PVE::INotify;
  14 use PVE::JSONSchema qw(get_standard_option);
  15 use PVE::Tools qw($IPV6RE $IPV4RE dir_glob_foreach);
  16 use PVE::Network;
  17 use PVE::AccessControl;
  18
  19 use Data::Dumper;
  20
  21 my $nodename = PVE::INotify::nodename();
  22
  23 cfs_register_file('/lxc/', \&parse_pct_config, \&write_pct_config);
  24
  25 PVE::JSONSchema::register_format('pve-lxc-network', \&verify_lxc_network);
  26 sub verify_lxc_network {
  27     my ($value, $noerr) = @_;
  28
  29     return $value if parse_lxc_network($value);
  30
  31     return undef if $noerr;
  32
  33     die "unable to parse network setting\n";
  34 }
  35
  36 PVE::JSONSchema::register_format('pve-ct-mountpoint', \&verify_ct_mountpoint);
  37 sub verify_ct_mountpoint {
  38     my ($value, $noerr) = @_;
  39
  40     return $value if parse_ct_mountpoint($value);
  41
  42     return undef if $noerr;
  43
  44     die "unable to parse CT mountpoint options\n";
  45 }
  46
  47 PVE::JSONSchema::register_standard_option('pve-ct-rootfs', {
  48     type => 'string', format => 'pve-ct-mountpoint',
  49     typetext => '[volume=]volume,] [,backup=yes|no] [,size=\d+]',
  50     description => "Use volume as container root.",
  51     optional => 1,
  52 });
  53
  54 PVE::JSONSchema::register_standard_option('pve-lxc-snapshot-name', {
  55     description => "The name of the snapshot.",
  56     type => 'string', format => 'pve-configid',
  57     maxLength => 40,
  58 });
  59
  60 my $confdesc = {
  61     lock => {
  62         optional => 1,
  63         type => 'string',
  64         description => "Lock/unlock the VM.",
  65         enum => [qw(migrate backup snapshot rollback)],
  66     },
  67     onboot => {
  68         optional => 1,
  69         type => 'boolean',
  70         description => "Specifies whether a VM will be started during system bootup.",
  71         default => 0,
  72     },
  73     startup => get_standard_option('pve-startup-order'),
  74     template => {
  75         optional => 1,
  76         type => 'boolean',
  77         description => "Enable/disable Template.",
  78         default => 0,
  79     },
  80     arch => {
  81         optional => 1,
  82         type => 'string',
  83         enum => ['amd64', 'i386'],
  84         description => "OS architecture type.",
  85         default => 'amd64',
  86     },
  87     ostype => {
  88         optional => 1,
  89         type => 'string',
  90         enum => ['debian', 'ubuntu', 'centos'],
  91         description => "OS type. Corresponds to lxc setup scripts in /usr/share/lxc/config/<ostype>.common.conf.",
  92     },
  93     console => {
  94         optional => 1,
  95         type => 'boolean',
  96         description => "Attach a console device (/dev/console) to the container.",
  97         default => 1,
  98     },
  99     tty => {
 100         optional => 1,
 101         type => 'integer',
 102         description => "Specify the number of tty available to the container",
 103         minimum => 0,
 104         maximum => 6,
 105         default => 2,
 106     },
 107     cpulimit => {
 108         optional => 1,
 109         type => 'number',
 110         description => "Limit of CPU usage. Note if the computer has 2 CPUs, it has total of '2' CPU time. Value '0' indicates no CPU limit.",
 111         minimum => 0,
 112         maximum => 128,
 113         default => 0,
 114     },
 115     cpuunits => {
 116         optional => 1,
 117         type => 'integer',
 118         description => "CPU weight for a VM. Argument is used in the kernel fair scheduler. The larger the number is, the more CPU time this VM gets. Number is relative to weights of all the other running VMs.\n\nNOTE: You can disable fair-scheduler configuration by setting this to 0.",
 119         minimum => 0,
 120         maximum => 500000,
 121         default => 1024,
 122     },
 123     memory => {
 124         optional => 1,
 125         type => 'integer',
 126         description => "Amount of RAM for the VM in MB.",
 127         minimum => 16,
 128         default => 512,
 129     },
 130     swap => {
 131         optional => 1,
 132         type => 'integer',
 133         description => "Amount of SWAP for the VM in MB.",
 134         minimum => 0,
 135         default => 512,
 136     },
 137     hostname => {
 138         optional => 1,
 139         description => "Set a host name for the container.",
 140         type => 'string',
 141         maxLength => 255,
 142     },
 143     description => {
 144         optional => 1,
 145         type => 'string',
 146         description => "Container description. Only used on the configuration web interface.",
 147     },
 148     searchdomain => {
 149         optional => 1,
 150         type => 'string',
 151         description => "Sets DNS search domains for a container. Create will automatically use the setting from the host if you neither set searchdomain or nameserver.",
 152     },
 153     nameserver => {
 154         optional => 1,
 155         type => 'string',
 156         description => "Sets DNS server IP address for a container. Create will automatically use the setting from the host if you neither set searchdomain or nameserver.",
 157     },
 158     rootfs => get_standard_option('pve-ct-rootfs'),
 159     parent => {
 160         optional => 1,
 161         type => 'string', format => 'pve-configid',
 162         maxLength => 40,
 163         description => "Parent snapshot name. This is used internally, and should not be modified.",
 164     },
 165     snaptime => {
 166         optional => 1,
 167         description => "Timestamp for snapshots.",
 168         type => 'integer',
 169         minimum => 0,
 170     },
 171     cmode => {
 172         optional => 1,
 173         description => "Console mode. By default, the console command tries to open a connection to one of the available tty devices. By setting cmode to 'console' it tries to attach to /dev/console instead. If you set cmode to 'shell', it simply invokes a shell inside the container (no login).",
 174         type => 'string',
 175         enum => ['shell', 'console', 'tty'],
 176         default => 'tty',
 177     },
 178 };
 179
 180 my $valid_lxc_conf_keys = {
 181     'lxc.include' => 1,
 182     'lxc.arch' => 1,
 183     'lxc.utsname' => 1,
 184     'lxc.haltsignal' => 1,
 185     'lxc.rebootsignal' => 1,
 186     'lxc.stopsignal' => 1,
 187     'lxc.init_cmd' => 1,
 188     'lxc.network.type' => 1,
 189     'lxc.network.flags' => 1,
 190     'lxc.network.link' => 1,
 191     'lxc.network.mtu' => 1,
 192     'lxc.network.name' => 1,
 193     'lxc.network.hwaddr' => 1,
 194     'lxc.network.ipv4' => 1,
 195     'lxc.network.ipv4.gateway' => 1,
 196     'lxc.network.ipv6' => 1,
 197     'lxc.network.ipv6.gateway' => 1,
 198     'lxc.network.script.up' => 1,
 199     'lxc.network.script.down' => 1,
 200     'lxc.pts' => 1,
 201     'lxc.console.logfile' => 1,
 202     'lxc.console' => 1,
 203     'lxc.tty' => 1,
 204     'lxc.devttydir' => 1,
 205     'lxc.hook.autodev' => 1,
 206     'lxc.autodev' => 1,
 207     'lxc.kmsg' => 1,
 208     'lxc.mount' => 1,
 209     'lxc.mount.entry' => 1,
 210     'lxc.mount.auto' => 1,
 211     'lxc.rootfs' => 1,
 212     'lxc.rootfs.mount' => 1,
 213     'lxc.rootfs.options' => 1,
 214     # lxc.cgroup.*
 215     'lxc.cap.drop' => 1,
 216     'lxc.cap.keep' => 1,
 217     'lxc.aa_profile' => 1,
 218     'lxc.aa_allow_incomplete' => 1,
 219     'lxc.se_context' => 1,
 220     'lxc.seccomp' => 1,
 221     'lxc.id_map' => 1,
 222     'lxc.hook.pre-start' => 1,
 223     'lxc.hook.pre-mount' => 1,
 224     'lxc.hook.mount' => 1,
 225     'lxc.hook.start' => 1,
 226     'lxc.hook.post-stop' => 1,
 227     'lxc.hook.clone' => 1,
 228     'lxc.hook.destroy' => 1,
 229     'lxc.loglevel' => 1,
 230     'lxc.logfile' => 1,
 231     'lxc.start.auto' => 1,
 232     'lxc.start.delay' => 1,
 233     'lxc.start.order' => 1,
 234     'lxc.group' => 1,
 235     'lxc.environment' => 1,
 236     'lxc.' => 1,
 237     'lxc.' => 1,
 238     'lxc.' => 1,
 239     'lxc.' => 1,
 240 };
 241
 242 my $MAX_LXC_NETWORKS = 10;
 243 for (my $i = 0; $i < $MAX_LXC_NETWORKS; $i++) {
 244     $confdesc->{"net$i"} = {
 245         optional => 1,
 246         type => 'string', format => 'pve-lxc-network',
 247         description => "Specifies network interfaces for the container.\n\n".
 248             "The string should have the follow format:\n\n".
 249             "-net<[0-9]> bridge=<vmbr<Nummber>>[,hwaddr=<MAC>]\n".
 250             "[,mtu=<Number>][,name=<String>][,ip=<IPv4Format/CIDR>]\n".
 251             ",ip6=<IPv6Format/CIDR>][,gw=<GatwayIPv4>]\n".
 252             ",gw6=<GatwayIPv6>][,firewall=<[1|0]>][,tag=<VlanNo>]",
 253     };
 254 }
 255
 256 my $MAX_MOUNT_POINTS = 10;
 257 for (my $i = 0; $i < $MAX_MOUNT_POINTS; $i++) {
 258     $confdesc->{"mp$i"} = {
 259         optional => 1,
 260         type => 'string', format => 'pve-ct-mountpoint',
 261         typetext => '[volume=]volume,] [,backup=yes|no] [,size=\d+] [,mp=mountpoint]',
 262         description => "Use volume as container mount point (experimental feature).",
 263         optional => 1,
 264     };
 265 }
 266
 267 sub write_pct_config {
 268     my ($filename, $conf) = @_;
 269
 270     delete $conf->{snapstate}; # just to be sure
 271
 272     my $generate_raw_config = sub {
 273         my ($conf) = @_;
 274
 275         my $raw = '';
 276
 277         # add description as comment to top of file
 278         my $descr = $conf->{description} || '';
 279         foreach my $cl (split(/\n/, $descr)) {
 280             $raw .= '#' .  PVE::Tools::encode_text($cl) . "\n";
 281         }
 282
 283         foreach my $key (sort keys %$conf) {
 284             next if $key eq 'digest' || $key eq 'description' || $key eq 'pending' ||
 285                 $key eq 'snapshots' || $key eq 'snapname' || $key eq 'lxc';
 286             $raw .= "$key: $conf->{$key}\n";
 287         }
 288
 289         if (my $lxcconf = $conf->{lxc}) {
 290             foreach my $entry (@$lxcconf) {
 291                 my ($k, $v) = @$entry;
 292                 $raw .= "$k: $v\n";
 293             }
 294         }
 295
 296         return $raw;
 297     };
 298
 299     my $raw = &$generate_raw_config($conf);
 300
 301     foreach my $snapname (sort keys %{$conf->{snapshots}}) {
 302         $raw .= "\n[$snapname]\n";
 303         $raw .= &$generate_raw_config($conf->{snapshots}->{$snapname});
 304     }
 305
 306     return $raw;
 307 }
 308
 309 sub check_type {
 310     my ($key, $value) = @_;
 311
 312     die "unknown setting '$key'\n" if !$confdesc->{$key};
 313
 314     my $type = $confdesc->{$key}->{type};
 315
 316     if (!defined($value)) {
 317         die "got undefined value\n";
 318     }
 319
 320     if ($value =~ m/[\n\r]/) {
 321         die "property contains a line feed\n";
 322     }
 323
 324     if ($type eq 'boolean') {
 325         return 1 if ($value eq '1') || ($value =~ m/^(on|yes|true)$/i);
 326         return 0 if ($value eq '0') || ($value =~ m/^(off|no|false)$/i);
 327         die "type check ('boolean') failed - got '$value'\n";
 328     } elsif ($type eq 'integer') {
 329         return int($1) if $value =~ m/^(\d+)$/;
 330         die "type check ('integer') failed - got '$value'\n";
 331     } elsif ($type eq 'number') {
 332         return $value if $value =~ m/^(\d+)(\.\d+)?$/;
 333         die "type check ('number') failed - got '$value'\n";
 334     } elsif ($type eq 'string') {
 335         if (my $fmt = $confdesc->{$key}->{format}) {
 336             PVE::JSONSchema::check_format($fmt, $value);
 337             return $value;
 338         }
 339         return $value;
 340     } else {
 341         die "internal error"
 342     }
 343 }
 344
 345 sub parse_pct_config {
 346     my ($filename, $raw) = @_;
 347
 348     return undef if !defined($raw);
 349
 350     my $res = {
 351         digest => Digest::SHA::sha1_hex($raw),
 352         snapshots => {},
 353     };
 354
 355     $filename =~ m|/lxc/(\d+).conf$|
 356         || die "got strange filename '$filename'";
 357
 358     my $vmid = $1;
 359
 360     my $conf = $res;
 361     my $descr = '';
 362     my $section = '';
 363
 364     my @lines = split(/\n/, $raw);
 365     foreach my $line (@lines) {
 366         next if $line =~ m/^\s*$/;
 367
 368         if ($line =~ m/^\[([a-z][a-z0-9_\-]+)\]\s*$/i) {
 369             $section = $1;
 370             $conf->{description} = $descr if $descr;
 371             $descr = '';
 372             $conf = $res->{snapshots}->{$section} = {};
 373             next;
 374         }
 375
 376         if ($line =~ m/^\#(.*)\s*$/) {
 377             $descr .= PVE::Tools::decode_text($1) . "\n";
 378             next;
 379         }
 380
 381         if ($line =~ m/^(lxc\.[a-z0-9\.]+)(:|\s*=)\s*(.*?)\s*$/) {
 382             my $key = $1;
 383             my $value = $3;
 384             if ($valid_lxc_conf_keys->{$key} || $key =~ m/^lxc\.cgroup\./) {
 385                 push @{$conf->{lxc}}, [$key, $value];
 386             } else {
 387                 warn "vm $vmid - unable to parse config: $line\n";
 388             }
 389         } elsif ($line =~ m/^(description):\s*(.*\S)\s*$/) {
 390             $descr .= PVE::Tools::decode_text($2);
 391         } elsif ($line =~ m/snapstate:\s*(prepare|delete)\s*$/) {
 392             $conf->{snapstate} = $1;
 393         } elsif ($line =~ m/^([a-z][a-z_]*\d*):\s*(\S+)\s*$/) {
 394             my $key = $1;
 395             my $value = $2;
 396             eval { $value = check_type($key, $value); };
 397             warn "vm $vmid - unable to parse value of '$key' - $@" if $@;
 398             $conf->{$key} = $value;
 399         } else {
 400             warn "vm $vmid - unable to parse config: $line\n";
 401         }
 402     }
 403
 404     $conf->{description} = $descr if $descr;
 405
 406     delete $res->{snapstate}; # just to be sure
 407
 408     return $res;
 409 }
 410
 411 sub config_list {
 412     my $vmlist = PVE::Cluster::get_vmlist();
 413     my $res = {};
 414     return $res if !$vmlist || !$vmlist->{ids};
 415     my $ids = $vmlist->{ids};
 416
 417     foreach my $vmid (keys %$ids) {
 418         next if !$vmid; # skip CT0
 419         my $d = $ids->{$vmid};
 420         next if !$d->{node} || $d->{node} ne $nodename;
 421         next if !$d->{type} || $d->{type} ne 'lxc';
 422         $res->{$vmid}->{type} = 'lxc';
 423     }
 424     return $res;
 425 }
 426
 427 sub cfs_config_path {
 428     my ($vmid, $node) = @_;
 429
 430     $node = $nodename if !$node;
 431     return "nodes/$node/lxc/$vmid.conf";
 432 }
 433
 434 sub config_file {
 435     my ($vmid, $node) = @_;
 436
 437     my $cfspath = cfs_config_path($vmid, $node);
 438     return "/etc/pve/$cfspath";
 439 }
 440
 441 sub load_config {
 442     my ($vmid, $node) = @_;
 443
 444     $node = $nodename if !$node;
 445     my $cfspath = cfs_config_path($vmid, $node);
 446
 447     my $conf = PVE::Cluster::cfs_read_file($cfspath);
 448     die "container $vmid does not exists\n" if !defined($conf);
 449
 450     return $conf;
 451 }
 452
 453 sub create_config {
 454     my ($vmid, $conf) = @_;
 455
 456     my $dir = "/etc/pve/nodes/$nodename/lxc";
 457     mkdir $dir;
 458
 459     write_config($vmid, $conf);
 460 }
 461
 462 sub destroy_config {
 463     my ($vmid) = @_;
 464
 465     unlink config_file($vmid, $nodename);
 466 }
 467
 468 sub write_config {
 469     my ($vmid, $conf) = @_;
 470
 471     my $cfspath = cfs_config_path($vmid);
 472
 473     PVE::Cluster::cfs_write_file($cfspath, $conf);
 474 }
 475
 476 # flock: we use one file handle per process, so lock file
 477 # can be called multiple times and succeeds for the same process.
 478
 479 my $lock_handles =  {};
 480 my $lockdir = "/run/lock/lxc";
 481
 482 sub lock_filename {
 483     my ($vmid) = @_;
 484
 485     return "$lockdir/pve-config-{$vmid}.lock";
 486 }
 487
 488 sub lock_aquire {
 489     my ($vmid, $timeout) = @_;
 490
 491     $timeout = 10 if !$timeout;
 492     my $mode = LOCK_EX;
 493
 494     my $filename = lock_filename($vmid);
 495
 496     mkdir $lockdir if !-d $lockdir;
 497
 498     my $lock_func = sub {
 499         if (!$lock_handles->{$$}->{$filename}) {
 500             my $fh = new IO::File(">>$filename") ||
 501                 die "can't open file - $!\n";
 502             $lock_handles->{$$}->{$filename} = { fh => $fh, refcount => 0};
 503         }
 504
 505         if (!flock($lock_handles->{$$}->{$filename}->{fh}, $mode |LOCK_NB)) {
 506             print STDERR "trying to aquire lock...";
 507             my $success;
 508             while(1) {
 509                 $success = flock($lock_handles->{$$}->{$filename}->{fh}, $mode);
 510                 # try again on EINTR (see bug #273)
 511                 if ($success || ($! != EINTR)) {
 512                     last;
 513                 }
 514             }
 515             if (!$success) {
 516                 print STDERR " failed\n";
 517                 die "can't aquire lock - $!\n";
 518             }
 519
 520             $lock_handles->{$$}->{$filename}->{refcount}++;
 521
 522             print STDERR " OK\n";
 523         }
 524     };
 525
 526     eval { PVE::Tools::run_with_timeout($timeout, $lock_func); };
 527     my $err = $@;
 528     if ($err) {
 529         die "can't lock file '$filename' - $err";
 530     }
 531 }
 532
 533 sub lock_release {
 534     my ($vmid) = @_;
 535
 536     my $filename = lock_filename($vmid);
 537
 538     if (my $fh = $lock_handles->{$$}->{$filename}->{fh}) {
 539         my $refcount = --$lock_handles->{$$}->{$filename}->{refcount};
 540         if ($refcount <= 0) {
 541             $lock_handles->{$$}->{$filename} = undef;
 542             close ($fh);
 543         }
 544     }
 545 }
 546
 547 sub lock_container {
 548     my ($vmid, $timeout, $code, @param) = @_;
 549
 550     my $res;
 551
 552     lock_aquire($vmid, $timeout);
 553     eval { $res = &$code(@param) };
 554     my $err = $@;
 555     lock_release($vmid);
 556
 557     die $err if $err;
 558
 559     return $res;
 560 }
 561
 562 sub option_exists {
 563     my ($name) = @_;
 564
 565     return defined($confdesc->{$name});
 566 }
 567
 568 # add JSON properties for create and set function
 569 sub json_config_properties {
 570     my $prop = shift;
 571
 572     foreach my $opt (keys %$confdesc) {
 573         next if $opt eq 'parent' || $opt eq 'snaptime';
 574         next if $prop->{$opt};
 575         $prop->{$opt} = $confdesc->{$opt};
 576     }
 577
 578     return $prop;
 579 }
 580
 581 sub json_config_properties_no_rootfs {
 582     my $prop = shift;
 583
 584     foreach my $opt (keys %$confdesc) {
 585         next if $prop->{$opt};
 586         next if $opt eq 'parent' || $opt eq 'snaptime' || $opt eq 'rootfs';
 587         $prop->{$opt} = $confdesc->{$opt};
 588     }
 589
 590     return $prop;
 591 }
 592
 593 # container status helpers
 594
 595 sub list_active_containers {
 596
 597     my $filename = "/proc/net/unix";
 598
 599     # similar test is used by lcxcontainers.c: list_active_containers
 600     my $res = {};
 601
 602     my $fh = IO::File->new ($filename, "r");
 603     return $res if !$fh;
 604
 605     while (defined(my $line = <$fh>)) {
 606         if ($line =~ m/^[a-f0-9]+:\s\S+\s\S+\s\S+\s\S+\s\S+\s\d+\s(\S+)$/) {
 607             my $path = $1;
 608             if ($path =~ m!^@/var/lib/lxc/(\d+)/command$!) {
 609                 $res->{$1} = 1;
 610             }
 611         }
 612     }
 613
 614     close($fh);
 615
 616     return $res;
 617 }
 618
 619 # warning: this is slow
 620 sub check_running {
 621     my ($vmid) = @_;
 622
 623     my $active_hash = list_active_containers();
 624
 625     return 1 if defined($active_hash->{$vmid});
 626
 627     return undef;
 628 }
 629
 630 sub get_container_disk_usage {
 631     my ($vmid) = @_;
 632
 633     my $cmd = ['lxc-attach', '-n', $vmid, '--', 'df',  '-P', '-B', '1', '/'];
 634
 635     my $res = {
 636         total => 0,
 637         used => 0,
 638         avail => 0,
 639     };
 640
 641     my $parser = sub {
 642         my $line = shift;
 643         if (my ($fsid, $total, $used, $avail) = $line =~
 644             m/^(\S+.*)\s+(\d+)\s+(\d+)\s+(\d+)\s+\d+%\s.*$/) {
 645             $res = {
 646                 total => $total,
 647                 used => $used,
 648                 avail => $avail,
 649             };
 650         }
 651     };
 652     eval { PVE::Tools::run_command($cmd, timeout => 1, outfunc => $parser); };
 653     warn $@ if $@;
 654
 655     return $res;
 656 }
 657
 658 sub vmstatus {
 659     my ($opt_vmid) = @_;
 660
 661     my $list = $opt_vmid ? { $opt_vmid => { type => 'lxc' }} : config_list();
 662
 663     my $active_hash = list_active_containers();
 664
 665     foreach my $vmid (keys %$list) {
 666         my $d = $list->{$vmid};
 667
 668         my $running = defined($active_hash->{$vmid});
 669
 670         $d->{status} = $running ? 'running' : 'stopped';
 671
 672         my $cfspath = cfs_config_path($vmid);
 673         my $conf = PVE::Cluster::cfs_read_file($cfspath) || {};
 674
 675         $d->{name} = $conf->{'hostname'} || "CT$vmid";
 676         $d->{name} =~ s/[\s]//g;
 677
 678         $d->{cpus} = $conf->{cpulimit} // 0;
 679
 680         if ($running) {
 681             my $res = get_container_disk_usage($vmid);
 682             $d->{disk} = $res->{used};
 683             $d->{maxdisk} = $res->{total};
 684         } else {
 685             $d->{disk} = 0;
 686             # use 4GB by default ??
 687             if (my $rootfs = $conf->{rootfs}) {
 688                 my $rootinfo = parse_ct_mountpoint($rootfs);
 689                 $d->{maxdisk} = int(($rootinfo->{size} || 4)*1024*1024)*1024;
 690             } else {
 691                 $d->{maxdisk} = 4*1024*1024*1024;
 692             }
 693         }
 694
 695         $d->{mem} = 0;
 696         $d->{swap} = 0;
 697         $d->{maxmem} = ($conf->{memory}||512)*1024*1024;
 698         $d->{maxswap} = ($conf->{swap}//0)*1024*1024;
 699
 700         $d->{uptime} = 0;
 701         $d->{cpu} = 0;
 702
 703         $d->{netout} = 0;
 704         $d->{netin} = 0;
 705
 706         $d->{diskread} = 0;
 707         $d->{diskwrite} = 0;
 708
 709         $d->{template} = is_template($conf);
 710     }
 711
 712     foreach my $vmid (keys %$list) {
 713         my $d = $list->{$vmid};
 714         next if $d->{status} ne 'running';
 715
 716         $d->{uptime} = 100; # fixme:
 717
 718         $d->{mem} = read_cgroup_value('memory', $vmid, 'memory.usage_in_bytes');
 719         $d->{swap} = read_cgroup_value('memory', $vmid, 'memory.memsw.usage_in_bytes') - $d->{mem};
 720
 721         my $blkio_bytes = read_cgroup_value('blkio', $vmid, 'blkio.throttle.io_service_bytes', 1);
 722         my @bytes = split(/\n/, $blkio_bytes);
 723         foreach my $byte (@bytes) {
 724             if (my ($key, $value) = $byte =~ /(Read|Write)\s+(\d+)/) {
 725                 $d->{diskread} = $2 if $key eq 'Read';
 726                 $d->{diskwrite} = $2 if $key eq 'Write';
 727             }
 728         }
 729     }
 730
 731     return $list;
 732 }
 733
 734 my $parse_size = sub {
 735     my ($value) = @_;
 736
 737     return undef if $value !~ m/^(\d+(\.\d+)?)([KMG])?$/;
 738     my ($size, $unit) = ($1, $3);
 739     if ($unit) {
 740         if ($unit eq 'K') {
 741             $size = $size * 1024;
 742         } elsif ($unit eq 'M') {
 743             $size = $size * 1024 * 1024;
 744         } elsif ($unit eq 'G') {
 745             $size = $size * 1024 * 1024 * 1024;
 746         }
 747     }
 748     return int($size);
 749 };
 750
 751 sub parse_ct_mountpoint {
 752     my ($data) = @_;
 753
 754     $data //= '';
 755
 756     my $res = {};
 757
 758     foreach my $p (split (/,/, $data)) {
 759         next if $p =~ m/^\s*$/;
 760
 761         if ($p =~ m/^(volume|backup|size|mp)=(.+)$/) {
 762             my ($k, $v) = ($1, $2);
 763             return undef if defined($res->{$k});
 764             $res->{$k} = $v;
 765         } else {
 766             if (!$res->{volume} && $p !~ m/=/) {
 767                 $res->{volume} = $p;
 768             } else {
 769                 return undef;
 770             }
 771         }
 772     }
 773
 774     return undef if !$res->{volume};
 775
 776     return undef if $res->{backup} && $res->{backup} !~ m/^(yes|no)$/;
 777
 778     if ($res->{size}) {
 779         return undef if !defined($res->{size} = &$parse_size($res->{size}));
 780     }
 781
 782     return $res;
 783 }
 784
 785 sub print_ct_mountpoint {
 786     my ($info) = @_;
 787
 788     my $opts = '';
 789
 790     die "missing volume\n" if !$info->{volume};
 791
 792     foreach my $o ('size', 'backup') {
 793         $opts .= ",$o=$info->{$o}" if defined($info->{$o});
 794     }
 795
 796     return "$info->{volume}$opts";
 797 }
 798
 799 sub print_lxc_network {
 800     my $net = shift;
 801
 802     die "no network name defined\n" if !$net->{name};
 803
 804     my $res = "name=$net->{name}";
 805
 806     foreach my $k (qw(hwaddr mtu bridge ip gw ip6 gw6 firewall tag)) {
 807         next if !defined($net->{$k});
 808         $res .= ",$k=$net->{$k}";
 809     }
 810
 811     return $res;
 812 }
 813
 814 sub parse_lxc_network {
 815     my ($data) = @_;
 816
 817     my $res = {};
 818
 819     return $res if !$data;
 820
 821     foreach my $pv (split (/,/, $data)) {
 822         if ($pv =~ m/^(bridge|hwaddr|mtu|name|ip|ip6|gw|gw6|firewall|tag)=(\S+)$/) {
 823             $res->{$1} = $2;
 824         } else {
 825             return undef;
 826         }
 827     }
 828
 829     $res->{type} = 'veth';
 830     $res->{hwaddr} = PVE::Tools::random_ether_addr() if !$res->{hwaddr};
 831
 832     return $res;
 833 }
 834
 835 sub read_cgroup_value {
 836     my ($group, $vmid, $name, $full) = @_;
 837
 838     my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 839
 840     return PVE::Tools::file_get_contents($path) if $full;
 841
 842     return PVE::Tools::file_read_firstline($path);
 843 }
 844
 845 sub write_cgroup_value {
 846    my ($group, $vmid, $name, $value) = @_;
 847
 848    my $path = "/sys/fs/cgroup/$group/lxc/$vmid/$name";
 849    PVE::ProcFSTools::write_proc_entry($path, $value) if -e $path;
 850
 851 }
 852
 853 sub find_lxc_console_pids {
 854
 855     my $res = {};
 856
 857     PVE::Tools::dir_glob_foreach('/proc', '\d+', sub {
 858         my ($pid) = @_;
 859
 860         my $cmdline = PVE::Tools::file_read_firstline("/proc/$pid/cmdline");
 861         return if !$cmdline;
 862
 863         my @args = split(/\0/, $cmdline);
 864
 865         # serach for lxc-console -n <vmid>
 866         return if scalar(@args) != 3;
 867         return if $args[1] ne '-n';
 868         return if $args[2] !~ m/^\d+$/;
 869         return if $args[0] !~ m|^(/usr/bin/)?lxc-console$|;
 870
 871         my $vmid = $args[2];
 872
 873         push @{$res->{$vmid}}, $pid;
 874     });
 875
 876     return $res;
 877 }
 878
 879 sub find_lxc_pid {
 880     my ($vmid) = @_;
 881
 882     my $pid = undef;
 883     my $parser = sub {
 884         my $line = shift;
 885         $pid = $1 if $line =~ m/^PID:\s+(\d+)$/;
 886     };
 887     PVE::Tools::run_command(['lxc-info', '-n', $vmid], outfunc => $parser);
 888
 889     die "unable to get PID for CT $vmid (not running?)\n" if !$pid;
 890
 891     return $pid;
 892 }
 893
 894 my $ipv4_reverse_mask = [
 895     '0.0.0.0',
 896     '128.0.0.0',
 897     '192.0.0.0',
 898     '224.0.0.0',
 899     '240.0.0.0',
 900     '248.0.0.0',
 901     '252.0.0.0',
 902     '254.0.0.0',
 903     '255.0.0.0',
 904     '255.128.0.0',
 905     '255.192.0.0',
 906     '255.224.0.0',
 907     '255.240.0.0',
 908     '255.248.0.0',
 909     '255.252.0.0',
 910     '255.254.0.0',
 911     '255.255.0.0',
 912     '255.255.128.0',
 913     '255.255.192.0',
 914     '255.255.224.0',
 915     '255.255.240.0',
 916     '255.255.248.0',
 917     '255.255.252.0',
 918     '255.255.254.0',
 919     '255.255.255.0',
 920     '255.255.255.128',
 921     '255.255.255.192',
 922     '255.255.255.224',
 923     '255.255.255.240',
 924     '255.255.255.248',
 925     '255.255.255.252',
 926     '255.255.255.254',
 927     '255.255.255.255',
 928 ];
 929
 930 # Note: we cannot use Net:IP, because that only allows strict
 931 # CIDR networks
 932 sub parse_ipv4_cidr {
 933     my ($cidr, $noerr) = @_;
 934
 935     if ($cidr =~ m!^($IPV4RE)(?:/(\d+))$! && ($2 > 7) &&  ($2 < 32)) {
 936         return { address => $1, netmask => $ipv4_reverse_mask->[$2] };
 937     }
 938
 939     return undef if $noerr;
 940
 941     die "unable to parse ipv4 address/mask\n";
 942 }
 943
 944 sub check_lock {
 945     my ($conf) = @_;
 946
 947     die "VM is locked ($conf->{'lock'})\n" if $conf->{'lock'};
 948 }
 949
 950 sub update_lxc_config {
 951     my ($storage_cfg, $vmid, $conf) = @_;
 952
 953     my $dir = "/var/lib/lxc/$vmid";
 954
 955     if ($conf->{template}) {
 956
 957         unlink "$dir/config";
 958
 959         return;
 960     }
 961
 962     my $raw = '';
 963
 964     die "missing 'arch' - internal error" if !$conf->{arch};
 965     $raw .= "lxc.arch = $conf->{arch}\n";
 966
 967     my $ostype = $conf->{ostype} || die "missing 'ostype' - internal error";
 968     if ($ostype =~ /^(?:debian | ubuntu | centos | archlinux)$/x) {
 969         $raw .= "lxc.include = /usr/share/lxc/config/$ostype.common.conf\n";
 970     } else {
 971         die "implement me";
 972     }
 973
 974     if (!has_dev_console($conf)) {
 975         $raw .= "lxc.console = none\n";
 976         $raw .= "lxc.cgroup.devices.deny = c 5:1 rwm\n";
 977     }
 978
 979     my $ttycount = get_tty_count($conf);
 980     $raw .= "lxc.tty = $ttycount\n";
 981
 982     my $utsname = $conf->{hostname} || "CT$vmid";
 983     $raw .= "lxc.utsname = $utsname\n";
 984
 985     my $memory = $conf->{memory} || 512;
 986     my $swap = $conf->{swap} // 0;
 987
 988     my $lxcmem = int($memory*1024*1024);
 989     $raw .= "lxc.cgroup.memory.limit_in_bytes = $lxcmem\n";
 990
 991     my $lxcswap = int(($memory + $swap)*1024*1024);
 992     $raw .= "lxc.cgroup.memory.memsw.limit_in_bytes = $lxcswap\n";
 993
 994     if (my $cpulimit = $conf->{cpulimit}) {
 995         $raw .= "lxc.cgroup.cpu.cfs_period_us = 100000\n";
 996         my $value = int(100000*$cpulimit);
 997         $raw .= "lxc.cgroup.cpu.cfs_quota_us = $value\n";
 998     }
 999
1000     my $shares = $conf->{cpuunits} || 1024;
1001     $raw .= "lxc.cgroup.cpu.shares = $shares\n";
1002
1003     my $mountpoint = parse_ct_mountpoint($conf->{rootfs});
1004     my $volid = $mountpoint->{volume};
1005     my $path = volid_path ($volid, $storage_cfg);
1006     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1007
1008     if ($storage) {
1009         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1010         $path = "loop:$path" if $scfg->{path};
1011     }
1012
1013     $raw .= "lxc.rootfs = $path\n";
1014
1015     my $netcount = 0;
1016     foreach my $k (keys %$conf) {
1017         next if $k !~ m/^net(\d+)$/;
1018         my $ind = $1;
1019         my $d = parse_lxc_network($conf->{$k});
1020         $netcount++;
1021         $raw .= "lxc.network.type = veth\n";
1022         $raw .= "lxc.network.veth.pair = veth${vmid}i${ind}\n";
1023         $raw .= "lxc.network.hwaddr = $d->{hwaddr}\n" if defined($d->{hwaddr});
1024         $raw .= "lxc.network.name = $d->{name}\n" if defined($d->{name});
1025         $raw .= "lxc.network.mtu = $d->{mtu}\n" if defined($d->{mtu});
1026     }
1027
1028     if (my $lxcconf = $conf->{lxc}) {
1029         foreach my $entry (@$lxcconf) {
1030             my ($k, $v) = @$entry;
1031             $netcount++ if $k eq 'lxc.network.type';
1032             $raw .= "$k = $v\n";
1033         }
1034     }
1035
1036     $raw .= "lxc.network.type = empty\n" if !$netcount;
1037
1038     File::Path::mkpath("$dir/rootfs");
1039
1040     PVE::Tools::file_set_contents("$dir/config", $raw);
1041 }
1042
1043 # verify and cleanup nameserver list (replace \0 with ' ')
1044 sub verify_nameserver_list {
1045     my ($nameserver_list) = @_;
1046
1047     my @list = ();
1048     foreach my $server (PVE::Tools::split_list($nameserver_list)) {
1049         PVE::JSONSchema::pve_verify_ip($server);
1050         push @list, $server;
1051     }
1052
1053     return join(' ', @list);
1054 }
1055
1056 sub verify_searchdomain_list {
1057     my ($searchdomain_list) = @_;
1058
1059     my @list = ();
1060     foreach my $server (PVE::Tools::split_list($searchdomain_list)) {
1061         # todo: should we add checks for valid dns domains?
1062         push @list, $server;
1063     }
1064
1065     return join(' ', @list);
1066 }
1067
1068 sub update_pct_config {
1069     my ($vmid, $conf, $running, $param, $delete) = @_;
1070
1071     my @nohotplug;
1072
1073     my $rootdir;
1074     if ($running) {
1075         my $pid = find_lxc_pid($vmid);
1076         $rootdir = "/proc/$pid/root";
1077     }
1078
1079     if (defined($delete)) {
1080         foreach my $opt (@$delete) {
1081             if ($opt eq 'hostname' || $opt eq 'memory' || $opt eq 'rootfs') {
1082                 die "unable to delete required option '$opt'\n";
1083             } elsif ($opt eq 'swap') {
1084                 delete $conf->{$opt};
1085                 write_cgroup_value("memory", $vmid, "memory.memsw.limit_in_bytes", -1);
1086             } elsif ($opt eq 'description' || $opt eq 'onboot' || $opt eq 'startup') {
1087                 delete $conf->{$opt};
1088             } elsif ($opt eq 'nameserver' || $opt eq 'searchdomain' ||
1089                      $opt eq 'tty' || $opt eq 'console' || $opt eq 'cmode') {
1090                 delete $conf->{$opt};
1091                 push @nohotplug, $opt;
1092                 next if $running;
1093             } elsif ($opt =~ m/^net(\d)$/) {
1094                 delete $conf->{$opt};
1095                 next if !$running;
1096                 my $netid = $1;
1097                 PVE::Network::veth_delete("veth${vmid}i$netid");
1098             } else {
1099                 die "implement me"
1100             }
1101             PVE::LXC::write_config($vmid, $conf) if $running;
1102         }
1103     }
1104
1105     # There's no separate swap size to configure, there's memory and "total"
1106     # memory (iow. memory+swap). This means we have to change them together.
1107     my $wanted_memory = PVE::Tools::extract_param($param, 'memory');
1108     my $wanted_swap =  PVE::Tools::extract_param($param, 'swap');
1109     if (defined($wanted_memory) || defined($wanted_swap)) {
1110
1111         $wanted_memory //= ($conf->{memory} || 512);
1112         $wanted_swap //=  ($conf->{swap} || 0);
1113
1114         my $total = $wanted_memory + $wanted_swap;
1115         if ($running) {
1116             write_cgroup_value("memory", $vmid, "memory.limit_in_bytes", int($wanted_memory*1024*1024));
1117             write_cgroup_value("memory", $vmid, "memory.memsw.limit_in_bytes", int($total*1024*1024));
1118         }
1119         $conf->{memory} = $wanted_memory;
1120         $conf->{swap} = $wanted_swap;
1121
1122         PVE::LXC::write_config($vmid, $conf) if $running;
1123     }
1124
1125     foreach my $opt (keys %$param) {
1126         my $value = $param->{$opt};
1127         if ($opt eq 'hostname') {
1128             $conf->{$opt} = $value;
1129         } elsif ($opt eq 'onboot') {
1130             $conf->{$opt} = $value ? 1 : 0;
1131         } elsif ($opt eq 'startup') {
1132             $conf->{$opt} = $value;
1133         } elsif ($opt eq 'tty' || $opt eq 'console' || $opt eq 'cmode') {
1134             $conf->{$opt} = $value;
1135             push @nohotplug, $opt;
1136             next if $running;
1137         } elsif ($opt eq 'nameserver') {
1138             my $list = verify_nameserver_list($value);
1139             $conf->{$opt} = $list;
1140             push @nohotplug, $opt;
1141             next if $running;
1142         } elsif ($opt eq 'searchdomain') {
1143             my $list = verify_searchdomain_list($value);
1144             $conf->{$opt} = $list;
1145             push @nohotplug, $opt;
1146             next if $running;
1147         } elsif ($opt eq 'cpulimit') {
1148             $conf->{$opt} = $value;
1149             push @nohotplug, $opt; # fixme: hotplug
1150             next;
1151         } elsif ($opt eq 'cpuunits') {
1152             $conf->{$opt} = $value;
1153             write_cgroup_value("cpu", $vmid, "cpu.shares", $value);
1154         } elsif ($opt eq 'description') {
1155             $conf->{$opt} = PVE::Tools::encode_text($value);
1156         } elsif ($opt =~ m/^net(\d+)$/) {
1157             my $netid = $1;
1158             my $net = parse_lxc_network($value);
1159             if (!$running) {
1160                 $conf->{$opt} = print_lxc_network($net);
1161             } else {
1162                 update_net($vmid, $conf, $opt, $net, $netid, $rootdir);
1163             }
1164         } else {
1165             die "implement me: $opt";
1166         }
1167         PVE::LXC::write_config($vmid, $conf) if $running;
1168     }
1169
1170     if ($running && scalar(@nohotplug)) {
1171         die "unable to modify " . join(',', @nohotplug) . " while container is running\n";
1172     }
1173 }
1174
1175 sub has_dev_console {
1176     my ($conf) = @_;
1177
1178     return !(defined($conf->{console}) && !$conf->{console});
1179 }
1180
1181 sub get_tty_count {
1182     my ($conf) = @_;
1183
1184     return $conf->{tty} // $confdesc->{tty}->{default};
1185 }
1186
1187 sub get_cmode {
1188     my ($conf) = @_;
1189
1190     return $conf->{cmode} // $confdesc->{cmode}->{default};
1191 }
1192
1193 sub get_console_command {
1194     my ($vmid, $conf) = @_;
1195
1196     my $cmode = get_cmode($conf);
1197
1198     if ($cmode eq 'console') {
1199         return ['lxc-console', '-n',  $vmid, '-t', 0];
1200     } elsif ($cmode eq 'tty') {
1201         return ['lxc-console', '-n',  $vmid];
1202     } elsif ($cmode eq 'shell') {
1203         return ['lxc-attach', '--clear-env', '-n', $vmid];
1204     } else {
1205         die "internal error";
1206     }
1207 }
1208
1209 sub get_primary_ips {
1210     my ($conf) = @_;
1211
1212     # return data from net0
1213
1214     return undef if !defined($conf->{net0});
1215     my $net = parse_lxc_network($conf->{net0});
1216
1217     my $ipv4 = $net->{ip};
1218     if ($ipv4) {
1219         if ($ipv4 =~ /^(dhcp|manual)$/) {
1220             $ipv4 = undef
1221         } else {
1222             $ipv4 =~ s!/\d+$!!;
1223         }
1224     }
1225     my $ipv6 = $net->{ip6};
1226     if ($ipv6) {
1227         if ($ipv6 =~ /^(dhcp|manual)$/) {
1228             $ipv6 = undef;
1229         } else {
1230             $ipv6 =~ s!/\d+$!!;
1231         }
1232     }
1233
1234     return ($ipv4, $ipv6);
1235 }
1236
1237
1238 sub destroy_lxc_container {
1239     my ($storage_cfg, $vmid, $conf) = @_;
1240
1241     my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
1242     if (defined($rootinfo->{volume})) {
1243         my ($vtype, $name, $owner) = PVE::Storage::parse_volname($storage_cfg, $rootinfo->{volume});
1244         PVE::Storage::vdisk_free($storage_cfg, $rootinfo->{volume}) if $vmid == $owner;;
1245     }
1246     rmdir "/var/lib/lxc/$vmid/rootfs";
1247     unlink "/var/lib/lxc/$vmid/config";
1248     rmdir "/var/lib/lxc/$vmid";
1249     destroy_config($vmid);
1250
1251     #my $cmd = ['lxc-destroy', '-n', $vmid ];
1252     #PVE::Tools::run_command($cmd);
1253 }
1254
1255 sub vm_stop_cleanup {
1256     my ($storage_cfg, $vmid, $conf, $keepActive) = @_;
1257
1258     eval {
1259         if (!$keepActive) {
1260
1261             my $vollist = get_vm_volumes($conf);
1262             my $loopdevlist = get_vm_volumes($conf, 'rootfs');
1263
1264             PVE::LXC::dettach_loops($storage_cfg, $loopdevlist);
1265             PVE::Storage::deactivate_volumes($storage_cfg, $vollist);
1266         }
1267     };
1268     warn $@ if $@; # avoid errors - just warn
1269 }
1270
1271 my $safe_num_ne = sub {
1272     my ($a, $b) = @_;
1273
1274     return 0 if !defined($a) && !defined($b);
1275     return 1 if !defined($a);
1276     return 1 if !defined($b);
1277
1278     return $a != $b;
1279 };
1280
1281 my $safe_string_ne = sub {
1282     my ($a, $b) = @_;
1283
1284     return 0 if !defined($a) && !defined($b);
1285     return 1 if !defined($a);
1286     return 1 if !defined($b);
1287
1288     return $a ne $b;
1289 };
1290
1291 sub update_net {
1292     my ($vmid, $conf, $opt, $newnet, $netid, $rootdir) = @_;
1293
1294     if ($newnet->{type} ne 'veth') {
1295         # for when there are physical interfaces
1296         die "cannot update interface of type $newnet->{type}";
1297     }
1298
1299     my $veth = "veth${vmid}i${netid}";
1300     my $eth = $newnet->{name};
1301
1302     if (my $oldnetcfg = $conf->{$opt}) {
1303         my $oldnet = parse_lxc_network($oldnetcfg);
1304
1305         if (&$safe_string_ne($oldnet->{hwaddr}, $newnet->{hwaddr}) ||
1306             &$safe_string_ne($oldnet->{name}, $newnet->{name})) {
1307
1308             PVE::Network::veth_delete($veth);
1309             delete $conf->{$opt};
1310             PVE::LXC::write_config($vmid, $conf);
1311
1312             hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1313
1314         } elsif (&$safe_string_ne($oldnet->{bridge}, $newnet->{bridge}) ||
1315                  &$safe_num_ne($oldnet->{tag}, $newnet->{tag}) ||
1316                  &$safe_num_ne($oldnet->{firewall}, $newnet->{firewall})) {
1317
1318                 if ($oldnet->{bridge}) {
1319                     PVE::Network::tap_unplug($veth);
1320                     foreach (qw(bridge tag firewall)) {
1321                         delete $oldnet->{$_};
1322                     }
1323                     $conf->{$opt} = print_lxc_network($oldnet);
1324                     PVE::LXC::write_config($vmid, $conf);
1325                 }
1326
1327                 PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall});
1328                 foreach (qw(bridge tag firewall)) {
1329                     $oldnet->{$_} = $newnet->{$_} if $newnet->{$_};
1330                 }
1331                 $conf->{$opt} = print_lxc_network($oldnet);
1332                 PVE::LXC::write_config($vmid, $conf);
1333         }
1334     } else {
1335         hotplug_net($vmid, $conf, $opt, $newnet, $netid);
1336     }
1337
1338     update_ipconfig($vmid, $conf, $opt, $eth, $newnet, $rootdir);
1339 }
1340
1341 sub hotplug_net {
1342     my ($vmid, $conf, $opt, $newnet, $netid) = @_;
1343
1344     my $veth = "veth${vmid}i${netid}";
1345     my $vethpeer = $veth . "p";
1346     my $eth = $newnet->{name};
1347
1348     PVE::Network::veth_create($veth, $vethpeer, $newnet->{bridge}, $newnet->{hwaddr});
1349     PVE::Network::tap_plug($veth, $newnet->{bridge}, $newnet->{tag}, $newnet->{firewall});
1350
1351     # attach peer in container
1352     my $cmd = ['lxc-device', '-n', $vmid, 'add', $vethpeer, "$eth" ];
1353     PVE::Tools::run_command($cmd);
1354
1355     # link up peer in container
1356     $cmd = ['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', '/sbin/ip', 'link', 'set', $eth ,'up'  ];
1357     PVE::Tools::run_command($cmd);
1358
1359     my $done = { type => 'veth' };
1360     foreach (qw(bridge tag firewall hwaddr name)) {
1361         $done->{$_} = $newnet->{$_} if $newnet->{$_};
1362     }
1363     $conf->{$opt} = print_lxc_network($done);
1364
1365     PVE::LXC::write_config($vmid, $conf);
1366 }
1367
1368 sub update_ipconfig {
1369     my ($vmid, $conf, $opt, $eth, $newnet, $rootdir) = @_;
1370
1371     my $lxc_setup = PVE::LXCSetup->new($conf, $rootdir);
1372
1373     my $optdata = parse_lxc_network($conf->{$opt});
1374     my $deleted = [];
1375     my $added = [];
1376     my $nscmd = sub {
1377         my $cmdargs = shift;
1378         PVE::Tools::run_command(['lxc-attach', '-n', $vmid, '-s', 'NETWORK', '--', @_], %$cmdargs);
1379     };
1380     my $ipcmd = sub { &$nscmd({}, '/sbin/ip', @_) };
1381
1382     my $change_ip_config = sub {
1383         my ($ipversion) = @_;
1384
1385         my $family_opt = "-$ipversion";
1386         my $suffix = $ipversion == 4 ? '' : $ipversion;
1387         my $gw= "gw$suffix";
1388         my $ip= "ip$suffix";
1389
1390         my $newip = $newnet->{$ip};
1391         my $newgw = $newnet->{$gw};
1392         my $oldip = $optdata->{$ip};
1393
1394         my $change_ip = &$safe_string_ne($oldip, $newip);
1395         my $change_gw = &$safe_string_ne($optdata->{$gw}, $newgw);
1396
1397         return if !$change_ip && !$change_gw;
1398
1399         # step 1: add new IP, if this fails we cancel
1400         if ($change_ip && $newip && $newip !~ /^(?:auto|dhcp)$/) {
1401             eval { &$ipcmd($family_opt, 'addr', 'add', $newip, 'dev', $eth); };
1402             if (my $err = $@) {
1403                 warn $err;
1404                 return;
1405             }
1406         }
1407
1408         # step 2: replace gateway
1409         #   If this fails we delete the added IP and cancel.
1410         #   If it succeeds we save the config and delete the old IP, ignoring
1411         #   errors. The config is then saved.
1412         # Note: 'ip route replace' can add
1413         if ($change_gw) {
1414             if ($newgw) {
1415                 eval { &$ipcmd($family_opt, 'route', 'replace', 'default', 'via', $newgw); };
1416                 if (my $err = $@) {
1417                     warn $err;
1418                     # the route was not replaced, the old IP is still available
1419                     # rollback (delete new IP) and cancel
1420                     if ($change_ip) {
1421                         eval { &$ipcmd($family_opt, 'addr', 'del', $newip, 'dev', $eth); };
1422                         warn $@ if $@; # no need to die here
1423                     }
1424                     return;
1425                 }
1426             } else {
1427                 eval { &$ipcmd($family_opt, 'route', 'del', 'default'); };
1428                 # if the route was not deleted, the guest might have deleted it manually
1429                 # warn and continue
1430                 warn $@ if $@;
1431             }
1432         }
1433
1434         # from this point on we save the configuration
1435         # step 3: delete old IP ignoring errors
1436         if ($change_ip && $oldip && $oldip !~ /^(?:auto|dhcp)$/) {
1437             # We need to enable promote_secondaries, otherwise our newly added
1438             # address will be removed along with the old one.
1439             my $promote = 0;
1440             eval {
1441                 if ($ipversion == 4) {
1442                     &$nscmd({ outfunc => sub { $promote = int(shift) } },
1443                             'cat', "/proc/sys/net/ipv4/conf/$eth/promote_secondaries");
1444                     &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=1");
1445                 }
1446                 &$ipcmd($family_opt, 'addr', 'del', $oldip, 'dev', $eth);
1447             };
1448             warn $@ if $@; # no need to die here
1449
1450             if ($ipversion == 4) {
1451                 &$nscmd({}, 'sysctl', "net.ipv4.conf.$eth.promote_secondaries=$promote");
1452             }
1453         }
1454
1455         foreach my $property ($ip, $gw) {
1456             if ($newnet->{$property}) {
1457                 $optdata->{$property} = $newnet->{$property};
1458             } else {
1459                 delete $optdata->{$property};
1460             }
1461         }
1462         $conf->{$opt} = print_lxc_network($optdata);
1463         PVE::LXC::write_config($vmid, $conf);
1464         $lxc_setup->setup_network($conf);
1465     };
1466
1467     &$change_ip_config(4);
1468     &$change_ip_config(6);
1469
1470 }
1471
1472 # Internal snapshots
1473
1474 # NOTE: Snapshot create/delete involves several non-atomic
1475 # action, and can take a long time.
1476 # So we try to avoid locking the file and use 'lock' variable
1477 # inside the config file instead.
1478
1479 my $snapshot_copy_config = sub {
1480     my ($source, $dest) = @_;
1481
1482     foreach my $k (keys %$source) {
1483         next if $k eq 'snapshots';
1484         next if $k eq 'snapstate';
1485         next if $k eq 'snaptime';
1486         next if $k eq 'vmstate';
1487         next if $k eq 'lock';
1488         next if $k eq 'digest';
1489         next if $k eq 'description';
1490
1491         $dest->{$k} = $source->{$k};
1492     }
1493 };
1494
1495 my $snapshot_prepare = sub {
1496     my ($vmid, $snapname, $comment) = @_;
1497
1498     my $snap;
1499
1500     my $updatefn =  sub {
1501
1502         my $conf = load_config($vmid);
1503
1504         die "you can't take a snapshot if it's a template\n"
1505             if is_template($conf);
1506
1507         check_lock($conf);
1508
1509         $conf->{lock} = 'snapshot';
1510
1511         die "snapshot name '$snapname' already used\n"
1512             if defined($conf->{snapshots}->{$snapname});
1513
1514         my $storecfg = PVE::Storage::config();
1515         die "snapshot feature is not available\n" if !has_feature('snapshot', $conf, $storecfg);
1516
1517         $snap = $conf->{snapshots}->{$snapname} = {};
1518
1519         &$snapshot_copy_config($conf, $snap);
1520
1521         $snap->{'snapstate'} = "prepare";
1522         $snap->{'snaptime'} = time();
1523         $snap->{'description'} = $comment if $comment;
1524         $conf->{snapshots}->{$snapname} = $snap;
1525
1526         PVE::LXC::write_config($vmid, $conf);
1527     };
1528
1529     lock_container($vmid, 10, $updatefn);
1530
1531     return $snap;
1532 };
1533
1534 my $snapshot_commit = sub {
1535     my ($vmid, $snapname) = @_;
1536
1537     my $updatefn = sub {
1538
1539         my $conf = load_config($vmid);
1540
1541         die "missing snapshot lock\n"
1542             if !($conf->{lock} && $conf->{lock} eq 'snapshot');
1543
1544         die "snapshot '$snapname' does not exist\n"
1545             if !defined($conf->{snapshots}->{$snapname});
1546
1547         die "wrong snapshot state\n"
1548             if !($conf->{snapshots}->{$snapname}->{'snapstate'} &&
1549                  $conf->{snapshots}->{$snapname}->{'snapstate'} eq "prepare");
1550
1551         delete $conf->{snapshots}->{$snapname}->{'snapstate'};
1552         delete $conf->{lock};
1553         $conf->{parent} = $snapname;
1554
1555         PVE::LXC::write_config($vmid, $conf);
1556     };
1557
1558     lock_container($vmid, 10 ,$updatefn);
1559 };
1560
1561 sub has_feature {
1562     my ($feature, $conf, $storecfg, $snapname) = @_;
1563
1564     #Fixme add other drives if necessary.
1565     my $err;
1566
1567     my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
1568     $err = 1 if !PVE::Storage::volume_has_feature($storecfg, $feature, $rootinfo->{volume}, $snapname);
1569
1570     return $err ? 0 : 1;
1571 }
1572
1573 sub snapshot_create {
1574     my ($vmid, $snapname, $comment) = @_;
1575
1576     my $snap = &$snapshot_prepare($vmid, $snapname, $comment);
1577
1578     my $conf = load_config($vmid);
1579
1580     my $cmd = "/usr/bin/lxc-freeze -n $vmid";
1581     my $running = check_running($vmid);
1582     eval {
1583         if ($running) {
1584             PVE::Tools::run_command($cmd);
1585         };
1586
1587         my $storecfg = PVE::Storage::config();
1588         my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
1589         my $volid = $rootinfo->{volume};
1590
1591         $cmd = "/usr/bin/lxc-unfreeze -n $vmid";
1592         if ($running) {
1593             PVE::Tools::run_command($cmd);
1594         };
1595
1596         PVE::Storage::volume_snapshot($storecfg, $volid, $snapname);
1597         &$snapshot_commit($vmid, $snapname);
1598     };
1599     if(my $err = $@) {
1600         snapshot_delete($vmid, $snapname, 1);
1601         die "$err\n";
1602     }
1603 }
1604
1605 sub snapshot_delete {
1606     my ($vmid, $snapname, $force) = @_;
1607
1608     my $snap;
1609
1610     my $conf;
1611
1612     my $updatefn =  sub {
1613
1614         $conf = load_config($vmid);
1615
1616         die "you can't delete a snapshot if vm is a template\n"
1617             if is_template($conf);
1618
1619         $snap = $conf->{snapshots}->{$snapname};
1620
1621         check_lock($conf);
1622
1623         die "snapshot '$snapname' does not exist\n" if !defined($snap);
1624
1625         $snap->{snapstate} = 'delete';
1626
1627         PVE::LXC::write_config($vmid, $conf);
1628     };
1629
1630     lock_container($vmid, 10, $updatefn);
1631
1632     my $storecfg = PVE::Storage::config();
1633
1634     my $del_snap =  sub {
1635
1636         check_lock($conf);
1637
1638         if ($conf->{parent} eq $snapname) {
1639             if ($conf->{snapshots}->{$snapname}->{snapname}) {
1640                 $conf->{parent} = $conf->{snapshots}->{$snapname}->{parent};
1641             } else {
1642                 delete $conf->{parent};
1643             }
1644         }
1645
1646         delete $conf->{snapshots}->{$snapname};
1647
1648         PVE::LXC::write_config($vmid, $conf);
1649     };
1650
1651     my $rootfs = $conf->{snapshots}->{$snapname}->{rootfs};
1652     my $rootinfo = PVE::LXC::parse_ct_mountpoint($rootfs);
1653     my $volid = $rootinfo->{volume};
1654
1655     eval {
1656         PVE::Storage::volume_snapshot_delete($storecfg, $volid, $snapname);
1657     };
1658     my $err = $@;
1659
1660     if(!$err || ($err && $force)) {
1661         lock_container($vmid, 10, $del_snap);
1662         if ($err) {
1663             die "Can't delete snapshot: $vmid $snapname $err\n";
1664         }
1665     }
1666 }
1667
1668 sub snapshot_rollback {
1669     my ($vmid, $snapname) = @_;
1670
1671     my $storecfg = PVE::Storage::config();
1672
1673     my $conf = load_config($vmid);
1674
1675     die "you can't rollback if vm is a template\n" if is_template($conf);
1676
1677     my $snap = $conf->{snapshots}->{$snapname};
1678
1679     die "snapshot '$snapname' does not exist\n" if !defined($snap);
1680
1681     my $rootfs = $snap->{rootfs};
1682     my $rootinfo = PVE::LXC::parse_ct_mountpoint($rootfs);
1683     my $volid = $rootinfo->{volume};
1684
1685     PVE::Storage::volume_rollback_is_possible($storecfg, $volid, $snapname);
1686
1687     my $updatefn = sub {
1688
1689         die "unable to rollback to incomplete snapshot (snapstate = $snap->{snapstate})\n"
1690             if $snap->{snapstate};
1691
1692         check_lock($conf);
1693
1694         system("lxc-stop -n $vmid --kill") if check_running($vmid);
1695
1696         die "unable to rollback vm $vmid: vm is running\n"
1697             if check_running($vmid);
1698
1699         $conf->{lock} = 'rollback';
1700
1701         my $forcemachine;
1702
1703         # copy snapshot config to current config
1704
1705         my $tmp_conf = $conf;
1706         &$snapshot_copy_config($tmp_conf->{snapshots}->{$snapname}, $conf);
1707         $conf->{snapshots} = $tmp_conf->{snapshots};
1708         delete $conf->{snaptime};
1709         delete $conf->{snapname};
1710         $conf->{parent} = $snapname;
1711
1712         PVE::LXC::write_config($vmid, $conf);
1713     };
1714
1715     my $unlockfn = sub {
1716         delete $conf->{lock};
1717         PVE::LXC::write_config($vmid, $conf);
1718     };
1719
1720     lock_container($vmid, 10, $updatefn);
1721
1722     PVE::Storage::volume_snapshot_rollback($storecfg, $volid, $snapname);
1723
1724     lock_container($vmid, 5, $unlockfn);
1725 }
1726
1727 sub template_create {
1728     my ($vmid, $conf) = @_;
1729
1730     my $storecfg = PVE::Storage::config();
1731
1732     my $rootinfo = PVE::LXC::parse_ct_mountpoint($conf->{rootfs});
1733     my $volid = $rootinfo->{volume};
1734
1735     die "Template feature is not available for '$volid'\n"
1736         if !PVE::Storage::volume_has_feature($storecfg, 'template', $volid);
1737
1738     PVE::Storage::activate_volumes($storecfg, [$volid]);
1739
1740     my $template_volid = PVE::Storage::vdisk_create_base($storecfg, $volid);
1741     $rootinfo->{volume} = $template_volid;
1742     $conf->{rootfs} = print_ct_mountpoint($rootinfo);
1743
1744     write_config($vmid, $conf);
1745 }
1746
1747 sub is_template {
1748     my ($conf) = @_;
1749
1750     return 1 if defined $conf->{template} && $conf->{template} == 1;
1751 }
1752
1753 sub foreach_mountpoint {
1754     my ($conf, $func) = @_;
1755
1756     my $mountpoint = parse_ct_mountpoint($conf->{rootfs});
1757     $mountpoint->{mp} = '/'; # just to be sure
1758     &$func('rootfs', $mountpoint);
1759
1760     for (my $i = 0; $i < $MAX_MOUNT_POINTS; $i++) {
1761         my $key = "mp$i";
1762         next if !defined($conf->{$key});
1763         $mountpoint = parse_ct_mountpoint($conf->{$key});
1764         &$func($key, $mountpoint);
1765     }
1766 }
1767
1768 sub loopdevices_list {
1769
1770     my $loopdev = {};
1771     my $parser = sub {
1772         my $line = shift;
1773         if ($line =~ m/^(\/dev\/loop\d+)\s+\d\s+\d\s+\d\s+\d\s(\S+)$/) {
1774             $loopdev->{$1} = $2;
1775         }
1776     };
1777
1778     PVE::Tools::run_command(['losetup'], outfunc => $parser);
1779
1780     return $loopdev;
1781 }
1782
1783 sub blockdevices_list {
1784
1785     my $bdevs = {};
1786     dir_glob_foreach("/sys/dev/block/", '(\d+):(\d+)', sub {
1787         my (undef, $major, $minor) = @_;
1788         my $bdev = readlink("/sys/dev/block/$major:$minor");
1789         $bdev =~ s/\.\.\/\.\.\/devices\/virtual\/block\//\/dev\//;
1790         $bdevs->{$bdev}->{major} = $major;
1791         $bdevs->{$bdev}->{minor} = $minor;
1792     });
1793     return $bdevs;
1794 }
1795
1796 sub find_loopdev {
1797     my ($loopdevs, $path) = @_;
1798
1799     foreach my $dev (keys %$loopdevs){
1800         return $dev if $loopdevs->{$dev} eq $path;
1801     }
1802 }
1803
1804 sub check_ct_modify_config_perm {
1805     my ($rpcenv, $authuser, $vmid, $pool, $key_list) = @_;
1806
1807     return 1 if $authuser ne 'root@pam';
1808
1809     foreach my $opt (@$key_list) {
1810
1811         if ($opt eq 'cpus' || $opt eq 'cpuunits' || $opt eq 'cpulimit') {
1812             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.CPU']);
1813         } elsif ($opt eq 'disk') {
1814             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Disk']);
1815         } elsif ($opt eq 'memory' || $opt eq 'swap') {
1816             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Memory']);
1817         } elsif ($opt =~ m/^net\d+$/ || $opt eq 'nameserver' ||
1818                  $opt eq 'searchdomain' || $opt eq 'hostname') {
1819             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Network']);
1820         } else {
1821             $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
1822         }
1823     }
1824
1825     return 1;
1826 }
1827
1828
1829 sub volid_path {
1830     my ($volid, $storage_cfg, $loopdevs) = @_;
1831
1832     my $path;
1833
1834     my ($storage, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1835
1836     if ($storage) {
1837
1838         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1839         $path = PVE::Storage::path($storage_cfg, $volid);
1840
1841         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1842             PVE::Storage::parse_volname($storage_cfg, $volid);
1843
1844         die "unable to use template as mountpoint\n" if $isBase;
1845
1846         if ($format eq 'subvol') {
1847             # do nothing
1848         } elsif ($format eq 'raw') {
1849
1850             if ($scfg->{path}) {
1851                 $path = PVE::LXC::find_loopdev($loopdevs, $path) if $loopdevs;
1852             } elsif ($scfg->{type} eq 'drbd' || $scfg->{type} eq 'rbd') {
1853                 # do nothing
1854             } else {
1855                 die "unsupported storage type '$scfg->{type}'\n";
1856             }
1857         } else {
1858             die "unsupported image format '$format'\n";
1859         }
1860     } elsif ($volid =~ m|^/dev/.+|) {
1861         $path = $volid;
1862     } elsif ($volid !~ m|^/dev/.+| && $volid =~ m|^/.+| && -d $volid) {
1863         $path = $volid;
1864     } else {
1865         die "unsupported storage";
1866     }
1867
1868     return $path;
1869 }
1870
1871 sub attach_loops {
1872     my ($storage_cfg, $vollist) = @_;
1873
1874     my $loopdevs = {};
1875
1876     foreach my $volid (@$vollist) {
1877
1878         my ($storage, $volname) = PVE::Storage::parse_volume_id($volid);
1879         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1880
1881         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1882             PVE::Storage::parse_volname($storage_cfg, $volid);
1883
1884         if (($format ne 'subvol') &&
1885             ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs')) {
1886             my $path = PVE::Storage::path($storage_cfg, $volid);
1887             my $loopdev;
1888
1889             my $parser = sub {
1890                 my $line = shift;
1891                 $loopdev = $line if $line =~m|^/dev/loop\d+$|;
1892                 $loopdevs->{$loopdev} = $path;
1893             };
1894
1895             PVE::Tools::run_command(['losetup', '--find', '--show', $path], outfunc => $parser);
1896         }
1897     }
1898
1899     return $loopdevs;
1900 }
1901
1902 sub dettach_loops {
1903     my ($storage_cfg, $vollist) = @_;
1904
1905     my $loopdevs = loopdevices_list();
1906
1907     foreach my $volid (@$vollist) {
1908
1909         my ($storage, $volname) = PVE::Storage::parse_volume_id($volid);
1910         my $scfg = PVE::Storage::storage_config($storage_cfg, $storage);
1911
1912         my ($vtype, undef, undef, undef, undef, $isBase, $format) =
1913             PVE::Storage::parse_volname($storage_cfg, $volid);
1914
1915         if($format ne 'subvol' && ($scfg->{type} eq 'dir' || $scfg->{type} eq 'nfs')) {
1916             my $path = PVE::Storage::path($storage_cfg, $volid);
1917             foreach my $dev (keys %$loopdevs){
1918                 PVE::Tools::run_command(['losetup', '-d', $dev]) if $loopdevs->{$dev} eq $path;
1919             }
1920         }
1921     }
1922 }
1923
1924
1925 sub mountpoint_mount {
1926     my ($mountpoint, $rootdir, $storage_cfg, $loopdevs) = @_;
1927
1928     my $volid = $mountpoint->{volume};
1929     my $mount = $mountpoint->{mp};
1930
1931     return if !$volid || !$mount;
1932
1933     $rootdir =~ s!/+$!!;
1934     my $mount_path = "$rootdir/$mount";
1935     File::Path::mkpath($mount_path);
1936
1937     if ($volid =~ m|^/dev/.+|) {
1938         PVE::Tools::run_command(['mount', $volid, $mount_path]);
1939         return;
1940     }
1941
1942     my $path = PVE::LXC::volid_path($volid, $storage_cfg, $loopdevs);
1943
1944     if ($path !~ m|^/dev/.+|) {
1945         PVE::Tools::run_command(['mount', '-o', 'bind', $path, $mount_path]);
1946         return;
1947     }
1948
1949     PVE::Tools::run_command(['mount', $path, $mount_path]);
1950 }
1951
1952 sub get_vm_volumes {
1953     my ($conf, $excludes) = @_;
1954
1955     my $vollist = [];
1956
1957     PVE::LXC::foreach_mountpoint($conf, sub {
1958         my ($ms, $mountpoint) = @_;
1959
1960         return if $excludes && $ms eq $excludes;
1961
1962         my $volid = $mountpoint->{volume};
1963
1964         return if !$volid || $volid =~ m|^/|;
1965
1966         my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
1967         return if !$sid;
1968
1969         push @$vollist, $volid;
1970     });
1971
1972     return $vollist;
1973 }
1974
1975 1;