tests/system-kmod-macros.at

   1 # _ADD_BR([name])
   2 #
   3 # Expands into the proper ovs-vsctl commands to create a bridge with the
   4 # appropriate type and properties
   5 m4_define([_ADD_BR], [[add-br $1 -- set Bridge $1 protocols=OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15 fail-mode=secure ]])
   6
   7 # OVS_TRAFFIC_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   8 #
   9 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
  10 # connected to that database, calls ovs-vsctl to create a bridge named
  11 # br0 with predictable settings, passing 'vsctl-args' as additional
  12 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
  13 # output (e.g. because it includes "create" commands) then 'vsctl-output'
  14 # specifies the expected output after filtering through uuidfilt.
  15 #
  16 # Best-effort loading of all available vport modules is performed.
  17 #
  18 m4_define([OVS_TRAFFIC_VSWITCHD_START],
  19   [AT_CHECK([modprobe openvswitch])
  20    on_exit 'modprobe -r openvswitch'
  21    m4_foreach([mod], [[vport_geneve], [vport_gre], [vport_lisp], [vport_stt], [vport_vxlan]],
  22               [modprobe -q mod || echo "Module mod not loaded."
  23                on_exit 'modprobe -q -r mod'
  24               ])
  25    on_exit 'ovs-dpctl del-dp ovs-system'
  26    on_exit 'ovs-appctl dpctl/flush-conntrack'
  27    _OVS_VSWITCHD_START([])
  28    dnl Add bridges, ports, etc.
  29    AT_CHECK([ovs-vsctl -- _ADD_BR([br0]) -- $1 m4_if([$2], [], [], [| uuidfilt])], [0], [$2])
  30 ])
  31
  32 # OVS_TRAFFIC_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  33 #
  34 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  35 # for messages with severity WARN or higher and signaling an error if any
  36 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  37 # commands to delete any warnings that are actually expected, e.g.:
  38 #
  39 #   OVS_TRAFFIC_VSWITCHD_STOP(["/expected error/d"])
  40 #
  41 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  42 # invoked. They can be used to perform additional cleanups such as name space
  43 # removal.
  44 m4_define([OVS_TRAFFIC_VSWITCHD_STOP],
  45   [OVS_VSWITCHD_STOP([$1])
  46    AT_CHECK([:; $2])
  47   ])
  48
  49 # CONFIGURE_VETH_OFFLOADS([VETH])
  50 #
  51 # The kernel datapath has no problem with offloads and veths. Nothing
  52 # to do here.
  53 m4_define([CONFIGURE_VETH_OFFLOADS],
  54 )
  55
  56 # CHECK_CONNTRACK()
  57 #
  58 # Perform requirements checks for running conntrack tests, and flush the
  59 # kernel conntrack tables when the test is finished.
  60 #
  61 m4_define([CHECK_CONNTRACK],
  62     [AT_SKIP_IF([test $HAVE_PYTHON2 = no])
  63      m4_foreach([mod], [[nf_conntrack_ipv4], [nf_conntrack_ipv6], [nf_nat_ftp],
  64                         [nf_nat_tftp]],
  65                 [modprobe mod || echo "Module mod not loaded."
  66                  on_exit 'modprobe -r mod'
  67                 ])
  68      sysctl -w net.netfilter.nf_conntrack_helper=0
  69      on_exit 'ovstest test-netlink-conntrack flush'
  70     ]
  71 )
  72
  73 # CHECK_CONNTRACK_ALG()
  74 #
  75 # Perform requirements checks for running conntrack ALG tests. The kernel
  76 # supports ALG, so no check is needed.
  77 #
  78 m4_define([CHECK_CONNTRACK_ALG])
  79
  80 # CHECK_CONNTRACK_FRAG()
  81 #
  82 # Perform requirements checks for running conntrack fragmentations tests.
  83 # The kernel always supports fragmentation, so no check is needed.
  84 m4_define([CHECK_CONNTRACK_FRAG])
  85
  86 # CHECK_CONNTRACK_LOCAL_STACK()
  87 #
  88 # Perform requirements checks for running conntrack tests with local stack.
  89 # The kernel always supports reading the connection state of an skb coming
  90 # from an internal port, without an explicit ct() action, so no check is
  91 # needed.
  92 m4_define([CHECK_CONNTRACK_LOCAL_STACK])
  93
  94 # CHECK_CONNTRACK_FRAG_OVERLAP()
  95 #
  96 # The kernel does not support overlapping fragments checking.
  97 m4_define([CHECK_CONNTRACK_FRAG_OVERLAP],
  98 [
  99     AT_SKIP_IF([:])
 100 ])
 101
 102 # CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN()
 103 #
 104 # The kernel does not support fragments with multiple extension headers.
 105 m4_define([CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN],
 106 [
 107     AT_SKIP_IF([:])
 108 ])
 109
 110 # CHECK_CONNTRACK_NAT()
 111 #
 112 # Perform requirements checks for running conntrack NAT tests. The kernel
 113 # always supports NAT, so no check is needed.
 114 #
 115 m4_define([CHECK_CONNTRACK_NAT])
 116
 117 # CHECK_CT_DPIF_SET_GET_MAXCONNS()
 118 #
 119 # Perform requirements checks for running ovs-dpctl ct-set-maxconns or
 120 # ovs-dpctl ct-get-maxconns. The kernel datapath does not support this
 121 # feature.
 122 m4_define([CHECK_CT_DPIF_SET_GET_MAXCONNS],
 123 [
 124     AT_SKIP_IF([:])
 125 ])
 126
 127 # CHECK_CT_DPIF_GET_NCONNS()
 128 #
 129 # Perform requirements checks for running ovs-dpctl ct-get-nconns. The
 130 # kernel datapath does not support this feature.
 131 m4_define([CHECK_CT_DPIF_GET_NCONNS],
 132 [
 133     AT_SKIP_IF([:])
 134 ])
 135
 136 # OVS_CHECK_KERNEL([minversion], [minsublevel], [maxversion], [maxsublevel])
 137 #
 138 # Check if kernel version falls between minversion.minsublevel and
 139 # maxversion.maxsublevel, skip this test if it is not.
 140 m4_define([OVS_CHECK_KERNEL],
 141 [
 142     version=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 1}')
 143     sublevel=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 2}')
 144     AT_SKIP_IF([test $version -lt $1 || ( test $version -eq $1 && test $sublevel -lt $2 ) || test $version -gt $3 || ( test $version -eq $3 && test $sublevel -gt $4 )])
 145 ])
 146
 147 # OVS_CHECK_KERNEL_EXCL([minversion], [minsublevel], [maxversion], [maxsublevel])
 148 #
 149 # Check that kernel version doesn't fall between minversion.minsublevel and
 150 # maxversion.maxsublevel, skip this test if it is.
 151 m4_define([OVS_CHECK_KERNEL_EXCL],
 152 [
 153     version=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 1}')
 154     sublevel=$(uname -r | sed -e 's/\./ /g' | awk '{print $ 2}')
 155     AT_SKIP_IF([ ! ( test $version -lt $1 || ( test $version -eq $1 && test $sublevel -lt $2 ) || test $version -gt $3 || ( test $version -eq $3 && test $sublevel -gt $4 ) ) ])
 156 ])