[mirror_lxcfs.git] / meson.build

# SPDX-License-Identifier: LGPL-2.1-or-later

# Project.
project(
    'lxcfs',
    'c',
    version: '5.0.0',
    license: 'LGPLv2+',
    default_options: [
        'b_colorout=always',
        'b_asneeded=true',
        'b_pie=true',
        'c_std=gnu11',
        'warning_level=2',
    ],
    meson_version: '>= 0.50')

cc = meson.get_compiler('c')

# Templater.
if run_command(
    'python3', '-c', 'import jinja2',
    check: false).returncode() != 0
        error('python3 jinja2 missing')
endif

meson_build_sh = find_program('tools/meson-build.sh')
meson_render_jinja2 = find_program('tools/meson-render-jinja2.py')

# Configuration options.
conf = configuration_data()
conf.set_quoted('PROJECT', meson.project_name())
conf.set_quoted('PROJECT_URL', 'https://linuxcontainers.org/lxcfs/')
conf.set_quoted('PROJECT_VERSION', meson.project_version())
conf.set_quoted('PACKAGE_VERSION', meson.project_version())
conf.set('_GNU_SOURCE', true)
conf.set('_FILE_OFFSET_BITS', 64)
conf.set('__STDC_FORMAT_MACROS', true)

project_source_root = meson.current_source_dir()
project_build_root = meson.current_build_dir()

# Path handling.
prefixdir = get_option('prefix')
bindir = join_paths(prefixdir, get_option('bindir'))
libdir = join_paths(prefixdir, get_option('libdir'))
lxcfsdir = join_paths(libdir, 'lxcfs')
sysconfdir = join_paths(prefixdir, get_option('sysconfdir'))
runtimepath = join_paths(prefixdir, get_option('runtime-path'))
localstatedir = join_paths('/', get_option('localstatedir'))
datadir = join_paths(prefixdir, get_option('datadir'))

lxcfssharedir = join_paths(datadir, 'lxcfs')
lxcconfdir = join_paths(datadir, 'lxc/config/common.conf.d')
lxcmandir = join_paths(datadir, 'man')

conf.set_quoted('BINDIR', bindir)
conf.set_quoted('LIBDIR', libdir)
conf.set_quoted('LOCALSTATEDIR', localstatedir)
conf.set_quoted('RUNTIME_PATH', runtimepath)
conf.set_quoted('SYSCONFDIR', sysconfdir)

conf.set_quoted('LXCCONFDIR', lxcconfdir)
conf.set_quoted('LXCFS_BUILD_ROOT', project_build_root)
conf.set_quoted('LXCFSSHAREDIR', lxcfssharedir)
conf.set_quoted('LXCFS_SOURCE_ROOT', project_source_root)
conf.set_quoted('LXCFSTARGETDIR', join_paths(localstatedir, 'lib/lxcfs'))

# Custom configuration.
init_script = get_option('init-script')
want_tests = get_option('tests')
want_docs= get_option('docs')


# Build flags.
possible_cc_flags = [
    '-Wvla',
    '-Wimplicit-fallthrough=5',
    '-Wcast-align',
    '-Wstrict-prototypes',
    '-fno-strict-aliasing',
    '-fstack-clash-protection',
    '-fstack-protector-strong',
    '--param=ssp-buffer-size=4',
    '--mcet -fcf-protection',
    '-Werror=implicit-function-declaration',
    '-Wlogical-op',
    '-Wmissing-include-dirs',
    '-Wold-style-definition',
    '-Winit-self',
    '-Wunused-but-set-variable',
    '-Wno-unused-parameter',
    '-Wfloat-equal',
    '-Wsuggest-attribute=noreturn',
    '-Werror=return-type',
    '-Werror=incompatible-pointer-types',
    '-Wformat=2',
    '-Wshadow',
    '-Wendif-labels',
    '-Werror=overflow',
    '-fdiagnostics-show-option',
    '-Werror=shift-count-overflow',
    '-Werror=shift-overflow=2',
    '-Wdate-time',
    '-Wnested-externs',
    '-fasynchronous-unwind-tables',
    '-fexceptions',
    '-Warray-bounds',
    '-Wrestrict',
    '-Wreturn-local-addr',
    '-fsanitize=cfi',
    '-Wstringop-overflow',
]

