+ return 0 == syscall(PVE::Syscall::unshare, $flags);
+}
+
+sub setns($$) {
+ my ($fileno, $nstype) = @_;
+ return 0 == syscall(PVE::Syscall::setns, $fileno, $nstype);
+}
+
+sub syncfs($) {
+ my ($fileno) = @_;
+ return 0 == syscall(PVE::Syscall::syncfs, $fileno);
+}
+
+sub fsync($) {
+ my ($fileno) = @_;
+ return 0 == syscall(PVE::Syscall::fsync, $fileno);
+}
+
+sub sync_mountpoint {
+ my ($path) = @_;
+ sysopen my $fd, $path, O_RDONLY|O_CLOEXEC or die "failed to open $path: $!\n";
+ my $syncfs_err;
+ if (!syncfs(fileno($fd))) {
+ $syncfs_err = "$!";
+ }
+ close($fd);
+ die "syncfs '$path' failed - $syncfs_err\n" if defined $syncfs_err;
+}
+
+# support sending multi-part mail messages with a text and or a HTML part
+# mailto may be a single email string or an array of receivers
+sub sendmail {
+ my ($mailto, $subject, $text, $html, $mailfrom, $author) = @_;
+ my $mail_re = qr/[^-a-zA-Z0-9+._@]/;
+
+ $mailto = [ $mailto ] if !ref($mailto);
+
+ foreach (@$mailto) {
+ die "illegal character in mailto address\n"
+ if ($_ =~ $mail_re);
+ }
+
+ my $rcvrtxt = join (', ', @$mailto);
+
+ $mailfrom = $mailfrom || "root";
+ die "illegal character in mailfrom address\n"
+ if $mailfrom =~ $mail_re;
+
+ $author = $author // 'Proxmox VE';
+
+ open (MAIL, "|-", "sendmail", "-B", "8BITMIME", "-f", $mailfrom, "--", @$mailto) ||
+ die "unable to open 'sendmail' - $!";
+
+ my $date = time2str('%a, %d %b %Y %H:%M:%S %z', time());
+
+ my $is_multipart = $text && $html;
+
+ # multipart spec see https://www.ietf.org/rfc/rfc1521.txt
+ my $boundary = "----_=_NextPart_001_".int(time).$$;
+
+ if ($subject =~ /[^[:ascii:]]/) {
+ $subject = Encode::encode('MIME-Header', $subject);
+ }
+
+ if ($subject =~ /[^[:ascii:]]/ || $is_multipart) {
+ print MAIL "MIME-Version: 1.0\n";
+ }
+ print MAIL "From: $author <$mailfrom>\n";
+ print MAIL "To: $rcvrtxt\n";
+ print MAIL "Date: $date\n";
+ print MAIL "Subject: $subject\n";
+
+ if ($is_multipart) {
+ print MAIL "Content-Type: multipart/alternative;\n";
+ print MAIL "\tboundary=\"$boundary\"\n";
+ print MAIL "\n";
+ print MAIL "This is a multi-part message in MIME format.\n\n";
+ print MAIL "--$boundary\n";
+ }
+
+ if (defined($text)) {
+ print MAIL "Content-Type: text/plain;\n";
+ print MAIL "\tcharset=\"UTF-8\"\n";
+ print MAIL "Content-Transfer-Encoding: 8bit\n";
+ print MAIL "\n";
+
+ # avoid 'remove extra line breaks' issue (MS Outlook)
+ my $fill = ' ';
+ $text =~ s/^/$fill/gm;
+
+ print MAIL $text;
+
+ print MAIL "\n--$boundary\n" if $is_multipart;
+ }
+
+ if (defined($html)) {
+ print MAIL "Content-Type: text/html;\n";
+ print MAIL "\tcharset=\"UTF-8\"\n";
+ print MAIL "Content-Transfer-Encoding: 8bit\n";
+ print MAIL "\n";
+
+ print MAIL $html;
+
+ print MAIL "\n--$boundary--\n" if $is_multipart;
+ }
+
+ close(MAIL);
+}
+
+sub tempfile {
+ my ($perm, %opts) = @_;
+
+ # default permissions are stricter than with file_set_contents
+ $perm = 0600 if !defined($perm);
+
+ my $dir = $opts{dir} // '/run';
+ my $mode = $opts{mode} // O_RDWR;
+ $mode |= O_EXCL if !$opts{allow_links};
+
+ my $fh = IO::File->new($dir, $mode | O_TMPFILE, $perm);
+ if (!$fh && $! == EOPNOTSUPP) {
+ $dir = '/tmp' if !defined($opts{dir});
+ $dir .= "/.tmpfile.$$";
+ $fh = IO::File->new($dir, $mode | O_CREAT | O_EXCL, $perm);
+ unlink($dir) if $fh;
+ }
+ die "failed to create tempfile: $!\n" if !$fh;
+ return $fh;
+}
+
+sub tempfile_contents {
+ my ($data, $perm, %opts) = @_;
+
+ my $fh = tempfile($perm, %opts);
+ eval {
+ die "unable to write to tempfile: $!\n" if !print {$fh} $data;
+ die "unable to flush to tempfile: $!\n" if !defined($fh->flush());
+ };
+ if (my $err = $@) {
+ close $fh;
+ die $err;
+ }
+
+ return ("/proc/$$/fd/".$fh->fileno, $fh);
+}
+
+sub validate_ssh_public_keys {
+ my ($raw) = @_;
+ my @lines = split(/\n/, $raw);
+
+ foreach my $line (@lines) {
+ next if $line =~ m/^\s*$/;
+ eval {
+ my ($filename, $handle) = tempfile_contents($line);
+ run_command(["ssh-keygen", "-l", "-f", $filename],
+ outfunc => sub {}, errfunc => sub {});
+ };
+ die "SSH public key validation error\n" if $@;
+ }
+}
+
+sub openat($$$;$) {
+ my ($dirfd, $pathname, $flags, $mode) = @_;
+ my $fd = syscall(PVE::Syscall::openat, $dirfd, $pathname, $flags, $mode//0);
+ return undef if $fd < 0;
+ # sysopen() doesn't deal with numeric file descriptors apparently
+ # so we need to convert to a mode string for IO::Handle->new_from_fd
+ my $flagstr = ($flags & O_RDWR) ? 'rw' : ($flags & O_WRONLY) ? 'w' : 'r';
+ my $handle = IO::Handle->new_from_fd($fd, $flagstr);
+ return $handle if $handle;
+ my $err = $!; # save error before closing the raw fd
+ syscall(PVE::Syscall::close, $fd); # close
+ $! = $err;
+ return undef;
+}
+
+sub mkdirat($$$) {
+ my ($dirfd, $name, $mode) = @_;
+ return syscall(PVE::Syscall::mkdirat, $dirfd, $name, $mode) == 0;
+}
+
+sub fchownat($$$$$) {
+ my ($dirfd, $pathname, $owner, $group, $flags) = @_;
+ return syscall(PVE::Syscall::fchownat, $dirfd, $pathname, $owner, $group, $flags) == 0;
+}
+
+my $salt_starter = time();
+
+sub encrypt_pw {
+ my ($pw) = @_;
+
+ $salt_starter++;
+ my $salt = substr(Digest::SHA::sha1_base64(time() + $salt_starter + $$), 0, 8);
+
+ # crypt does not want '+' in salt (see 'man crypt')
+ $salt =~ s/\+/X/g;
+
+ return crypt(encode("utf8", $pw), "\$5\$$salt\$");
+}
+
+# intended usage: convert_size($val, "kb" => "gb")
+# we round up to the next integer by default
+# E.g. `convert_size(1023, "b" => "kb")` returns 1
+# use $no_round_up to switch this off, above example would then return 0
+# this is also true for converting down e.g. 0.0005 gb to mb returns 1
+# (0 if $no_round_up is true)
+# allowed formats for value:
+# 1234
+# 1234.
+# 1234.1234
+# .1234
+sub convert_size {
+ my ($value, $from, $to, $no_round_up) = @_;
+
+ my $units = {
+ b => 0,
+ kb => 1,
+ mb => 2,
+ gb => 3,
+ tb => 4,
+ pb => 5,
+ };
+
+ die "no value given"
+ if !defined($value) || $value eq "";
+
+ $from = lc($from // ''); $to = lc($to // '');
+ die "unknown 'from' and/or 'to' units ($from => $to)"
+ if !defined($units->{$from}) || !defined($units->{$to});
+
+ die "value '$value' is not a valid, positive number"
+ if $value !~ m/^(?:[0-9]+\.?[0-9]*|[0-9]*\.[0-9]+)$/;
+
+ my $shift_amount = ($units->{$from} - $units->{$to}) * 10;
+
+ $value *= 2**$shift_amount;
+ $value++ if !$no_round_up && ($value - int($value)) > 0.0;
+
+ return int($value);
+}
+
+# uninterruptible readline
+# retries on EINTR
+sub readline_nointr {
+ my ($fh) = @_;
+ my $line;
+ while (1) {
+ $line = <$fh>;
+ last if defined($line) || ($! != EINTR);
+ }
+ return $line;
+}
+
+my $host_arch;
+sub get_host_arch {
+ $host_arch = (POSIX::uname())[4] if !$host_arch;
+ return $host_arch;
+}
+
+# Devices are: [ (12 bits minor) (12 bits major) (8 bits minor) ]
+sub dev_t_major($) {
+ my ($dev_t) = @_;
+ return (int($dev_t) & 0xfff00) >> 8;
+}
+
+sub dev_t_minor($) {
+ my ($dev_t) = @_;
+ $dev_t = int($dev_t);
+ return (($dev_t >> 12) & 0xfff00) | ($dev_t & 0xff);
+}
+
+# Given an array of array refs [ \[a b c], \[a b b], \[e b a] ]
+# Returns the intersection of elements as a single array [a b]
+sub array_intersect {
+ my ($arrays) = @_;
+
+ if (!ref($arrays->[0])) {
+ $arrays = [ grep { ref($_) eq 'ARRAY' } @_ ];
+ }
+
+ return [] if scalar(@$arrays) == 0;
+ return $arrays->[0] if scalar(@$arrays) == 1;
+
+ my $array_unique = sub {
+ my %seen = ();
+ return grep { ! $seen{ $_ }++ } @_;
+ };
+
+ # base idea is to get all unique members from the first array, then
+ # check the common elements with the next (uniquely made) one, only keep
+ # those. Repeat for every array and at the end we only have those left
+ # which exist in all arrays
+ my $return_arr = [ $array_unique->(@{$arrays->[0]}) ];
+ for my $i (1 .. $#$arrays) {
+ my %count = ();
+ # $return_arr is already unique, explicit at before the loop, implicit below.
+ foreach my $element (@$return_arr, $array_unique->(@{$arrays->[$i]})) {
+ $count{$element}++;
+ }
+ $return_arr = [];
+ foreach my $element (keys %count) {
+ push @$return_arr, $element if $count{$element} > 1;
+ }
+ last if scalar(@$return_arr) == 0; # empty intersection, early exit
+ }
+
+ return $return_arr;
+}
+
+sub open_tree($$$) {
+ my ($dfd, $pathname, $flags) = @_;
+ return PVE::Syscall::file_handle_result(syscall(
+ &PVE::Syscall::open_tree,
+ $dfd,
+ $pathname,
+ $flags,
+ ));
+}
+
+sub move_mount($$$$$) {
+ my ($from_dirfd, $from_pathname, $to_dirfd, $to_pathname, $flags) = @_;
+ return 0 == syscall(
+ &PVE::Syscall::move_mount,
+ $from_dirfd,
+ $from_pathname,
+ $to_dirfd,
+ $to_pathname,
+ $flags,
+ );
+}
+
+sub fsopen($$) {
+ my ($fsname, $flags) = @_;
+ return PVE::Syscall::file_handle_result(syscall(&PVE::Syscall::fsopen, $fsname, $flags));
+}
+
+sub fsmount($$$) {
+ my ($fd, $flags, $mount_attrs) = @_;
+ return PVE::Syscall::file_handle_result(syscall(
+ &PVE::Syscall::fsmount,
+ $fd,
+ $flags,
+ $mount_attrs,
+ ));
+}
+
+sub fspick($$$) {
+ my ($dirfd, $pathname, $flags) = @_;
+ return PVE::Syscall::file_handle_result(syscall(
+ &PVE::Syscall::fspick,
+ $dirfd,
+ $pathname,
+ $flags,
+ ));
+}
+
+sub fsconfig($$$$$) {
+ my ($fd, $command, $key, $value, $aux) = @_;
+ return 0 == syscall(&PVE::Syscall::fsconfig, $fd, $command, $key, $value, $aux);
+}
+
+# "raw" mount, old api, not for generic use (as it does not invoke any helpers).
+# use for lower level stuff such as bind/remount/... or simple tmpfs mounts
+sub mount($$$$$) {
+ my ($source, $target, $filesystemtype, $mountflags, $data) = @_;
+ return 0 == syscall(
+ &PVE::Syscall::mount,
+ $source,
+ $target,
+ $filesystemtype,
+ $mountflags,
+ $data,
+ );
+}
+
+sub safe_compare {
+ my ($left, $right, $cmp) = @_;
+
+ return 0 if !defined($left) && !defined($right);
+ return -1 if !defined($left);
+ return 1 if !defined($right);
+ return $cmp->($left, $right);