tests/system-kmod-macros.at

   1 # _ADD_BR([name])
   2 #
   3 # Expands into the proper ovs-vsctl commands to create a bridge with the
   4 # appropriate type and properties
   5 m4_define([_ADD_BR], [[add-br $1 -- set Bridge $1 protocols=OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15 fail-mode=secure ]])
   6
   7 # OVS_TRAFFIC_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   8 #
   9 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
  10 # connected to that database, calls ovs-vsctl to create a bridge named
  11 # br0 with predictable settings, passing 'vsctl-args' as additional
  12 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
  13 # output (e.g. because it includes "create" commands) then 'vsctl-output'
  14 # specifies the expected output after filtering through uuidfilt.
  15 #
  16 # Best-effort loading of all available vport modules is performed.
  17 #
  18 m4_define([OVS_TRAFFIC_VSWITCHD_START],
  19   [AT_CHECK([modprobe openvswitch])
  20    on_exit 'modprobe -r openvswitch'
  21    m4_foreach([mod], [[vport_geneve], [vport_gre], [vport_lisp], [vport_stt], [vport_vxlan]],
  22               [modprobe -q mod || echo "Module mod not loaded."
  23                on_exit 'modprobe -q -r mod'
  24               ])
  25    on_exit 'ovs-dpctl del-dp ovs-system'
  26    on_exit 'ovs-appctl dpctl/flush-conntrack'
  27    _OVS_VSWITCHD_START([])
  28    dnl Add bridges, ports, etc.
  29    AT_CHECK([ovs-vsctl -- _ADD_BR([br0]) -- $1 m4_if([$2], [], [], [| uuidfilt])], [0], [$2])
  30 ])
  31
  32 # OVS_TRAFFIC_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  33 #
  34 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  35 # for messages with severity WARN or higher and signaling an error if any
  36 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  37 # commands to delete any warnings that are actually expected, e.g.:
  38 #
  39 #   OVS_TRAFFIC_VSWITCHD_STOP(["/expected error/d"])
  40 #
  41 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  42 # invoked. They can be used to perform additional cleanups such as name space
  43 # removal.
  44 m4_define([OVS_TRAFFIC_VSWITCHD_STOP],
  45   [OVS_VSWITCHD_STOP([$1])
  46    AT_CHECK([:; $2])
  47   ])
  48
  49 # CONFIGURE_VETH_OFFLOADS([VETH])
  50 #
  51 # The kernel datapath has no problem with offloads and veths. Nothing
  52 # to do here.
  53 m4_define([CONFIGURE_VETH_OFFLOADS],
  54 )
  55
  56 # CHECK_CONNTRACK()
  57 #
  58 # Perform requirements checks for running conntrack tests, and flush the
  59 # kernel conntrack tables when the test is finished.
  60 #
  61 m4_define([CHECK_CONNTRACK],
  62     [AT_SKIP_IF([test $HAVE_PYTHON2 = no])
  63      m4_foreach([mod], [[nf_conntrack_ipv4], [nf_conntrack_ipv6], [nf_nat_ftp],
  64                         [nf_nat_tftp]],
  65                 [modprobe mod || echo "Module mod not loaded."
  66                  on_exit 'modprobe -r mod'
  67                 ])
  68      sysctl -w net.netfilter.nf_conntrack_helper=0
  69      on_exit 'ovstest test-netlink-conntrack flush'
  70     ]
  71 )
  72
  73 # CHECK_CONNTRACK_ALG()
  74 #
  75 # Perform requirements checks for running conntrack ALG tests. The kernel
  76 # supports ALG, so no check is needed.
  77 #
  78 m4_define([CHECK_CONNTRACK_ALG])
  79
  80 # CHECK_CONNTRACK_LOCAL_STACK()
  81 #
  82 # Perform requirements checks for running conntrack tests with local stack.
  83 # The kernel always supports reading the connection state of an skb coming
  84 # from an internal port, without an explicit ct() action, so no check is
  85 # needed.
  86 m4_define([CHECK_CONNTRACK_LOCAL_STACK])
  87
  88 # CHECK_CONNTRACK_FRAG_OVERLAP()
  89 #
  90 # The kernel does not support overlapping fragments checking.
  91 m4_define([CHECK_CONNTRACK_FRAG_OVERLAP],
  92 [
  93     AT_SKIP_IF([:])
  94 ])
  95
  96 # CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN()
  97 #
  98 # The kernel does not support fragments with multiple extension headers.
  99 m4_define([CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN],
 100 [
 101     AT_SKIP_IF([:])
 102 ])
 103
 104 # CHECK_CONNTRACK_NAT()
 105 #
 106 # Perform requirements checks for running conntrack NAT tests. The kernel
 107 # always supports NAT, so no check is needed.
 108 #
 109 m4_define([CHECK_CONNTRACK_NAT])
 110
 111 # CHECK_CT_DPIF_PER_ZONE_LIMIT()
 112 #
 113 # Perform requirements checks for running ovs-dpctl ct-[set|get|del]-limits per
 114 # zone. The kernel datapath does support this feature. Will remove this check
 115 # after both kernel and userspace datapath support it.
 116 m4_define([CHECK_CT_DPIF_PER_ZONE_LIMIT])
 117
 118 # CHECK_CT_DPIF_SET_GET_MAXCONNS()
 119 #
 120 # Perform requirements checks for running ovs-dpctl ct-set-maxconns or
 121 # ovs-dpctl ct-get-maxconns. The kernel datapath does not support this
 122 # feature.
 123 m4_define([CHECK_CT_DPIF_SET_GET_MAXCONNS],
 124 [
 125     AT_SKIP_IF([:])
 126 ])
 127
 128 # CHECK_CT_DPIF_GET_NCONNS()
 129 #
 130 # Perform requirements checks for running ovs-dpctl ct-get-nconns. The
 131 # kernel datapath does not support this feature.
 132 m4_define([CHECK_CT_DPIF_GET_NCONNS],
 133 [
 134     AT_SKIP_IF([:])
 135 ])
 136
 137 # DPCTL_SET_MIN_FRAG_SIZE()
 138 #
 139 # The kernel does not support this command.
 140 m4_define([DPCTL_SET_MIN_FRAG_SIZE],
 141 [
 142
 143 ])
 144
 145 # DPCTL_MODIFY_FRAGMENTATION()
 146 #
 147 # The kernel does not support this command.
 148 m4_define([DPCTL_MODIFY_FRAGMENTATION],
 149 [
 150
 151 ])
 152
 153 # DPCTL_CHECK_FRAGMENTATION_PASS()
 154 #
 155 # The kernel does not support this command.
 156 m4_define([DPCTL_CHECK_FRAGMENTATION_PASS],
 157 [
 158
 159 ])
 160
 161 # DPCTL_CHECK_V6_FRAGMENTATION_PASS()
 162 #
 163 # The kernel does not support this command.
 164 m4_define([DPCTL_CHECK_V6_FRAGMENTATION_PASS],
 165 [
 166
 167 ])
 168
 169 # DPCTL_CHECK_FRAGMENTATION_FAIL()
 170 #
 171 # The kernel does not support this command.
 172 m4_define([DPCTL_CHECK_FRAGMENTATION_FAIL],
 173 [
 174
 175 ])
 176
 177 # OVS_CHECK_KERNEL([minversion], [minsublevel], [maxversion], [maxsublevel])
 178 #
 179 # Check if kernel version falls between minversion.minsublevel and
 180 # maxversion.maxsublevel, skip this test if it is not.
 181 m4_define([OVS_CHECK_KERNEL],
 182 [
 183     version=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 1}')
 184     sublevel=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 2}')
 185     AT_SKIP_IF([test $version -lt $1 || ( test $version -eq $1 && test $sublevel -lt $2 ) || test $version -gt $3 || ( test $version -eq $3 && test $sublevel -gt $4 )])
 186 ])
 187
 188 # OVS_CHECK_KERNEL_EXCL([minversion], [minsublevel], [maxversion], [maxsublevel])
 189 #
 190 # Check that kernel version doesn't fall between minversion.minsublevel and
 191 # maxversion.maxsublevel, skip this test if it is.
 192 m4_define([OVS_CHECK_KERNEL_EXCL],
 193 [
 194     version=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 1}')
 195     sublevel=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 2}')
 196     AT_SKIP_IF([ ! ( test $version -lt $1 || ( test $version -eq $1 && test $sublevel -lt $2 ) || test $version -gt $3 || ( test $version -eq $3 && test $sublevel -gt $4 ) ) ])
 197 ])