possible_link_flags = [
    '-Wl,--gc-sections',
    '-Wl,-z,relro',
    '-Wl,-z,now',
    '-Wl,-fuse-ld=gold',
]

if meson.version().version_compare('>=0.46')
    add_project_link_arguments(cc.get_supported_link_arguments(possible_link_flags), language: 'c')
else
    add_project_link_arguments(possible_link_flags, language: 'c')
endif

add_project_arguments(cc.get_supported_arguments(possible_cc_flags), language: 'c')

# Feature detection.
foreach ident: [
    ['strlcpy', '''#include <string.h>'''],
    ['strlcat', '''#include <string.h>'''],
    ['pidfd_send_signal',
     '''#include <stdlib.h>
        #include <unistd.h>
        #include <signal.h>
        #include <sys/wait.h>'''],
    ['pidfd_open',
     '''#include <stdlib.h>
        #include <unistd.h>
        #include <signal.h>
        #include <sys/wait.h>'''],
]
    have = cc.has_function(ident[0], prefix: ident[1], args: '-D_GNU_SOURCE')
    conf.set10('HAVE_' + ident[0].to_upper(), have)
endforeach

libfuse = dependency('fuse3', required: false)
if libfuse.found()
    conf.set10('HAVE_FUSE3', true)
    conf.set('FUSE_USE_VERSION', 30)
else
    libfuse = dependency('fuse', version: '>= 2.6')
    if libfuse.found()
        conf.set10('HAVE_FUSE', true)
        conf.set('FUSE_USE_VERSION', 26)
    endif
endif

libdl = cc.find_library('dl')
threads = dependency('threads')

config_h = configure_file(
    output: 'config.h',
    configuration: conf)
config_include = include_directories('.')
add_project_arguments('-include', 'config.h', language: 'c')

# Binary.
lxcfs_sources = files('src/lxcfs.c')
lxcfs = executable(
    'lxcfs',
    lxcfs_sources,
    dependencies: [
        threads,
        libdl,
        libfuse,
    ],
    install: true,
    install_dir: bindir)

# Library.
liblxcfs_sources = files(
    'src/api_extensions.h',
    'src/bindings.c',
    'src/bindings.h',
    'src/cgroups/cgfsng.c',
    'src/cgroups/cgroup.c',
    'src/cgroups/cgroup.h',
    'src/cgroups/cgroup2_devices.c',
    'src/cgroups/cgroup2_devices.h',
    'src/cgroups/cgroup_utils.c',
    'src/cgroups/cgroup_utils.h',
    'src/cgroup_fuse.c',
    'src/cgroup_fuse.h',
    'src/cpuset_parse.c',
    'src/cpuset_parse.h',
    'src/lxcfs.c',
    'src/lxcfs_fuse.h',
    'src/lxcfs_fuse_compat.h',
    'src/macro.h',
    'src/memory_utils.h',
    'src/proc_cpuview.c',
    'src/proc_cpuview.h',
    'src/proc_fuse.c',
    'src/proc_fuse.h',
    'src/proc_loadavg.c',
    'src/proc_loadavg.h',
    'src/syscall_numbers.h',
    'src/sysfs_fuse.c',
    'src/sysfs_fuse.h',
    'src/utils.c',
    'src/utils.h')

liblxcfs_common_dependencies = declare_dependency(
    sources: liblxcfs_sources,
    dependencies: [
        threads,
        libfuse,
    ])

liblxcfs = shared_module(
    'lxcfs',
    liblxcfs_sources,
    dependencies: liblxcfs_common_dependencies,
    install: true,
    install_dir: lxcfsdir)

