src/libudev/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 libudev_sources = files(
   4         'libudev-device.c',
   5         'libudev-device-internal.h',
   6         'libudev-enumerate.c',
   7         'libudev-hwdb.c',
   8         'libudev-list.c',
   9         'libudev-list-internal.h',
  10         'libudev-monitor.c',
  11         'libudev-queue.c',
  12         'libudev-util.c',
  13         'libudev-util.h',
  14         'libudev.c',
  15         'libudev.h')
  16
  17 ############################################################
  18
  19 libudev_includes = [includes, include_directories('.')]
  20
  21 libudev_sym = files('libudev.sym')
  22 libudev_sym_path = join_paths(meson.current_source_dir(), 'libudev.sym')
  23
  24 install_headers('libudev.h')
  25 libudev_h_path = join_paths(meson.current_source_dir(), 'libudev.h')
  26
  27 libudev_basic = static_library(
  28         'udev-basic',
  29         libudev_sources,
  30         include_directories : includes,
  31         c_args : ['-fvisibility=default'])
  32
  33 libudev_static = static_library(
  34         'udev_static',
  35         include_directories : includes,
  36         link_with : udev_link_with,
  37         link_whole : libudev_basic)
  38
  39 static_libudev = get_option('static-libudev')
  40 static_libudev_pic = static_libudev == 'true' or static_libudev == 'pic'
  41
  42 custom_target(
  43         'libudev.pc',
  44         input : 'libudev.pc.in',
  45         output : 'libudev.pc',
  46         command : [meson_render_jinja2, config_h, '@INPUT@'],
  47         capture : true,
  48         install : pkgconfiglibdir != 'no',
  49         install_dir : pkgconfiglibdir)
  50
  51 ############################################################
  52
  53 tests += [
  54         [['src/libudev/test-libudev.c'],
  55          [libshared,
  56           libudev_static]],
  57 ]