tests/system-kmod-macros.at

   1 # _ADD_BR([name])
   2 #
   3 # Expands into the proper ovs-vsctl commands to create a bridge with the
   4 # appropriate type and properties
   5 m4_define([_ADD_BR], [[add-br $1 -- set Bridge $1 protocols=OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15 fail-mode=secure ]])
   6
   7 # OVS_TRAFFIC_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   8 #
   9 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
  10 # connected to that database, calls ovs-vsctl to create a bridge named
  11 # br0 with predictable settings, passing 'vsctl-args' as additional
  12 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
  13 # output (e.g. because it includes "create" commands) then 'vsctl-output'
  14 # specifies the expected output after filtering through uuidfilt.
  15 #
  16 # Best-effort loading of all available vport modules is performed.
  17 #
  18 m4_define([OVS_TRAFFIC_VSWITCHD_START],
  19   [AT_CHECK([modprobe openvswitch])
  20    on_exit 'modprobe -r openvswitch'
  21    m4_foreach([mod], [[vport_geneve], [vport_gre], [vport_lisp], [vport_stt], [vport_vxlan]],
  22               [modprobe -q mod || echo "Module mod not loaded."
  23                on_exit 'modprobe -q -r mod'
  24               ])
  25    on_exit 'ovs-dpctl del-dp ovs-system'
  26    on_exit 'ovs-appctl dpctl/flush-conntrack'
  27    _OVS_VSWITCHD_START([])
  28    dnl Add bridges, ports, etc.
  29    AT_CHECK([ovs-vsctl -- _ADD_BR([br0]) -- $1 m4_if([$2], [], [], [| uuidfilt])], [0], [$2])
  30 ])
  31
  32 # OVS_TRAFFIC_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  33 #
  34 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  35 # for messages with severity WARN or higher and signaling an error if any
  36 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  37 # commands to delete any warnings that are actually expected, e.g.:
  38 #
  39 #   OVS_TRAFFIC_VSWITCHD_STOP(["/expected error/d"])
  40 #
  41 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  42 # invoked. They can be used to perform additional cleanups such as name space
  43 # removal.
  44 m4_define([OVS_TRAFFIC_VSWITCHD_STOP],
  45   [OVS_VSWITCHD_STOP([$1])
  46    AT_CHECK([:; $2])
  47   ])
  48
  49 # CONFIGURE_VETH_OFFLOADS([VETH])
  50 #
  51 # The kernel datapath has no problem with offloads and veths. Nothing
  52 # to do here.
  53 m4_define([CONFIGURE_VETH_OFFLOADS],
  54 )
  55
  56 # CHECK_CONNTRACK()
  57 #
  58 # Perform requirements checks for running conntrack tests, and flush the
  59 # kernel conntrack tables when the test is finished.
  60 #
  61 m4_define([CHECK_CONNTRACK],
  62     [AT_SKIP_IF([test $HAVE_PYTHON = no])
  63      m4_foreach([mod], [[nf_conntrack_ipv4], [nf_conntrack_ipv6], [nf_nat_ftp],
  64                         [nf_nat_tftp]],
  65                 [modprobe mod || echo "Module mod not loaded."
  66                  on_exit 'modprobe -r mod'
  67                 ])
  68      sysctl -w net.netfilter.nf_conntrack_helper=0
  69      on_exit 'ovstest test-netlink-conntrack flush'
  70     ]
  71 )
  72
  73 # CHECK_CONNTRACK_ALG()
  74 #
  75 # Perform requirements checks for running conntrack ALG tests. The kernel
  76 # supports ALG, so no check is needed.
  77 #
  78 m4_define([CHECK_CONNTRACK_ALG])
  79
  80 # CHECK_CONNTRACK_FRAG()
  81 #
  82 # Perform requirements checks for running conntrack fragmentations tests.
  83 # The kernel always supports fragmentation, so no check is needed.
  84 m4_define([CHECK_CONNTRACK_FRAG])
  85
  86 # CHECK_CONNTRACK_LOCAL_STACK()
  87 #
  88 # Perform requirements checks for running conntrack tests with local stack.
  89 # The kernel always supports reading the connection state of an skb coming
  90 # from an internal port, without an explicit ct() action, so no check is
  91 # needed.
  92 m4_define([CHECK_CONNTRACK_LOCAL_STACK])
  93
  94 # CHECK_CONNTRACK_NAT()
  95 #
  96 # Perform requirements checks for running conntrack NAT tests. The kernel
  97 # always supports NAT, so no check is needed.
  98 #
  99 m4_define([CHECK_CONNTRACK_NAT])
 100
 101 # CHECK_CT_DPIF_FLUSH_BY_CT_TUPLE()
 102 #
 103 # Perform requirements checks for running ovs-dpctl flush-conntrack by
 104 # conntrack 5-tuple test. The kernel datapath does support this
 105 # feature. Will remove this check after both kernel and userspace datapath
 106 # support it.
 107 m4_define([CHECK_CT_DPIF_FLUSH_BY_CT_TUPLE])
 108
 109 # CHECK_CT_DPIF_SET_GET_MAXCONNS()
 110 #
 111 # Perform requirements checks for running ovs-dpctl ct-set-maxconns or
 112 # ovs-dpctl ct-get-maxconns. The kernel datapath does not support this
 113 # feature.
 114 m4_define([CHECK_CT_DPIF_SET_GET_MAXCONNS],
 115 [
 116     AT_SKIP_IF([:])
 117 ])
 118
 119 # CHECK_CT_DPIF_GET_NCONNS()
 120 #
 121 # Perform requirements checks for running ovs-dpctl ct-get-nconns. The
 122 # kernel datapath does not support this feature.
 123 m4_define([CHECK_CT_DPIF_GET_NCONNS],
 124 [
 125     AT_SKIP_IF([:])
 126 ])