# Tests.
test_programs = []
if want_tests == true
    liblxcfs_test = shared_module(
        'lxcfstest',
        liblxcfs_sources,
        dependencies: liblxcfs_common_dependencies,
        install: false,
        install_dir: lxcfsdir,
        c_args: '-DRELOADTEST -DDEBUG')
endif

# RPM spec.
lxcfs_spec = custom_target(
    'lxcfs.spec',
    build_by_default: true,
    input: 'lxcfs.spec.in',
    output: 'lxcfs.spec',
    command: [
        meson_render_jinja2,
        config_h,
        '@INPUT@',
        '@OUTPUT@',
    ])

# Man pages
if want_docs == true
    help2man = find_program('help2man')
    help2man_opts = [
       '--name="System virtualization filesystem for containers"',
       '--no-discard-stderr',
       '--section=1',
       '--opt-include=docs/lxcfs.man.add',
       '--no-info',
    ]
    custom_target('lxcfs.1',
        output: 'lxcfs.1',
        command: [help2man, help2man_opts, '--output=@OUTPUT@', lxcfs],
        install: true,
        install_dir: join_paths(lxcmandir, 'man1'))
endif


# Include sub-directories.
subdir('config/init')
subdir('share')
subdir('tests')

# Build overview.
status = [
    '@0@ @1@'.format(meson.project_name(), meson.project_version()),

    'FUSE version:			@0@'.format(libfuse.version()),
    'bin directory:			@0@'.format(bindir),
    'lib directory:			@0@'.format(libdir),
    'data directory:		@0@'.format(datadir),
    'local state directory:		@0@'.format(localstatedir),
    'prefix directory:		@0@'.format(prefixdir),
    'runtime directory:		@0@'.format(runtimepath),
    'sysconf directory:		@0@'.format(sysconfdir),
    'lxc conf directory:		@0@'.format(lxcconfdir),
    'lxcfs directory:		@0@'.format(lxcfsdir),
    'lxcfs shared directory:	@0@'.format(lxcfssharedir),
    'lxcfs build root directory:	@0@'.format(project_build_root),
    'lxcfs source root directory:	@0@'.format(project_source_root),
    'init system:			@0@'.format(init_script),
    'tests:				@0@'.format(want_tests),
    'documentation:			@0@'.format(want_docs),
]
message('\n         '.join(status))
Commit	Line	Data
1fbf5591 CB	1	# SPDX-License-Identifier: LGPL-2.1-or-later
1fbf5591 CB	2
3c34a198 SG	3	# Project.
	4	project(
	5	'lxcfs',
	6	'c',
64045b1c	7	version: '5.0.0',
3c34a198 SG	8	license: 'LGPLv2+',
	9	default_options: [
	10	'b_colorout=always',
	11	'b_asneeded=true',
	12	'b_pie=true',
	13	'c_std=gnu11',
	14	'warning_level=2',
	15	],
	16	meson_version: '>= 0.50')
1fbf5591	17
3c34a198 SG	18	cc = meson.get_compiler('c')
	19
	20	# Templater.
776b8594 SG	21	if run_command(
	22	'python3', '-c', 'import jinja2',
	23	check: false).returncode() != 0
3c34a198 SG	24	error('python3 jinja2 missing')
	25	endif
	26
	27	meson_build_sh = find_program('tools/meson-build.sh')
	28	meson_render_jinja2 = find_program('tools/meson-render-jinja2.py')
	29
	30	# Configuration options.
1fbf5591	31	conf = configuration_data()
e5af758b	32	conf.set_quoted('PROJECT', meson.project_name())
3c34a198 SG	33	conf.set_quoted('PROJECT_URL', 'https://linuxcontainers.org/lxcfs/')
	34	conf.set_quoted('PROJECT_VERSION', meson.project_version())
	35	conf.set_quoted('PACKAGE_VERSION', meson.project_version())
915700c3 CB	36	conf.set('_GNU_SOURCE', true)
	37	conf.set('_FILE_OFFSET_BITS', 64)
	38	conf.set('__STDC_FORMAT_MACROS', true)
	39
