tests/qtest/meson.build

   1 # All QTests for now are POSIX-only, but the dependencies are
   2 # really in libqtest, not in the testcases themselves.
   3 if not config_host.has_key('CONFIG_POSIX')
   4   subdir_done()
   5 endif
   6
   7 qtests_generic = [
   8   'cdrom-test',
   9   'device-introspect-test',
  10   'machine-none-test',
  11   'qmp-test',
  12   'qmp-cmd-test',
  13   'qom-test',
  14   'test-hmp',
  15   'qos-test',
  16 ]
  17 if config_host.has_key('CONFIG_MODULES')
  18   qtests_generic += [ 'modules-test' ]
  19 endif
  20
  21 qtests_pci = \
  22   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  23   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  24
  25 qtests_i386 = \
  26   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +             \
  27   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                     \
  28   (have_tools ? ['ahci-test'] : []) +                                                       \
  29   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  30   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  31   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['test-filter-redirector'] : []) +    \
  32   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  33   (config_host.has_key('CONFIG_LINUX') and                                                  \
  34    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  35   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  36   (config_all_devices.has_key('CONFIG_PVPANIC') ? ['pvpanic-test'] : []) +                  \
  37   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  38   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  39   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  40   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  41   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  42    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  43   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  44   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  45   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  46   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  47   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  48   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  49   qtests_pci +                                                                              \
  50   ['fdc-test',
  51    'ide-test',
  52    'hd-geo-test',
  53    'boot-order-test',
  54    'bios-tables-test',
  55    'rtc-test',
  56    'i440fx-test',
  57    'fuzz-test',
  58    'fw_cfg-test',
  59    'device-plug-test',
  60    'drive_del-test',
  61    'tco-test',
  62    'cpu-plug-test',
  63    'q35-test',
  64    'vmgenid-test',
  65    'migration-test',
  66    'test-x86-cpuid-compat',
  67    'numa-test']
  68
  69 dbus_daemon = find_program('dbus-daemon', required: false)
  70 if dbus_daemon.found() and config_host.has_key('GDBUS_CODEGEN')
  71   # Temporarily disabled due to Patchew failures:
  72   #qtests_i386 += ['dbus-vmstate-test']
  73   dbus_vmstate1 = custom_target('dbus-vmstate description',
  74                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
  75                                 input: files('dbus-vmstate1.xml'),
  76                                 command: [config_host['GDBUS_CODEGEN'],
  77                                           '@INPUT@',
  78                                           '--interface-prefix', 'org.qemu',
  79                                           '--generate-c-code', '@BASENAME@']).to_list()
  80 else
  81   dbus_vmstate1 = []
  82 endif
  83
  84 qtests_x86_64 = qtests_i386
  85
  86 qtests_alpha = [ 'boot-serial-test' ] +                                                      \
  87   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
  88
  89 qtests_avr = [ 'boot-serial-test' ]
  90
  91 qtests_hppa = [ 'boot-serial-test' ] +                                                       \
  92   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
  93
  94 qtests_m68k = [ 'boot-serial-test' ]
  95 qtests_microblaze = [ 'boot-serial-test' ]
  96 qtests_microblazeel = qtests_microblaze
  97
  98 qtests_mips = \
  99   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 100   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 101
 102 qtests_mips64 = \
 103   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 104   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 105
 106 qtests_mips64el = \
 107   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 108   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 109
 110 qtests_moxie = [ 'boot-serial-test' ]
 111
 112 qtests_ppc = \
 113   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 114   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 115   ['boot-order-test', 'prom-env-test', 'boot-serial-test']                 \
 116
 117 qtests_ppc64 = \
 118   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 119   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 120   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 121   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +              \
 122   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 123   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 124   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                      \
 125   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 126
 127 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 128 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 129
 130 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test']
 131
 132 qtests_sparc64 = \
 133   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 134   ['prom-env-test', 'boot-serial-test']
 135
 136 qtests_npcm7xx = ['npcm7xx_timer-test']
 137 qtests_arm = \
 138   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 139   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 140   ['arm-cpu-features',
 141    'microbit-test',
 142    'm25p80-test',
 143    'test-arm-mptimer',
 144    'boot-serial-test',
 145    'hexloader-test']
 146
 147 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 148 qtests_aarch64 = \
 149   (cpu != 'arm' ? ['bios-tables-test'] : []) +                                                  \
 150   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-test'] : []) +        \
 151   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-swtpm-test'] : []) +  \
 152   ['arm-cpu-features',
 153    'numa-test',
 154    'boot-serial-test',
 155    'migration-test']
 156
 157 qtests_s390x = \
 158   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 159   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 160   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 161   ['boot-serial-test',
 162    'drive_del-test',
 163    'device-plug-test',
 164    'virtio-ccw-test',
 165    'cpu-plug-test',
 166    'migration-test']
 167
 168 qos_test_ss = ss.source_set()
 169 qos_test_ss.add(
 170   'ac97-test.c',
 171   'ds1338-test.c',
 172   'e1000-test.c',
 173   'e1000e-test.c',
 174   'eepro100-test.c',
 175   'es1370-test.c',
 176   'ipoctal232-test.c',
 177   'megasas-test.c',
 178   'ne2000-test.c',
 179   'tulip-test.c',
 180   'nvme-test.c',
 181   'pca9552-test.c',
 182   'pci-test.c',
 183   'pcnet-test.c',
 184   'sdhci-test.c',
 185   'spapr-phb-test.c',
 186   'tmp105-test.c',
 187   'usb-hcd-ohci-test.c',
 188   'virtio-test.c',
 189   'virtio-blk-test.c',
 190   'virtio-net-test.c',
 191   'virtio-rng-test.c',
 192   'virtio-scsi-test.c',
 193   'virtio-serial-test.c',
 194   'vmxnet3-test.c',
 195 )
 196 qos_test_ss.add(when: 'CONFIG_VIRTFS', if_true: files('virtio-9p-test.c'))
 197 qos_test_ss.add(when: 'CONFIG_VHOST_USER', if_true: files('vhost-user-test.c'))
 198
 199 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 200
 201 qtests = {
 202   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 203   'cdrom-test': files('boot-sector.c'),
 204   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 205   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 206   'migration-test': files('migration-helpers.c'),
 207   'pxe-test': files('boot-sector.c'),
 208   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 209   'tpm-crb-swtpm-test': [io, tpmemu_files],
 210   'tpm-crb-test': [io, tpmemu_files],
 211   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 212   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 213   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 214   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 215   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 216 }
 217
 218 qtest_executables = {}
 219 foreach dir : target_dirs
 220   if not dir.endswith('-softmmu')
 221     continue
 222   endif
 223
 224   target_base = dir.split('-')[0]
 225   qtest_emulator = emulators['qemu-system-' + target_base]
 226   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 227
 228   test_deps = []
 229   qtest_env = environment()
 230   if have_tools
 231     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 232     test_deps += [qemu_img]
 233   endif
 234   qtest_env.set('G_TEST_DBUS_DAEMON', meson.source_root() / 'tests/dbus-vmstate-daemon.sh')
 235   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 236
 237   foreach test : target_qtests
 238     # Executables are shared across targets, declare them only the first time we
 239     # encounter them
 240     if not qtest_executables.has_key(test)
 241       src = [test + '.c']
 242       deps = [qemuutil, qos]
 243       if test in qtests
 244         # use a sourceset to quickly separate sources and deps
 245         test_ss = ss.source_set()
 246         test_ss.add(qtests[test])
 247         src += test_ss.all_sources()
 248         deps += test_ss.all_dependencies()
 249       endif
 250       qtest_executables += {
 251         test: executable(test, src, dependencies: deps)
 252       }
 253     endif
 254     # FIXME: missing dependency on the emulator binary and qemu-img
 255     test('qtest-@0@/@1@'.format(target_base, test),
 256          qtest_executables[test],
 257          depends: [test_deps, qtest_emulator],
 258          env: qtest_env,
 259          args: ['--tap', '-k'],
 260          protocol: 'tap',
 261          suite: ['qtest', 'qtest-' + target_base])
 262   endforeach
 263 endforeach