src/binaryen/test/spec/loop.wast

   1 ;; Test `loop` opcode
   2
   3 (module
   4   (func $dummy)
   5
   6   (func (export "empty")
   7     (loop)
   8     (loop $l)
   9   )
  10
  11   (func (export "singular") (result i32)
  12     (loop (nop))
  13     (loop i32 (i32.const 7))
  14   )
  15
  16   (func (export "multi") (result i32)
  17     (loop (call $dummy) (call $dummy) (call $dummy) (call $dummy))
  18     (loop i32 (call $dummy) (call $dummy) (call $dummy) (i32.const 8))
  19   )
  20
  21   (func (export "nested") (result i32)
  22     (loop i32
  23       (loop (call $dummy) (block) (nop))
  24       (loop i32 (call $dummy) (i32.const 9))
  25     )
  26   )
  27
  28   (func (export "deep") (result i32)
  29     (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  30       (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  31         (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  32           (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  33             (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  34               (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  35                 (loop i32 (block i32 (loop i32 (block i32 (loop i32 (block i32
  36                   (loop i32 (block i32 (call $dummy) (i32.const 150)))
  37                 ))))))
  38               ))))))
  39             ))))))
  40           ))))))
  41         ))))))
  42       ))))))
  43     ))))))
  44   )
  45
  46   (func (export "as-unary-operand") (result i32)
  47     (i32.ctz (loop i32 (call $dummy) (i32.const 13)))
  48   )
  49   (func (export "as-binary-operand") (result i32)
  50     (i32.mul
  51       (loop i32 (call $dummy) (i32.const 3))
  52       (loop i32 (call $dummy) (i32.const 4))
  53     )
  54   )
  55   (func (export "as-test-operand") (result i32)
  56     (i32.eqz (loop i32 (call $dummy) (i32.const 13)))
  57   )
  58   (func (export "as-compare-operand") (result i32)
  59     (f32.gt
  60       (loop f32 (call $dummy) (f32.const 3))
  61       (loop f32 (call $dummy) (f32.const 3))
  62     )
  63   )
  64
  65   (func (export "break-bare") (result i32)
  66     (block (loop (br 1) (br 0) (unreachable)))
  67     (block (loop (br_if 1 (i32.const 1)) (unreachable)))
  68     (block (loop (br_table 1 (i32.const 0)) (unreachable)))
  69     (block (loop (br_table 1 1 1 (i32.const 1)) (unreachable)))
  70     (i32.const 19)
  71   )
  72   (func (export "break-value") (result i32)
  73     (block i32 (loop i32 (br 1 (i32.const 18)) (br 0) (i32.const 19)))
  74   )
  75   (func (export "break-repeated") (result i32)
  76     (block i32
  77       (loop i32
  78         (br 1 (i32.const 18))
  79         (br 1 (i32.const 19))
  80         (drop (br_if 1 (i32.const 20) (i32.const 0)))
  81         (drop (br_if 1 (i32.const 20) (i32.const 1)))
  82         (br 1 (i32.const 21))
  83         (br_table 1 (i32.const 22) (i32.const 0))
  84         (br_table 1 1 1 (i32.const 23) (i32.const 1))
  85         (i32.const 21)
  86       )
  87     )
  88   )
  89   (func (export "break-inner") (result i32)
  90     (local i32)
  91     (set_local 0 (i32.const 0))
  92     (set_local 0 (i32.add (get_local 0) (block i32 (loop i32 (block i32 (br 2 (i32.const 0x1)))))))
  93     (set_local 0 (i32.add (get_local 0) (block i32 (loop i32 (loop i32 (br 2 (i32.const 0x2)))))))
  94     (set_local 0 (i32.add (get_local 0) (block i32 (loop i32 (block i32 (loop i32 (br 1 (i32.const 0x4))))))))
  95     (set_local 0 (i32.add (get_local 0) (block i32 (loop i32 (i32.ctz (br 1 (i32.const 0x8)))))))
  96     (set_local 0 (i32.add (get_local 0) (block i32 (loop i32 (i32.ctz (loop i32 (br 2 (i32.const 0x10))))))))
  97     (get_local 0)
  98   )
  99   (func (export "cont-inner") (result i32)
 100     (local i32)
 101     (set_local 0 (i32.const 0))
 102     (set_local 0 (i32.add (get_local 0) (loop i32 (loop i32 (br 1)))))
 103     (set_local 0 (i32.add (get_local 0) (loop i32 (i32.ctz (br 0)))))
 104     (set_local 0 (i32.add (get_local 0) (loop i32 (i32.ctz (loop i32 (br 1))))))
 105     (get_local 0)
 106   )
 107
 108   (func $fx (export "effects") (result i32)
 109     (local i32)
 110     (block
 111       (loop
 112         (set_local 0 (i32.const 1))
 113         (set_local 0 (i32.mul (get_local 0) (i32.const 3)))
 114         (set_local 0 (i32.sub (get_local 0) (i32.const 5)))
 115         (set_local 0 (i32.mul (get_local 0) (i32.const 7)))
 116         (br 1)
 117         (set_local 0 (i32.mul (get_local 0) (i32.const 100)))
 118       )
 119     )
 120     (i32.eq (get_local 0) (i32.const -14))
 121   )
 122
 123   (func (export "while") (param i64) (result i64)
 124     (local i64)
 125     (set_local 1 (i64.const 1))
 126     (block
 127       (loop
 128         (br_if 1 (i64.eqz (get_local 0)))
 129         (set_local 1 (i64.mul (get_local 0) (get_local 1)))
 130         (set_local 0 (i64.sub (get_local 0) (i64.const 1)))
 131         (br 0)
 132       )
 133     )
 134     (get_local 1)
 135   )
 136
 137   (func (export "for") (param i64) (result i64)
 138     (local i64 i64)
 139     (set_local 1 (i64.const 1))
 140     (set_local 2 (i64.const 2))
 141     (block
 142       (loop
 143         (br_if 1 (i64.gt_u (get_local 2) (get_local 0)))
 144         (set_local 1 (i64.mul (get_local 1) (get_local 2)))
 145         (set_local 2 (i64.add (get_local 2) (i64.const 1)))
 146         (br 0)
 147       )
 148     )
 149     (get_local 1)
 150   )
 151
 152   (func (export "nesting") (param f32 f32) (result f32)
 153     (local f32 f32)
 154     (block
 155       (loop
 156         (br_if 1 (f32.eq (get_local 0) (f32.const 0)))
 157         (set_local 2 (get_local 1))
 158         (block
 159           (loop
 160             (br_if 1 (f32.eq (get_local 2) (f32.const 0)))
 161             (br_if 3 (f32.lt (get_local 2) (f32.const 0)))
 162             (set_local 3 (f32.add (get_local 3) (get_local 2)))
 163             (set_local 2 (f32.sub (get_local 2) (f32.const 2)))
 164             (br 0)
 165           )
 166         )
 167         (set_local 3 (f32.div (get_local 3) (get_local 0)))
 168         (set_local 0 (f32.sub (get_local 0) (f32.const 1)))
 169         (br 0)
 170       )
 171     )
 172     (get_local 3)
 173   )
 174 )
 175
 176 (assert_return (invoke "empty"))
 177 (assert_return (invoke "singular") (i32.const 7))
 178 (assert_return (invoke "multi") (i32.const 8))
 179 (assert_return (invoke "nested") (i32.const 9))
 180 (assert_return (invoke "deep") (i32.const 150))
 181
 182 (assert_return (invoke "as-unary-operand") (i32.const 0))
 183 (assert_return (invoke "as-binary-operand") (i32.const 12))
 184 (assert_return (invoke "as-test-operand") (i32.const 0))
 185 (assert_return (invoke "as-compare-operand") (i32.const 0))
 186
 187 (assert_return (invoke "break-bare") (i32.const 19))
 188 (assert_return (invoke "break-value") (i32.const 18))
 189 (assert_return (invoke "break-repeated") (i32.const 18))
 190 (assert_return (invoke "break-inner") (i32.const 0x1f))
 191
 192 (assert_return (invoke "effects") (i32.const 1))
 193
 194 (assert_return (invoke "while" (i64.const 0)) (i64.const 1))
 195 (assert_return (invoke "while" (i64.const 1)) (i64.const 1))
 196 (assert_return (invoke "while" (i64.const 2)) (i64.const 2))
 197 (assert_return (invoke "while" (i64.const 3)) (i64.const 6))
 198 (assert_return (invoke "while" (i64.const 5)) (i64.const 120))
 199 (assert_return (invoke "while" (i64.const 20)) (i64.const 2432902008176640000))
 200
 201 (assert_return (invoke "for" (i64.const 0)) (i64.const 1))
 202 (assert_return (invoke "for" (i64.const 1)) (i64.const 1))
 203 (assert_return (invoke "for" (i64.const 2)) (i64.const 2))
 204 (assert_return (invoke "for" (i64.const 3)) (i64.const 6))
 205 (assert_return (invoke "for" (i64.const 5)) (i64.const 120))
 206 (assert_return (invoke "for" (i64.const 20)) (i64.const 2432902008176640000))
 207
 208 (assert_return (invoke "nesting" (f32.const 0) (f32.const 7)) (f32.const 0))
 209 (assert_return (invoke "nesting" (f32.const 7) (f32.const 0)) (f32.const 0))
 210 (assert_return (invoke "nesting" (f32.const 1) (f32.const 1)) (f32.const 1))
 211 (assert_return (invoke "nesting" (f32.const 1) (f32.const 2)) (f32.const 2))
 212 (assert_return (invoke "nesting" (f32.const 1) (f32.const 3)) (f32.const 4))
 213 (assert_return (invoke "nesting" (f32.const 1) (f32.const 4)) (f32.const 6))
 214 (assert_return (invoke "nesting" (f32.const 1) (f32.const 100)) (f32.const 2550))
 215 (assert_return (invoke "nesting" (f32.const 1) (f32.const 101)) (f32.const 2601))
 216 (assert_return (invoke "nesting" (f32.const 2) (f32.const 1)) (f32.const 1))
 217 (assert_return (invoke "nesting" (f32.const 3) (f32.const 1)) (f32.const 1))
 218 (assert_return (invoke "nesting" (f32.const 10) (f32.const 1)) (f32.const 1))
 219 (assert_return (invoke "nesting" (f32.const 2) (f32.const 2)) (f32.const 3))
 220 (assert_return (invoke "nesting" (f32.const 2) (f32.const 3)) (f32.const 4))
 221 (assert_return (invoke "nesting" (f32.const 7) (f32.const 4)) (f32.const 10.3095235825))
 222 (assert_return (invoke "nesting" (f32.const 7) (f32.const 100)) (f32.const 4381.54785156))
 223 (assert_return (invoke "nesting" (f32.const 7) (f32.const 101)) (f32.const 2601))
 224
 225 (assert_invalid
 226   (module (func $type-empty-i32 (result i32) (loop)))
 227   "type mismatch"
 228 )
 229 (assert_invalid
 230   (module (func $type-empty-i64 (result i64) (loop)))
 231   "type mismatch"
 232 )
 233 (assert_invalid
 234   (module (func $type-empty-f32 (result f32) (loop)))
 235   "type mismatch"
 236 )
 237 (assert_invalid
 238   (module (func $type-empty-f64 (result f64) (loop)))
 239   "type mismatch"
 240 )
 241
 242 (assert_invalid
 243   (module (func $type-value-void-vs-num (result i32)
 244     (loop (nop))
 245   ))
 246   "type mismatch"
 247 )
 248 (assert_invalid
 249   (module (func $type-value-num-vs-num (result i32)
 250     (loop (f32.const 0))
 251   ))
 252   "type mismatch"
 253 )
 254
 255 (; TODO(stack): soft failure
 256 (assert_invalid
 257   (module (func $type-value-void-vs-num-after-break (result i32)
 258     (loop (br 1 (i32.const 1)) (nop))
 259   ))
 260   "type mismatch"
 261 )
 262 (assert_invalid
 263   (module (func $type-value-num-vs-num-after-break (result i32)
 264     (loop (br 1 (i32.const 1)) (f32.const 0))
 265   ))
 266   "type mismatch"
 267 )
 268 ;)
 269
 270 (assert_invalid
 271   (module (func $type-cont-last-void-vs-empty (result i32)
 272     (loop (br 0 (nop)))
 273   ))
 274   "type mismatch"
 275 )
 276 (assert_invalid
 277   (module (func $type-cont-last-num-vs-empty (result i32)
 278     (loop (br 0 (i32.const 0)))
 279   ))
 280   "type mismatch"
 281 )
 282