src/compiler-rt/lib/tsan/tests/CMakeLists.txt

   1 include_directories(../rtl)
   2
   3 add_custom_target(TsanUnitTests)
   4 set_target_properties(TsanUnitTests PROPERTIES
   5   FOLDER "TSan unittests")
   6
   7 set(TSAN_UNITTEST_CFLAGS
   8   ${TSAN_CFLAGS}
   9   ${COMPILER_RT_TEST_CFLAGS}
  10   ${COMPILER_RT_GTEST_CFLAGS}
  11   -I${COMPILER_RT_SOURCE_DIR}/lib
  12   -I${COMPILER_RT_SOURCE_DIR}/lib/tsan/rtl
  13   -DGTEST_HAS_RTTI=0)
  14
  15 set(TSAN_RTL_HEADERS)
  16 foreach (header ${TSAN_HEADERS})
  17   list(APPEND TSAN_RTL_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../${header})
  18 endforeach()
  19
  20 # tsan_compile(obj_list, source, arch, {headers})
  21 macro(tsan_compile obj_list source arch)
  22   get_filename_component(basename ${source} NAME)
  23   set(output_obj "${basename}.${arch}.o")
  24   get_target_flags_for_arch(${arch} TARGET_CFLAGS)
  25   set(COMPILE_DEPS ${TSAN_RTL_HEADERS} ${ARGN})
  26   if(NOT COMPILER_RT_STANDALONE_BUILD)
  27     list(APPEND COMPILE_DEPS gtest tsan)
  28   endif()
  29   clang_compile(${output_obj} ${source}
  30           CFLAGS ${TSAN_UNITTEST_CFLAGS} ${TARGET_CFLAGS}
  31           DEPS ${COMPILE_DEPS})
  32   list(APPEND ${obj_list} ${output_obj})
  33 endmacro()
  34
  35 macro(add_tsan_unittest testname)
  36   # Build unit tests only for 64-bit Linux.
  37   if(UNIX AND NOT APPLE)
  38     foreach(arch ${TSAN_SUPPORTED_ARCH})
  39       cmake_parse_arguments(TEST "" "" "SOURCES;HEADERS" ${ARGN})
  40       set(TEST_OBJECTS)
  41       foreach(SOURCE ${TEST_SOURCES} ${COMPILER_RT_GTEST_SOURCE})
  42         tsan_compile(TEST_OBJECTS ${SOURCE} ${arch} ${TEST_HEADERS})
  43       endforeach()
  44       get_target_flags_for_arch(${arch} TARGET_LINK_FLAGS)
  45       set(TEST_DEPS ${TEST_OBJECTS})
  46       if(NOT COMPILER_RT_STANDALONE_BUILD)
  47         list(APPEND TEST_DEPS tsan)
  48       endif()
  49       # FIXME: Looks like we should link TSan with just-built runtime,
  50       # and not rely on -fsanitize=thread, as these tests are essentially
  51       # unit tests.
  52       add_compiler_rt_test(TsanUnitTests ${testname}
  53               OBJECTS ${TEST_OBJECTS}
  54               DEPS ${TEST_DEPS}
  55               LINK_FLAGS ${TARGET_LINK_FLAGS}
  56                          -fsanitize=thread
  57                          -lstdc++ -lm)
  58     endforeach()
  59   endif()
  60 endmacro()
  61
  62 if(COMPILER_RT_CAN_EXECUTE_TESTS)
  63   add_subdirectory(rtl)
  64   add_subdirectory(unit)
  65 endif()