1fbf5591 CB	40	project_source_root = meson.current_source_dir()
	41	project_build_root = meson.current_build_dir()
	42
3c34a198	43	# Path handling.
1fbf5591	44	prefixdir = get_option('prefix')
1fbf5591 CB	45	bindir = join_paths(prefixdir, get_option('bindir'))
	46	libdir = join_paths(prefixdir, get_option('libdir'))
	47	lxcfsdir = join_paths(libdir, 'lxcfs')
	48	sysconfdir = join_paths(prefixdir, get_option('sysconfdir'))
	49	runtimepath = join_paths(prefixdir, get_option('runtime-path'))
	50	localstatedir = join_paths('/', get_option('localstatedir'))
0d2038cd	51	datadir = join_paths(prefixdir, get_option('datadir'))
1fbf5591	52
0d2038cd	53	lxcfssharedir = join_paths(datadir, 'lxcfs')
0d2038cd	54	lxcconfdir = join_paths(datadir, 'lxc/config/common.conf.d')
83d9dee7	55	lxcmandir = join_paths(datadir, 'man')
0d2038cd	56
3c34a198 SG	57	conf.set_quoted('BINDIR', bindir)
	58	conf.set_quoted('LIBDIR', libdir)
	59	conf.set_quoted('LOCALSTATEDIR', localstatedir)
	60	conf.set_quoted('RUNTIME_PATH', runtimepath)
	61	conf.set_quoted('SYSCONFDIR', sysconfdir)
1fbf5591	62
3c34a198 SG	63	conf.set_quoted('LXCCONFDIR', lxcconfdir)
	64	conf.set_quoted('LXCFS_BUILD_ROOT', project_build_root)
	65	conf.set_quoted('LXCFSSHAREDIR', lxcfssharedir)
	66	conf.set_quoted('LXCFS_SOURCE_ROOT', project_source_root)
	67	conf.set_quoted('LXCFSTARGETDIR', join_paths(localstatedir, 'lib/lxcfs'))
e5af758b	68
3c34a198 SG	69	# Custom configuration.
3c34a198 SG	70	init_script = get_option('init-script')
1fbf5591	71	want_tests = get_option('tests')
83d9dee7	72	want_docs= get_option('docs')
1fbf5591	73
3c34a198 SG	74
3c34a198 SG	75	# Build flags.
1fbf5591	76	possible_cc_flags = [
3c34a198 SG	77	'-Wvla',
	78	'-Wimplicit-fallthrough=5',
	79	'-Wcast-align',
	80	'-Wstrict-prototypes',
	81	'-fno-strict-aliasing',
	82	'-fstack-clash-protection',
	83	'-fstack-protector-strong',
	84	'--param=ssp-buffer-size=4',
	85	'--mcet -fcf-protection',
	86	'-Werror=implicit-function-declaration',
	87	'-Wlogical-op',
	88	'-Wmissing-include-dirs',
	89	'-Wold-style-definition',
	90	'-Winit-self',
	91	'-Wunused-but-set-variable',
	92	'-Wno-unused-parameter',
	93	'-Wfloat-equal',
	94	'-Wsuggest-attribute=noreturn',
	95	'-Werror=return-type',
	96	'-Werror=incompatible-pointer-types',
	97	'-Wformat=2',
	98	'-Wshadow',
	99	'-Wendif-labels',
	100	'-Werror=overflow',
	101	'-fdiagnostics-show-option',
	102	'-Werror=shift-count-overflow',
	103	'-Werror=shift-overflow=2',
	104	'-Wdate-time',
	105	'-Wnested-externs',
	106	'-fasynchronous-unwind-tables',
	107	'-fexceptions',
	108	'-Warray-bounds',
	109	'-Wrestrict',
	110	'-Wreturn-local-addr',
	111	'-fsanitize=cfi',
	112	'-Wstringop-overflow',
1fbf5591 CB	113	]
	114
	115	possible_link_flags = [
3c34a198 SG	116	'-Wl,--gc-sections',
	117	'-Wl,-z,relro',
	118	'-Wl,-z,now',
	119	'-Wl,-fuse-ld=gold',
1fbf5591 CB	120	]
	121
	122	if meson.version().version_compare('>=0.46')
