zfs/config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUBMIT_BIO
  12         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  13         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  14         ZFS_AC_KERNEL_TYPE_FMODE_T
  15         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_RW_BARRIER
  32         ZFS_AC_KERNEL_BIO_RW_DISCARD
  33         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  34         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  36         ZFS_AC_KERNEL_GET_DISK_RO
  37         ZFS_AC_KERNEL_GET_GENDISK
  38         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  39         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  40         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  41         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  42         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  43         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  44         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  45         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  46         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  47         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  48         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  49         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  50         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  51         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  52         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  53         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  54         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  55         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  57         ZFS_AC_KERNE_GET_ACL_HANDLE_CACHE
  58         ZFS_AC_KERNEL_SHOW_OPTIONS
  59         ZFS_AC_KERNEL_FILE_INODE
  60         ZFS_AC_KERNEL_FSYNC
  61         ZFS_AC_KERNEL_EVICT_INODE
  62         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  63         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  64         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  65         ZFS_AC_KERNEL_FALLOCATE
  66         ZFS_AC_KERNEL_AIO_FSYNC
  67         ZFS_AC_KERNEL_MKDIR_UMODE_T
  68         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  69         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  70         ZFS_AC_KERNEL_GET_LINK
  71         ZFS_AC_KERNEL_PUT_LINK
  72         ZFS_AC_KERNEL_TRUNCATE_RANGE
  73         ZFS_AC_KERNEL_AUTOMOUNT
  74         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  75         ZFS_AC_KERNEL_COMMIT_METADATA
  76         ZFS_AC_KERNEL_CLEAR_INODE
  77         ZFS_AC_KERNEL_SETATTR_PREPARE
  78         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  79         ZFS_AC_KERNEL_D_MAKE_ROOT
  80         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  81         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  82         ZFS_AC_KERNEL_D_SET_D_OP
  83         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  84         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  85         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  86         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  87         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  88         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  89         ZFS_AC_KERNEL_MOUNT_NODEV
  90         ZFS_AC_KERNEL_SHRINK
  91         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  92         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  93         ZFS_AC_KERNEL_S_D_OP
  94         ZFS_AC_KERNEL_BDI_SETUP_AND_REGISTER
  95         ZFS_AC_KERNEL_SET_NLINK
  96         ZFS_AC_KERNEL_ELEVATOR_CHANGE
  97         ZFS_AC_KERNEL_5ARG_SGET
  98         ZFS_AC_KERNEL_LSEEK_EXECUTE
  99         ZFS_AC_KERNEL_VFS_ITERATE
 100         ZFS_AC_KERNEL_VFS_RW_ITERATE
 101         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 102         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 103         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 104         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 105         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 106         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 107         ZFS_AC_KERNEL_USE_REQ_FLAGS
 108
 109         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 110                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 111         ])
 112         AC_SUBST(KERNELMAKE_PARAMS)
 113
 114
 115         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 116         dnl # compiler options are added by the kernel build system.
 117         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 118         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 119         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 120         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 121
 122         AC_SUBST(KERNELCPPFLAGS)
 123 ])
 124
 125 dnl #
 126 dnl # Detect name used for Module.symvers file in kernel
 127 dnl #
 128 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 129         modpost=$LINUX/scripts/Makefile.modpost
 130         AC_MSG_CHECKING([kernel file name for module symbols])
 131         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 132                 AS_IF([grep -q Modules.symvers $modpost], [
 133                         LINUX_SYMBOLS=Modules.symvers
 134                 ], [
 135                         LINUX_SYMBOLS=Module.symvers
 136                 ])
 137
 138                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 139                         AC_MSG_ERROR([
 140         *** Please make sure the kernel devel package for your distribution
 141         *** is installed.  If you are building with a custom kernel, make sure the
 142         *** kernel is configured, built, and the '--with-linux=PATH' configure
 143         *** option refers to the location of the kernel source.])
 144                 ])
 145         ], [
 146                 LINUX_SYMBOLS=NONE
 147         ])
 148         AC_MSG_RESULT($LINUX_SYMBOLS)
 149         AC_SUBST(LINUX_SYMBOLS)
 150 ])
 151
 152 dnl #
 153 dnl # Detect the kernel to be built against
 154 dnl #
 155 AC_DEFUN([ZFS_AC_KERNEL], [
 156         AC_ARG_WITH([linux],
 157                 AS_HELP_STRING([--with-linux=PATH],
 158                 [Path to kernel source]),
 159                 [kernelsrc="$withval"])
 160
 161         AC_ARG_WITH(linux-obj,
 162                 AS_HELP_STRING([--with-linux-obj=PATH],
 163                 [Path to kernel build objects]),
 164                 [kernelbuild="$withval"])
 165
 166         AC_MSG_CHECKING([kernel source directory])
 167         AS_IF([test -z "$kernelsrc"], [
 168                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 169                         headersdir="/lib/modules/$(uname -r)/source"
 170                         sourcelink=$(readlink -f "$headersdir")
 171                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 172                         headersdir="/lib/modules/$(uname -r)/build"
 173                         sourcelink=$(readlink -f "$headersdir")
 174                 ], [
 175                         sourcelink=$(ls -1d /usr/src/kernels/* \
 176                                      /usr/src/linux-* \
 177                                      2>/dev/null | grep -v obj | tail -1)
 178                 ])
 179
 180                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 181                         kernelsrc=`readlink -f ${sourcelink}`
 182                 ], [
 183                         kernelsrc="[Not found]"
 184                 ])
 185         ], [
 186                 AS_IF([test "$kernelsrc" = "NONE"], [
 187                         kernsrcver=NONE
 188                 ])
 189         ])
 190
 191         AC_MSG_RESULT([$kernelsrc])
 192         AS_IF([test ! -d "$kernelsrc"], [
 193                 AC_MSG_ERROR([
 194         *** Please make sure the kernel devel package for your distribution
 195         *** is installed and then try again.  If that fails, you can specify the
 196         *** location of the kernel source with the '--with-linux=PATH' option.])
 197         ])
 198
 199         AC_MSG_CHECKING([kernel build directory])
 200         AS_IF([test -z "$kernelbuild"], [
 201                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 202                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 203                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 204                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 205                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 206                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 207                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 208                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 209                 ], [
 210                         kernelbuild=${kernelsrc}
 211                 ])
 212         ])
 213         AC_MSG_RESULT([$kernelbuild])
 214
 215         AC_MSG_CHECKING([kernel source version])
 216         utsrelease1=$kernelbuild/include/linux/version.h
 217         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 218         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 219         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 220                 utsrelease=linux/version.h
 221         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 222                 utsrelease=linux/utsrelease.h
 223         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 224                 utsrelease=generated/utsrelease.h
 225         ])
 226
 227         AS_IF([test "$utsrelease"], [
 228                 kernsrcver=`(echo "#include <$utsrelease>";
 229                              echo "kernsrcver=UTS_RELEASE") |
 230                              cpp -I $kernelbuild/include |
 231                              grep "^kernsrcver=" | cut -d \" -f 2`
 232
 233                 AS_IF([test -z "$kernsrcver"], [
 234                         AC_MSG_RESULT([Not found])
 235                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 236                 ])
 237         ], [
 238                 AC_MSG_RESULT([Not found])
 239                 if test "x$enable_linux_builtin" != xyes; then
 240                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 241                 else
 242                         AC_MSG_ERROR([
 243         *** Cannot find UTS_RELEASE definition.
 244         *** Please run 'make prepare' inside the kernel source tree.])
 245                 fi
 246         ])
 247
 248         AC_MSG_RESULT([$kernsrcver])
 249
 250         LINUX=${kernelsrc}
 251         LINUX_OBJ=${kernelbuild}
 252         LINUX_VERSION=${kernsrcver}
 253
 254         AC_SUBST(LINUX)
 255         AC_SUBST(LINUX_OBJ)
 256         AC_SUBST(LINUX_VERSION)
 257
 258         ZFS_AC_MODULE_SYMVERS
 259 ])
 260
 261
 262 dnl #
 263 dnl # Detect the SPL module to be built against
 264 dnl #
 265 AC_DEFUN([ZFS_AC_SPL], [
 266         AC_ARG_WITH([spl],
 267                 AS_HELP_STRING([--with-spl=PATH],
 268                 [Path to spl source]),
 269                 [splsrc="$withval"])
 270
 271         AC_ARG_WITH([spl-obj],
 272                 AS_HELP_STRING([--with-spl-obj=PATH],
 273                 [Path to spl build objects]),
 274                 [splbuild="$withval"])
 275
 276         AC_ARG_WITH([spl-timeout],
 277                 AS_HELP_STRING([--with-spl-timeout=SECS],
 278                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 279                 [timeout="$withval"], [timeout=0])
 280
 281         dnl #
 282         dnl # The existence of spl.release.in is used to identify a valid
 283         dnl # source directory.  In order of preference:
 284         dnl #
 285         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 286         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 287         splsrc2="/usr/local/src/spl-${VERSION}"
 288         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 289         splsrc4="/usr/src/spl-${VERSION}"
 290         splsrc5="../spl/"
 291         splsrc6="$LINUX"
 292
 293         AC_MSG_CHECKING([spl source directory])
 294         AS_IF([test -z "${splsrc}"], [
 295                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 296                         splsrc=${splsrc0}
 297                 ], [ test -e "${splsrc1}/spl.release.in"], [
 298                         splsrc=${splsrc1}
 299                 ], [ test -e "${splsrc2}/spl.release.in"], [
 300                         splsrc=${splsrc2}
 301                 ], [ test -e "${splsrc3}/spl.release.in"], [
 302                         splsrc=$(readlink -f "${splsrc3}")
 303                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 304                         splsrc=${splsrc4}
 305                 ], [ test -e "${splsrc5}/spl.release.in"], [
 306                         splsrc=$(readlink -f "${splsrc5}")
 307                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 308                         splsrc=${splsrc6}
 309                 ], [
 310                         splsrc="[Not found]"
 311                 ])
 312         ], [
 313                 AS_IF([test "$splsrc" = "NONE"], [
 314                         splbuild=NONE
 315                         splsrcver=NONE
 316                 ])
 317         ])
 318
 319         AC_MSG_RESULT([$splsrc])
 320         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 321                 AC_MSG_ERROR([
 322         *** Please make sure the kmod spl devel package for your distribution
 323         *** is installed then try again.  If that fails you can specify the
 324         *** location of the spl source with the '--with-spl=PATH' option.])
 325         ])
 326
 327         dnl #
 328         dnl # The existence of the spl_config.h is used to identify a valid
 329         dnl # spl object directory.  In many cases the object and source
 330         dnl # directory are the same, however the objects may also reside
 331         dnl # is a subdirectory named after the kernel version.
 332         dnl #
 333         dnl # This file is supposed to be available after DKMS finishes
 334         dnl # building the SPL kernel module for the target kernel.  The
 335         dnl # '--with-spl-timeout' option can be passed to pause here,
 336         dnl # waiting for the file to appear from a concurrently building
 337         dnl # SPL package.
 338         dnl #
 339         AC_MSG_CHECKING([spl build directory])
 340         while true; do
 341                 AS_IF([test -z "$splbuild"], [
 342                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 343                                 splbuild="${splsrc}/${LINUX_VERSION}"
 344                         ], [ test -e "${splsrc}/spl_config.h" ], [
 345                                 splbuild="${splsrc}"
 346                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 347                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 348                         ], [
 349                                 splbuild="[Not found]"
 350                         ])
 351                 ])
 352                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 353                         break;
 354                 ], [
 355                         sleep 1
 356                         timeout=$((timeout-1))
 357                 ])
 358         done
 359
 360         AC_MSG_RESULT([$splbuild])
 361         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 362                 AC_MSG_ERROR([
 363         *** Please make sure the kmod spl devel <kernel> package for your
 364         *** distribution is installed then try again.  If that fails you
 365         *** can specify the location of the spl objects with the
 366         *** '--with-spl-obj=PATH' option.])
 367         ])
 368
 369         AC_MSG_CHECKING([spl source version])
 370         AS_IF([test -r $splbuild/spl_config.h &&
 371                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 372
 373                 splsrcver=`(echo "#include <spl_config.h>";
 374                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 375                             cpp -I $splbuild |
 376                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 377         ])
 378
 379         AS_IF([test -z "$splsrcver"], [
 380                 AC_MSG_RESULT([Not found])
 381                 AC_MSG_ERROR([
 382         *** Cannot determine the version of the spl source.
 383         *** Please prepare the spl source before running this script])
 384         ])
 385
 386         AC_MSG_RESULT([$splsrcver])
 387
 388         SPL=${splsrc}
 389         SPL_OBJ=${splbuild}
 390         SPL_VERSION=${splsrcver}
 391
 392         AC_SUBST(SPL)
 393         AC_SUBST(SPL_OBJ)
 394         AC_SUBST(SPL_VERSION)
 395
 396         dnl #
 397         dnl # Detect the name used for the SPL Module.symvers file.  If one
 398         dnl # does not exist this is likely because the SPL has been configured
 399         dnl # but not built.  The '--with-spl-timeout' option can be passed
 400         dnl # to pause here, waiting for the file to appear from a concurrently
 401         dnl # building SPL package.  If the file does not appear in time, a good
 402         dnl # guess is made as to what this file will be named based on what it
 403         dnl # is named in the kernel build products.  This file will first be
 404         dnl # used at link time so if the guess is wrong the build will fail
 405         dnl # then.  This unfortunately means the ZFS package does not contain a
 406         dnl # reliable mechanism to detect symbols exported by the SPL at
 407         dnl # configure time.
 408         dnl #
 409         AC_MSG_CHECKING([spl file name for module symbols])
 410         SPL_SYMBOLS=NONE
 411
 412         while true; do
 413                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 414                         SPL_SYMBOLS=Module.symvers
 415                 ], [test -r $SPL_OBJ/Modules.symvers], [
 416                         SPL_SYMBOLS=Modules.symvers
 417                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 418                         SPL_SYMBOLS=Module.symvers
 419                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 420                         SPL_SYMBOLS=Modules.symvers
 421                 ])
 422
 423                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 424                         break;
 425                 ], [
 426                         sleep 1
 427                         timeout=$((timeout-1))
 428                 ])
 429         done
 430
 431         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 432                 SPL_SYMBOLS=$LINUX_SYMBOLS
 433         ])
 434
 435         AC_MSG_RESULT([$SPL_SYMBOLS])
 436         AC_SUBST(SPL_SYMBOLS)
 437 ])
 438
 439 dnl #
 440 dnl # Basic toolchain sanity check.
 441 dnl #
 442 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 443         AC_MSG_CHECKING([whether modules can be built])
 444         ZFS_LINUX_TRY_COMPILE([],[],[
 445                 AC_MSG_RESULT([yes])
 446         ],[
 447                 AC_MSG_RESULT([no])
 448                 if test "x$enable_linux_builtin" != xyes; then
 449                         AC_MSG_ERROR([*** Unable to build an empty module.])
 450                 else
 451                         AC_MSG_ERROR([
 452         *** Unable to build an empty module.
 453         *** Please run 'make scripts' inside the kernel source tree.])
 454                 fi
 455         ])
 456 ])
 457
 458 dnl #
 459 dnl # Certain kernel build options are not supported.  These must be
 460 dnl # detected at configure time and cause a build failure.  Otherwise
 461 dnl # modules may be successfully built that behave incorrectly.
 462 dnl #
 463 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 464         AS_IF([test "x$cross_compiling" != xyes], [
 465                 AC_RUN_IFELSE([
 466                         AC_LANG_PROGRAM([
 467                                 #include "$LINUX/include/linux/license.h"
 468                         ], [
 469                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 470                         ])
 471                 ], [
 472                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 473                             [Define to 1 if GPL-only symbols can be used])
 474                 ], [
 475                 ])
 476         ])
 477
 478         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 479 ])
 480
 481 dnl #
 482 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 483 dnl #
 484 dnl # This is typically only set for debug kernels because it comes with
 485 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 486 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 487 dnl # This will cause a failure at link time which we'd rather know about
 488 dnl # at compile time.
 489 dnl #
 490 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 491 dnl # with the upstream community we add a check to detect this case.
 492 dnl #
 493 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 494
 495         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 496                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 497                 tmp_flags="$EXTRA_KCFLAGS"
 498                 ZFS_LINUX_TRY_COMPILE([
 499                         #include <linux/module.h>
 500                         #include <linux/mutex.h>
 501
 502                         MODULE_LICENSE("$ZFS_META_LICENSE");
 503                 ],[
 504                         struct mutex lock;
 505
 506                         mutex_init(&lock);
 507                         mutex_lock(&lock);
 508                         mutex_unlock(&lock);
 509                 ],[
 510                         AC_MSG_RESULT(no)
 511                 ],[
 512                         AC_MSG_RESULT(yes)
 513                         AC_MSG_ERROR([
 514         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 515         *** with the CDDL license and will prevent the module linking stage
 516         *** from succeeding.  You must rebuild your kernel without this
 517         *** option enabled.])
 518                 ])
 519                 EXTRA_KCFLAGS="$tmp_flags"
 520         ], [])
 521 ])
 522
 523 dnl #
 524 dnl # ZFS_LINUX_CONFTEST_H
 525 dnl #
 526 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 527 cat - <<_ACEOF >conftest.h
 528 $1
 529 _ACEOF
 530 ])
 531
 532 dnl #
 533 dnl # ZFS_LINUX_CONFTEST_C
 534 dnl #
 535 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 536 cat confdefs.h - <<_ACEOF >conftest.c
 537 $1
 538 _ACEOF
 539 ])
 540
 541 dnl #
 542 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 543 dnl #
 544 m4_define([ZFS_LANG_PROGRAM], [
 545 $1
 546 int
 547 main (void)
 548 {
 549 dnl Do *not* indent the following line: there may be CPP directives.
 550 dnl Don't move the `;' right after for the same reason.
 551 $2
 552   ;
 553   return 0;
 554 }
 555 ])
 556
 557 dnl #
 558 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 559 dnl #
 560 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 561         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 562         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 563         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 564         echo "obj-m := conftest.o" >build/Makefile
 565         modpost_flag=''
 566         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 567         AS_IF(
 568                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 569                 [$4],
 570                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 571         )
 572         rm -Rf build
 573 ])
 574
 575 dnl #
 576 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 577 dnl #
 578 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 579         [ZFS_LINUX_COMPILE_IFELSE(
 580         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 581         [modules],
 582         [test -s build/conftest.o],
 583         [$3], [$4])
 584 ])
 585
 586 dnl #
 587 dnl # ZFS_LINUX_CONFIG
 588 dnl #
 589 AC_DEFUN([ZFS_LINUX_CONFIG],
 590         [AC_MSG_CHECKING([whether Linux was built with CONFIG_$1])
 591         ZFS_LINUX_TRY_COMPILE([
 592                 #include <linux/module.h>
 593         ],[
 594                 #ifndef CONFIG_$1
 595                 #error CONFIG_$1 not #defined
 596                 #endif
 597         ],[
 598                 AC_MSG_RESULT([yes])
 599                 $2
 600         ],[
 601                 AC_MSG_RESULT([no])
 602                 $3
 603         ])
 604 ])
 605
 606 dnl #
 607 dnl # ZFS_CHECK_SYMBOL_EXPORT
 608 dnl # check symbol exported or not
 609 dnl #
 610 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 611         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 612                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 613         rc=$?
 614         if test $rc -ne 0; then
 615                 export=0
 616                 for file in $2; do
 617                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 618                                 "$LINUX/$file" 2>/dev/null
 619                         rc=$?
 620                         if test $rc -eq 0; then
 621                                 export=1
 622                                 break;
 623                         fi
 624                 done
 625                 if test $export -eq 0; then :
 626                         $4
 627                 else :
 628                         $3
 629                 fi
 630         else :
 631                 $3
 632         fi
 633 ])
 634
 635 dnl #
 636 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 637 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 638 dnl # is called if not compiling for builtin
 639 dnl #
 640 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 641         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 642         if test $rc -ne 0; then :
 643                 $6
 644         else
 645                 if test "x$enable_linux_builtin" != xyes; then
 646                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 647                 fi
 648                 if test $rc -ne 0; then :
 649                         $6
 650                 else :
 651                         $5
 652                 fi
 653         fi
 654 ])
 655
 656 dnl #
 657 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 658 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 659 dnl # provided via the fifth parameter
 660 dnl #
 661 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 662         [ZFS_LINUX_COMPILE_IFELSE(
 663         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 664         [modules],
 665         [test -s build/conftest.o],
 666         [$3], [$4], [$5])
 667 ])