+sub prune_backups {
+ my ($class, $scfg, $storeid, $keep, $vmid, $type, $dryrun, $logfunc) = @_;
+
+ $logfunc //= sub { print "$_[1]\n" };
+
+ my $backups = $class->list_volumes($storeid, $scfg, $vmid, ['backup']);
+
+ my $backup_groups = {};
+ my $prune_list = [];
+
+ foreach my $backup (@{$backups}) {
+ my $volid = $backup->{volid};
+ my $archive_info = eval { PVE::Storage::archive_info($volid) } // {};
+ my $backup_type = $archive_info->{type} // 'unknown';
+ my $backup_vmid = $archive_info->{vmid} // $backup->{vmid};
+
+ next if defined($type) && $type ne $backup_type;
+
+ my $prune_entry = {
+ ctime => $backup->{ctime},
+ type => $backup_type,
+ volid => $volid,
+ };
+
+ $prune_entry->{vmid} = $backup_vmid if defined($backup_vmid);
+
+ if ($archive_info->{is_std_name}) {
+ die "internal error - got no VMID\n" if !defined($backup_vmid);
+ die "internal error - got wrong VMID '$backup_vmid' != '$vmid'\n"
+ if defined($vmid) && $backup_vmid ne $vmid;
+
+ $prune_entry->{ctime} = $archive_info->{ctime};
+ my $group = "$backup_type/$backup_vmid";
+ push @{$backup_groups->{$group}}, $prune_entry;
+ } else {
+ # ignore backups that don't use the standard naming scheme
+ $prune_entry->{mark} = 'protected';
+ }
+
+ push @{$prune_list}, $prune_entry;
+ }
+
+ foreach my $backup_group (values %{$backup_groups}) {
+ PVE::Storage::prune_mark_backup_group($backup_group, $keep);
+ }
+
+ my $failed;
+ if (!$dryrun) {
+ foreach my $prune_entry (@{$prune_list}) {
+ next if $prune_entry->{mark} ne 'remove';
+
+ my $volid = $prune_entry->{volid};
+ $logfunc->('info', "removing backup '$volid'");
+ eval {
+ my (undef, $volname) = parse_volume_id($volid);
+ my $archive_path = $class->filesystem_path($scfg, $volname);
+ PVE::Storage::archive_remove($archive_path);
+ };
+ if (my $err = $@) {
+ $logfunc->('err', "error when removing backup '$volid' - $err\n");
+ $failed = 1;
+ }
+ }
+ }
+ die "error pruning backups - check log\n" if $failed;
+
+ return $prune_list;
+}
+
+# Import/Export interface:
+# Any path based storage is assumed to support 'raw' and 'tar' streams, so
+# the default implementations will return this if $scfg->{path} is set,
+# mimicking the old PVE::Storage::storage_migrate() function.
+#
+# Plugins may fall back to PVE::Storage::Plugin::volume_{export,import}...
+# functions in case the format doesn't match their specialized
+# implementations to reuse the raw/tar code.
+#
+# Format specification:
+# The following formats are all prefixed with image information in the form
+# of a 64 bit little endian unsigned integer (pack('Q<')) in order to be able
+# to preallocate the image on storages which require it.
+#
+# raw+size: (image files only)
+# A raw binary data stream such as produced via `dd if=TheImageFile`.
+# qcow2+size, vmdk: (image files only)
+# A raw qcow2/vmdk/... file such as produced via `dd if=some.qcow2` for
+# files which are already in qcow2 format, or via `qemu-img convert`.
+# Note that these formats are only valid with $with_snapshots being true.
+# tar+size: (subvolumes only)
+# A GNU tar stream containing just the inner contents of the subvolume.
+# This does not distinguish between the contents of a privileged or
+# unprivileged container. In other words, this is from the root user
+# namespace's point of view with no uid-mapping in effect.
+# As produced via `tar -C vm-100-disk-1.subvol -cpf TheOutputFile.dat .`
+
+# Plugins may reuse these helpers. Changes to the header format should be
+# reflected by changes to the function prototypes.
+sub write_common_header($$) {
+ my ($fh, $image_size_in_bytes) = @_;
+ syswrite($fh, pack("Q<", $image_size_in_bytes), 8);
+}
+
+sub read_common_header($) {
+ my ($fh) = @_;
+ sysread($fh, my $size, 8);
+ $size = unpack('Q<', $size);
+ die "import: no size found in export header, aborting.\n" if !defined($size);
+ die "import: got a bad size (not a multiple of 1K), aborting.\n" if ($size&1023);
+ # Size is in bytes!
+ return $size;
+}
+
+# Export a volume into a file handle as a stream of desired format.
+sub volume_export {
+ my ($class, $scfg, $storeid, $fh, $volname, $format, $snapshot, $base_snapshot, $with_snapshots) = @_;
+ if ($scfg->{path} && !defined($snapshot) && !defined($base_snapshot)) {
+ my $file = $class->path($scfg, $volname, $storeid)
+ or goto unsupported;
+ my ($size, $file_format) = file_size_info($file);
+
+ if ($format eq 'raw+size') {
+ goto unsupported if $with_snapshots || $file_format eq 'subvol';
+ write_common_header($fh, $size);
+ if ($file_format eq 'raw') {
+ run_command(['dd', "if=$file", "bs=4k"], output => '>&'.fileno($fh));
+ } else {
+ run_command(['qemu-img', 'convert', '-f', $file_format, '-O', 'raw', $file, '/dev/stdout'],
+ output => '>&'.fileno($fh));
+ }
+ return;
+ } elsif ($format =~ /^(qcow2|vmdk)\+size$/) {
+ my $data_format = $1;
+ goto unsupported if !$with_snapshots || $file_format ne $data_format;
+ write_common_header($fh, $size);
+ run_command(['dd', "if=$file", "bs=4k"], output => '>&'.fileno($fh));
+ return;
+ } elsif ($format eq 'tar+size') {
+ goto unsupported if $file_format ne 'subvol';
+ write_common_header($fh, $size);
+ run_command(['tar', @COMMON_TAR_FLAGS, '-cf', '-', '-C', $file, '.'],
+ output => '>&'.fileno($fh));
+ return;
+ }
+ }
+ unsupported:
+ die "volume export format $format not available for $class";
+}
+
+sub volume_export_formats {
+ my ($class, $scfg, $storeid, $volname, $snapshot, $base_snapshot, $with_snapshots) = @_;
+ if ($scfg->{path} && !defined($snapshot) && !defined($base_snapshot)) {
+ my $file = $class->path($scfg, $volname, $storeid)
+ or return;
+ my ($size, $format) = file_size_info($file);
+
+ if ($with_snapshots) {
+ return ($format.'+size') if ($format eq 'qcow2' || $format eq 'vmdk');
+ return ();
+ }
+ return ('tar+size') if $format eq 'subvol';
+ return ('raw+size');
+ }
+ return ();
+}
+
+# Import data from a stream, creating a new or replacing or adding to an existing volume.
+sub volume_import {
+ my ($class, $scfg, $storeid, $fh, $volname, $format, $base_snapshot, $with_snapshots, $allow_rename) = @_;
+
+ die "volume import format '$format' not available for $class\n"
+ if $format !~ /^(raw|tar|qcow2|vmdk)\+size$/;
+ my $data_format = $1;
+
+ die "format $format cannot be imported without snapshots\n"
+ if !$with_snapshots && ($data_format eq 'qcow2' || $data_format eq 'vmdk');
+ die "format $format cannot be imported with snapshots\n"
+ if $with_snapshots && ($data_format eq 'raw' || $data_format eq 'tar');
+
+ my ($vtype, $name, $vmid, $basename, $basevmid, $isBase, $file_format) =
+ $class->parse_volname($volname);
+
+ # XXX: Should we bother with conversion routines at this level? This won't
+ # happen without manual CLI usage, so for now we just error out...
+ die "cannot import format $format into a file of format $file_format\n"
+ if $data_format ne $file_format && !($data_format eq 'tar' && $file_format eq 'subvol');
+
+ # Check for an existing file first since interrupting alloc_image doesn't
+ # free it.
+ my $file = $class->path($scfg, $volname, $storeid);
+ if (-e $file) {
+ die "file '$file' already exists\n" if !$allow_rename;
+ warn "file '$file' already exists - importing with a different name\n";
+ $name = undef;
+ }
+
+ my ($size) = read_common_header($fh);
+ $size = int($size/1024);
+
+ eval {
+ my $allocname = $class->alloc_image($storeid, $scfg, $vmid, $file_format, $name, $size);
+ my $oldname = $volname;
+ $volname = $allocname;
+ if (defined($name) && $allocname ne $oldname) {
+ die "internal error: unexpected allocated name: '$allocname' != '$oldname'\n";
+ }
+ my $file = $class->path($scfg, $volname, $storeid)
+ or die "internal error: failed to get path to newly allocated volume $volname\n";
+ if ($data_format eq 'raw' || $data_format eq 'qcow2' || $data_format eq 'vmdk') {
+ run_command(['dd', "of=$file", 'conv=sparse', 'bs=64k'],
+ input => '<&'.fileno($fh));
+ } elsif ($data_format eq 'tar') {
+ run_command(['tar', @COMMON_TAR_FLAGS, '-C', $file, '-xf', '-'],
+ input => '<&'.fileno($fh));
+ } else {
+ die "volume import format '$format' not available for $class";
+ }
+ };
+ if (my $err = $@) {
+ eval { $class->free_image($storeid, $scfg, $volname, 0, $file_format) };
+ warn $@ if $@;
+ die $err;
+ }
+
+ return "$storeid:$volname";
+}
+
+sub volume_import_formats {
+ my ($class, $scfg, $storeid, $volname, $base_snapshot, $with_snapshots) = @_;
+ if ($scfg->{path} && !defined($base_snapshot)) {
+ my $format = ($class->parse_volname($volname))[6];
+ if ($with_snapshots) {
+ return ($format.'+size') if ($format eq 'qcow2' || $format eq 'vmdk');
+ return ();
+ }
+ return ('tar+size') if $format eq 'subvol';
+ return ('raw+size');
+ }
+ return ();
+}