src/PVE/VZDump/LXC.pm

   1 package PVE::VZDump::LXC;
   2
   3 use strict;
   4 use warnings;
   5 use File::Path;
   6 use File::Basename;
   7 use PVE::INotify;
   8 use PVE::Cluster qw(cfs_read_file);
   9 use PVE::Storage;
  10 use PVE::VZDump;
  11 use PVE::LXC;
  12 use PVE::LXC::Config;
  13 use PVE::Tools;
  14
  15 use base qw (PVE::VZDump::Plugin);
  16
  17 my $default_mount_point = "/mnt/vzsnap0";
  18
  19 my $rsync_vm = sub {
  20     my ($self, $task, $to, $text, $first) = @_;
  21
  22     my $disks = $task->{disks};
  23     my $from = $disks->[0]->{dir} . '/';
  24     $self->loginfo ("starting $text sync $from to $to");
  25
  26     my $opts = $self->{vzdump}->{opts};
  27
  28     my @xattr = $task->{no_xattrs} ? () : ('-X', '-A');
  29
  30     my $rsync = ['rsync', '--stats', @xattr, '--numeric-ids',
  31                  '-aH', '--delete', '--no-whole-file',
  32                  ($first ? '--sparse' : '--inplace'),
  33                  '--one-file-system', '--relative'];
  34     push @$rsync, "--bwlimit=$opts->{bwlimit}" if $opts->{bwlimit};
  35     push @$rsync, map { "--exclude=$_" } @{$self->{vzdump}->{findexcl}};
  36     push @$rsync, map { "--exclude=$_" } @{$task->{exclude_dirs}};
  37
  38     my $starttime = time();
  39     # See the rsync(1) manpage for --relative in conjunction with /./ in paths.
  40     # This is the only way to have exclude-dirs work together with the
  41     # --one-file-system option.
  42     # This way we can pass multiple source paths and tell rsync which directory
  43     # they're supposed to be relative to.
  44     # Otherwise with eg. using multiple rsync commands means the --exclude
  45     # directives need to be modified for every command as they are meant to be
  46     # relative to the rootdir, while rsync treats them as relative to the
  47     # source dir.
  48     foreach my $disk (@$disks) {
  49         push @$rsync, "$from/.$disk->{mp}";
  50     }
  51     $self->cmd([@$rsync, $to]);
  52     my $delay = time () - $starttime;
  53
  54     $self->loginfo ("$text sync finished ($delay seconds)");
  55 };
  56
  57 sub new {
  58     my ($class, $vzdump) = @_;
  59
  60     PVE::VZDump::check_bin('lxc-stop');
  61     PVE::VZDump::check_bin('lxc-start');
  62     PVE::VZDump::check_bin('lxc-freeze');
  63     PVE::VZDump::check_bin('lxc-unfreeze');
  64
  65     my $self = bless {};
  66
  67     $self->{vzdump} = $vzdump;
  68     $self->{storecfg} = PVE::Storage::config();
  69
  70     $self->{vmlist} = PVE::LXC::config_list();
  71
  72     return $self;
  73 }
  74
  75 sub type {
  76     return 'lxc';
  77 }
  78
  79 sub vm_status {
  80     my ($self, $vmid) = @_;
  81
  82     my $running = PVE::LXC::check_running($vmid) ? 1 : 0;
  83
  84     return wantarray ? ($running, $running ? 'running' : 'stopped') : $running;
  85 }
  86
  87 my $check_mountpoint_empty = sub {
  88     my ($mountpoint) = @_;
  89
  90     die "mount point '$mountpoint' is not a directory\n" if ! -d $mountpoint;
  91
  92     PVE::Tools::dir_glob_foreach($mountpoint, qr/.*/, sub {
  93         my $entry = shift;
  94         return if $entry eq '.' || $entry eq '..';
  95         die "mount point '$mountpoint' not empty\n";
  96     });
  97 };
  98
  99 sub prepare {
 100     my ($self, $task, $vmid, $mode) = @_;
 101
 102     my $conf = $self->{vmlist}->{$vmid} = PVE::LXC::Config->load_config($vmid);
 103     my $storage_cfg = $self->{storecfg};
 104
 105     $self->loginfo("CT Name: $conf->{hostname}")
 106         if defined($conf->{hostname});
 107
 108     my $running = PVE::LXC::check_running($vmid);
 109
 110     my $disks = $task->{disks} = [];
 111     my $exclude_dirs = $task->{exclude_dirs} = [];
 112
 113     $task->{hostname} = $conf->{'hostname'} || "CT$vmid";
 114
 115     my ($id_map, $rootuid, $rootgid) = PVE::LXC::parse_id_maps($conf);
 116     $task->{userns_cmd} = PVE::LXC::userns_command($id_map);
 117     $task->{rootuid} = $rootuid;
 118     $task->{rootgid} = $rootgid;
 119
 120     my $volids = $task->{volids} = [];
 121     PVE::LXC::Config->foreach_mountpoint($conf, sub {
 122         my ($name, $data) = @_;
 123         my $volid = $data->{volume};
 124         my $mount = $data->{mp};
 125         my $type = $data->{type};
 126
 127         return if !$volid || !$mount;
 128
 129         if (!PVE::LXC::Config->mountpoint_backup_enabled($name, $data)) {
 130             push @$exclude_dirs, $mount;
 131             $self->loginfo("excluding $type mount point $name ('$mount') from backup");
 132             return;
 133         }
 134
 135         push @$disks, $data;
 136         push @$volids, $volid
 137             if $type eq 'volume';
 138     });
 139
 140     if ($mode eq 'snapshot') {
 141         if (!PVE::LXC::Config->has_feature('snapshot', $conf, $storage_cfg, undef, undef, 1)) {
 142             die "mode failure - some volumes do not support snapshots\n";
 143         }
 144
 145
 146         if ($conf->{snapshots} && $conf->{snapshots}->{vzdump}) {
 147             $self->loginfo("found old vzdump snapshot (force removal)");
 148             PVE::LXC::Config->lock_config($vmid, sub {
 149                 $self->unlock_vm($vmid);
 150                 PVE::LXC::Config->snapshot_delete($vmid, 'vzdump', 1);
 151                 $self->lock_vm($vmid);
 152             });
 153         }
 154
 155         my $rootdir = $default_mount_point;
 156         mkpath $rootdir;
 157         &$check_mountpoint_empty($rootdir);
 158
 159         # set snapshot_count (freezes CT if snapshot_count > 1)
 160         $task->{snapshot_count} = scalar(@$volids);
 161     } elsif ($mode eq 'stop') {
 162         my $rootdir = $default_mount_point;
 163         mkpath $rootdir;
 164         &$check_mountpoint_empty($rootdir);
 165         PVE::Storage::activate_volumes($storage_cfg, $volids);
 166     } elsif ($mode eq 'suspend') {
 167         my $pid = PVE::LXC::find_lxc_pid($vmid);
 168         foreach my $disk (@$disks) {
 169             $disk->{dir} = "/proc/$pid/root$disk->{mp}";
 170         }
 171         $task->{snapdir} = $task->{tmpdir};
 172     } else {
 173         unlock_vm($self, $vmid);
 174         die "unknown mode '$mode'\n"; # should not happen
 175     }
 176
 177     if ($mode ne 'suspend') {
 178         # If we perform mount operations, let's unshare the mount namespace
 179         # to not influence the running host.
 180         PVE::Tools::unshare(PVE::Tools::CLONE_NEWNS);
 181         PVE::Tools::run_command(['mount', '--make-rslave', '/']);
 182     }
 183 }
 184
 185 sub lock_vm {
 186     my ($self, $vmid) = @_;
 187
 188     PVE::LXC::Config->set_lock($vmid, 'backup');
 189 }
 190
 191 sub unlock_vm {
 192     my ($self, $vmid) = @_;
 193
 194     PVE::LXC::Config->remove_lock($vmid, 'backup')
 195 }
 196
 197 sub snapshot {
 198     my ($self, $task, $vmid) = @_;
 199
 200     $self->loginfo("create storage snapshot 'vzdump'");
 201
 202     # todo: freeze/unfreeze if we have more than one volid
 203     PVE::LXC::Config->lock_config($vmid, sub {
 204         $self->unlock_vm($vmid);
 205         PVE::LXC::Config->snapshot_create($vmid, 'vzdump', 0, "vzdump backup snapshot");
 206         $self->lock_vm($vmid);
 207     });
 208     $task->{cleanup}->{remove_snapshot} = 1;
 209
 210     # reload config
 211     my $conf = $self->{vmlist}->{$vmid} = PVE::LXC::Config->load_config($vmid);
 212     die "unable to read vzdump snapshot config - internal error"
 213         if !($conf->{snapshots} && $conf->{snapshots}->{vzdump});
 214
 215     my $disks = $task->{disks};
 216     my $volids = $task->{volids};
 217
 218     my $rootdir = $default_mount_point;
 219     my $storage_cfg = $self->{storecfg};
 220
 221     PVE::Storage::activate_volumes($storage_cfg, $volids, 'vzdump');
 222     foreach my $disk (@$disks) {
 223         $disk->{dir} = "${rootdir}$disk->{mp}";
 224         PVE::LXC::mountpoint_mount($disk, $rootdir, $storage_cfg, 'vzdump', $task->{rootuid}, $task->{rootgid});
 225     }
 226
 227     $task->{snapdir} = $rootdir;
 228 }
 229
 230 sub copy_data_phase1 {
 231     my ($self, $task) = @_;
 232
 233     if (my $mntinfo = PVE::VZDump::get_mount_info($task->{snapdir})) {
 234         if ($mntinfo->{fstype} =~ /^nfs4?/) {
 235             $self->loginfo(
 236                  "temporary directory is on NFS, disabling xattr and acl"
 237                 ." support, consider configuring a local tmpdir via"
 238                 ." /etc/vzdump.conf\n");
 239             $task->{no_xattrs} = 1;
 240         }
 241     }
 242
 243     $self->$rsync_vm($task, $task->{snapdir}, "first", 1);
 244 }
 245
 246 sub copy_data_phase2 {
 247     my ($self, $task) = @_;
 248
 249     $self->$rsync_vm($task, $task->{snapdir}, "final", 0);
 250 }
 251
 252 sub stop_vm {
 253     my ($self, $task, $vmid) = @_;
 254
 255     my $opts = $self->{vzdump}->{opts};
 256     my $timeout = $opts->{stopwait} * 60;
 257
 258     PVE::LXC::vm_stop($vmid, 0, $timeout);
 259 }
 260
 261 sub start_vm {
 262     my ($self, $task, $vmid) = @_;
 263
 264     $self->cmd(['systemctl', 'start', "pve-container\@$vmid"]);
 265 }
 266
 267 sub suspend_vm {
 268     my ($self, $task, $vmid) = @_;
 269
 270     $self->cmd ("lxc-freeze -n $vmid");
 271 }
 272
 273 sub resume_vm {
 274     my ($self, $task, $vmid) = @_;
 275
 276     $self->cmd ("lxc-unfreeze -n $vmid");
 277 }
 278
 279 sub assemble {
 280     my ($self, $task, $vmid) = @_;
 281
 282     my $tmpdir = $task->{tmpdir};
 283
 284     mkpath "$tmpdir/etc/vzdump/";
 285
 286     my $conf = PVE::LXC::Config->load_config($vmid);
 287     delete $conf->{lock};
 288     delete $conf->{snapshots};
 289     delete $conf->{parent};
 290     delete $conf->{pending};
 291
 292     PVE::Tools::file_set_contents("$tmpdir/etc/vzdump/pct.conf", PVE::LXC::Config::write_pct_config("/lxc/$vmid.conf", $conf));
 293
 294     my $firewall ="/etc/pve/firewall/$vmid.fw";
 295     my $fwconftmp = "$tmpdir/etc/vzdump/pct.fw";
 296     if (-e  $firewall) {
 297         PVE::Tools::file_copy($firewall, $fwconftmp);
 298     } else {
 299         PVE::Tools::file_set_contents($fwconftmp, '');
 300     }
 301     $task->{fw} = 1;
 302 }
 303
 304 sub archive {
 305     my ($self, $task, $vmid, $filename, $comp) = @_;
 306
 307     my $disks = $task->{disks};
 308     my @sources;
 309
 310     if ($task->{mode} eq 'stop') {
 311         my $rootdir = $default_mount_point;
 312         my $storage_cfg = $self->{storecfg};
 313         PVE::Storage::activate_volumes($storage_cfg, $task->{volids});
 314         foreach my $disk (@$disks) {
 315             $disk->{dir} = "${rootdir}$disk->{mp}";
 316             PVE::LXC::mountpoint_mount($disk, $rootdir, $storage_cfg, undef, $task->{rootuid}, $task->{rootgid});
 317             # add every enabled mountpoint (since we use --one-file-system)
 318             # mp already starts with a / so we only need to add the dot
 319             push @sources, ".$disk->{mp}";
 320         }
 321         $task->{snapdir} = $rootdir;
 322     } elsif ($task->{mode} eq 'snapshot') {
 323         # mounting the vzdump snapshots and setting $snapdir is already done,
 324         # but we need to include all mountpoints here!
 325         foreach my $disk (@$disks) {
 326             push @sources, ".$disk->{mp}";
 327         }
 328     } else {
 329         # the data was rsynced to a temporary location, only use '.' to avoid
 330         # having mountpoints duplicated
 331         push @sources, '.';
 332     }
 333
 334     my $opts = $self->{vzdump}->{opts};
 335     my $snapdir = $task->{snapdir};
 336     my $tmpdir = $task->{tmpdir};
 337
 338     my $userns_cmd = $task->{userns_cmd};
 339     my $tar = [@$userns_cmd, 'tar', 'cpf', '-', '--totals',
 340                @PVE::Storage::Plugin::COMMON_TAR_FLAGS,
 341                '--one-file-system', '--warning=no-file-ignored'];
 342
 343     # note: --remove-files does not work because we do not
 344     # backup all files (filters). tar complains:
 345     # Cannot rmdir: Directory not empty
 346     # we disable this optimization for now
 347     #if ($snapdir eq $task->{tmpdir} && $snapdir =~ m|^$opts->{dumpdir}/|) {
 348     #       push @$tar, "--remove-files"; # try to save space
 349     #}
 350
 351     # The directory parameter can give an alternative directory as source.
 352     # the second parameter gives the structure in the tar.
 353     push @$tar, "--directory=$tmpdir", './etc/vzdump/pct.conf';
 354     push @$tar, "./etc/vzdump/pct.fw" if $task->{fw};
 355     push @$tar, "--directory=$snapdir";
 356     push @$tar, '--no-anchored', '--exclude=lost+found' if $userns_cmd;
 357     push @$tar, '--anchored';
 358     push @$tar, map { "--exclude=.$_" } @{$self->{vzdump}->{findexcl}};
 359
 360     push @$tar, @sources;
 361
 362     my $cmd = [ $tar ];
 363
 364     my $bwl = $opts->{bwlimit}*1024; # bandwidth limit for cstream
 365     push @$cmd, [ 'cstream', '-t', $bwl ] if $opts->{bwlimit};
 366     push @$cmd, [ split(/\s+/, $comp) ] if $comp;
 367
 368     if ($opts->{stdout}) {
 369         $self->cmd($cmd, output => ">&" . fileno($opts->{stdout}));
 370     } else {
 371         push @{$cmd->[-1]}, \(">" . PVE::Tools::shellquote($filename));
 372        $self->cmd($cmd);
 373     }
 374 }
 375
 376 sub cleanup {
 377     my ($self, $task, $vmid) = @_;
 378
 379     my $conf = PVE::LXC::Config->load_config($vmid);
 380
 381     if ($task->{mode} ne 'suspend') {
 382         my $rootdir = $default_mount_point;
 383         my $disks = $task->{disks};
 384         foreach my $disk (reverse @$disks) {
 385             PVE::Tools::run_command(['umount', '-l', '-d', $disk->{dir}]) if $disk->{dir};
 386         }
 387     }
 388
 389     if ($task->{cleanup}->{remove_snapshot}) {
 390         $self->loginfo("remove vzdump snapshot");
 391         PVE::LXC::Config->snapshot_delete($vmid, 'vzdump', 0);
 392     }
 393 }
 394
 395 1;