3c34a198	123	add_project_link_arguments(cc.get_supported_link_arguments(possible_link_flags), language: 'c')
1fbf5591	124	else
3c34a198	125	add_project_link_arguments(possible_link_flags, language: 'c')
1fbf5591 CB	126	endif
1fbf5591 CB	127
3c34a198 SG	128	add_project_arguments(cc.get_supported_arguments(possible_cc_flags), language: 'c')
	129
	130	# Feature detection.
	131	foreach ident: [
	132	['strlcpy', '''#include <string.h>'''],
	133	['strlcat', '''#include <string.h>'''],
	134	['pidfd_send_signal',
	135	'''#include <stdlib.h>
	136	#include <unistd.h>
	137	#include <signal.h>
	138	#include <sys/wait.h>'''],
	139	['pidfd_open',
	140	'''#include <stdlib.h>
	141	#include <unistd.h>
	142	#include <signal.h>
	143	#include <sys/wait.h>'''],
1fbf5591	144	]
3c34a198 SG	145	have = cc.has_function(ident[0], prefix: ident[1], args: '-D_GNU_SOURCE')
3c34a198 SG	146	conf.set10('HAVE_' + ident[0].to_upper(), have)
1fbf5591 CB	147	endforeach
1fbf5591 CB	148
3c34a198	149	libfuse = dependency('fuse3', required: false)
1fbf5591	150	if libfuse.found()
3c34a198 SG	151	conf.set10('HAVE_FUSE3', true)
3c34a198 SG	152	conf.set('FUSE_USE_VERSION', 30)
1fbf5591	153	else
3c34a198 SG	154	libfuse = dependency('fuse', version: '>= 2.6')
	155	if libfuse.found()
	156	conf.set10('HAVE_FUSE', true)
	157	conf.set('FUSE_USE_VERSION', 26)
	158	endif
1fbf5591 CB	159	endif
	160
	161	libdl = cc.find_library('dl')
	162	threads = dependency('threads')
	163
	164	config_h = configure_file(
3c34a198 SG	165	output: 'config.h',
3c34a198 SG	166	configuration: conf)
1fbf5591	167	config_include = include_directories('.')
3c34a198	168	add_project_arguments('-include', 'config.h', language: 'c')
1fbf5591	169
3c34a198	170	# Binary.
1fbf5591	171	lxcfs_sources = files('src/lxcfs.c')
83d9dee7	172	lxcfs = executable(
3c34a198 SG	173	'lxcfs',
	174	lxcfs_sources,
	175	dependencies: [
	176	threads,
	177	libdl,
	178	libfuse,
	179	],
	180	install: true,
	181	install_dir: bindir)
	182
	183	# Library.
1fbf5591	184	liblxcfs_sources = files(
3c34a198 SG	185	'src/api_extensions.h',
	186	'src/bindings.c',
	187	'src/bindings.h',
	188	'src/cgroups/cgfsng.c',
	189	'src/cgroups/cgroup.c',
	190	'src/cgroups/cgroup.h',
	191	'src/cgroups/cgroup2_devices.c',
	192	'src/cgroups/cgroup2_devices.h',
	193	'src/cgroups/cgroup_utils.c',
	194	'src/cgroups/cgroup_utils.h',
	195	'src/cgroup_fuse.c',
	196	'src/cgroup_fuse.h',
	197	'src/cpuset_parse.c',
	198	'src/cpuset_parse.h',
	199	'src/lxcfs.c',
	200	'src/lxcfs_fuse.h',
	201	'src/lxcfs_fuse_compat.h',
	202	'src/macro.h',
	203	'src/memory_utils.h',
	204	'src/proc_cpuview.c',
	205	'src/proc_cpuview.h',
	206	'src/proc_fuse.c',
	207	'src/proc_fuse.h',
	208	'src/proc_loadavg.c',
	209	'src/proc_loadavg.h',
	210	'src/syscall_numbers.h',
	211	'src/sysfs_fuse.c',
	212	'src/sysfs_fuse.h',
	213	'src/utils.c',
	214	'src/utils.h')
