src/compiler-rt/lib/tsan/CMakeLists.txt

   1 # Build for the ThreadSanitizer runtime support library.
   2
   3 include_directories(..)
   4
   5 set(TSAN_CFLAGS ${SANITIZER_COMMON_CFLAGS})
   6 # SANITIZER_COMMON_CFLAGS contains -fPIC, but it's performance-critical for
   7 # TSan runtime to be built with -fPIE to reduce the number of register spills.
   8 append_list_if(COMPILER_RT_HAS_FPIE_FLAG -fPIE TSAN_CFLAGS)
   9 append_no_rtti_flag(TSAN_CFLAGS)
  10
  11 set(TSAN_RTL_CFLAGS ${TSAN_CFLAGS})
  12 append_list_if(COMPILER_RT_HAS_MSSE3_FLAG -msse3 TSAN_RTL_CFLAGS)
  13 append_list_if(SANITIZER_LIMIT_FRAME_SIZE -Wframe-larger-than=512
  14                TSAN_RTL_CFLAGS)
  15 append_list_if(COMPILER_RT_HAS_WGLOBAL_CONSTRUCTORS_FLAG -Wglobal-constructors
  16                TSAN_RTL_CFLAGS)
  17 # FIXME: Add support for --sysroot=. compile flag:
  18
  19 set(TSAN_SOURCES
  20   rtl/tsan_clock.cc
  21   rtl/tsan_flags.cc
  22   rtl/tsan_fd.cc
  23   rtl/tsan_ignoreset.cc
  24   rtl/tsan_interceptors.cc
  25   rtl/tsan_interface_ann.cc
  26   rtl/tsan_interface_atomic.cc
  27   rtl/tsan_interface.cc
  28   rtl/tsan_interface_java.cc
  29   rtl/tsan_malloc_mac.cc
  30   rtl/tsan_md5.cc
  31   rtl/tsan_mman.cc
  32   rtl/tsan_mutex.cc
  33   rtl/tsan_mutexset.cc
  34   rtl/tsan_report.cc
  35   rtl/tsan_rtl.cc
  36   rtl/tsan_rtl_mutex.cc
  37   rtl/tsan_rtl_report.cc
  38   rtl/tsan_rtl_thread.cc
  39   rtl/tsan_stack_trace.cc
  40   rtl/tsan_stat.cc
  41   rtl/tsan_suppressions.cc
  42   rtl/tsan_symbolize.cc
  43   rtl/tsan_sync.cc)
  44
  45 set(TSAN_CXX_SOURCES
  46   rtl/tsan_new_delete.cc)
  47
  48 if(APPLE)
  49   list(APPEND TSAN_SOURCES
  50     rtl/tsan_platform_mac.cc
  51     rtl/tsan_platform_posix.cc)
  52 elseif(UNIX)
  53   # Assume Linux
  54   list(APPEND TSAN_SOURCES
  55     rtl/tsan_platform_linux.cc
  56     rtl/tsan_platform_posix.cc)
  57 endif()
  58
  59 set(TSAN_HEADERS
  60   rtl/tsan_clock.h
  61   rtl/tsan_defs.h
  62   rtl/tsan_dense_alloc.h
  63   rtl/tsan_fd.h
  64   rtl/tsan_flags.h
  65   rtl/tsan_flags.inc
  66   rtl/tsan_ignoreset.h
  67   rtl/tsan_interceptors.h
  68   rtl/tsan_interface_ann.h
  69   rtl/tsan_interface.h
  70   rtl/tsan_interface_inl.h
  71   rtl/tsan_interface_java.h
  72   rtl/tsan_mman.h
  73   rtl/tsan_mutex.h
  74   rtl/tsan_mutexset.h
  75   rtl/tsan_platform.h
  76   rtl/tsan_report.h
  77   rtl/tsan_rtl.h
  78   rtl/tsan_stack_trace.h
  79   rtl/tsan_stat.h
  80   rtl/tsan_suppressions.h
  81   rtl/tsan_symbolize.h
  82   rtl/tsan_sync.h
  83   rtl/tsan_trace.h
  84   rtl/tsan_update_shadow_word_inl.h
  85   rtl/tsan_vector.h)
  86
  87 set(TSAN_RUNTIME_LIBRARIES)
  88 add_custom_target(tsan)
  89
  90 if(APPLE)
  91   add_compiler_rt_runtime(clang_rt.tsan
  92     SHARED
  93     OS ${TSAN_SUPPORTED_OS}
  94     ARCHS ${TSAN_SUPPORTED_ARCH}
  95     SOURCES ${TSAN_SOURCES} ${TSAN_CXX_SOURCES}
  96     OBJECT_LIBS RTInterception
  97                 RTSanitizerCommon
  98                 RTSanitizerCommonLibc
  99                 RTUbsan
 100     CFLAGS ${TSAN_RTL_CFLAGS}
 101     PARENT_TARGET tsan)
 102 else()
 103   foreach(arch ${TSAN_SUPPORTED_ARCH})
 104     if(arch STREQUAL "x86_64")
 105       set(TSAN_ASM_SOURCES rtl/tsan_rtl_amd64.S)
 106       # Pass ASM file directly to the C++ compiler.
 107       set_source_files_properties(${TSAN_ASM_SOURCES} PROPERTIES
 108         LANGUAGE C)
 109       # Sanity check for Go runtime.
 110       set(BUILDGO_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/go/buildgo.sh)
 111       add_custom_target(GotsanRuntimeCheck
 112         COMMAND env "CC=${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}"
 113                 IN_TMPDIR=1 SILENT=1 ${BUILDGO_SCRIPT}
 114         DEPENDS clang_rt.tsan-${arch} ${BUILDGO_SCRIPT}
 115         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/go
 116         COMMENT "Checking TSan Go runtime..."
 117         VERBATIM)
 118     else()
 119       set(TSAN_ASM_SOURCES)
 120     endif()
 121     add_compiler_rt_runtime(clang_rt.tsan
 122       STATIC
 123       ARCHS ${arch}
 124       SOURCES ${TSAN_SOURCES} ${TSAN_ASM_SOURCES}
 125               $<TARGET_OBJECTS:RTInterception.${arch}>
 126               $<TARGET_OBJECTS:RTSanitizerCommon.${arch}>
 127               $<TARGET_OBJECTS:RTSanitizerCommonLibc.${arch}>
 128               $<TARGET_OBJECTS:RTUbsan.${arch}>
 129       CFLAGS ${TSAN_RTL_CFLAGS})
 130     add_compiler_rt_runtime(clang_rt.tsan_cxx
 131       STATIC
 132       ARCHS ${arch}
 133       SOURCES ${TSAN_CXX_SOURCES}
 134               $<TARGET_OBJECTS:RTUbsan_cxx.${arch}>
 135       CFLAGS ${TSAN_RTL_CFLAGS})
 136     list(APPEND TSAN_RUNTIME_LIBRARIES clang_rt.tsan-${arch}
 137                                        clang_rt.tsan_cxx-${arch})
 138     add_sanitizer_rt_symbols(clang_rt.tsan
 139       ARCHS ${arch}
 140       EXTRA rtl/tsan.syms.extra)
 141     add_sanitizer_rt_symbols(clang_rt.tsan_cxx
 142       ARCHS ${arch}
 143       EXTRA rtl/tsan.syms.extra)
 144     add_dependencies(tsan clang_rt.tsan-${arch}
 145                           clang_rt.tsan_cxx-${arch}
 146                           clang_rt.tsan-${arch}-symbols
 147                           clang_rt.tsan_cxx-${arch}-symbols)
 148   endforeach()
 149 endif()
 150
 151 add_dependencies(compiler-rt tsan)
 152
 153 # Build libcxx instrumented with TSan.
 154 if(COMPILER_RT_HAS_LIBCXX_SOURCES AND
 155    COMPILER_RT_TEST_COMPILER_ID STREQUAL "Clang")
 156   set(LIBCXX_PREFIX ${CMAKE_CURRENT_BINARY_DIR}/libcxx_tsan)
 157   add_custom_libcxx(libcxx_tsan ${LIBCXX_PREFIX}
 158     DEPS ${TSAN_RUNTIME_LIBRARIES}
 159     CFLAGS -fsanitize=thread)
 160 endif()
 161
 162 if(COMPILER_RT_INCLUDE_TESTS)
 163   add_subdirectory(tests)
 164 endif()