src/lxc-pve-poststop-hook

   1 #!/usr/bin/perl
   2
   3 package lxc_pve_poststop_hook;
   4
   5 use strict;
   6 use warnings;
   7
   8 exit 0 if $ENV{LXC_NAME} && $ENV{LXC_NAME} !~ /^\d+$/;
   9
  10 use POSIX;
  11 use File::Path;
  12
  13 use PVE::SafeSyslog;
  14 use PVE::Tools;
  15 use PVE::Cluster;
  16 use PVE::INotify;
  17 use PVE::RPCEnvironment;
  18 use PVE::JSONSchema qw(get_standard_option);
  19 use PVE::CLIHandler;
  20 use PVE::Storage;
  21 use PVE::Storage::Plugin;
  22 use PVE::LXC;
  23 use Data::Dumper;
  24
  25 use base qw(PVE::CLIHandler);
  26
  27 __PACKAGE__->register_method ({
  28     name => 'lxc-pve-poststop-hook',
  29     path => 'lxc-pve-poststop-hook',
  30     method => 'GET',
  31     description => "vm_stop_cleanup.",
  32     parameters => {
  33         additionalProperties => 0,
  34         properties => {
  35             name => {
  36                 description => "The container name. This hook is only active for containers using numeric IDs, where configuration is stored on /etc/pve/lxc/<name>.conf (else it is just a NOP).",
  37                 type => 'string',
  38                 pattern => '\S+',
  39                 maxLength => 64,
  40             }
  41         },
  42     },
  43     returns => { type => 'null' },
  44
  45     code => sub {
  46         my ($param) = @_;
  47
  48         return undef if $param->{name} !~ m/^\d+$/;
  49
  50         my $vmid = $param->{name};
  51
  52         return undef if ! -f PVE::LXC::Config->config_file($vmid);
  53
  54         my $conf = PVE::LXC::Config->load_config($vmid);
  55
  56         my $storage_cfg = PVE::Storage::config();
  57
  58         PVE::LXC::vm_stop_cleanup($storage_cfg, $vmid, $conf);
  59
  60         my $rootfs = $ENV{LXC_ROOTFS_PATH};
  61         die "Missing container root directory!\n" if !$rootfs;
  62         PVE::Tools::run_command(['umount', '--recursive', $rootfs]);
  63
  64         # Because netlink is not a reliable protocol it can happen that lxc's
  65         # link-deletion messages get lost (or end up being too early?)
  66         for my $k (keys %$conf) {
  67             next if $k !~ /^net(\d+)/;
  68             my $ind = $1;
  69             my $net = PVE::LXC::Config->parse_lxc_network($conf->{$k});
  70             next if $net->{type} ne 'veth';
  71             # veth_delete tests with '-d /sys/class/net/$name' before running the command
  72             PVE::Network::veth_delete("veth${vmid}i$ind");
  73         }
  74
  75         my $target = $ENV{LXC_TARGET};
  76         if ($target && $target eq 'reboot') {
  77             # in order to make sure hot-plugged config changes aren't reverted
  78             # to what the monitor initially loaded we need to stop the container
  79             # and restart it
  80             local $SIG{HUP} = 'IGNORE';
  81             my $pid = fork();
  82             die "fork failed during container reboot: $!\n" if !defined($pid);
  83             if (!$pid) {
  84                 POSIX::setsid();
  85                 close STDIN;
  86                 close STDOUT;
  87                 close STDERR;
  88                 PVE::LXC::update_lxc_config($vmid, $conf);
  89                 exec {'lxc-start'} 'lxc-start', '-n', $vmid
  90                 or POSIX::_exit(-1);
  91             }
  92             # cause lxc to stop instead of rebooting
  93             POSIX::_exit(1);
  94         }
  95
  96         return undef;
  97     }});
  98
  99
 100 push @ARGV, 'help' if !scalar(@ARGV);
 101
 102 my $param = {};
 103
 104 if ((scalar(@ARGV) == 3) && ($ARGV[1] eq 'lxc') && ($ARGV[2] eq 'post-stop')) {
 105     $param->{name} = $ENV{'LXC_NAME'};
 106     die "got wrong name" if $param->{name} ne $ARGV[0];
 107
 108     @ARGV = ();
 109 } else {
 110     @ARGV = ('help');
 111 }
 112
 113 our $cmddef = [ __PACKAGE__, 'lxc-pve-poststop-hook', [], $param];
 114
 115 __PACKAGE__->run_cli_handler();