tests/qtest/meson.build

   1 slow_qtests = {
   2   'ahci-test' : 60,
   3   'bios-tables-test' : 120,
   4   'boot-serial-test' : 60,
   5   'migration-test' : 150,
   6   'npcm7xx_pwm-test': 150,
   7   'prom-env-test' : 60,
   8   'pxe-test' : 60,
   9   'qos-test' : 60,
  10   'qom-test' : 300,
  11   'test-hmp' : 120,
  12 }
  13
  14 qtests_generic = [
  15   'cdrom-test',
  16   'device-introspect-test',
  17   'machine-none-test',
  18   'qmp-test',
  19   'qmp-cmd-test',
  20   'qom-test',
  21   'test-hmp',
  22   'qos-test',
  23   'readconfig-test',
  24   'netdev-socket',
  25 ]
  26 if enable_modules
  27   qtests_generic += [ 'modules-test' ]
  28 endif
  29
  30 qtests_pci = \
  31   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  32   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  33
  34 qtests_cxl = \
  35   (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
  36
  37 # FIXME: Get rid of get_option('default_devices') here and check
  38 #        for the availability of the default NICs in the tests
  39 qtests_filter = \
  40   (get_option('default_devices') and slirp.found() ? ['test-netfilter'] : []) + \
  41   (get_option('default_devices') and host_os != 'windows' ? ['test-filter-mirror'] : []) + \
  42   (get_option('default_devices') and host_os != 'windows' ? ['test-filter-redirector'] : [])
  43
  44 qtests_i386 = \
  45   (slirp.found() ? ['pxe-test'] : []) + \
  46   qtests_filter + \
  47   (have_tools ? ['ahci-test'] : []) +                                                       \
  48   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  49   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  50   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  51   (host_os == 'linux' and                                                                  \
  52    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') and
  53    config_all_devices.has_key('CONFIG_IPMI_EXTERN') ? ['ipmi-bt-test'] : []) +              \
  54   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  55   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  56   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  57   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  58   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  59   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  60   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  61   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  62   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  63    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  64   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  65   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  66   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  67   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  68   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  69   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  70   (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
  71   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
  72   (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
  73   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
  74   (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
  75   (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
  76   (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
  77   (host_os != 'windows' and                                                                \
  78    config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
  79   (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
  80    config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
  81    config_all_devices.has_key('CONFIG_Q35') and                                             \
  82    config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
  83    slirp.found() ? ['virtio-net-failover'] : []) +                                          \
  84   (unpack_edk2_blobs and                                                                    \
  85    config_all_devices.has_key('CONFIG_HPET') and                                            \
  86    config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
  87   qtests_pci +                                                                              \
  88   qtests_cxl +                                                                              \
  89   ['fdc-test',
  90    'ide-test',
  91    'hd-geo-test',
  92    'boot-order-test',
  93    'rtc-test',
  94    'i440fx-test',
  95    'fw_cfg-test',
  96    'device-plug-test',
  97    'drive_del-test',
  98    'tco-test',
  99    'cpu-plug-test',
 100    'q35-test',
 101    'vmgenid-test',
 102    'migration-test',
 103    'test-x86-cpuid-compat',
 104    'numa-test'
 105   ]
 106
 107 if dbus_display
 108   qtests_i386 += ['dbus-display-test']
 109 endif
 110
 111 dbus_daemon = find_program('dbus-daemon', required: false)
 112 if dbus_daemon.found() and gdbus_codegen.found()
 113   # Temporarily disabled due to Patchew failures:
 114   #qtests_i386 += ['dbus-vmstate-test']
 115   dbus_vmstate1 = custom_target('dbus-vmstate description',
 116                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
 117                                 input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
 118                                 command: [gdbus_codegen, '@INPUT@',
 119                                           '--interface-prefix', 'org.qemu',
 120                                           '--generate-c-code', '@BASENAME@']).to_list()
 121 else
 122   dbus_vmstate1 = []
 123 endif
 124
 125 qtests_x86_64 = qtests_i386
 126
 127 qtests_alpha = ['boot-serial-test'] + \
 128   qtests_filter + \
 129   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 130
 131 qtests_avr = [ 'boot-serial-test' ]
 132
 133 qtests_hppa = ['boot-serial-test'] + \
 134   qtests_filter + \
 135   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 136
 137 qtests_m68k = ['boot-serial-test'] + \
 138   qtests_filter
 139
 140 qtests_microblaze = ['boot-serial-test'] + \
 141   qtests_filter
 142
 143 qtests_microblazeel = qtests_microblaze
 144
 145 qtests_mips = \
 146   qtests_filter + \
 147   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 148   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 149
 150 qtests_mipsel = qtests_mips
 151 qtests_mips64 = qtests_mips
 152 qtests_mips64el = qtests_mips
 153
 154 qtests_ppc = \
 155   qtests_filter + \
 156   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 157   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 158   (config_all_accel.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                              \
 159   (config_all_accel.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                           \
 160   ['boot-order-test']
 161
 162 qtests_ppc64 = \
 163   qtests_ppc + \
 164   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 165   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 166   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 167   (slirp.found() ? ['pxe-test'] : []) +              \
 168   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 169   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 170   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 171
 172 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 173 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 174
 175 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
 176   qtests_filter
 177
 178 qtests_sparc64 = \
 179   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 180   qtests_filter + \
 181   ['prom-env-test', 'boot-serial-test']
 182
 183 qtests_npcm7xx = \
 184   ['npcm7xx_adc-test',
 185    'npcm7xx_gpio-test',
 186    'npcm7xx_pwm-test',
 187    'npcm7xx_rng-test',
 188    'npcm7xx_sdhci-test',
 189    'npcm7xx_smbus-test',
 190    'npcm7xx_timer-test',
 191    'npcm7xx_watchdog_timer-test'] + \
 192    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 193 qtests_aspeed = \
 194   ['aspeed_hace-test',
 195    'aspeed_smc-test',
 196    'aspeed_gpio-test']
 197 qtests_arm = \
 198   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 199   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 200   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 201   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 202   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') and
 203    config_all_devices.has_key('CONFIG_MUSICPAL') ? ['pflash-cfi02-test'] : []) + \
 204   (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
 205   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 206   (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
 207   (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 208   (config_all_devices.has_key('CONFIG_VEXPRESS') ? ['test-arm-mptimer'] : []) + \
 209   (config_all_devices.has_key('CONFIG_MICROBIT') ? ['microbit-test'] : []) + \
 210   ['arm-cpu-features',
 211    'boot-serial-test']
 212
 213 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 214 qtests_aarch64 = \
 215   (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
 216   (config_all_accel.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
 217     ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
 218   (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
 219   (config_all_devices.has_key('CONFIG_XLNX_VERSAL') ? ['xlnx-canfd-test', 'xlnx-versal-trng-test'] : []) + \
 220   (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test'] : []) +  \
 221   (config_all_accel.has_key('CONFIG_TCG') and                                            \
 222    config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 223   ['arm-cpu-features',
 224    'numa-test',
 225    'boot-serial-test',
 226    'migration-test']
 227
 228 qtests_s390x = \
 229   qtests_filter + \
 230   ['boot-serial-test',
 231    'drive_del-test',
 232    'device-plug-test',
 233    'virtio-ccw-test',
 234    'cpu-plug-test',
 235    'migration-test']
 236
 237 qtests_riscv32 = \
 238   (config_all_devices.has_key('CONFIG_SIFIVE_E_AON') ? ['sifive-e-aon-watchdog-test'] : [])
 239
 240 qos_test_ss = ss.source_set()
 241 qos_test_ss.add(
 242   'ac97-test.c',
 243   'adm1272-test.c',
 244   'adm1266-test.c',
 245   'ds1338-test.c',
 246   'e1000-test.c',
 247   'eepro100-test.c',
 248   'es1370-test.c',
 249   'ipoctal232-test.c',
 250   'lsm303dlhc-mag-test.c',
 251   'isl_pmbus_vr-test.c',
 252   'max34451-test.c',
 253   'megasas-test.c',
 254   'ne2000-test.c',
 255   'tulip-test.c',
 256   'nvme-test.c',
 257   'pca9552-test.c',
 258   'pci-test.c',
 259   'pcnet-test.c',
 260   'sdhci-test.c',
 261   'spapr-phb-test.c',
 262   'tmp105-test.c',
 263   'emc141x-test.c',
 264   'usb-hcd-ohci-test.c',
 265   'virtio-test.c',
 266   'virtio-blk-test.c',
 267   'virtio-net-test.c',
 268   'virtio-rng-test.c',
 269   'virtio-scsi-test.c',
 270   'virtio-iommu-test.c',
 271   'vmxnet3-test.c',
 272   'igb-test.c',
 273   'ufs-test.c',
 274 )
 275
 276 if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
 277   qos_test_ss.add(files('virtio-serial-test.c'))
 278 endif
 279
 280 if host_os != 'windows'
 281   qos_test_ss.add(files('e1000e-test.c'))
 282 endif
 283 if have_virtfs
 284   qos_test_ss.add(files('virtio-9p-test.c'))
 285 endif
 286 if have_vhost_user
 287   qos_test_ss.add(files('vhost-user-test.c'))
 288 endif
 289 if have_tools and have_vhost_user_blk_server
 290   qos_test_ss.add(files('vhost-user-blk-test.c'))
 291 endif
 292
 293 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 294
 295 migration_files = [files('migration-helpers.c')]
 296 if gnutls.found()
 297   migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
 298
 299   if tasn1.found()
 300     migration_files += [files('../unit/crypto-tls-x509-helpers.c',
 301                               '../unit/pkix_asn1_tab.c'), tasn1]
 302   endif
 303 endif
 304
 305 qtests = {
 306   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 307   'cdrom-test': files('boot-sector.c'),
 308   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 309   'erst-test': files('erst-test.c'),
 310   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 311   'migration-test': migration_files,
 312   'pxe-test': files('boot-sector.c'),
 313   'qos-test': [chardev, io, qos_test_ss.apply({}).sources()],
 314   'tpm-crb-swtpm-test': [io, tpmemu_files],
 315   'tpm-crb-test': [io, tpmemu_files],
 316   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 317   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 318   'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
 319   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 320   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 321   'virtio-net-failover': files('migration-helpers.c'),
 322   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 323   'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
 324 }
 325
 326 if vnc.found()
 327   gvnc = dependency('gvnc-1.0', method: 'pkg-config', required: false)
 328   if gvnc.found()
 329     qtests += {'vnc-display-test': [gvnc]}
 330     qtests_generic += [ 'vnc-display-test' ]
 331   endif
 332 endif
 333
 334 if dbus_display
 335   qtests += {'dbus-display-test': [dbus_display1, gio]}
 336 endif
 337
 338 qtest_executables = {}
 339 foreach dir : target_dirs
 340   if not dir.endswith('-softmmu')
 341     continue
 342   endif
 343
 344   target_base = dir.split('-')[0]
 345   qtest_emulator = emulators['qemu-system-' + target_base]
 346   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 347
 348   test_deps = roms
 349   qtest_env = environment()
 350   if have_tools
 351     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 352     test_deps += [qemu_img]
 353   endif
 354   qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
 355   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 356   if have_tools and have_vhost_user_blk_server
 357     qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
 358     test_deps += [qsd]
 359   endif
 360
 361   qtest_env.set('PYTHON', python.full_path())
 362
 363   foreach test : target_qtests
 364     # Executables are shared across targets, declare them only the first time we
 365     # encounter them
 366     if not qtest_executables.has_key(test)
 367       src = [test + '.c']
 368       deps = [qemuutil, qos]
 369       if test in qtests
 370         # use a sourceset to quickly separate sources and deps
 371         test_ss = ss.source_set()
 372         test_ss.add(qtests[test])
 373         src += test_ss.all_sources()
 374         deps += test_ss.all_dependencies()
 375       endif
 376       qtest_executables += {
 377         test: executable(test, src, dependencies: deps)
 378       }
 379     endif
 380     test('qtest-@0@/@1@'.format(target_base, test),
 381          qtest_executables[test],
 382          depends: [test_deps, qtest_emulator, emulator_modules],
 383          env: qtest_env,
 384          args: ['--tap', '-k'],
 385          protocol: 'tap',
 386          timeout: slow_qtests.get(test, 30),
 387          priority: slow_qtests.get(test, 30),
 388          suite: ['qtest', 'qtest-' + target_base])
 389   endforeach
 390 endforeach