src/libcompiler_builtins/compiler-rt/test/msan/CMakeLists.txt

   1 set(MSAN_LIT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   2
   3 set(MSAN_TESTSUITES)
   4
   5 set(MSAN_TEST_ARCH ${MSAN_SUPPORTED_ARCH})
   6 if(APPLE)
   7   darwin_filter_host_archs(MSAN_SUPPORTED_ARCH MSAN_TEST_ARCH)
   8 endif()
   9
  10 foreach(arch ${MSAN_TEST_ARCH})
  11   set(MSAN_TEST_TARGET_ARCH ${arch})
  12   string(TOLOWER "-${arch}" MSAN_TEST_CONFIG_SUFFIX)
  13   get_test_cc_for_arch(${arch} MSAN_TEST_TARGET_CC MSAN_TEST_TARGET_CFLAGS)
  14   string(TOUPPER ${arch} ARCH_UPPER_CASE)
  15   set(CONFIG_NAME ${ARCH_UPPER_CASE}Config)
  16
  17   configure_lit_site_cfg(
  18     ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
  19     ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME}/lit.site.cfg)
  20   list(APPEND MSAN_TESTSUITES ${CMAKE_CURRENT_BINARY_DIR}/${CONFIG_NAME})
  21 endforeach()
  22
  23 set(MSAN_TEST_DEPS ${SANITIZER_COMMON_LIT_TEST_DEPS})
  24 if(NOT COMPILER_RT_STANDALONE_BUILD)
  25   list(APPEND MSAN_TEST_DEPS msan)
  26 endif()
  27
  28 if(COMPILER_RT_INCLUDE_TESTS AND COMPILER_RT_HAS_LIBCXX_SOURCES)
  29   configure_lit_site_cfg(
  30     ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
  31     ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg)
  32   list(APPEND MSAN_TEST_DEPS MsanUnitTests)
  33   list(APPEND MSAN_TESTSUITES ${CMAKE_CURRENT_BINARY_DIR}/Unit)
  34 endif()
  35
  36 add_lit_testsuite(check-msan "Running the MemorySanitizer tests"
  37   ${MSAN_TESTSUITES}
  38   DEPENDS ${MSAN_TEST_DEPS}
  39   )
  40 set_target_properties(check-msan PROPERTIES FOLDER "Compiler-RT Misc")