zfs/config/zfs-build.m4

   1 AC_DEFUN([ZFS_AC_LICENSE], [
   2         AC_MSG_CHECKING([zfs author])
   3         AC_MSG_RESULT([$ZFS_META_AUTHOR])
   4
   5         AC_MSG_CHECKING([zfs license])
   6         AC_MSG_RESULT([$ZFS_META_LICENSE])
   7 ])
   8
   9 AC_DEFUN([ZFS_AC_DEBUG], [
  10         AC_MSG_CHECKING([whether debugging is enabled])
  11         AC_ARG_ENABLE([debug],
  12                 [AS_HELP_STRING([--enable-debug],
  13                 [Enable generic debug support @<:@default=no@:>@])],
  14                 [],
  15                 [enable_debug=no])
  16
  17         AS_IF([test "x$enable_debug" = xyes],
  18         [
  19                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG -Werror"
  20                 HOSTCFLAGS="${HOSTCFLAGS} -DDEBUG -Werror"
  21                 DEBUG_CFLAGS="-DDEBUG -Werror"
  22                 DEBUG_STACKFLAGS="-fstack-check"
  23                 DEBUG_ZFS="_with_debug"
  24                 AC_DEFINE(ZFS_DEBUG, 1, [zfs debugging enabled])
  25         ],
  26         [
  27                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DNDEBUG "
  28                 HOSTCFLAGS="${HOSTCFLAGS} -DNDEBUG "
  29                 DEBUG_CFLAGS="-DNDEBUG"
  30                 DEBUG_STACKFLAGS=""
  31                 DEBUG_ZFS="_without_debug"
  32         ])
  33
  34         AC_SUBST(DEBUG_CFLAGS)
  35         AC_SUBST(DEBUG_STACKFLAGS)
  36         AC_SUBST(DEBUG_ZFS)
  37         AC_MSG_RESULT([$enable_debug])
  38 ])
  39
  40 AC_DEFUN([ZFS_AC_DEBUG_DMU_TX], [
  41         AC_ARG_ENABLE([debug-dmu-tx],
  42                 [AS_HELP_STRING([--enable-debug-dmu-tx],
  43                 [Enable dmu tx validation @<:@default=no@:>@])],
  44                 [],
  45                 [enable_debug_dmu_tx=no])
  46
  47         AS_IF([test "x$enable_debug_dmu_tx" = xyes],
  48         [
  49                 KERNELCPPFLAGS="${KERNELCPPFLAGS} -DDEBUG_DMU_TX"
  50                 DEBUG_DMU_TX="_with_debug_dmu_tx"
  51                 AC_DEFINE([DEBUG_DMU_TX], [1],
  52                 [Define to 1 to enabled dmu tx validation])
  53         ],
  54         [
  55                 DEBUG_DMU_TX="_without_debug_dmu_tx"
  56         ])
  57
  58         AC_SUBST(DEBUG_DMU_TX)
  59         AC_MSG_CHECKING([whether dmu tx validation is enabled])
  60         AC_MSG_RESULT([$enable_debug_dmu_tx])
  61 ])
  62
  63 AC_DEFUN([ZFS_AC_CONFIG_ALWAYS], [
  64         ZFS_AC_CONFIG_ALWAYS_NO_UNUSED_BUT_SET_VARIABLE
  65         ZFS_AC_CONFIG_ALWAYS_NO_BOOL_COMPARE
  66 ])
  67
  68 AC_DEFUN([ZFS_AC_CONFIG], [
  69         TARGET_ASM_DIR=asm-generic
  70         AC_SUBST(TARGET_ASM_DIR)
  71
  72         ZFS_CONFIG=all
  73         AC_ARG_WITH([config],
  74                 AS_HELP_STRING([--with-config=CONFIG],
  75                 [Config file 'kernel|user|all|srpm']),
  76                 [ZFS_CONFIG="$withval"])
  77         AC_ARG_ENABLE([linux-builtin],
  78                 [AC_HELP_STRING([--enable-linux-builtin],
  79                 [Configure for builtin in-tree kernel modules @<:@default=no@:>@])],
  80                 [],
  81                 [enable_linux_builtin=no])
  82
  83         AC_MSG_CHECKING([zfs config])
  84         AC_MSG_RESULT([$ZFS_CONFIG]);
  85         AC_SUBST(ZFS_CONFIG)
  86
  87         ZFS_AC_CONFIG_ALWAYS
  88
  89         case "$ZFS_CONFIG" in
  90                 user)   ZFS_AC_CONFIG_USER   ;;
  91                 kernel) ZFS_AC_CONFIG_KERNEL ;;
  92                 all)    ZFS_AC_CONFIG_KERNEL
  93                         ZFS_AC_CONFIG_USER   ;;
  94                 srpm)                        ;;
  95                 *)
  96                 AC_MSG_RESULT([Error!])
  97                 AC_MSG_ERROR([Bad value "$ZFS_CONFIG" for --with-config,
  98                               user kernel|user|all|srpm]) ;;
  99         esac
 100
 101         AM_CONDITIONAL([CONFIG_USER],
 102                        [test "$ZFS_CONFIG" = user -o "$ZFS_CONFIG" = all])
 103         AM_CONDITIONAL([CONFIG_KERNEL],
 104                        [test "$ZFS_CONFIG" = kernel -o "$ZFS_CONFIG" = all] &&
 105                        [test "x$enable_linux_builtin" != xyes ])
 106 ])
 107
 108 dnl #
 109 dnl # Check for rpm+rpmbuild to build RPM packages.  If these tools
 110 dnl # are missing it is non-fatal but you will not be able to build
 111 dnl # RPM packages and will be warned if you try too.
 112 dnl #
 113 dnl # By default the generic spec file will be used because it requires
 114 dnl # minimal dependencies.  Distribution specific spec files can be
 115 dnl # placed under the 'rpm/<distribution>' directory and enabled using
 116 dnl # the --with-spec=<distribution> configure option.
 117 dnl #
 118 AC_DEFUN([ZFS_AC_RPM], [
 119         RPM=rpm
 120         RPMBUILD=rpmbuild
 121
 122         AC_MSG_CHECKING([whether $RPM is available])
 123         AS_IF([tmp=$($RPM --version 2>/dev/null)], [
 124                 RPM_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 125                 HAVE_RPM=yes
 126                 AC_MSG_RESULT([$HAVE_RPM ($RPM_VERSION)])
 127         ],[
 128                 HAVE_RPM=no
 129                 AC_MSG_RESULT([$HAVE_RPM])
 130         ])
 131
 132         AC_MSG_CHECKING([whether $RPMBUILD is available])
 133         AS_IF([tmp=$($RPMBUILD --version 2>/dev/null)], [
 134                 RPMBUILD_VERSION=$(echo $tmp | $AWK '/RPM/ { print $[3] }')
 135                 HAVE_RPMBUILD=yes
 136                 AC_MSG_RESULT([$HAVE_RPMBUILD ($RPMBUILD_VERSION)])
 137         ],[
 138                 HAVE_RPMBUILD=no
 139                 AC_MSG_RESULT([$HAVE_RPMBUILD])
 140         ])
 141
 142         RPM_DEFINE_COMMON='--define "$(DEBUG_ZFS) 1" --define "$(DEBUG_DMU_TX) 1"'
 143         RPM_DEFINE_UTIL='--define "_dracutdir $(dracutdir)" --define "_udevdir $(udevdir)" --define "_udevruledir $(udevruledir)" --define "_initconfdir $(DEFAULT_INITCONF_DIR)" $(DEFINE_INITRAMFS)'
 144         RPM_DEFINE_KMOD='--define "kernels $(LINUX_VERSION)" --define "require_spldir $(SPL)" --define "require_splobj $(SPL_OBJ)" --define "ksrc $(LINUX)" --define "kobj $(LINUX_OBJ)"'
 145         RPM_DEFINE_DKMS=
 146
 147         SRPM_DEFINE_COMMON='--define "build_src_rpm 1"'
 148         SRPM_DEFINE_UTIL=
 149         SRPM_DEFINE_KMOD=
 150         SRPM_DEFINE_DKMS=
 151
 152         RPM_SPEC_DIR="rpm/generic"
 153         AC_ARG_WITH([spec],
 154                 AS_HELP_STRING([--with-spec=SPEC],
 155                 [Spec files 'generic|redhat']),
 156                 [RPM_SPEC_DIR="rpm/$withval"])
 157
 158         AC_MSG_CHECKING([whether spec files are available])
 159         AC_MSG_RESULT([yes ($RPM_SPEC_DIR/*.spec.in)])
 160
 161         AC_SUBST(HAVE_RPM)
 162         AC_SUBST(RPM)
 163         AC_SUBST(RPM_VERSION)
 164
 165         AC_SUBST(HAVE_RPMBUILD)
 166         AC_SUBST(RPMBUILD)
 167         AC_SUBST(RPMBUILD_VERSION)
 168
 169         AC_SUBST(RPM_SPEC_DIR)
 170         AC_SUBST(RPM_DEFINE_UTIL)
 171         AC_SUBST(RPM_DEFINE_KMOD)
 172         AC_SUBST(RPM_DEFINE_DKMS)
 173         AC_SUBST(RPM_DEFINE_COMMON)
 174         AC_SUBST(SRPM_DEFINE_UTIL)
 175         AC_SUBST(SRPM_DEFINE_KMOD)
 176         AC_SUBST(SRPM_DEFINE_DKMS)
 177         AC_SUBST(SRPM_DEFINE_COMMON)
 178 ])
 179
 180 dnl #
 181 dnl # Check for dpkg+dpkg-buildpackage to build DEB packages.  If these
 182 dnl # tools are missing it is non-fatal but you will not be able to build
 183 dnl # DEB packages and will be warned if you try too.
 184 dnl #
 185 AC_DEFUN([ZFS_AC_DPKG], [
 186         DPKG=dpkg
 187         DPKGBUILD=dpkg-buildpackage
 188
 189         AC_MSG_CHECKING([whether $DPKG is available])
 190         AS_IF([tmp=$($DPKG --version 2>/dev/null)], [
 191                 DPKG_VERSION=$(echo $tmp | $AWK '/Debian/ { print $[7] }')
 192                 HAVE_DPKG=yes
 193                 AC_MSG_RESULT([$HAVE_DPKG ($DPKG_VERSION)])
 194         ],[
 195                 HAVE_DPKG=no
 196                 AC_MSG_RESULT([$HAVE_DPKG])
 197         ])
 198
 199         AC_MSG_CHECKING([whether $DPKGBUILD is available])
 200         AS_IF([tmp=$($DPKGBUILD --version 2>/dev/null)], [
 201                 DPKGBUILD_VERSION=$(echo $tmp | \
 202                     $AWK '/Debian/ { print $[4] }' | cut -f-4 -d'.')
 203                 HAVE_DPKGBUILD=yes
 204                 AC_MSG_RESULT([$HAVE_DPKGBUILD ($DPKGBUILD_VERSION)])
 205         ],[
 206                 HAVE_DPKGBUILD=no
 207                 AC_MSG_RESULT([$HAVE_DPKGBUILD])
 208         ])
 209
 210         AC_SUBST(HAVE_DPKG)
 211         AC_SUBST(DPKG)
 212         AC_SUBST(DPKG_VERSION)
 213
 214         AC_SUBST(HAVE_DPKGBUILD)
 215         AC_SUBST(DPKGBUILD)
 216         AC_SUBST(DPKGBUILD_VERSION)
 217 ])
 218
 219 dnl #
 220 dnl # Until native packaging for various different packing systems
 221 dnl # can be added the least we can do is attempt to use alien to
 222 dnl # convert the RPM packages to the needed package type.  This is
 223 dnl # a hack but so far it has worked reasonable well.
 224 dnl #
 225 AC_DEFUN([ZFS_AC_ALIEN], [
 226         ALIEN=alien
 227
 228         AC_MSG_CHECKING([whether $ALIEN is available])
 229         AS_IF([tmp=$($ALIEN --version 2>/dev/null)], [
 230                 ALIEN_VERSION=$(echo $tmp | $AWK '{ print $[3] }')
 231                 HAVE_ALIEN=yes
 232                 AC_MSG_RESULT([$HAVE_ALIEN ($ALIEN_VERSION)])
 233         ],[
 234                 HAVE_ALIEN=no
 235                 AC_MSG_RESULT([$HAVE_ALIEN])
 236         ])
 237
 238         AC_SUBST(HAVE_ALIEN)
 239         AC_SUBST(ALIEN)
 240         AC_SUBST(ALIEN_VERSION)
 241 ])
 242
 243 dnl #
 244 dnl # Using the VENDOR tag from config.guess set the default
 245 dnl # package type for 'make pkg': (rpm | deb | tgz)
 246 dnl #
 247 AC_DEFUN([ZFS_AC_DEFAULT_PACKAGE], [
 248         AC_MSG_CHECKING([linux distribution])
 249         if test -f /etc/toss-release ; then
 250                 VENDOR=toss ;
 251         elif test -f /etc/fedora-release ; then
 252                 VENDOR=fedora ;
 253         elif test -f /etc/redhat-release ; then
 254                 VENDOR=redhat ;
 255         elif test -f /etc/gentoo-release ; then
 256                 VENDOR=gentoo ;
 257         elif test -f /etc/arch-release ; then
 258                 VENDOR=arch ;
 259         elif test -f /etc/SuSE-release ; then
 260                 VENDOR=sles ;
 261         elif test -f /etc/slackware-version ; then
 262                 VENDOR=slackware ;
 263         elif test -f /etc/lunar.release ; then
 264                 VENDOR=lunar ;
 265         elif test -f /etc/lsb-release ; then
 266                 VENDOR=ubuntu ;
 267         elif test -f /etc/debian_version ; then
 268                 VENDOR=debian ;
 269         else
 270                 VENDOR= ;
 271         fi
 272         AC_MSG_RESULT([$VENDOR])
 273         AC_SUBST(VENDOR)
 274
 275         AC_MSG_CHECKING([default package type])
 276         case "$VENDOR" in
 277                 toss)       DEFAULT_PACKAGE=rpm  ;;
 278                 redhat)     DEFAULT_PACKAGE=rpm  ;;
 279                 fedora)     DEFAULT_PACKAGE=rpm  ;;
 280                 gentoo)     DEFAULT_PACKAGE=tgz  ;;
 281                 arch)       DEFAULT_PACKAGE=tgz  ;;
 282                 sles)       DEFAULT_PACKAGE=rpm  ;;
 283                 slackware)  DEFAULT_PACKAGE=tgz  ;;
 284                 lunar)      DEFAULT_PACKAGE=tgz  ;;
 285                 ubuntu)     DEFAULT_PACKAGE=deb  ;;
 286                 debian)     DEFAULT_PACKAGE=deb  ;;
 287                 *)          DEFAULT_PACKAGE=rpm  ;;
 288         esac
 289         AC_MSG_RESULT([$DEFAULT_PACKAGE])
 290         AC_SUBST(DEFAULT_PACKAGE)
 291
 292         DEFAULT_INIT_DIR=$sysconfdir/init.d
 293         AC_MSG_CHECKING([default init directory])
 294         AC_MSG_RESULT([$DEFAULT_INIT_DIR])
 295         AC_SUBST(DEFAULT_INIT_DIR)
 296
 297         AC_MSG_CHECKING([default init script type])
 298         case "$VENDOR" in
 299                 toss)       DEFAULT_INIT_SCRIPT=redhat ;;
 300                 redhat)     DEFAULT_INIT_SCRIPT=redhat ;;
 301                 fedora)     DEFAULT_INIT_SCRIPT=fedora ;;
 302                 gentoo)     DEFAULT_INIT_SCRIPT=gentoo ;;
 303                 arch)       DEFAULT_INIT_SCRIPT=lsb    ;;
 304                 sles)       DEFAULT_INIT_SCRIPT=lsb    ;;
 305                 slackware)  DEFAULT_INIT_SCRIPT=lsb    ;;
 306                 lunar)      DEFAULT_INIT_SCRIPT=lunar  ;;
 307                 ubuntu)     DEFAULT_INIT_SCRIPT=lsb    ;;
 308                 debian)     DEFAULT_INIT_SCRIPT=lsb    ;;
 309                 *)          DEFAULT_INIT_SCRIPT=lsb    ;;
 310         esac
 311         AC_MSG_RESULT([$DEFAULT_INIT_SCRIPT])
 312         AC_SUBST(DEFAULT_INIT_SCRIPT)
 313
 314         AC_MSG_CHECKING([default init config direectory])
 315         case "$VENDOR" in
 316                 gentoo)     DEFAULT_INITCONF_DIR=/etc/conf.d    ;;
 317                 toss)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 318                 redhat)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 319                 fedora)     DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 320                 sles)       DEFAULT_INITCONF_DIR=/etc/sysconfig ;;
 321                 ubuntu)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 322                 debian)     DEFAULT_INITCONF_DIR=/etc/default   ;;
 323                 *)          DEFAULT_INITCONF_DIR=/etc/default   ;;
 324         esac
 325         AC_MSG_RESULT([$DEFAULT_INITCONF_DIR])
 326         AC_SUBST(DEFAULT_INITCONF_DIR)
 327
 328         AC_MSG_CHECKING([whether initramfs-tools is available])
 329         if test -d /usr/share/initramfs-tools ; then
 330                 DEFINE_INITRAMFS='--define "_initramfs 1"'
 331                 AC_MSG_RESULT([yes])
 332         else
 333                 DEFINE_INITRAMFS=''
 334                 AC_MSG_RESULT([no])
 335         fi
 336         AC_SUBST(DEFINE_INITRAMFS)
 337 ])
 338
 339 dnl #
 340 dnl # Default ZFS package configuration
 341 dnl #
 342 AC_DEFUN([ZFS_AC_PACKAGE], [
 343         ZFS_AC_DEFAULT_PACKAGE
 344         ZFS_AC_RPM
 345         ZFS_AC_DPKG
 346         ZFS_AC_ALIEN
 347 ])