1fbf5591	215
1314b3b8	216	liblxcfs_common_dependencies = declare_dependency(
3c34a198 SG	217	sources: liblxcfs_sources,
	218	dependencies: [
	219	threads,
	220	libfuse,
	221	])
1314b3b8	222
a962e7a1	223	liblxcfs = shared_module(
3c34a198 SG	224	'lxcfs',
	225	liblxcfs_sources,
	226	dependencies: liblxcfs_common_dependencies,
	227	install: true,
	228	install_dir: lxcfsdir)
1fbf5591	229
3c34a198 SG	230	# Tests.
3c34a198 SG	231	test_programs = []
1fbf5591	232	if want_tests == true
3c34a198 SG	233	liblxcfs_test = shared_module(
	234	'lxcfstest',
	235	liblxcfs_sources,
	236	dependencies: liblxcfs_common_dependencies,
	237	install: false,
	238	install_dir: lxcfsdir,
	239	c_args: '-DRELOADTEST -DDEBUG')
1fbf5591 CB	240	endif
1fbf5591 CB	241
3c34a198	242	# RPM spec.
e5af758b	243	lxcfs_spec = custom_target(
3c34a198 SG	244	'lxcfs.spec',
	245	build_by_default: true,
	246	input: 'lxcfs.spec.in',
	247	output: 'lxcfs.spec',
	248	command: [
	249	meson_render_jinja2,
	250	config_h,
	251	'@INPUT@',
	252	'@OUTPUT@',
	253	])
	254
83d9dee7 ML	255	# Man pages
	256	if want_docs == true
	257	help2man = find_program('help2man')
	258	help2man_opts = [
	259	'--name="System virtualization filesystem for containers"',
	260	'--no-discard-stderr',
	261	'--section=1',
	262	'--opt-include=docs/lxcfs.man.add',
	263	'--no-info',
	264	]
	265	custom_target('lxcfs.1',
	266	output: 'lxcfs.1',
	267	command: [help2man, help2man_opts, '--output=@OUTPUT@', lxcfs],
	268	install: true,
	269	install_dir: join_paths(lxcmandir, 'man1'))
	270	endif
	271
	272
3c34a198	273	# Include sub-directories.
e5af758b	274	subdir('config/init')
3c34a198 SG	275	subdir('share')
3c34a198 SG	276	subdir('tests')
d90ab57e	277
3c34a198	278	# Build overview.
1fbf5591	279	status = [
3c34a198 SG	280	'@0@ @1@'.format(meson.project_name(), meson.project_version()),
	281
	282	'FUSE version: @0@'.format(libfuse.version()),
	283	'bin directory: @0@'.format(bindir),
	284	'lib directory: @0@'.format(libdir),
	285	'data directory: @0@'.format(datadir),
	286	'local state directory: @0@'.format(localstatedir),
	287	'prefix directory: @0@'.format(prefixdir),
	288	'runtime directory: @0@'.format(runtimepath),
	289	'sysconf directory: @0@'.format(sysconfdir),
	290	'lxc conf directory: @0@'.format(lxcconfdir),
	291	'lxcfs directory: @0@'.format(lxcfsdir),
	292	'lxcfs shared directory: @0@'.format(lxcfssharedir),
	293	'lxcfs build root directory: @0@'.format(project_build_root),
	294	'lxcfs source root directory: @0@'.format(project_source_root),
	295	'init system: @0@'.format(init_script),
	296	'tests: @0@'.format(want_tests),
83d9dee7	297	'documentation: @0@'.format(want_docs),
3c34a198	298	]
1fbf5591	299	message('\n '.join(status))