tools/memory-model/linux-kernel.bell

   1 // SPDX-License-Identifier: GPL-2.0+
   2 (*
   3  * Copyright (C) 2015 Jade Alglave <j.alglave@ucl.ac.uk>,
   4  * Copyright (C) 2016 Luc Maranget <luc.maranget@inria.fr> for Inria
   5  * Copyright (C) 2017 Alan Stern <stern@rowland.harvard.edu>,
   6  *                    Andrea Parri <parri.andrea@gmail.com>
   7  *
   8  * An earlier version of this file appeared in the companion webpage for
   9  * "Frightening small children and disconcerting grown-ups: Concurrency
  10  * in the Linux kernel" by Alglave, Maranget, McKenney, Parri, and Stern,
  11  * which appeared in ASPLOS 2018.
  12  *)
  13
  14 "Linux-kernel memory consistency model"
  15
  16 enum Accesses = 'once (*READ_ONCE,WRITE_ONCE*) ||
  17                 'release (*smp_store_release*) ||
  18                 'acquire (*smp_load_acquire*) ||
  19                 'noreturn (* R of non-return RMW *)
  20 instructions R[{'once,'acquire,'noreturn}]
  21 instructions W[{'once,'release}]
  22 instructions RMW[{'once,'acquire,'release}]
  23
  24 enum Barriers = 'wmb (*smp_wmb*) ||
  25                 'rmb (*smp_rmb*) ||
  26                 'mb (*smp_mb*) ||
  27                 'rcu-lock (*rcu_read_lock*)  ||
  28                 'rcu-unlock (*rcu_read_unlock*) ||
  29                 'sync-rcu (*synchronize_rcu*) ||
  30                 'before-atomic (*smp_mb__before_atomic*) ||
  31                 'after-atomic (*smp_mb__after_atomic*) ||
  32                 'after-spinlock (*smp_mb__after_spinlock*) ||
  33                 'after-unlock-lock (*smp_mb__after_unlock_lock*)
  34 instructions F[Barriers]
  35
  36 (* Compute matching pairs of nested Rcu-lock and Rcu-unlock *)
  37 let matched = let rec
  38             unmatched-locks = Rcu-lock \ domain(matched)
  39         and unmatched-unlocks = Rcu-unlock \ range(matched)
  40         and unmatched = unmatched-locks | unmatched-unlocks
  41         and unmatched-po = [unmatched] ; po ; [unmatched]
  42         and unmatched-locks-to-unlocks =
  43                 [unmatched-locks] ; po ; [unmatched-unlocks]
  44         and matched = matched | (unmatched-locks-to-unlocks \
  45                 (unmatched-po ; unmatched-po))
  46         in matched
  47
  48 (* Validate nesting *)
  49 flag ~empty Rcu-lock \ domain(matched) as unbalanced-rcu-locking
  50 flag ~empty Rcu-unlock \ range(matched) as unbalanced-rcu-locking
  51
  52 (* Outermost level of nesting only *)
  53 let crit = matched \ (po^-1 ; matched ; po^-1)