src/lxc-pve-prestart-hook

   1 #!/usr/bin/perl
   2
   3 package lxc_pve_prestart_hook;
   4
   5 use strict;
   6 use warnings;
   7
   8 exit 0 if $ENV{LXC_NAME} && $ENV{LXC_NAME} !~ /^\d+$/;
   9
  10 use POSIX;
  11 use File::Path;
  12 use Fcntl ':mode';
  13
  14 use PVE::SafeSyslog;
  15 use PVE::Tools;
  16 use PVE::Cluster;
  17 use PVE::INotify;
  18 use PVE::RPCEnvironment;
  19 use PVE::JSONSchema qw(get_standard_option);
  20 use PVE::CLIHandler;
  21 use PVE::Storage;
  22 use PVE::LXC;
  23 use PVE::LXC::Setup;
  24 use Data::Dumper;
  25
  26 use base qw(PVE::CLIHandler);
  27
  28 __PACKAGE__->register_method ({
  29     name => 'lxc-pve-prestart-hook',
  30     path => 'lxc-pve-prestart-hook',
  31     method => 'GET',
  32     description => "Create a new container root directory.",
  33     parameters => {
  34         additionalProperties => 0,
  35         properties => {
  36             name => {
  37                 description => "The container name. This hook is only active for containers using numeric IDs, where configuration is stored on /etc/pve/lxc/<name>.conf (else it is just a NOP).",
  38                 type => 'string',
  39                 pattern => '\S+',
  40                 maxLength => 64,
  41             },
  42             path => {
  43                 description => "The path to the container configuration directory (LXC internal argument - do not pass manually!).",
  44                 type => 'string',
  45             },
  46             rootfs => {
  47                 description => "The path to the container's rootfs (LXC internal argument - do not pass manually!)",
  48                 type => 'string',
  49             },
  50         },
  51     },
  52     returns => { type => 'null' },
  53
  54     code => sub {
  55         my ($param) = @_;
  56
  57         return undef if $param->{name} !~ m/^\d+$/;
  58
  59         my $vmid = $param->{name};
  60
  61         PVE::Cluster::check_cfs_quorum(); # only start if we have quorum
  62
  63         return undef if ! -f PVE::LXC::config_file($vmid);
  64
  65         my $conf = PVE::LXC::load_config($vmid);
  66
  67         my $storage_cfg = PVE::Storage::config();
  68
  69         my $vollist = PVE::LXC::get_vm_volumes($conf);
  70         my $loopdevlist = PVE::LXC::get_vm_volumes($conf, 'rootfs');
  71
  72         PVE::Storage::activate_volumes($storage_cfg, $vollist);
  73
  74         my $rootdir = $param->{rootfs};
  75
  76         my $setup_mountpoint = sub {
  77             my ($ms, $mountpoint) = @_;
  78
  79             #return if $ms eq 'rootfs';
  80             PVE::LXC::mountpoint_mount($mountpoint, $rootdir, $storage_cfg);
  81         };
  82
  83         my $setup_cgroup_device = sub {
  84             my ($ms, $mountpoint) = @_;
  85
  86             my $volid = $mountpoint->{volume};
  87             return if !$volid || $volid !~ m|^/dev/.+|;
  88
  89             my $path = PVE::LXC::mountpoint_mount_path($mountpoint, $storage_cfg);
  90
  91             my (undef, undef, $mode, undef, undef, undef, $rdev) = stat($path);
  92             if ($mode && S_ISBLK($mode) && $rdev) {
  93                 my $major = int($rdev / 0x100);
  94                 my $minor = $rdev % 0x100;
  95                 if ($major != 7) { # must not be a loop device
  96                     PVE::Tools::run_command(['mknod', '-m', '666', "$rootdir$path", 'b', $major, $minor]);
  97                     PVE::LXC::write_cgroup_value("devices", $vmid, "devices.allow", "b ${major}:${minor} rwm");
  98                 }
  99             }
 100         };
 101
 102         PVE::LXC::foreach_mountpoint($conf, $setup_mountpoint);
 103
 104         PVE::LXC::foreach_mountpoint($conf, $setup_cgroup_device);
 105
 106         my $lxc_setup = PVE::LXC::Setup->new($conf, $rootdir);
 107         $lxc_setup->pre_start_hook();
 108         return undef;
 109     }});
 110
 111
 112 push @ARGV, 'help' if !scalar(@ARGV);
 113
 114 my $param = {};
 115
 116 if ((scalar(@ARGV) == 3) && ($ARGV[1] eq 'lxc') && ($ARGV[2] eq 'pre-start')) {
 117     $param->{name} = $ENV{'LXC_NAME'};
 118     die "got wrong name" if $param->{name} ne $ARGV[0];
 119
 120     $param->{path} = $ENV{'LXC_CONFIG_FILE'};
 121     $param->{rootfs} = $ENV{'LXC_ROOTFS_PATH'};
 122     @ARGV = ();
 123 } else {
 124     @ARGV = ('help');
 125 }
 126
 127 our $cmddef = [ __PACKAGE__, 'lxc-pve-prestart-hook', [], $param];
 128
 129 __PACKAGE__->run_cli_handler();