tests/qtest/meson.build

   1 slow_qtests = {
   2   'ahci-test' : 60,
   3   'bios-tables-test' : 120,
   4   'boot-serial-test' : 60,
   5   'migration-test' : 150,
   6   'npcm7xx_pwm-test': 150,
   7   'prom-env-test' : 60,
   8   'pxe-test' : 60,
   9   'qos-test' : 60,
  10   'qom-test' : 300,
  11   'test-hmp' : 120,
  12 }
  13
  14 qtests_generic = [
  15   'cdrom-test',
  16   'device-introspect-test',
  17   'machine-none-test',
  18   'qmp-test',
  19   'qmp-cmd-test',
  20   'qom-test',
  21   'test-hmp',
  22   'qos-test',
  23   'readconfig-test',
  24   'netdev-socket',
  25 ]
  26 if enable_modules
  27   qtests_generic += [ 'modules-test' ]
  28 endif
  29
  30 qtests_pci = \
  31   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  32   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  33
  34 qtests_cxl = \
  35   (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
  36
  37 qtests_filter = \
  38   (slirp.found() ? ['test-netfilter'] : []) + \
  39   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) + \
  40   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : [])
  41
  42 qtests_i386 = \
  43   (slirp.found() ? ['pxe-test'] : []) + \
  44   qtests_filter + \
  45   (have_tools ? ['ahci-test'] : []) +                                                       \
  46   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  47   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  48   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  49   (config_host.has_key('CONFIG_LINUX') and                                                  \
  50    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  51   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  52   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  53   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  54   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  55   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  56   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  57   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  58   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  59   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  60    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  61   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  62   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  63   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  64   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  65   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  66   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  67   (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
  68   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
  69   (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
  70   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
  71   (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
  72   (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
  73   (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
  74   (config_host.has_key('CONFIG_POSIX') and                                                  \
  75    config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
  76   (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
  77    config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
  78    config_all_devices.has_key('CONFIG_Q35') and                                             \
  79    config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
  80    slirp.found() ? ['virtio-net-failover'] : []) +                                          \
  81   (unpack_edk2_blobs and                                                                    \
  82    config_all_devices.has_key('CONFIG_HPET') and                                            \
  83    config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
  84   qtests_pci +                                                                              \
  85   qtests_cxl +                                                                              \
  86   ['fdc-test',
  87    'ide-test',
  88    'hd-geo-test',
  89    'boot-order-test',
  90    'rtc-test',
  91    'i440fx-test',
  92    'fw_cfg-test',
  93    'device-plug-test',
  94    'drive_del-test',
  95    'tco-test',
  96    'cpu-plug-test',
  97    'q35-test',
  98    'vmgenid-test',
  99    'migration-test',
 100    'test-x86-cpuid-compat',
 101    'numa-test'
 102   ]
 103
 104 if dbus_display and targetos != 'windows'
 105   qtests_i386 += ['dbus-display-test']
 106 endif
 107
 108 dbus_daemon = find_program('dbus-daemon', required: false)
 109 if dbus_daemon.found() and gdbus_codegen.found()
 110   # Temporarily disabled due to Patchew failures:
 111   #qtests_i386 += ['dbus-vmstate-test']
 112   dbus_vmstate1 = custom_target('dbus-vmstate description',
 113                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
 114                                 input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
 115                                 command: [gdbus_codegen, '@INPUT@',
 116                                           '--interface-prefix', 'org.qemu',
 117                                           '--generate-c-code', '@BASENAME@']).to_list()
 118 else
 119   dbus_vmstate1 = []
 120 endif
 121
 122 qtests_x86_64 = qtests_i386
 123
 124 qtests_alpha = ['boot-serial-test'] + \
 125   qtests_filter + \
 126   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 127
 128 qtests_avr = [ 'boot-serial-test' ]
 129
 130 qtests_hppa = ['boot-serial-test'] + \
 131   qtests_filter + \
 132   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 133
 134 qtests_m68k = ['boot-serial-test'] + \
 135   qtests_filter
 136
 137 qtests_microblaze = ['boot-serial-test'] + \
 138   qtests_filter
 139
 140 qtests_microblazeel = qtests_microblaze
 141
 142 qtests_mips = \
 143   qtests_filter + \
 144   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 145   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 146
 147 qtests_mipsel = qtests_mips
 148 qtests_mips64 = qtests_mips
 149 qtests_mips64el = qtests_mips
 150
 151 qtests_ppc = \
 152   qtests_filter + \
 153   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 154   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 155   (config_all_devices.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                      \
 156   (config_all_devices.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                   \
 157   ['boot-order-test']
 158
 159 qtests_ppc64 = \
 160   qtests_ppc + \
 161   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 162   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 163   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 164   (slirp.found() ? ['pxe-test'] : []) +              \
 165   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 166   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 167   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 168
 169 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 170 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 171
 172 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
 173   qtests_filter
 174
 175 qtests_sparc64 = \
 176   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 177   qtests_filter + \
 178   ['prom-env-test', 'boot-serial-test']
 179
 180 qtests_npcm7xx = \
 181   ['npcm7xx_adc-test',
 182    'npcm7xx_gpio-test',
 183    'npcm7xx_pwm-test',
 184    'npcm7xx_rng-test',
 185    'npcm7xx_sdhci-test',
 186    'npcm7xx_smbus-test',
 187    'npcm7xx_timer-test',
 188    'npcm7xx_watchdog_timer-test'] + \
 189    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 190 qtests_aspeed = \
 191   ['aspeed_hace-test',
 192    'aspeed_smc-test',
 193    'aspeed_gpio-test']
 194 qtests_arm = \
 195   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 196   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 197   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 198   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 199   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 200   (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
 201   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 202   (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
 203   (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 204   ['arm-cpu-features',
 205    'microbit-test',
 206    'test-arm-mptimer',
 207    'boot-serial-test']
 208
 209 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 210 qtests_aarch64 = \
 211   (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
 212   (config_all.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
 213     ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
 214   (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
 215   (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test'] : []) +  \
 216   (config_all.has_key('CONFIG_TCG') and                                            \
 217    config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 218   ['arm-cpu-features',
 219    'numa-test',
 220    'boot-serial-test',
 221    'migration-test']
 222
 223 qtests_s390x = \
 224   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 225   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 226   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 227   ['boot-serial-test',
 228    'drive_del-test',
 229    'device-plug-test',
 230    'virtio-ccw-test',
 231    'cpu-plug-test',
 232    'migration-test']
 233
 234 qos_test_ss = ss.source_set()
 235 qos_test_ss.add(
 236   'ac97-test.c',
 237   'adm1272-test.c',
 238   'ds1338-test.c',
 239   'e1000-test.c',
 240   'eepro100-test.c',
 241   'es1370-test.c',
 242   'ipoctal232-test.c',
 243   'lsm303dlhc-mag-test.c',
 244   'isl_pmbus_vr-test.c',
 245   'max34451-test.c',
 246   'megasas-test.c',
 247   'ne2000-test.c',
 248   'tulip-test.c',
 249   'nvme-test.c',
 250   'pca9552-test.c',
 251   'pci-test.c',
 252   'pcnet-test.c',
 253   'sdhci-test.c',
 254   'spapr-phb-test.c',
 255   'tmp105-test.c',
 256   'emc141x-test.c',
 257   'usb-hcd-ohci-test.c',
 258   'virtio-test.c',
 259   'virtio-blk-test.c',
 260   'virtio-net-test.c',
 261   'virtio-rng-test.c',
 262   'virtio-scsi-test.c',
 263   'virtio-iommu-test.c',
 264   'vmxnet3-test.c',
 265   'igb-test.c',
 266 )
 267
 268 if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
 269   qos_test_ss.add(files('virtio-serial-test.c'))
 270 endif
 271
 272 if config_host.has_key('CONFIG_POSIX')
 273   qos_test_ss.add(files('e1000e-test.c'))
 274 endif
 275 if have_virtfs
 276   qos_test_ss.add(files('virtio-9p-test.c'))
 277 endif
 278 if have_vhost_user
 279   qos_test_ss.add(files('vhost-user-test.c'))
 280 endif
 281 if have_tools and have_vhost_user_blk_server
 282   qos_test_ss.add(files('vhost-user-blk-test.c'))
 283 endif
 284
 285 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 286
 287 migration_files = [files('migration-helpers.c')]
 288 if gnutls.found()
 289   migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
 290
 291   if tasn1.found()
 292     migration_files += [files('../unit/crypto-tls-x509-helpers.c',
 293                               '../unit/pkix_asn1_tab.c'), tasn1]
 294   endif
 295 endif
 296
 297 qtests = {
 298   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 299   'cdrom-test': files('boot-sector.c'),
 300   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 301   'erst-test': files('erst-test.c'),
 302   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 303   'migration-test': migration_files,
 304   'pxe-test': files('boot-sector.c'),
 305   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 306   'tpm-crb-swtpm-test': [io, tpmemu_files],
 307   'tpm-crb-test': [io, tpmemu_files],
 308   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 309   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 310   'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
 311   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 312   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 313   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 314   'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
 315 }
 316
 317 if vnc.found()
 318   gvnc = dependency('gvnc-1.0', required: false)
 319   if gvnc.found()
 320     qtests += {'vnc-display-test': [gvnc]}
 321     qtests_generic += [ 'vnc-display-test' ]
 322   endif
 323 endif
 324
 325 if dbus_display
 326   qtests += {'dbus-display-test': [dbus_display1, gio]}
 327 endif
 328
 329 qtest_executables = {}
 330 foreach dir : target_dirs
 331   if not dir.endswith('-softmmu')
 332     continue
 333   endif
 334
 335   target_base = dir.split('-')[0]
 336   qtest_emulator = emulators['qemu-system-' + target_base]
 337   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 338
 339   test_deps = roms
 340   qtest_env = environment()
 341   if have_tools
 342     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 343     test_deps += [qemu_img]
 344   endif
 345   qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
 346   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 347   if have_tools and have_vhost_user_blk_server
 348     qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
 349     test_deps += [qsd]
 350   endif
 351
 352   foreach test : target_qtests
 353     # Executables are shared across targets, declare them only the first time we
 354     # encounter them
 355     if not qtest_executables.has_key(test)
 356       src = [test + '.c']
 357       deps = [qemuutil, qos]
 358       if test in qtests
 359         # use a sourceset to quickly separate sources and deps
 360         test_ss = ss.source_set()
 361         test_ss.add(qtests[test])
 362         src += test_ss.all_sources()
 363         deps += test_ss.all_dependencies()
 364       endif
 365       qtest_executables += {
 366         test: executable(test, src, dependencies: deps)
 367       }
 368     endif
 369     test('qtest-@0@/@1@'.format(target_base, test),
 370          qtest_executables[test],
 371          depends: [test_deps, qtest_emulator, emulator_modules],
 372          env: qtest_env,
 373          args: ['--tap', '-k'],
 374          protocol: 'tap',
 375          timeout: slow_qtests.get(test, 30),
 376          priority: slow_qtests.get(test, 30),
 377          suite: ['qtest', 'qtest-' + target_base])
 378   endforeach
 379 endforeach