zfs/config/kernel.m4

   1 dnl #
   2 dnl # Default ZFS kernel configuration
   3 dnl #
   4 AC_DEFUN([ZFS_AC_CONFIG_KERNEL], [
   5         ZFS_AC_KERNEL
   6         ZFS_AC_SPL
   7         ZFS_AC_TEST_MODULE
   8         ZFS_AC_KERNEL_CONFIG
   9         ZFS_AC_KERNEL_DECLARE_EVENT_CLASS
  10         ZFS_AC_KERNEL_CURRENT_BIO_TAIL
  11         ZFS_AC_KERNEL_SUBMIT_BIO
  12         ZFS_AC_KERNEL_BDEV_BLOCK_DEVICE_OPERATIONS
  13         ZFS_AC_KERNEL_BLOCK_DEVICE_OPERATIONS_RELEASE_VOID
  14         ZFS_AC_KERNEL_TYPE_FMODE_T
  15         ZFS_AC_KERNEL_KOBJ_NAME_LEN
  16         ZFS_AC_KERNEL_3ARG_BLKDEV_GET
  17         ZFS_AC_KERNEL_BLKDEV_GET_BY_PATH
  18         ZFS_AC_KERNEL_OPEN_BDEV_EXCLUSIVE
  19         ZFS_AC_KERNEL_LOOKUP_BDEV
  20         ZFS_AC_KERNEL_INVALIDATE_BDEV_ARGS
  21         ZFS_AC_KERNEL_BDEV_LOGICAL_BLOCK_SIZE
  22         ZFS_AC_KERNEL_BDEV_PHYSICAL_BLOCK_SIZE
  23         ZFS_AC_KERNEL_BIO_BVEC_ITER
  24         ZFS_AC_KERNEL_BIO_FAILFAST_DTD
  25         ZFS_AC_KERNEL_REQ_FAILFAST_MASK
  26         ZFS_AC_KERNEL_REQ_OP_DISCARD
  27         ZFS_AC_KERNEL_REQ_OP_SECURE_ERASE
  28         ZFS_AC_KERNEL_REQ_OP_FLUSH
  29         ZFS_AC_KERNEL_BIO_BI_OPF
  30         ZFS_AC_KERNEL_BIO_END_IO_T_ARGS
  31         ZFS_AC_KERNEL_BIO_BI_STATUS
  32         ZFS_AC_KERNEL_BIO_RW_BARRIER
  33         ZFS_AC_KERNEL_BIO_RW_DISCARD
  34         ZFS_AC_KERNEL_BLK_QUEUE_FLUSH
  35         ZFS_AC_KERNEL_BLK_QUEUE_MAX_HW_SECTORS
  36         ZFS_AC_KERNEL_BLK_QUEUE_MAX_SEGMENTS
  37         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BIO_RW_UNPLUG
  38         ZFS_AC_KERNEL_BLK_QUEUE_HAVE_BLK_PLUG
  39         ZFS_AC_KERNEL_GET_DISK_RO
  40         ZFS_AC_KERNEL_GET_GENDISK
  41         ZFS_AC_KERNEL_HAVE_BIO_SET_OP_ATTRS
  42         ZFS_AC_KERNEL_GENERIC_READLINK_GLOBAL
  43         ZFS_AC_KERNEL_DISCARD_GRANULARITY
  44         ZFS_AC_KERNEL_CONST_XATTR_HANDLER
  45         ZFS_AC_KERNEL_XATTR_HANDLER_NAME
  46         ZFS_AC_KERNEL_XATTR_HANDLER_GET
  47         ZFS_AC_KERNEL_XATTR_HANDLER_SET
  48         ZFS_AC_KERNEL_XATTR_HANDLER_LIST
  49         ZFS_AC_KERNEL_INODE_OWNER_OR_CAPABLE
  50         ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
  51         ZFS_AC_KERNEL_POSIX_ACL_RELEASE
  52         ZFS_AC_KERNEL_SET_CACHED_ACL_USABLE
  53         ZFS_AC_KERNEL_POSIX_ACL_CHMOD
  54         ZFS_AC_KERNEL_POSIX_ACL_EQUIV_MODE_WANTS_UMODE_T
  55         ZFS_AC_KERNEL_POSIX_ACL_VALID_WITH_NS
  56         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION
  57         ZFS_AC_KERNEL_INODE_OPERATIONS_PERMISSION_WITH_NAMEIDATA
  58         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL
  59         ZFS_AC_KERNEL_INODE_OPERATIONS_CHECK_ACL_WITH_FLAGS
  60         ZFS_AC_KERNEL_INODE_OPERATIONS_GET_ACL
  61         ZFS_AC_KERNEL_INODE_OPERATIONS_SET_ACL
  62         ZFS_AC_KERNEL_INODE_OPERATIONS_GETATTR
  63         ZFS_AC_KERNEL_GET_ACL_HANDLE_CACHE
  64         ZFS_AC_KERNEL_SHOW_OPTIONS
  65         ZFS_AC_KERNEL_FILE_INODE
  66         ZFS_AC_KERNEL_FSYNC
  67         ZFS_AC_KERNEL_EVICT_INODE
  68         ZFS_AC_KERNEL_DIRTY_INODE_WITH_FLAGS
  69         ZFS_AC_KERNEL_NR_CACHED_OBJECTS
  70         ZFS_AC_KERNEL_FREE_CACHED_OBJECTS
  71         ZFS_AC_KERNEL_FALLOCATE
  72         ZFS_AC_KERNEL_AIO_FSYNC
  73         ZFS_AC_KERNEL_MKDIR_UMODE_T
  74         ZFS_AC_KERNEL_LOOKUP_NAMEIDATA
  75         ZFS_AC_KERNEL_CREATE_NAMEIDATA
  76         ZFS_AC_KERNEL_GET_LINK
  77         ZFS_AC_KERNEL_PUT_LINK
  78         ZFS_AC_KERNEL_TRUNCATE_RANGE
  79         ZFS_AC_KERNEL_AUTOMOUNT
  80         ZFS_AC_KERNEL_ENCODE_FH_WITH_INODE
  81         ZFS_AC_KERNEL_COMMIT_METADATA
  82         ZFS_AC_KERNEL_CLEAR_INODE
  83         ZFS_AC_KERNEL_SETATTR_PREPARE
  84         ZFS_AC_KERNEL_INSERT_INODE_LOCKED
  85         ZFS_AC_KERNEL_D_MAKE_ROOT
  86         ZFS_AC_KERNEL_D_OBTAIN_ALIAS
  87         ZFS_AC_KERNEL_D_PRUNE_ALIASES
  88         ZFS_AC_KERNEL_D_SET_D_OP
  89         ZFS_AC_KERNEL_D_REVALIDATE_NAMEIDATA
  90         ZFS_AC_KERNEL_CONST_DENTRY_OPERATIONS
  91         ZFS_AC_KERNEL_CHECK_DISK_SIZE_CHANGE
  92         ZFS_AC_KERNEL_TRUNCATE_SETSIZE
  93         ZFS_AC_KERNEL_6ARGS_SECURITY_INODE_INIT_SECURITY
  94         ZFS_AC_KERNEL_CALLBACK_SECURITY_INODE_INIT_SECURITY
  95         ZFS_AC_KERNEL_MOUNT_NODEV
  96         ZFS_AC_KERNEL_SHRINK
  97         ZFS_AC_KERNEL_SHRINK_CONTROL_HAS_NID
  98         ZFS_AC_KERNEL_S_INSTANCES_LIST_HEAD
  99         ZFS_AC_KERNEL_S_D_OP
 100         ZFS_AC_KERNEL_BDI
 101         ZFS_AC_KERNEL_SET_NLINK
 102         ZFS_AC_KERNEL_ELEVATOR_CHANGE
 103         ZFS_AC_KERNEL_5ARG_SGET
 104         ZFS_AC_KERNEL_LSEEK_EXECUTE
 105         ZFS_AC_KERNEL_VFS_ITERATE
 106         ZFS_AC_KERNEL_VFS_RW_ITERATE
 107         ZFS_AC_KERNEL_GENERIC_WRITE_CHECKS
 108         ZFS_AC_KERNEL_KMAP_ATOMIC_ARGS
 109         ZFS_AC_KERNEL_FOLLOW_DOWN_ONE
 110         ZFS_AC_KERNEL_MAKE_REQUEST_FN
 111         ZFS_AC_KERNEL_GENERIC_IO_ACCT
 112         ZFS_AC_KERNEL_RENAME_WANTS_FLAGS
 113         ZFS_AC_KERNEL_HAVE_GENERIC_SETXATTR
 114         ZFS_AC_KERNEL_CURRENT_TIME
 115
 116         AS_IF([test "$LINUX_OBJ" != "$LINUX"], [
 117                 KERNELMAKE_PARAMS="$KERNELMAKE_PARAMS O=$LINUX_OBJ"
 118         ])
 119         AC_SUBST(KERNELMAKE_PARAMS)
 120
 121
 122         dnl # -Wall -fno-strict-aliasing -Wstrict-prototypes and other
 123         dnl # compiler options are added by the kernel build system.
 124         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_UNUSED_BUT_SET_VARIABLE"
 125         KERNELCPPFLAGS="$KERNELCPPFLAGS $NO_BOOL_COMPARE"
 126         KERNELCPPFLAGS="$KERNELCPPFLAGS -DHAVE_SPL -D_KERNEL"
 127         KERNELCPPFLAGS="$KERNELCPPFLAGS -DTEXT_DOMAIN=\\\"zfs-linux-kernel\\\""
 128
 129         AC_SUBST(KERNELCPPFLAGS)
 130 ])
 131
 132 dnl #
 133 dnl # Detect name used for Module.symvers file in kernel
 134 dnl #
 135 AC_DEFUN([ZFS_AC_MODULE_SYMVERS], [
 136         modpost=$LINUX/scripts/Makefile.modpost
 137         AC_MSG_CHECKING([kernel file name for module symbols])
 138         AS_IF([test "x$enable_linux_builtin" != xyes -a -f "$modpost"], [
 139                 AS_IF([grep -q Modules.symvers $modpost], [
 140                         LINUX_SYMBOLS=Modules.symvers
 141                 ], [
 142                         LINUX_SYMBOLS=Module.symvers
 143                 ])
 144
 145                 AS_IF([test ! -f "$LINUX_OBJ/$LINUX_SYMBOLS"], [
 146                         AC_MSG_ERROR([
 147         *** Please make sure the kernel devel package for your distribution
 148         *** is installed.  If you are building with a custom kernel, make sure the
 149         *** kernel is configured, built, and the '--with-linux=PATH' configure
 150         *** option refers to the location of the kernel source.])
 151                 ])
 152         ], [
 153                 LINUX_SYMBOLS=NONE
 154         ])
 155         AC_MSG_RESULT($LINUX_SYMBOLS)
 156         AC_SUBST(LINUX_SYMBOLS)
 157 ])
 158
 159 dnl #
 160 dnl # Detect the kernel to be built against
 161 dnl #
 162 AC_DEFUN([ZFS_AC_KERNEL], [
 163         AC_ARG_WITH([linux],
 164                 AS_HELP_STRING([--with-linux=PATH],
 165                 [Path to kernel source]),
 166                 [kernelsrc="$withval"])
 167
 168         AC_ARG_WITH(linux-obj,
 169                 AS_HELP_STRING([--with-linux-obj=PATH],
 170                 [Path to kernel build objects]),
 171                 [kernelbuild="$withval"])
 172
 173         AC_MSG_CHECKING([kernel source directory])
 174         AS_IF([test -z "$kernelsrc"], [
 175                 AS_IF([test -e "/lib/modules/$(uname -r)/source"], [
 176                         headersdir="/lib/modules/$(uname -r)/source"
 177                         sourcelink=$(readlink -f "$headersdir")
 178                 ], [test -e "/lib/modules/$(uname -r)/build"], [
 179                         headersdir="/lib/modules/$(uname -r)/build"
 180                         sourcelink=$(readlink -f "$headersdir")
 181                 ], [
 182                         sourcelink=$(ls -1d /usr/src/kernels/* \
 183                                      /usr/src/linux-* \
 184                                      2>/dev/null | grep -v obj | tail -1)
 185                 ])
 186
 187                 AS_IF([test -n "$sourcelink" && test -e ${sourcelink}], [
 188                         kernelsrc=`readlink -f ${sourcelink}`
 189                 ], [
 190                         kernelsrc="[Not found]"
 191                 ])
 192         ], [
 193                 AS_IF([test "$kernelsrc" = "NONE"], [
 194                         kernsrcver=NONE
 195                 ])
 196         ])
 197
 198         AC_MSG_RESULT([$kernelsrc])
 199         AS_IF([test ! -d "$kernelsrc"], [
 200                 AC_MSG_ERROR([
 201         *** Please make sure the kernel devel package for your distribution
 202         *** is installed and then try again.  If that fails, you can specify the
 203         *** location of the kernel source with the '--with-linux=PATH' option.])
 204         ])
 205
 206         AC_MSG_CHECKING([kernel build directory])
 207         AS_IF([test -z "$kernelbuild"], [
 208                 AS_IF([test -e "/lib/modules/$(uname -r)/build"], [
 209                         kernelbuild=`readlink -f /lib/modules/$(uname -r)/build`
 210                 ], [test -d ${kernelsrc}-obj/${target_cpu}/${target_cpu}], [
 211                         kernelbuild=${kernelsrc}-obj/${target_cpu}/${target_cpu}
 212                 ], [test -d ${kernelsrc}-obj/${target_cpu}/default], [
 213                         kernelbuild=${kernelsrc}-obj/${target_cpu}/default
 214                 ], [test -d `dirname ${kernelsrc}`/build-${target_cpu}], [
 215                         kernelbuild=`dirname ${kernelsrc}`/build-${target_cpu}
 216                 ], [
 217                         kernelbuild=${kernelsrc}
 218                 ])
 219         ])
 220         AC_MSG_RESULT([$kernelbuild])
 221
 222         AC_MSG_CHECKING([kernel source version])
 223         utsrelease1=$kernelbuild/include/linux/version.h
 224         utsrelease2=$kernelbuild/include/linux/utsrelease.h
 225         utsrelease3=$kernelbuild/include/generated/utsrelease.h
 226         AS_IF([test -r $utsrelease1 && fgrep -q UTS_RELEASE $utsrelease1], [
 227                 utsrelease=linux/version.h
 228         ], [test -r $utsrelease2 && fgrep -q UTS_RELEASE $utsrelease2], [
 229                 utsrelease=linux/utsrelease.h
 230         ], [test -r $utsrelease3 && fgrep -q UTS_RELEASE $utsrelease3], [
 231                 utsrelease=generated/utsrelease.h
 232         ])
 233
 234         AS_IF([test "$utsrelease"], [
 235                 kernsrcver=`(echo "#include <$utsrelease>";
 236                              echo "kernsrcver=UTS_RELEASE") |
 237                              cpp -I $kernelbuild/include |
 238                              grep "^kernsrcver=" | cut -d \" -f 2`
 239
 240                 AS_IF([test -z "$kernsrcver"], [
 241                         AC_MSG_RESULT([Not found])
 242                         AC_MSG_ERROR([*** Cannot determine kernel version.])
 243                 ])
 244         ], [
 245                 AC_MSG_RESULT([Not found])
 246                 if test "x$enable_linux_builtin" != xyes; then
 247                         AC_MSG_ERROR([*** Cannot find UTS_RELEASE definition.])
 248                 else
 249                         AC_MSG_ERROR([
 250         *** Cannot find UTS_RELEASE definition.
 251         *** Please run 'make prepare' inside the kernel source tree.])
 252                 fi
 253         ])
 254
 255         AC_MSG_RESULT([$kernsrcver])
 256
 257         LINUX=${kernelsrc}
 258         LINUX_OBJ=${kernelbuild}
 259         LINUX_VERSION=${kernsrcver}
 260
 261         AC_SUBST(LINUX)
 262         AC_SUBST(LINUX_OBJ)
 263         AC_SUBST(LINUX_VERSION)
 264
 265         ZFS_AC_MODULE_SYMVERS
 266 ])
 267
 268
 269 dnl #
 270 dnl # Detect the SPL module to be built against
 271 dnl #
 272 AC_DEFUN([ZFS_AC_SPL], [
 273         AC_ARG_WITH([spl],
 274                 AS_HELP_STRING([--with-spl=PATH],
 275                 [Path to spl source]),
 276                 [splsrc="$withval"])
 277
 278         AC_ARG_WITH([spl-obj],
 279                 AS_HELP_STRING([--with-spl-obj=PATH],
 280                 [Path to spl build objects]),
 281                 [splbuild="$withval"])
 282
 283         AC_ARG_WITH([spl-timeout],
 284                 AS_HELP_STRING([--with-spl-timeout=SECS],
 285                 [Wait SECS for SPL header and symver file @<:@default=0@:>@]),
 286                 [timeout="$withval"], [timeout=0])
 287
 288         dnl #
 289         dnl # The existence of spl.release.in is used to identify a valid
 290         dnl # source directory.  In order of preference:
 291         dnl #
 292         splsrc0="/var/lib/dkms/spl/${VERSION}/build"
 293         splsrc1="/usr/local/src/spl-${VERSION}/${LINUX_VERSION}"
 294         splsrc2="/usr/local/src/spl-${VERSION}"
 295         splsrc3="/usr/src/spl-${VERSION}/${LINUX_VERSION}"
 296         splsrc4="/usr/src/spl-${VERSION}"
 297         splsrc5="../spl/"
 298         splsrc6="$LINUX"
 299
 300         AC_MSG_CHECKING([spl source directory])
 301         AS_IF([test -z "${splsrc}"], [
 302                 AS_IF([ test -e "${splsrc0}/spl.release.in"], [
 303                         splsrc=${splsrc0}
 304                 ], [ test -e "${splsrc1}/spl.release.in"], [
 305                         splsrc=${splsrc1}
 306                 ], [ test -e "${splsrc2}/spl.release.in"], [
 307                         splsrc=${splsrc2}
 308                 ], [ test -e "${splsrc3}/spl.release.in"], [
 309                         splsrc=$(readlink -f "${splsrc3}")
 310                 ], [ test -e "${splsrc4}/spl.release.in" ], [
 311                         splsrc=${splsrc4}
 312                 ], [ test -e "${splsrc5}/spl.release.in"], [
 313                         splsrc=$(readlink -f "${splsrc5}")
 314                 ], [ test -e "${splsrc6}/spl.release.in" ], [
 315                         splsrc=${splsrc6}
 316                 ], [
 317                         splsrc="[Not found]"
 318                 ])
 319         ], [
 320                 AS_IF([test "$splsrc" = "NONE"], [
 321                         splbuild=NONE
 322                         splsrcver=NONE
 323                 ])
 324         ])
 325
 326         AC_MSG_RESULT([$splsrc])
 327         AS_IF([ test ! -e "$splsrc/spl.release.in"], [
 328                 AC_MSG_ERROR([
 329         *** Please make sure the kmod spl devel package for your distribution
 330         *** is installed then try again.  If that fails you can specify the
 331         *** location of the spl source with the '--with-spl=PATH' option.])
 332         ])
 333
 334         dnl #
 335         dnl # The existence of the spl_config.h is used to identify a valid
 336         dnl # spl object directory.  In many cases the object and source
 337         dnl # directory are the same, however the objects may also reside
 338         dnl # is a subdirectory named after the kernel version.
 339         dnl #
 340         dnl # This file is supposed to be available after DKMS finishes
 341         dnl # building the SPL kernel module for the target kernel.  The
 342         dnl # '--with-spl-timeout' option can be passed to pause here,
 343         dnl # waiting for the file to appear from a concurrently building
 344         dnl # SPL package.
 345         dnl #
 346         AC_MSG_CHECKING([spl build directory])
 347         while true; do
 348                 AS_IF([test -z "$splbuild"], [
 349                         AS_IF([ test -e "${splsrc}/${LINUX_VERSION}/spl_config.h" ], [
 350                                 splbuild="${splsrc}/${LINUX_VERSION}"
 351                         ], [ test -e "${splsrc}/spl_config.h" ], [
 352                                 splbuild="${splsrc}"
 353                         ], [ find -L "${splsrc}" -name spl_config.h 2> /dev/null | grep -wq spl_config.h ], [
 354                                 splbuild=$(find -L "${splsrc}" -name spl_config.h | sed 's,/spl_config.h,,')
 355                         ], [
 356                                 splbuild="[Not found]"
 357                         ])
 358                 ])
 359                 AS_IF([test -e "$splbuild/spl_config.h" -o $timeout -le 0], [
 360                         break;
 361                 ], [
 362                         sleep 1
 363                         timeout=$((timeout-1))
 364                 ])
 365         done
 366
 367         AC_MSG_RESULT([$splbuild])
 368         AS_IF([ ! test -e "$splbuild/spl_config.h"], [
 369                 AC_MSG_ERROR([
 370         *** Please make sure the kmod spl devel <kernel> package for your
 371         *** distribution is installed then try again.  If that fails you
 372         *** can specify the location of the spl objects with the
 373         *** '--with-spl-obj=PATH' option.])
 374         ])
 375
 376         AC_MSG_CHECKING([spl source version])
 377         AS_IF([test -r $splbuild/spl_config.h &&
 378                 fgrep -q SPL_META_VERSION $splbuild/spl_config.h], [
 379
 380                 splsrcver=`(echo "#include <spl_config.h>";
 381                             echo "splsrcver=SPL_META_VERSION-SPL_META_RELEASE") |
 382                             cpp -I $splbuild |
 383                             grep "^splsrcver=" | tr -d \" | cut -d= -f2`
 384         ])
 385
 386         AS_IF([test -z "$splsrcver"], [
 387                 AC_MSG_RESULT([Not found])
 388                 AC_MSG_ERROR([
 389         *** Cannot determine the version of the spl source.
 390         *** Please prepare the spl source before running this script])
 391         ])
 392
 393         AC_MSG_RESULT([$splsrcver])
 394
 395         SPL=${splsrc}
 396         SPL_OBJ=${splbuild}
 397         SPL_VERSION=${splsrcver}
 398
 399         AC_SUBST(SPL)
 400         AC_SUBST(SPL_OBJ)
 401         AC_SUBST(SPL_VERSION)
 402
 403         dnl #
 404         dnl # Detect the name used for the SPL Module.symvers file.  If one
 405         dnl # does not exist this is likely because the SPL has been configured
 406         dnl # but not built.  The '--with-spl-timeout' option can be passed
 407         dnl # to pause here, waiting for the file to appear from a concurrently
 408         dnl # building SPL package.  If the file does not appear in time, a good
 409         dnl # guess is made as to what this file will be named based on what it
 410         dnl # is named in the kernel build products.  This file will first be
 411         dnl # used at link time so if the guess is wrong the build will fail
 412         dnl # then.  This unfortunately means the ZFS package does not contain a
 413         dnl # reliable mechanism to detect symbols exported by the SPL at
 414         dnl # configure time.
 415         dnl #
 416         AC_MSG_CHECKING([spl file name for module symbols])
 417         SPL_SYMBOLS=NONE
 418
 419         while true; do
 420                 AS_IF([test -r $SPL_OBJ/Module.symvers], [
 421                         SPL_SYMBOLS=Module.symvers
 422                 ], [test -r $SPL_OBJ/Modules.symvers], [
 423                         SPL_SYMBOLS=Modules.symvers
 424                 ], [test -r $SPL_OBJ/module/Module.symvers], [
 425                         SPL_SYMBOLS=Module.symvers
 426                 ], [test -r $SPL_OBJ/module/Modules.symvers], [
 427                         SPL_SYMBOLS=Modules.symvers
 428                 ])
 429
 430                 AS_IF([test $SPL_SYMBOLS != NONE -o $timeout -le 0], [
 431                         break;
 432                 ], [
 433                         sleep 1
 434                         timeout=$((timeout-1))
 435                 ])
 436         done
 437
 438         AS_IF([test "$SPL_SYMBOLS" = NONE], [
 439                 SPL_SYMBOLS=$LINUX_SYMBOLS
 440         ])
 441
 442         AC_MSG_RESULT([$SPL_SYMBOLS])
 443         AC_SUBST(SPL_SYMBOLS)
 444 ])
 445
 446 dnl #
 447 dnl # Basic toolchain sanity check.
 448 dnl #
 449 AC_DEFUN([ZFS_AC_TEST_MODULE], [
 450         AC_MSG_CHECKING([whether modules can be built])
 451         ZFS_LINUX_TRY_COMPILE([],[],[
 452                 AC_MSG_RESULT([yes])
 453         ],[
 454                 AC_MSG_RESULT([no])
 455                 if test "x$enable_linux_builtin" != xyes; then
 456                         AC_MSG_ERROR([*** Unable to build an empty module.])
 457                 else
 458                         AC_MSG_ERROR([
 459         *** Unable to build an empty module.
 460         *** Please run 'make scripts' inside the kernel source tree.])
 461                 fi
 462         ])
 463 ])
 464
 465 dnl #
 466 dnl # Certain kernel build options are not supported.  These must be
 467 dnl # detected at configure time and cause a build failure.  Otherwise
 468 dnl # modules may be successfully built that behave incorrectly.
 469 dnl #
 470 AC_DEFUN([ZFS_AC_KERNEL_CONFIG], [
 471         AS_IF([test "x$cross_compiling" != xyes], [
 472                 AC_RUN_IFELSE([
 473                         AC_LANG_PROGRAM([
 474                                 #include "$LINUX/include/linux/license.h"
 475                         ], [
 476                                 return !license_is_gpl_compatible("$ZFS_META_LICENSE");
 477                         ])
 478                 ], [
 479                         AC_DEFINE([ZFS_IS_GPL_COMPATIBLE], [1],
 480                             [Define to 1 if GPL-only symbols can be used])
 481                 ], [
 482                 ])
 483         ])
 484
 485         ZFS_AC_KERNEL_CONFIG_THREAD_SIZE
 486         ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC
 487 ])
 488
 489 dnl #
 490 dnl # Check configured THREAD_SIZE
 491 dnl #
 492 dnl # The stack size will vary by architecture, but as of Linux 3.15 on x86_64
 493 dnl # the default thread stack size was increased to 16K from 8K.  Therefore,
 494 dnl # on newer kernels and some architectures stack usage optimizations can be
 495 dnl # conditionally applied to improve performance without negatively impacting
 496 dnl # stability.
 497 dnl #
 498 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_THREAD_SIZE], [
 499         AC_MSG_CHECKING([whether kernel was built with 16K or larger stacks])
 500         ZFS_LINUX_TRY_COMPILE([
 501                 #include <linux/module.h>
 502         ],[
 503                 #if (THREAD_SIZE < 16384)
 504                 #error "THREAD_SIZE is less than 16K"
 505                 #endif
 506         ],[
 507                 AC_MSG_RESULT([yes])
 508                 AC_DEFINE(HAVE_LARGE_STACKS, 1, [kernel has large stacks])
 509         ],[
 510                 AC_MSG_RESULT([no])
 511         ])
 512 ])
 513
 514 dnl #
 515 dnl # Check CONFIG_DEBUG_LOCK_ALLOC
 516 dnl #
 517 dnl # This is typically only set for debug kernels because it comes with
 518 dnl # a performance penalty.  However, when it is set it maps the non-GPL
 519 dnl # symbol mutex_lock() to the GPL-only mutex_lock_nested() symbol.
 520 dnl # This will cause a failure at link time which we'd rather know about
 521 dnl # at compile time.
 522 dnl #
 523 dnl # Since we plan to pursue making mutex_lock_nested() a non-GPL symbol
 524 dnl # with the upstream community we add a check to detect this case.
 525 dnl #
 526 AC_DEFUN([ZFS_AC_KERNEL_CONFIG_DEBUG_LOCK_ALLOC], [
 527
 528         ZFS_LINUX_CONFIG([DEBUG_LOCK_ALLOC], [
 529                 AC_MSG_CHECKING([whether mutex_lock() is GPL-only])
 530                 tmp_flags="$EXTRA_KCFLAGS"
 531                 ZFS_LINUX_TRY_COMPILE([
 532                         #include <linux/module.h>
 533                         #include <linux/mutex.h>
 534
 535                         MODULE_LICENSE("$ZFS_META_LICENSE");
 536                 ],[
 537                         struct mutex lock;
 538
 539                         mutex_init(&lock);
 540                         mutex_lock(&lock);
 541                         mutex_unlock(&lock);
 542                 ],[
 543                         AC_MSG_RESULT(no)
 544                 ],[
 545                         AC_MSG_RESULT(yes)
 546                         AC_MSG_ERROR([
 547         *** Kernel built with CONFIG_DEBUG_LOCK_ALLOC which is incompatible
 548         *** with the CDDL license and will prevent the module linking stage
 549         *** from succeeding.  You must rebuild your kernel without this
 550         *** option enabled.])
 551                 ])
 552                 EXTRA_KCFLAGS="$tmp_flags"
 553         ], [])
 554 ])
 555
 556 dnl #
 557 dnl # ZFS_LINUX_CONFTEST_H
 558 dnl #
 559 AC_DEFUN([ZFS_LINUX_CONFTEST_H], [
 560 cat - <<_ACEOF >conftest.h
 561 $1
 562 _ACEOF
 563 ])
 564
 565 dnl #
 566 dnl # ZFS_LINUX_CONFTEST_C
 567 dnl #
 568 AC_DEFUN([ZFS_LINUX_CONFTEST_C], [
 569 cat confdefs.h - <<_ACEOF >conftest.c
 570 $1
 571 _ACEOF
 572 ])
 573
 574 dnl #
 575 dnl # ZFS_LANG_PROGRAM(C)([PROLOGUE], [BODY])
 576 dnl #
 577 m4_define([ZFS_LANG_PROGRAM], [
 578 $1
 579 int
 580 main (void)
 581 {
 582 dnl Do *not* indent the following line: there may be CPP directives.
 583 dnl Don't move the `;' right after for the same reason.
 584 $2
 585   ;
 586   return 0;
 587 }
 588 ])
 589
 590 dnl #
 591 dnl # ZFS_LINUX_COMPILE_IFELSE / like AC_COMPILE_IFELSE
 592 dnl #
 593 AC_DEFUN([ZFS_LINUX_COMPILE_IFELSE], [
 594         m4_ifvaln([$1], [ZFS_LINUX_CONFTEST_C([$1])])
 595         m4_ifvaln([$6], [ZFS_LINUX_CONFTEST_H([$6])], [ZFS_LINUX_CONFTEST_H([])])
 596         rm -Rf build && mkdir -p build && touch build/conftest.mod.c
 597         echo "obj-m := conftest.o" >build/Makefile
 598         modpost_flag=''
 599         test "x$enable_linux_builtin" = xyes && modpost_flag='modpost=true' # fake modpost stage
 600         AS_IF(
 601                 [AC_TRY_COMMAND(cp conftest.c conftest.h build && make [$2] -C $LINUX_OBJ EXTRA_CFLAGS="-Werror $EXTRA_KCFLAGS" $ARCH_UM M=$PWD/build $modpost_flag) >/dev/null && AC_TRY_COMMAND([$3])],
 602                 [$4],
 603                 [_AC_MSG_LOG_CONFTEST m4_ifvaln([$5],[$5])]
 604         )
 605         rm -Rf build
 606 ])
 607
 608 dnl #
 609 dnl # ZFS_LINUX_TRY_COMPILE like AC_TRY_COMPILE
 610 dnl #
 611 AC_DEFUN([ZFS_LINUX_TRY_COMPILE],
 612         [ZFS_LINUX_COMPILE_IFELSE(
 613         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 614         [modules],
 615         [test -s build/conftest.o],
 616         [$3], [$4])
 617 ])
 618
 619 dnl #
 620 dnl # ZFS_LINUX_CONFIG
 621 dnl #
 622 AC_DEFUN([ZFS_LINUX_CONFIG],
 623         [AC_MSG_CHECKING([whether kernel was built with CONFIG_$1])
 624         ZFS_LINUX_TRY_COMPILE([
 625                 #include <linux/module.h>
 626         ],[
 627                 #ifndef CONFIG_$1
 628                 #error CONFIG_$1 not #defined
 629                 #endif
 630         ],[
 631                 AC_MSG_RESULT([yes])
 632                 $2
 633         ],[
 634                 AC_MSG_RESULT([no])
 635                 $3
 636         ])
 637 ])
 638
 639 dnl #
 640 dnl # ZFS_CHECK_SYMBOL_EXPORT
 641 dnl # check symbol exported or not
 642 dnl #
 643 AC_DEFUN([ZFS_CHECK_SYMBOL_EXPORT], [
 644         grep -q -E '[[[:space:]]]$1[[[:space:]]]' \
 645                 $LINUX_OBJ/$LINUX_SYMBOLS 2>/dev/null
 646         rc=$?
 647         if test $rc -ne 0; then
 648                 export=0
 649                 for file in $2; do
 650                         grep -q -E "EXPORT_SYMBOL.*($1)" \
 651                                 "$LINUX/$file" 2>/dev/null
 652                         rc=$?
 653                         if test $rc -eq 0; then
 654                                 export=1
 655                                 break;
 656                         fi
 657                 done
 658                 if test $export -eq 0; then :
 659                         $4
 660                 else :
 661                         $3
 662                 fi
 663         else :
 664                 $3
 665         fi
 666 ])
 667
 668 dnl #
 669 dnl # ZFS_LINUX_TRY_COMPILE_SYMBOL
 670 dnl # like ZFS_LINUX_TRY_COMPILE, except ZFS_CHECK_SYMBOL_EXPORT
 671 dnl # is called if not compiling for builtin
 672 dnl #
 673 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_SYMBOL], [
 674         ZFS_LINUX_TRY_COMPILE([$1], [$2], [rc=0], [rc=1])
 675         if test $rc -ne 0; then :
 676                 $6
 677         else
 678                 if test "x$enable_linux_builtin" != xyes; then
 679                         ZFS_CHECK_SYMBOL_EXPORT([$3], [$4], [rc=0], [rc=1])
 680                 fi
 681                 if test $rc -ne 0; then :
 682                         $6
 683                 else :
 684                         $5
 685                 fi
 686         fi
 687 ])
 688
 689 dnl #
 690 dnl # ZFS_LINUX_TRY_COMPILE_HEADER
 691 dnl # like ZFS_LINUX_TRY_COMPILE, except the contents conftest.h are
 692 dnl # provided via the fifth parameter
 693 dnl #
 694 AC_DEFUN([ZFS_LINUX_TRY_COMPILE_HEADER],
 695         [ZFS_LINUX_COMPILE_IFELSE(
 696         [AC_LANG_SOURCE([ZFS_LANG_PROGRAM([[$1]], [[$2]])])],
 697         [modules],
 698         [test -s build/conftest.o],
 699         [$3], [$4], [$5])
 700 ])