tests/system-userspace-macros.at

   1 # _ADD_BR([name])
   2 #
   3 # Expands into the proper ovs-vsctl commands to create a bridge with the
   4 # appropriate type and properties
   5 m4_define([_ADD_BR], [[add-br $1 -- set Bridge $1 datapath_type="netdev" protocols=OpenFlow10,OpenFlow11,OpenFlow12,OpenFlow13,OpenFlow14,OpenFlow15 fail-mode=secure ]])
   6
   7 # OVS_TRAFFIC_VSWITCHD_START([vsctl-args], [vsctl-output], [=override])
   8 #
   9 # Creates a database and starts ovsdb-server, starts ovs-vswitchd
  10 # connected to that database, calls ovs-vsctl to create a bridge named
  11 # br0 with predictable settings, passing 'vsctl-args' as additional
  12 # commands to ovs-vsctl.  If 'vsctl-args' causes ovs-vsctl to provide
  13 # output (e.g. because it includes "create" commands) then 'vsctl-output'
  14 # specifies the expected output after filtering through uuidfilt.
  15 m4_define([OVS_TRAFFIC_VSWITCHD_START],
  16   [
  17    OVS_WAIT_WHILE([ip link show ovs-netdev])
  18    _OVS_VSWITCHD_START([--disable-system])
  19    dnl Add bridges, ports, etc.
  20    OVS_WAIT_WHILE([ip link show br0])
  21    AT_CHECK([ovs-vsctl -- _ADD_BR([br0]) -- $1 m4_if([$2], [], [], [| uuidfilt])], [0], [$2])
  22 ])
  23
  24 # OVS_TRAFFIC_VSWITCHD_STOP([WHITELIST], [extra_cmds])
  25 #
  26 # Gracefully stops ovs-vswitchd and ovsdb-server, checking their log files
  27 # for messages with severity WARN or higher and signaling an error if any
  28 # is present.  The optional WHITELIST may contain shell-quoted "sed"
  29 # commands to delete any warnings that are actually expected, e.g.:
  30 #
  31 #   OVS_TRAFFIC_VSWITCHD_STOP(["/expected error/d"])
  32 #
  33 # 'extra_cmds' are shell commands to be executed afte OVS_VSWITCHD_STOP() is
  34 # invoked. They can be used to perform additional cleanups such as name space
  35 # removal.
  36 m4_define([OVS_TRAFFIC_VSWITCHD_STOP],
  37   [OVS_VSWITCHD_STOP([dnl
  38 $1";/netdev_linux.*obtaining netdev stats via vport failed/d
  39 /dpif_netlink.*Generic Netlink family 'ovs_datapath' does not exist. The Open vSwitch kernel module is probably not loaded./d"])
  40    AT_CHECK([:; $2])
  41   ])
  42
  43 # CONFIGURE_VETH_OFFLOADS([VETH])
  44 #
  45 # Disable TX offloads for veths.  The userspace datapath uses the AF_PACKET
  46 # socket to receive packets for veths.  Unfortunately, the AF_PACKET socket
  47 # doesn't play well with offloads:
  48 # 1. GSO packets are received without segmentation and therefore discarded.
  49 # 2. Packets with offloaded partial checksum are received with the wrong
  50 #    checksum, therefore discarded by the receiver.
  51 #
  52 # By disabling tx offloads in the non-OVS side of the veth peer we make sure
  53 # that the AF_PACKET socket will not receive bad packets.
  54 #
  55 # This is a workaround, and should be removed when offloads are properly
  56 # supported in netdev-linux.
  57 m4_define([CONFIGURE_VETH_OFFLOADS],
  58     [AT_CHECK([ethtool -K $1 tx off], [0], [ignore], [ignore])]
  59 )
  60
  61 # CHECK_CONNTRACK()
  62 #
  63 # Perform requirements checks for running conntrack tests.
  64 #
  65 m4_define([CHECK_CONNTRACK],
  66     [AT_SKIP_IF([test $HAVE_PYTHON2 = no])]
  67 )
  68
  69 # CHECK_CONNTRACK_ALG()
  70 #
  71 # Perform requirements checks for running conntrack ALG tests. The userspace
  72 # supports FTP and TFTP.
  73 #
  74 m4_define([CHECK_CONNTRACK_ALG])
  75
  76 # CHECK_CONNTRACK_FRAG()
  77 #
  78 # Perform requirements checks for running conntrack fragmentations tests.
  79 # The userspace doesn't support fragmentation yet, so skip the tests.
  80 m4_define([CHECK_CONNTRACK_FRAG],
  81 [
  82     AT_SKIP_IF([:])
  83 ])
  84
  85 # CHECK_CONNTRACK_LOCAL_STACK()
  86 #
  87 # Perform requirements checks for running conntrack tests with local stack.
  88 # While the kernel connection tracker automatically passes all the connection
  89 # tracking state from an internal port to the OpenvSwitch kernel module, there
  90 # is simply no way of doing that with the userspace, so skip the tests.
  91 m4_define([CHECK_CONNTRACK_LOCAL_STACK],
  92 [
  93     AT_SKIP_IF([:])
  94 ])
  95
  96 # CHECK_CONNTRACK_FRAG_OVERLAP()
  97 #
  98 # The userspace datapath does not support fragments yet.
  99 m4_define([CHECK_CONNTRACK_FRAG_OVERLAP],
 100 [
 101     AT_SKIP_IF([:])
 102 ])
 103
 104 # CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN()
 105 #
 106 # The userspace datapath does not support fragments yet.
 107 m4_define([CHECK_CONNTRACK_FRAG_IPV6_MULT_EXTEN],
 108 [
 109     AT_SKIP_IF([:])
 110 ])
 111
 112 # CHECK_CONNTRACK_NAT()
 113 #
 114 # Perform requirements checks for running conntrack NAT tests. The userspace
 115 # datapath supports NAT.
 116 #
 117 m4_define([CHECK_CONNTRACK_NAT])
 118
 119 # CHECK_CT_DPIF_PER_ZONE_LIMIT()
 120 #
 121 # Perform requirements checks for running ovs-dpctl ct-[set|get|del]-limits per
 122 # zone. The userspace datapath does not support this feature yet.
 123 m4_define([CHECK_CT_DPIF_PER_ZONE_LIMIT],
 124 [
 125     AT_SKIP_IF([:])
 126 ])
 127
 128 # CHECK_CT_DPIF_SET_GET_MAXCONNS()
 129 #
 130 # Perform requirements checks for running ovs-dpctl ct-set-maxconns or
 131 # ovs-dpctl ct-get-maxconns. The userspace datapath does support this feature.
 132 m4_define([CHECK_CT_DPIF_SET_GET_MAXCONNS])
 133
 134 # CHECK_CT_DPIF_GET_NCONNS()
 135 #
 136 # Perform requirements checks for running ovs-dpctl ct-get-nconns. The
 137 # userspace datapath does support this feature.
 138 m4_define([CHECK_CT_DPIF_GET_NCONNS])
 139
 140 # OVS_CHECK_KERNEL([minversion], [maxversion], [minsublevel], [maxsublevel])
 141 #
 142 # The userspace skips all tests that check kernel version.
 143 m4_define([OVS_CHECK_KERNEL],
 144 [
 145     AT_SKIP_IF([:])
 146 ])
 147
 148 # OVS_CHECK_KERNEL_EXCL([minversion], [maxversion], [minsublevel], [maxsublevel])
 149 #
 150 # The userspace skips all tests that check kernel version.
 151 m4_define([OVS_CHECK_KERNEL_EXCL],
 152 [
 153     AT_SKIP_IF([:])
 154 ])