]> git.proxmox.com Git - mirror_ovs.git/blame - acinclude.m4
projects / mirror_ovs.git / blame
? search:
summary | shortlog | log | commit | commitdiff | tree
blob | blame (incremental) | history | HEAD
datapath: introduce nf_conntrack_helper_put function
[mirror_ovs.git] / acinclude.m4
CommitLineData
064af421
BP		 1# -*- autoconf -*-
2
344f6253 3# Copyright (c) 2008, 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Nicira, Inc.
064af421 4#
a14bc59f
BP		 5# Licensed under the Apache License, Version 2.0 (the "License");
6# you may not use this file except in compliance with the License.
7# You may obtain a copy of the License at:
064af421 8#
a14bc59f
BP		 9# http://www.apache.org/licenses/LICENSE-2.0
10#
11# Unless required by applicable law or agreed to in writing, software
12# distributed under the License is distributed on an "AS IS" BASIS,
13# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
14# See the License for the specific language governing permissions and
15# limitations under the License.
064af421 16
a64e37a1
BP		 17dnl OVS_ENABLE_WERROR
18AC_DEFUN([OVS_ENABLE_WERROR],
19 [AC_ARG_ENABLE(
20 [Werror],
21 [AC_HELP_STRING([--enable-Werror], [Add -Werror to CFLAGS])],
22 [], [enable_Werror=no])
23 AC_CONFIG_COMMANDS_PRE(
24 [if test "X$enable_Werror" = Xyes; then
95626395 25 OVS_CFLAGS="$OVS_CFLAGS -Werror"
308bf988
BP		 26 fi])
27
28 # Unless --enable-Werror is specified, report but do not fail the build
29 # for errors reported by flake8.
30 if test "X$enable_Werror" = Xyes; then
31 FLAKE8_WERROR=
32 else
33 FLAKE8_WERROR=-
34 fi
35 AC_SUBST([FLAKE8_WERROR])])
a64e37a1 36
e3438006 37dnl OVS_CHECK_LINUX
064af421 38dnl
997d327d 39dnl Configure linux kernel source tree
e3438006 40AC_DEFUN([OVS_CHECK_LINUX], [
8a2d6596
BP		 41 AC_ARG_WITH([linux],
42 [AC_HELP_STRING([--with-linux=/path/to/linux],
43 [Specify the Linux kernel build directory])])
44 AC_ARG_WITH([linux-source],
45 [AC_HELP_STRING([--with-linux-source=/path/to/linux-source],
46 [Specify the Linux kernel source directory
a0903134
YT		 47 (usually figured out automatically from build
48 directory)])])
8a2d6596
BP		 49
50 # Deprecated equivalents to --with-linux, --with-linux-source.
51 AC_ARG_WITH([l26])
52 AC_ARG_WITH([l26-source])
53
54 if test X"$with_linux" != X; then
55 KBUILD=$with_linux
56 elif test X"$with_l26" != X; then
57 KBUILD=$with_l26
58 AC_MSG_WARN([--with-l26 is deprecated, please use --with-linux instead])
59 else
60 KBUILD=
61 fi
62
63 if test X"$KBUILD" != X; then
64 if test X"$with_linux_source" != X; then
65 KSRC=$with_linux_source
66 elif test X"$with_l26_source" != X; then
67 KSRC=$with_l26_source
68 AC_MSG_WARN([--with-l26-source is deprecated, please use --with-linux-source instead])
0a89c170
BP		 69 else
70 KSRC=
8a2d6596
BP		 71 fi
72 elif test X"$with_linux_source" != X || test X"$with_l26_source" != X; then
73 AC_MSG_ERROR([Linux source directory may not be specified without Linux build directory])
74 fi
75
e3438006
BP		 76 if test -n "$KBUILD"; then
77 KBUILD=`eval echo "$KBUILD"`
78 case $KBUILD in
0b6d72fc 79 /*) ;;
e3438006 80 *) KBUILD=`pwd`/$KBUILD ;;
0b6d72fc 81 esac
064af421 82
7c9e113b
BP		 83 # The build directory is what the user provided.
84 # Make sure that it exists.
8a2d6596 85 AC_MSG_CHECKING([for Linux build directory])
e3438006 86 if test -d "$KBUILD"; then
a0903134
YT		 87 AC_MSG_RESULT([$KBUILD])
88 AC_SUBST(KBUILD)
064af421 89 else
a0903134
YT		 90 AC_MSG_RESULT([no])
91 AC_ERROR([source dir $KBUILD doesn't exist])
064af421
BP		 92 fi
93
7c9e113b 94 # Debian breaks kernel headers into "source" header and "build" headers.
e3438006 95 # We want the source headers, but $KBUILD gives us the "build" headers.
7c9e113b 96 # Use heuristics to find the source headers.
8a2d6596 97 AC_MSG_CHECKING([for Linux source directory])
e3438006
BP		 98 if test -n "$KSRC"; then
99 KSRC=`eval echo "$KSRC"`
100 case $KSRC in
f5fb5de6 101 /*) ;;
e3438006 102 *) KSRC=`pwd`/$KSRC ;;
b57f675c 103 esac
e3438006 104 if test ! -e $KSRC/include/linux/kernel.h; then
53319f95 105 AC_MSG_ERROR([$KSRC is not a kernel source directory])
f5fb5de6
BP		 106 fi
107 else
e3438006
BP		 108 KSRC=$KBUILD
109 if test ! -e $KSRC/include/linux/kernel.h; then
fe0731b1
BP		 110 # Debian kernel build Makefiles tend to include a line of the form:
111 # MAKEARGS := -C /usr/src/linux-headers-3.2.0-1-common O=/usr/src/linux-headers-3.2.0-1-486
112 # First try to extract the source directory from this line.
113 KSRC=`sed -n 's/.*-C \([[^ ]]*\).*/\1/p' "$KBUILD"/Makefile`
114 if test ! -e "$KSRC"/include/linux/kernel.h; then
115 # Didn't work. Fall back to name-based heuristics that used to work.
116 case `echo "$KBUILD" | sed 's,/*$,,'` in # (
117 */build)
118 KSRC=`echo "$KBUILD" | sed 's,/build/*$,/source,'`
119 ;; # (
120 *)
121 KSRC=`(cd $KBUILD && pwd -P) | sed 's,-[[^-]]*$,-common,'`
122 ;;
123 esac
124 fi
f5fb5de6 125 fi
fe0731b1 126 if test ! -e "$KSRC"/include/linux/kernel.h; then
8a2d6596 127 AC_MSG_ERROR([cannot find source directory (please use --with-linux-source)])
7c9e113b
BP		 128 fi
129 fi
e3438006 130 AC_MSG_RESULT([$KSRC])
7c9e113b
BP		 131
132 AC_MSG_CHECKING([for kernel version])
71fe9970 133 version=`sed -n 's/^VERSION = //p' "$KSRC/Makefile"`
e3438006
BP		 134 patchlevel=`sed -n 's/^PATCHLEVEL = //p' "$KSRC/Makefile"`
135 sublevel=`sed -n 's/^SUBLEVEL = //p' "$KSRC/Makefile"`
71fe9970 136 if test X"$version" = X || test X"$patchlevel" = X; then
7c9e113b 137 AC_ERROR([cannot determine kernel version])
71fe9970
BP		 138 elif test X"$sublevel" = X; then
139 kversion=$version.$patchlevel
140 else
141 kversion=$version.$patchlevel.$sublevel
7c9e113b 142 fi
71fe9970
BP		 143 AC_MSG_RESULT([$kversion])
144
3afcde43 145 if test "$version" -ge 4; then
2c0e107e 146 if test "$version" = 4 && test "$patchlevel" -le 11; then
3afcde43 147 : # Linux 4.x
d76aabea 148 else
2c0e107e 149 AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version newer than 4.11.x is not supported (please refer to the FAQ for advice)])
d76aabea 150 fi
8063e095 151 elif test "$version" = 3 && test "$patchlevel" -ge 10; then
3afcde43 152 : # Linux 3.x
71fe9970 153 else
8063e095 154 AC_ERROR([Linux kernel in $KBUILD is version $kversion, but version 3.10 or later is required])
064af421 155 fi
2520f452
IY		 156 if (test ! -e "$KBUILD"/include/linux/version.h && \
157 test ! -e "$KBUILD"/include/generated/uapi/linux/version.h)|| \
e3438006
BP		 158 (test ! -e "$KBUILD"/include/linux/autoconf.h && \
159 test ! -e "$KBUILD"/include/generated/autoconf.h); then
a0903134 160 AC_MSG_ERROR([Linux kernel source in $KBUILD is not configured])
064af421 161 fi
e3438006 162 OVS_CHECK_LINUX_COMPAT
064af421 163 fi
e3438006 164 AM_CONDITIONAL(LINUX_ENABLED, test -n "$KBUILD")
064af421
BP		 165])
166
1dc0da67
PB		 167dnl OVS_CHECK_LINUX_TC
168dnl
169dnl Configure Linux tc compat.
170AC_DEFUN([OVS_CHECK_LINUX_TC], [
171 AC_COMPILE_IFELSE([
172 AC_LANG_PROGRAM([#include <linux/pkt_cls.h>], [
173 int x = TCA_ACT_COOKIE;
174 ])],
175 [AC_DEFINE([HAVE_TCA_ACT_COOKIE], [1],
176 [Define to 1 if TCA_ACT_COOKIE is avaiable.])])
177
178 AC_COMPILE_IFELSE([
179 AC_LANG_PROGRAM([#include <linux/tc_act/tc_vlan.h>], [
180 int x = TCA_VLAN_PUSH_VLAN_PRIORITY;
181 ])],
182 [AC_DEFINE([HAVE_TCA_VLAN_PUSH_VLAN_PRIORITY], [1],
183 [Define to 1 if TCA_VLAN_PUSH_VLAN_PRIORITY is avaiable.])])
184
185 AC_COMPILE_IFELSE([
186 AC_LANG_PROGRAM([#include <linux/tc_act/tc_tunnel_key.h>], [
187 int x = TCA_TUNNEL_KEY_ENC_DST_PORT;
188 ])],
189 [AC_DEFINE([HAVE_TCA_TUNNEL_KEY_ENC_DST_PORT], [1],
190 [Define to 1 if TCA_TUNNEL_KEY_ENC_DST_PORT is avaiable.])])
191])
192
8a9562d2
PS		 193dnl OVS_CHECK_DPDK
194dnl
195dnl Configure DPDK source tree
196AC_DEFUN([OVS_CHECK_DPDK], [
197 AC_ARG_WITH([dpdk],
198 [AC_HELP_STRING([--with-dpdk=/path/to/dpdk],
4c16ee48
MV		 199 [Specify the DPDK build directory])],
200 [have_dpdk=true])
8a9562d2 201
40b5ea86 202 AC_MSG_CHECKING([whether dpdk datapath is enabled])
4c16ee48 203 if test "$have_dpdk" != true || test "$with_dpdk" = no; then
40b5ea86
BB		 204 AC_MSG_RESULT([no])
205 DPDKLIB_FOUND=false
206 else
207 AC_MSG_RESULT([yes])
208 case "$with_dpdk" in
209 yes)
210 DPDK_AUTO_DISCOVER="true"
211 DPDK_INCLUDE="/usr/local/include/dpdk -I/usr/include/dpdk"
212 ;;
213 *)
214 DPDK_AUTO_DISCOVER="false"
215 DPDK_INCLUDE="$with_dpdk/include"
216 # If 'with_dpdk' is passed install directory, point to headers
217 # installed in $DESTDIR/$prefix/include/dpdk
214ac6d4
BP		 218 if test ! -e "$DPDK_INCLUDE/rte_config.h" && \
219 test -e "$DPDK_INCLUDE/dpdk/rte_config.h"; then
220 DPDK_INCLUDE=$DPDK_INCLUDE/dpdk
221 fi
40b5ea86
BB		 222 DPDK_LIB_DIR="$with_dpdk/lib"
223 ;;
224 esac
8a9562d2 225
18f777b2 226 DPDK_LIB="-ldpdk"
10d01ad2 227 DPDK_EXTRA_LIB=""
8a9562d2 228
95626395
TG		 229 ovs_save_CFLAGS="$CFLAGS"
230 ovs_save_LDFLAGS="$LDFLAGS"
c1223b11 231 CFLAGS="$CFLAGS -I$DPDK_INCLUDE"
40b5ea86
BB		 232 if test "$DPDK_AUTO_DISCOVER" = "false"; then
233 LDFLAGS="$LDFLAGS -L${DPDK_LIB_DIR}"
234 fi
235
435aaddd
CL		 236 AC_COMPILE_IFELSE([
237 AC_LANG_PROGRAM(
238 [
239 #include <rte_config.h>
240#if RTE_LIBRTE_VHOST_NUMA
241#error
242#endif
243 ], [])
244 ], [],
245 [AC_SEARCH_LIBS([get_mempolicy],[numa],[],[AC_MSG_ERROR([unable to find libnuma, install the dependency package])])
5b9bf9e0
CL		 246 DPDK_EXTRA_LIB="-lnuma"
247 AC_DEFINE([VHOST_NUMA], [1], [NUMA Aware vHost support detected in DPDK.])])
16dfb8fa 248
4b88d678
CL		 249 AC_COMPILE_IFELSE([
250 AC_LANG_PROGRAM(
251 [
252 #include <rte_config.h>
253#if RTE_LIBRTE_PMD_PCAP
254#error
255#endif
256 ], [])
257 ], [],
258 [AC_SEARCH_LIBS([pcap_dump],[pcap],[],[AC_MSG_ERROR([unable to find libpcap, install the dependency package])])
259 DPDK_EXTRA_LIB="-lpcap"
260 AC_COMPILE_IFELSE([
261 AC_LANG_PROGRAM(
262 [
263 #include <rte_config.h>
264#if RTE_LIBRTE_PDUMP
265#error
266#endif
267 ], [])
268 ], [],
269 [AC_DEFINE([DPDK_PDUMP], [1], [DPDK pdump enabled in OVS.])])
270 ])
271
c1223b11
DDP		 272 # On some systems we have to add -ldl to link with dpdk
273 #
274 # This code, at first, tries to link without -ldl (""),
275 # then adds it and tries again.
276 # Before each attempt the search cache must be unset,
277 # otherwise autoconf will stick with the old result
278
40b5ea86 279 DPDKLIB_FOUND=false
c1223b11
DDP		 280 save_LIBS=$LIBS
281 for extras in "" "-ldl"; do
435aaddd 282 LIBS="$DPDK_LIB $extras $save_LIBS $DPDK_EXTRA_LIB"
c1223b11
DDP		 283 AC_LINK_IFELSE(
284 [AC_LANG_PROGRAM([#include <rte_config.h>
285 #include <rte_eal.h>],
286 [int rte_argc; char ** rte_argv;
287 rte_eal_init(rte_argc, rte_argv);])],
40b5ea86
BB		 288 [DPDKLIB_FOUND=true])
289 if $DPDKLIB_FOUND; then
c1223b11
DDP		 290 break
291 fi
292 done
40b5ea86
BB		 293
294 # If linking unsuccessful
295 if test "$DPDKLIB_FOUND" = "false" ; then
296 if $DPDK_AUTO_DISCOVER; then
297 AC_MSG_ERROR([Could not find DPDK library in default search path, Use --with-dpdk to specify the DPDK library installed in non-standard location])
298 else
299 AC_MSG_ERROR([Could not find DPDK libraries in $DPDK_LIB_DIR])
300 fi
c1223b11 301 fi
95626395
TG		 302 CFLAGS="$ovs_save_CFLAGS"
303 LDFLAGS="$ovs_save_LDFLAGS"
40b5ea86
BB		 304 if test "$DPDK_AUTO_DISCOVER" = "false"; then
305 OVS_LDFLAGS="$OVS_LDFLAGS -L$DPDK_LIB_DIR"
306 fi
ab2a3154
IM		 307 OVS_CFLAGS="$OVS_CFLAGS -I$DPDK_INCLUDE"
308 OVS_ENABLE_OPTION([-mssse3])
8a9562d2 309
3c94676c 310 # DPDK pmd drivers are not linked unless --whole-archive is used.
d7310583
DDP		 311 #
312 # This happens because the rest of the DPDK code doesn't use any symbol in
313 # the pmd driver objects, and the drivers register themselves using an
314 # __attribute__((constructor)) function.
315 #
316 # These options are specified inside a single -Wl directive to prevent
317 # autotools from reordering them.
3c94676c 318 DPDK_vswitchd_LDFLAGS=-Wl,--whole-archive,$DPDK_LIB,--no-whole-archive
9475dfeb 319 AC_SUBST([DPDK_vswitchd_LDFLAGS])
8a9562d2 320 AC_DEFINE([DPDK_NETDEV], [1], [System uses the DPDK module.])
8a9562d2
PS		 321 fi
322
40b5ea86 323 AM_CONDITIONAL([DPDK_NETDEV], test "$DPDKLIB_FOUND" = true)
8a9562d2
PS		 324])
325
8828e5c7 326dnl OVS_GREP_IFELSE(FILE, REGEX, [IF-MATCH], [IF-NO-MATCH])
064af421
BP		 327dnl
328dnl Greps FILE for REGEX. If it matches, runs IF-MATCH, otherwise IF-NO-MATCH.
8828e5c7
BP		 329dnl If IF-MATCH is empty then it defines to OVS_DEFINE(HAVE_<REGEX>), with
330dnl <REGEX> translated to uppercase.
064af421
BP		 331AC_DEFUN([OVS_GREP_IFELSE], [
332 AC_MSG_CHECKING([whether $2 matches in $1])
7507ec48
JG		 333 if test -f $1; then
334 grep '$2' $1 >/dev/null 2>&1
335 status=$?
336 case $status in
997d327d 337 0)
7507ec48 338 AC_MSG_RESULT([yes])
8828e5c7 339 m4_if([$3], [], [OVS_DEFINE([HAVE_]m4_toupper([$2]))], [$3])
7507ec48 340 ;;
997d327d 341 1)
7507ec48
JG		 342 AC_MSG_RESULT([no])
343 $4
344 ;;
997d327d 345 *)
7507ec48
JG		 346 AC_MSG_ERROR([grep exited with status $status])
347 ;;
348 esac
349 else
350 AC_MSG_RESULT([file not found])
351 $4
352 fi
064af421
BP		 353])
354
13dd4a97
JS		 355dnl OVS_FIND_FIELD_IFELSE(FILE, STRUCTURE, REGEX, [IF-MATCH], [IF-NO-MATCH])
356dnl
357dnl Looks for STRUCTURE in FILE. If it is found, greps for REGEX within the
358dnl structure definition. If this is successful, runs IF-MATCH, otherwise
359dnl IF_NO_MATCH. If IF-MATCH is empty then it defines to
360dnl OVS_DEFINE(HAVE_<STRUCTURE>_WITH_<REGEX>), with <STRUCTURE> and <REGEX>
361dnl translated to uppercase.
362AC_DEFUN([OVS_FIND_FIELD_IFELSE], [
363 AC_MSG_CHECKING([whether $2 has member $3 in $1])
364 if test -f $1; then
83a27884 365 awk '/$2.{/,/^}/' $1 2>/dev/null | grep '$3' >/dev/null
13dd4a97
JS		 366 status=$?
367 case $status in
368 0)
369 AC_MSG_RESULT([yes])
370 m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
371 ;;
372 1)
373 AC_MSG_RESULT([no])
374 $5
375 ;;
376 *)
377 AC_MSG_ERROR([grep exited with status $status])
378 ;;
379 esac
380 else
381 AC_MSG_RESULT([file not found])
382 $5
383 fi
384])
385
71ce9edd
JR		 386dnl OVS_FIND_PARAM_IFELSE(FILE, FUNCTION, REGEX, [IF-MATCH], [IF-NO-MATCH])
387dnl
388dnl Looks for FUNCTION in FILE. If it is found, greps for REGEX within
389dnl the function signature starting from the line matching FUNCTION
390dnl and ending with the line containing the closing parenthesis. If
391dnl this is successful, runs IF-MATCH, otherwise IF_NO_MATCH. If
392dnl IF-MATCH is empty then it defines to
393dnl OVS_DEFINE(HAVE_<FUNCTION>_WITH_<REGEX>), with <FUNCTION> and
394dnl <REGEX> translated to uppercase.
395AC_DEFUN([OVS_FIND_PARAM_IFELSE], [
396 AC_MSG_CHECKING([whether $2 has parameter $3 in $1])
397 if test -f $1; then
398 awk '/$2[[ \t\n]]*\(/,/\)/' $1 2>/dev/null | grep '$3' >/dev/null
399 status=$?
400 case $status in
401 0)
402 AC_MSG_RESULT([yes])
403 m4_if([$4], [], [OVS_DEFINE([HAVE_]m4_toupper([$2])[_WITH_]m4_toupper([$3]))], [$4])
404 ;;
405 1)
406 AC_MSG_RESULT([no])
407 $5
408 ;;
409 *)
410 AC_MSG_ERROR([grep exited with status $status])
411 ;;
412 esac
413 else
414 AC_MSG_RESULT([file not found])
415 $5
416 fi
417])
418
064af421
BP		 419dnl OVS_DEFINE(NAME)
420dnl
421dnl Defines NAME to 1 in kcompat.h.
422AC_DEFUN([OVS_DEFINE], [
22bcc0e7 423 echo '#define $1 1' >> datapath/linux/kcompat.h.new
064af421
BP		 424])
425
e3438006 426dnl OVS_CHECK_LINUX_COMPAT
064af421 427dnl
8063e095 428dnl Runs various Autoconf checks on the Linux kernel source in
e3438006
BP		 429dnl the directory in $KBUILD.
430AC_DEFUN([OVS_CHECK_LINUX_COMPAT], [
22bcc0e7
JG		 431 rm -f datapath/linux/kcompat.h.new
432 mkdir -p datapath/linux
433 : > datapath/linux/kcompat.h.new
4aa13c0c 434
e23775f2
PS		 435 echo '#include <linux/version.h>
436#ifndef RHEL_RELEASE_CODE
437#define RHEL_RELEASE_CODE 0
438#define RHEL_RELEASE_VERSION(a, b) 0
439#endif' >> datapath/linux/kcompat.h.new
440
e3438006 441 OVS_GREP_IFELSE([$KSRC/arch/x86/include/asm/checksum_32.h], [src_err,],
25fb3596
JG		 442 [OVS_DEFINE([HAVE_CSUM_COPY_DBG])])
443
e23775f2
PS		 444 OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_dst_lookup.*net],
445 [OVS_DEFINE([HAVE_IPV6_DST_LOOKUP_NET])])
446 OVS_GREP_IFELSE([$KSRC/include/net/addrconf.h], [ipv6_stub])
447
e3438006 448 OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [ERR_CAST])
4303ec34 449 OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [IS_ERR_OR_NULL])
54125dd0 450 OVS_GREP_IFELSE([$KSRC/include/linux/err.h], [PTR_ERR_OR_ZERO])
4aa13c0c 451
d923a695 452 OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [eth_hw_addr_random])
e2f3178f 453 OVS_GREP_IFELSE([$KSRC/include/linux/etherdevice.h], [ether_addr_copy])
d923a695 454
e23775f2
PS		 455 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [IFLA_GENEVE_TOS])
456 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/if_link.h], [rtnl_link_stats64])
457 OVS_GREP_IFELSE([$KSRC/include/linux/if_link.h], [rtnl_link_stats64])
d923a695 458 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_set_encap_proto])
ec96e663 459 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_hwaccel_push_inside])
d923a695 460
e3438006 461 OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [ipv4_is_multicast])
46d69d18 462 OVS_GREP_IFELSE([$KSRC/include/linux/in.h], [proto_ports_offset])
2ea82414
PS		 463 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*dst_entry],
464 [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_DST_ENTRY])])
e23775f2
PS		 465 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [__ip_select_ident.*net],
466 [OVS_DEFINE([HAVE_IP_SELECT_IDENT_USING_NET])])
467
13dd4a97
JS		 468 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [inet_get_local_port_range.*net],
469 [OVS_DEFINE([HAVE_INET_GET_LOCAL_PORT_RANGE_USING_NET])])
39c0ff22
JS		 470 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_defrag.*net],
471 [OVS_DEFINE([HAVE_IP_DEFRAG_TAKES_NET])])
0374bcbe
EB		 472 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
473 [ip_do_fragment], [net],
474 [OVS_DEFINE([HAVE_IP_DO_FRAGMENT_TAKES_NET])])
0643a78b
PS		 475 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/ip.h],
476 [ip_local_out], [net],
477 [OVS_DEFINE([HAVE_IP_LOCAL_OUT_TAKES_NET])])
478
cfda4537 479 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [ip_skb_dst_mtu])
0f09d6e3
JS		 480
481 OVS_GREP_IFELSE([$KSRC/include/net/ip.h], [IPSKB_FRAG_PMTU],
482 [OVS_DEFINE([HAVE_CORRECT_MRU_HANDLING])])
06f1a61a 483 OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h], [__ip_tunnel_change_mtu])
595e069a
JS		 484 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [hashfn.*const],
485 [OVS_DEFINE([HAVE_INET_FRAGS_CONST])])
8f00ece9
JS		 486 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [last_in],
487 [OVS_DEFINE([HAVE_INET_FRAGS_LAST_IN])])
e0d45da3 488 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evicting])
ccd0a13b 489 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_evictor])
91408ae0
JS		 490 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
491 [frags_work])
d1c390e6
JS		 492 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frags],
493 [rwlock])
e0d45da3
JS		 494 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_queue],
495 [list_evictor])
38f45380 496 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [inet_frag_lru_move])
6ccf21ca
YHW		 497 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/inet_frag.h],
498 [sub_frag_mem_limit], [struct.netns_frags],
499 [OVS_DEFINE([HAVE_SUB_FRAG_MEM_LIMIT_ARG_STRUCT_NETNS_FRAGS])])
500 OVS_GREP_IFELSE([$KSRC/include/net/inet_frag.h], [void.*inet_frags_init],
501 [OVS_DEFINE([HAVE_VOID_INET_FRAGS_INIT])])
401da7b9
JS		 502 OVS_GREP_IFELSE([$KSRC/include/net/inetpeer.h], [vif],
503 [OVS_DEFINE([HAVE_INETPEER_VIF_SUPPORT])])
8f00ece9 504
f2252c61
PS		 505 dnl Check for dst_cache and ipv6 lable to use backported tunnel infrastructure.
506 dnl OVS does not really need ipv6 label field, but its presence signifies that
507 dnl the stack has all required ipv6 support.
508 dnl OVS also does not need dst_cache But this dependency allows us to write
509 dnl much cleaner code.
510
3259c4ff
PS		 511 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/ip_tunnels.h], [ip_tunnel_key],
512 [label],
513 [OVS_GREP_IFELSE([$KSRC/include/net/ip_tunnels.h],
514 [iptunnel_pull_offloads],
997d327d 515 [OVS_GREP_IFELSE([$KSRC/include/net/dst_cache.h], [dst_cache],
f2252c61 516 [OVS_DEFINE([USE_UPSTREAM_TUNNEL])])])])
4aa13c0c 517
65590144
YHW		 518 OVS_GREP_IFELSE([$KSRC/include/net/mpls.h], [mpls_hdr],
519 [OVS_DEFINE([MPLS_HEADER_IS_L3])])
fdce83a3
PS		 520 OVS_GREP_IFELSE([$KSRC/include/linux/net.h], [sock_create_kern.*net],
521 [OVS_DEFINE([HAVE_SOCK_CREATE_KERN_NET])])
aad7cb91 522 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_fill_metadata_dst])
e3438006
BP		 523 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_disable_lro])
524 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_stats])
525 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_get_by_index_rcu])
3f506f07 526 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [dev_recursion_level])
42d5dd95
TG		 527 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [__skb_gso_segment])
528 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [can_checksum_protocol])
e23775f2 529 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_get_iflink])
0a0d9095
PS		 530 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_features_check],
531 [OVS_DEFINE([USE_UPSTREAM_TUNNEL_GSO])])
f2252c61
PS		 532 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_vxlan_port])
533 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [ndo_add_geneve_port])
d1890de5 534 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netdev_features_t])
8063e095
PS		 535 dnl Ubuntu kernel 3.13 has defined this struct but not used for netdev->tstats.
536 dnl So check type of tstats.
537 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [pcpu_sw_netstats.*tstats],
538 [OVS_DEFINE([HAVE_PCPU_SW_NETSTATS])])
e23775f2
PS		 539 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [netif_needs_gso.*net_device],
540 [OVS_DEFINE([HAVE_NETIF_NEEDS_GSO_NETDEV])])
541 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload])
542 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [udp_offload.*uoff],
543 [OVS_DEFINE([HAVE_UDP_OFFLOAD_ARG_UOFF])])
544 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [gro_remcsum])
8ce37339 545 OVS_GREP_IFELSE([$KSRC/include/linux/netdevice.h], [IFF_PHONY_HEADROOM])
6ccf21ca
YHW		 546 OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device_ops],
547 [extended])
7efb1e09
PS		 548 OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netdevice.h],
549 [netdev_master_upper_dev_link], [upper_priv],
550 [OVS_DEFINE([HAVE_NETDEV_MASTER_UPPER_DEV_LINK_PRIV])])
6c0bf091
JW		 551 OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netdevice.h], [net_device],
552 [max_mtu])
e23775f2
PS		 553
554 OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_state])
555 OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_register_net_hook])
cd7330d0
PS		 556 OVS_GREP_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn.*nf_hook_ops],
557 [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_OPS])])
0643a78b
PS		 558 OVS_FIND_PARAM_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hookfn], [priv],
559 [OVS_DEFINE([HAVE_NF_HOOKFN_ARG_PRIV])])
560 OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter.h], [nf_hook_ops],
561 [owner], [OVS_DEFINE([HAVE_NF_HOOKS_OPS_OWNER])])
562
e4e04c3b 563 OVS_FIND_FIELD_IFELSE([$KSRC/include/linux/netfilter_ipv6.h], [nf_ipv6_ops],
2b64e8fc 564 [fragment.*sock], [OVS_DEFINE([HAVE_NF_IPV6_OPS_FRAGMENT])])
e2f3178f 565
6d9b6937
JR		 566 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
567 [nf_conn], [struct timer_list[[ \t]]*timeout],
568 [OVS_DEFINE([HAVE_NF_CONN_TIMER])])
569 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
570 [nf_ct_delete(], [OVS_DEFINE([HAVE_NF_CT_DELETE])])
571
71ce9edd
JR		 572 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
573 [nf_ct_tmpl_alloc], [nf_conntrack_zone],
057772cf 574 [OVS_DEFINE([HAVE_NF_CT_TMPL_ALLOC_TAKES_STRUCT_ZONE])])
71ce9edd
JR		 575 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
576 [nf_ct_get_tuplepr], [struct.net],
fa67f8e0 577 [OVS_DEFINE([HAVE_NF_CT_GET_TUPLEPR_TAKES_STRUCT_NET])])
dfa791b2
FW		 578 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
579 [nf_ct_set])
56ec5593
JS		 580 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack.h],
581 [nf_ct_is_untracked])
ac9cd0d2
JS		 582 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_zones.h],
583 [nf_ct_zone_init])
459064e7
JS		 584 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
585 [nf_connlabels_get])
7f2ab8cd
JR		 586 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
587 [nf_connlabels_get], [int bit],
588 [OVS_DEFINE([HAVE_NF_CONNLABELS_GET_TAKES_BIT])])
9f04eabe
JR		 589 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_labels.h],
590 [nf_conn_labels], [words])
0d330e42
JR		 591 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_ct_nat_ext_add])
592 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_nat.h], [nf_nat_alloc_null_binding])
593 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_seqadj.h], [nf_ct_seq_adjust])
057772cf 594
e2f3178f 595 OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32])
f000c879 596 OVS_GREP_IFELSE([$KSRC/include/linux/random.h], [prandom_u32_max])
4aa13c0c 597
e23775f2
PS		 598 OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [get_link_net])
599 OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [name_assign_type])
600 OVS_GREP_IFELSE([$KSRC/include/net/rtnetlink.h], [rtnl_create_link.*src_net],
601 [OVS_DEFINE([HAVE_RTNL_CREATE_LINK_SRC_NET])])
602 OVS_GREP_IFELSE([$KSRC/include/net/net_namespace.h], [possible_net_t])
603
e3438006
BP		 604 OVS_GREP_IFELSE([$KSRC/include/linux/rcupdate.h], [rcu_read_lock_held], [],
605 [OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h],
cf6cb3a2 606 [rcu_read_lock_held])])
8fa52250 607 OVS_GREP_IFELSE([$KSRC/include/linux/rtnetlink.h], [lockdep_rtnl_is_held])
997d327d 608
6a33828d
BP		 609 # Check for the proto_data_valid member in struct sk_buff. The [^@]
610 # is necessary because some versions of this header remove the
611 # member but retain the kerneldoc comment that describes it (which
612 # starts with @). The brackets must be doubled because of m4
613 # quoting rules.
e3438006 614 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [[[^@]]proto_data_valid],
6a33828d 615 [OVS_DEFINE([HAVE_PROTO_DATA_VALID])])
ccb75a28 616 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_checksum_start_offset])
e23775f2 617 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol])
f2252c61 618 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [inner_protocol_type])
c1eb2500 619 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_inner_transport_offset])
d23239a2 620 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [kfree_skb_list])
60c4904f 621 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [rxhash])
5640cbd8
JG		 622 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u16.*rxhash],
623 [OVS_DEFINE([HAVE_U16_RXHASH])])
e3438006 624 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_dst(],
85444c3f 625 [OVS_DEFINE([HAVE_SKB_DST_ACCESSOR_FUNCS])])
997d327d 626 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
8828e5c7 627 [skb_copy_from_linear_data_offset])
b9c15df9
PS		 628 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h],
629 [skb_reset_tail_pointer])
e3438006 630 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_cow_head])
e3438006 631 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_warn_if_lro],
4aa13c0c 632 [OVS_DEFINE([HAVE_SKB_WARN_LRO])])
e3438006 633 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [consume_skb])
6c4ea27c 634 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_frag_page])
da4bbeb7 635 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_has_frag_list])
0aa6fda7 636 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_fill_page_desc])
d923a695 637 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_reset_mac_len])
dc0d542d 638 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_unclone])
1edc458d 639 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_orphan_frags])
c253c2e3
MC		 640 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_get_hash(],
641 [OVS_DEFINE([HAVE_SKB_GET_HASH])])
e2f3178f 642 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash])
705e9260
PS		 643 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [int.skb_zerocopy(],
644 [OVS_DEFINE([HAVE_SKB_ZEROCOPY])])
75e93287
FL		 645 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [u8.*l4_rxhash],
646 [OVS_DEFINE([HAVE_L4_RXHASH])])
5cce04b6 647 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_ensure_writable])
97894370 648 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_pop])
a27c454e 649 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [__skb_vlan_pop])
97894370 650 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_vlan_push])
c6e13fcc 651 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_clear_hash_if_not_l4])
ea3acd7a 652 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_postpush_rcsum])
73daf51a 653 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [lco_csum])
d3c313c1 654 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [skb_nfct])
4aa13c0c 655
e3438006 656 OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [bool],
4aa13c0c 657 [OVS_DEFINE([HAVE_BOOL_TYPE])])
e3438006 658 OVS_GREP_IFELSE([$KSRC/include/linux/types.h], [__wsum],
e215ebca 659 [OVS_DEFINE([HAVE_CSUM_TYPES])])
8dbe1f9f
PS		 660 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/types.h], [__wsum],
661 [OVS_DEFINE([HAVE_CSUM_TYPES])])
4aa13c0c 662
e3438006
BP		 663 OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_replace4])
664 OVS_GREP_IFELSE([$KSRC/include/net/checksum.h], [csum_unfold])
4aa13c0c 665
0d03e51c 666 OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [dst_discard_sk])
1dba1690 667 OVS_GREP_IFELSE([$KSRC/include/net/dst.h], [__skb_dst_copy])
0d03e51c 668
114fce23
SG		 669 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_has_listeners])
670 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [mcgrp_offset])
14002a59 671 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [parallel_ops])
6233a1bd
TG		 672 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [netlink_has_listeners(net->genl_sock],
673 [OVS_DEFINE([HAVE_GENL_HAS_LISTENERS_TAKES_NET])])
c623ba49 674 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genlmsg_parse])
13dd4a97
JS		 675 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [genl_notify.*family],
676 [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_FAMILY])])
0643a78b
PS		 677 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/genetlink.h],
678 [genl_notify], [net],
679 [OVS_DEFINE([HAVE_GENL_NOTIFY_TAKES_NET])])
680
13dd4a97
JS		 681
682 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/genetlink.h],
683 [genl_multicast_group], [id])
fdce83a3 684 OVS_GREP_IFELSE([$KSRC/include/net/geneve.h], [geneve_hdr])
13dd4a97 685
cc1d0dea 686 OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_cisco_register])
e23775f2 687 OVS_GREP_IFELSE([$KSRC/include/net/gre.h], [gre_handle_offloads])
8abaa53c 688 OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [IP6_FH_F_SKIP_RH])
e23775f2 689 OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [ip6_local_out_sk])
2d3ef70b 690 OVS_GREP_IFELSE([$KSRC/include/net/ipv6.h], [__ipv6_addr_jhash])
a94ebc39
JS		 691 OVS_GREP_IFELSE([$KSRC/include/net/ip6_fib.h], [rt6i.*u.dst],
692 [OVS_DEFINE([HAVE_RT6INFO_DST_UNION])])
213e1f54
JS		 693 OVS_GREP_IFELSE([$KSRC/include/net/ip6_route.h], [ip6_frag.*sock],
694 [OVS_DEFINE([HAVE_IP_FRAGMENT_TAKES_SOCK])])
695
91b37647 696 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_64bit])
e3438006 697 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_get_be16])
42d5dd95
TG		 698 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be16])
699 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be32])
700 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_be64])
dd693f9b 701 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_put_in_addr])
e3438006 702 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_find_nested])
0fcc086d 703 OVS_GREP_IFELSE([$KSRC/include/net/netlink.h], [nla_is_last])
6dbd98e6
SH		 704 OVS_GREP_IFELSE([$KSRC/include/linux/netlink.h], [void.*netlink_set_err],
705 [OVS_DEFINE([HAVE_VOID_NETLINK_SET_ERR])])
15702dc9
JB		 706 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netlink.h],
707 [nla_parse], [netlink_ext_ack],
708 [OVS_DEFINE([HAVE_NETLINK_EXT_ACK])])
4aa13c0c 709
c4e976db
JG		 710 OVS_GREP_IFELSE([$KSRC/include/net/sctp/checksum.h], [sctp_compute_cksum])
711
e3438006 712 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [ADD_ALL_VLANS_CMD],
431488e6 713 [OVS_DEFINE([HAVE_VLAN_BUG_WORKAROUND])])
1f649f1c 714 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_insert_tag_set_proto])
17e3889f 715 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [__vlan_insert_tag])
e23775f2 716 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [vlan_get_protocol])
5c3f23fe 717 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [skb_vlan_tagged])
ca6da1b1 718 OVS_GREP_IFELSE([$KSRC/include/linux/if_vlan.h], [eth_type_vlan])
431488e6 719
09f27436
JG		 720 OVS_GREP_IFELSE([$KSRC/include/linux/u64_stats_sync.h], [u64_stats_fetch_begin_irq])
721
3174a818
TG		 722 OVS_GREP_IFELSE([$KSRC/include/net/vxlan.h], [struct vxlan_metadata],
723 [OVS_DEFINE([HAVE_VXLAN_METADATA])])
f6a0c895 724 OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_flow_src_port],
13dd4a97
JS		 725 [OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [inet_get_local_port_range(net],
726 [OVS_DEFINE([HAVE_UDP_FLOW_SRC_PORT])])])
727 OVS_GREP_IFELSE([$KSRC/include/net/udp.h], [udp_v4_check])
e23775f2 728 OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_gro_complete])
06aeda48
PS		 729 OVS_GREP_IFELSE([$KSRC/include/net/udp_tunnel.h], [sk_buff.*udp_tunnel_handle_offloads],
730 [OVS_DEFINE([HAVE_UDP_TUNNEL_HANDLE_OFFLOAD_RET_SKB])])
d7e58913
PS		 731 OVS_FIND_FIELD_IFELSE([$KSRC/include/net/udp_tunnel.h], [udp_tunnel_sock_cfg],
732 [gro_receive])
e23775f2
PS		 733
734 OVS_GREP_IFELSE([$KSRC/include/linux/skbuff.h], [ignore_df],
f6a0c895
TG		 735 [OVS_DEFINE([HAVE_IGNORE_DF_RENAME])])
736 OVS_GREP_IFELSE([$KSRC/include/uapi/linux/netdevice.h], [NET_NAME_UNKNOWN],
737 [OVS_DEFINE([HAVE_NET_NAME_UNKNOWN])])
f285d3e7 738
b7ebebcd
PS		 739 OVS_GREP_IFELSE([$KSRC/include/net/sock.h], [sk_no_check_tx])
740 OVS_GREP_IFELSE([$KSRC/include/linux/udp.h], [no_check6_tx])
21a719d6
FL		 741 OVS_GREP_IFELSE([$KSRC/include/linux/utsrelease.h], [el6],
742 [OVS_DEFINE([HAVE_RHEL6_PER_CPU])])
c970aa4e
PS		 743 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/protocol.h],
744 [udp_add_offload], [net],
745 [OVS_DEFINE([HAVE_UDP_ADD_OFFLOAD_TAKES_NET])])
802d12b6
GR		 746 OVS_FIND_PARAM_IFELSE([$KSRC/include/net/netfilter/ipv6/nf_defrag_ipv6.h],
747 [nf_defrag_ipv6_enable], [net],
748 [OVS_DEFINE([HAVE_DEFRAG_ENABLE_TAKES_NET])])
bef862bc
GR		 749 OVS_GREP_IFELSE([$KSRC/include/net/genetlink.h], [family_list],
750 [OVS_DEFINE([HAVE_GENL_FAMILY_LIST])])
ac8e3c6d
GR		 751 OVS_GREP_IFELSE([$KSRC/include/net/netfilter/nf_conntrack_helper.h],
752 [nf_conntrack_helper_put])
21a719d6 753
22bcc0e7
JG		 754 if cmp -s datapath/linux/kcompat.h.new \
755 datapath/linux/kcompat.h >/dev/null 2>&1; then
756 rm datapath/linux/kcompat.h.new
064af421 757 else
22bcc0e7 758 mv datapath/linux/kcompat.h.new datapath/linux/kcompat.h
064af421
BP		 759 fi
760])
761
762dnl Checks for net/if_packet.h.
763AC_DEFUN([OVS_CHECK_IF_PACKET],
764 [AC_CHECK_HEADER([net/if_packet.h],
765 [HAVE_IF_PACKET=yes],
766 [HAVE_IF_PACKET=no])
767 AM_CONDITIONAL([HAVE_IF_PACKET], [test "$HAVE_IF_PACKET" = yes])
768 if test "$HAVE_IF_PACKET" = yes; then
769 AC_DEFINE([HAVE_IF_PACKET], [1],
770 [Define to 1 if net/if_packet.h is available.])
771 fi])
772
f6eb6b20 773dnl Checks for net/if_dl.h.
d30e714c 774dnl
d23fa2ed
YT		 775dnl (We use this as a proxy for checking whether we're building on FreeBSD
776dnl or NetBSD.)
9360d9b7
EM		 777AC_DEFUN([OVS_CHECK_IF_DL],
778 [AC_CHECK_HEADER([net/if_dl.h],
779 [HAVE_IF_DL=yes],
780 [HAVE_IF_DL=no])
781 AM_CONDITIONAL([HAVE_IF_DL], [test "$HAVE_IF_DL" = yes])
782 if test "$HAVE_IF_DL" = yes; then
783 AC_DEFINE([HAVE_IF_DL], [1],
784 [Define to 1 if net/if_dl.h is available.])
d30e714c 785
d23fa2ed 786 # On these platforms we use libpcap to access network devices.
d30e714c 787 AC_SEARCH_LIBS([pcap_open_live], [pcap])
9360d9b7
EM		 788 fi])
789
e50097d2
BP		 790dnl Checks for buggy strtok_r.
791dnl
792dnl Some versions of glibc 2.7 has a bug in strtok_r when compiling
793dnl with optimization that can cause segfaults:
794dnl
795dnl http://sources.redhat.com/bugzilla/show_bug.cgi?id=5614.
796AC_DEFUN([OVS_CHECK_STRTOK_R],
797 [AC_CACHE_CHECK(
798 [whether strtok_r macro segfaults on some inputs],
799 [ovs_cv_strtok_r_bug],
800 [AC_RUN_IFELSE(
801 [AC_LANG_PROGRAM([#include <stdio.h>
802 #include <string.h>
803 ],
416e7132
BP		 804 [[#if __GLIBC__ == 2 && __GLIBC_MINOR__ < 8
805 /* Assume bug is present, because relatively minor
806 changes in compiler settings (e.g. optimization
807 level) can make it crop up. */
808 return 1;
809 #else
810 char string[] = ":::";
e50097d2
BP		 811 char *save_ptr = (char *) 0xc0ffee;
812 char *token1, *token2;
813 token1 = strtok_r(string, ":", &save_ptr);
814 token2 = strtok_r(NULL, ":", &save_ptr);
5819a7cd 815 freopen ("/dev/null", "w", stdout);
e50097d2
BP		 816 printf ("%s %s\n", token1, token2);
817 return 0;
416e7132 818 #endif
e50097d2
BP		 819 ]])],
820 [ovs_cv_strtok_r_bug=no],
821 [ovs_cv_strtok_r_bug=yes],
822 [ovs_cv_strtok_r_bug=yes])])
823 if test $ovs_cv_strtok_r_bug = yes; then
824 AC_DEFINE([HAVE_STRTOK_R_BUG], [1],
825 [Define if strtok_r macro segfaults on some inputs])
826 fi
827])
828
064af421
BP		 829dnl ----------------------------------------------------------------------
830dnl These macros are from GNU PSPP, with the following original license:
831dnl Copyright (C) 2005, 2006, 2007 Free Software Foundation, Inc.
832dnl This file is free software; the Free Software Foundation
833dnl gives unlimited permission to copy and/or distribute it,
834dnl with or without modifications, as long as this notice is preserved.
835
50194820 836AC_DEFUN([_OVS_CHECK_CC_OPTION], [dnl
726af752 837 m4_define([ovs_cv_name], [ovs_cv_[]m4_translit([$1], [-= ], [__])])dnl
064af421
BP		 838 AC_CACHE_CHECK([whether $CC accepts $1], [ovs_cv_name],
839 [ovs_save_CFLAGS="$CFLAGS"
50194820
BP		 840 dnl Include -Werror in the compiler options, because without -Werror
841 dnl clang's GCC-compatible compiler driver does not return a failure
842 dnl exit status even though it complains about options it does not
843 dnl understand.
c2deac54
YT		 844 dnl
845 dnl Also, check stderr as gcc exits with status 0 for options
846 dnl rejected at getopt level.
847 dnl % touch /tmp/a.c
848 dnl % gcc -g -c -Werror -Qunused-arguments /tmp/a.c; echo $?
849 dnl gcc: unrecognized option '-Qunused-arguments'
850 dnl 0
851 dnl %
50194820 852 CFLAGS="$CFLAGS $WERROR $1"
37f4615e
BP		 853 AC_COMPILE_IFELSE(
854 [AC_LANG_SOURCE([int x;])],
855 [if test -s conftest.err && grep "unrecognized option" conftest.err
856 then
857 ovs_cv_name[]=no
858 else
859 ovs_cv_name[]=yes
860 fi],
861 [ovs_cv_name[]=no])
064af421
BP		 862 CFLAGS="$ovs_save_CFLAGS"])
863 if test $ovs_cv_name = yes; then
83f6c050 864 m4_if([$2], [], [:], [$2])
064af421
BP		 865 else
866 m4_if([$3], [], [:], [$3])
867 fi
868])
869
50194820
BP		 870dnl OVS_CHECK_WERROR
871dnl
872dnl Check whether the C compiler accepts -Werror.
873dnl Sets $WERROR to "-Werror", if so, and otherwise to the empty string.
874AC_DEFUN([OVS_CHECK_WERROR],
875 [WERROR=
876 _OVS_CHECK_CC_OPTION([-Werror], [WERROR=-Werror])])
877
878dnl OVS_CHECK_CC_OPTION([OPTION], [ACTION-IF-ACCEPTED], [ACTION-IF-REJECTED])
879dnl Check whether the given C compiler OPTION is accepted.
880dnl If so, execute ACTION-IF-ACCEPTED, otherwise ACTION-IF-REJECTED.
881AC_DEFUN([OVS_CHECK_CC_OPTION],
882 [AC_REQUIRE([OVS_CHECK_WERROR])
883 _OVS_CHECK_CC_OPTION([$1], [$2], [$3])])
884
064af421
BP		 885dnl OVS_ENABLE_OPTION([OPTION])
886dnl Check whether the given C compiler OPTION is accepted.
d161c099 887dnl If so, add it to WARNING_FLAGS.
064af421
BP		 888dnl Example: OVS_ENABLE_OPTION([-Wdeclaration-after-statement])
889AC_DEFUN([OVS_ENABLE_OPTION],
d161c099
BP		 890 [OVS_CHECK_CC_OPTION([$1], [WARNING_FLAGS="$WARNING_FLAGS $1"])
891 AC_SUBST([WARNING_FLAGS])])
c72e245a
BP		 892
893dnl OVS_CONDITIONAL_CC_OPTION([OPTION], [CONDITIONAL])
894dnl Check whether the given C compiler OPTION is accepted.
895dnl If so, enable the given Automake CONDITIONAL.
896
897dnl Example: OVS_CONDITIONAL_CC_OPTION([-Wno-unused], [HAVE_WNO_UNUSED])
898AC_DEFUN([OVS_CONDITIONAL_CC_OPTION],
899 [OVS_CHECK_CC_OPTION(
900 [$1], [ovs_have_cc_option=yes], [ovs_have_cc_option=no])
901 AM_CONDITIONAL([$2], [test $ovs_have_cc_option = yes])])
064af421 902dnl ----------------------------------------------------------------------
ed2d4f6a
BP		 903
904dnl Check for too-old XenServer.
905AC_DEFUN([OVS_CHECK_XENSERVER_VERSION],
906 [AC_CACHE_CHECK([XenServer release], [ovs_cv_xsversion],
907 [if test -e /etc/redhat-release; then
908 ovs_cv_xsversion=`sed -n 's/^XenServer DDK release \([[^-]]*\)-.*/\1/p' /etc/redhat-release`
909 fi
910 if test -z "$ovs_cv_xsversion"; then
911 ovs_cv_xsversion=none
912 fi])
913 case $ovs_cv_xsversion in
914 none)
915 ;;
916
917 [[1-9]][[0-9]]* | dnl XenServer 10 or later
918 [[6-9]]* | dnl XenServer 6 or later
919 5.[[7-9]]* | dnl XenServer 5.7 or later
920 5.6.[[1-9]][[0-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.1000 or later
921 5.6.[[2-9]][[0-9]][[0-9]]* | dnl XenServer 5.6.200 or later
922 5.6.1[[0-9]][[0-9]]) dnl Xenserver 5.6.100 or later
923 ;;
924
925 *)
926 AC_MSG_ERROR([This appears to be XenServer $ovs_cv_xsversion, but only XenServer 5.6.100 or later is supported. (If you are really using a supported version of XenServer, you may override this error message by specifying 'ovs_cv_xsversion=5.6.100' on the "configure" command line.)])
927 ;;
928 esac])
29d935d6 929
643c0c34
BP		 930dnl OVS_CHECK_SPARSE_TARGET
931dnl
932dnl The "cgcc" script from "sparse" isn't very good at detecting the
933dnl target for which the code is being built. This helps it out.
934AC_DEFUN([OVS_CHECK_SPARSE_TARGET],
935 [AC_CACHE_CHECK(
936 [target hint for cgcc],
937 [ac_cv_sparse_target],
938 [AS_CASE([`$CC -dumpmachine 2>/dev/null`],
939 [i?86-* | athlon-*], [ac_cv_sparse_target=x86],
940 [x86_64-*], [ac_cv_sparse_target=x86_64],
941 [ac_cv_sparse_target=other])])
942 AS_CASE([$ac_cv_sparse_target],
943 [x86], [SPARSEFLAGS= CGCCFLAGS=-target=i86],
944 [x86_64], [SPARSEFLAGS=-m64 CGCCFLAGS=-target=x86_64],
945 [SPARSEFLAGS= CGCCFLAGS=])
946 AC_SUBST([SPARSEFLAGS])
947 AC_SUBST([CGCCFLAGS])])
948
32e96ab7
AZ		 949dnl OVS_SPARSE_EXTRA_INCLUDES
950dnl
951dnl The cgcc script from "sparse" does not search gcc's default
952dnl search path. Get the default search path from GCC and pass
953dnl them to sparse.
954AC_DEFUN([OVS_SPARSE_EXTRA_INCLUDES],
955 AC_SUBST([SPARSE_EXTRA_INCLUDES],
956 [`$CC -v -E - </dev/null 2>&1 >/dev/null | sed -n -e '/^#include.*search.*starts.*here:/,/^End.*of.*search.*list\./s/^ \(.*\)/-I \1/p' |grep -v /usr/lib | grep -x -v '\-I /usr/include' | tr \\\n ' ' `] ))
957
29d935d6
BP		 958dnl OVS_ENABLE_SPARSE
959AC_DEFUN([OVS_ENABLE_SPARSE],
643c0c34 960 [AC_REQUIRE([OVS_CHECK_SPARSE_TARGET])
32e96ab7 961 AC_REQUIRE([OVS_SPARSE_EXTRA_INCLUDES])
372d58a4
BP		 962 : ${SPARSE=sparse}
963 AC_SUBST([SPARSE])
964 AC_CONFIG_COMMANDS_PRE(
344f6253 965 [CC='$(if $(C),env REAL_CC="'"$CC"'" CHECK="$(SPARSE) -I $(top_srcdir)/include/sparse $(SPARSEFLAGS) $(SPARSE_EXTRA_INCLUDES) " cgcc $(CGCCFLAGS),'"$CC"')'])])
8a8cd0ac 966
0eaaacac
FL		 967dnl OVS_CTAGS_IDENTIFIERS
968dnl
969dnl ctags ignores symbols with extras identifiers. This builds a list of
970dnl specially handled identifiers to be ignored.
971AC_DEFUN([OVS_CTAGS_IDENTIFIERS],
972 AC_SUBST([OVS_CTAGS_IDENTIFIERS_LIST],
c9990318 973 [`printf %s '-I "'; sed -n 's/^#define \(OVS_[A-Z_]\+\)(\.\.\.)$/\1+/p' ${srcdir}/include/openvswitch/compiler.h | tr \\\n ' ' ; printf '"'`] ))
0eaaacac 974
8a8cd0ac
BP		 975dnl OVS_PTHREAD_SET_NAME
976dnl
977dnl This checks for three known variants of pthreads functions for setting
978dnl the name of the current thread:
979dnl
980dnl glibc: int pthread_setname_np(pthread_t, const char *name);
981dnl NetBSD: int pthread_setname_np(pthread_t, const char *format, void *arg);
982dnl FreeBSD: int pthread_set_name_np(pthread_t, const char *name);
983dnl
984dnl For glibc and FreeBSD, the arguments are just a thread and its name. For
985dnl NetBSD, 'format' is a printf() format string and 'arg' is an argument to
986dnl provide to it.
987dnl
988dnl This macro defines:
989dnl
990dnl glibc: HAVE_GLIBC_PTHREAD_SETNAME_NP
991dnl NetBSD: HAVE_NETBSD_PTHREAD_SETNAME_NP
992dnl FreeBSD: HAVE_PTHREAD_SET_NAME_NP
993AC_DEFUN([OVS_CHECK_PTHREAD_SET_NAME],
994 [AC_CHECK_FUNCS([pthread_set_name_np])
995 if test $ac_cv_func_pthread_set_name_np != yes; then
996 AC_CACHE_CHECK(
997 [for pthread_setname_np() variant],
998 [ovs_cv_pthread_setname_np],
999 [AC_LINK_IFELSE(
a0903134 1000 [AC_LANG_PROGRAM([#include <pthread.h>
8a8cd0ac 1001 ], [pthread_setname_np(pthread_self(), "name");])],
a0903134 1002 [ovs_cv_pthread_setname_np=glibc],
8a8cd0ac 1003 [AC_LINK_IFELSE(
a0903134 1004 [AC_LANG_PROGRAM([#include <pthread.h>
8a8cd0ac
BP		 1005], [pthread_setname_np(pthread_self(), "%s", "name");])],
1006 [ovs_cv_pthread_setname_np=netbsd],
a0903134 1007 [ovs_cv_pthread_setname_np=none])])])
8a8cd0ac
BP		 1008 case $ovs_cv_pthread_setname_np in # (
1009 glibc)
a0903134
YT		 1010 AC_DEFINE(
1011 [HAVE_GLIBC_PTHREAD_SETNAME_NP], [1],
1012 [Define to 1 if pthread_setname_np() is available and takes 2 parameters (like glibc).])
1013 ;; # (
8a8cd0ac 1014 netbsd)
a0903134
YT		 1015 AC_DEFINE(
1016 [HAVE_NETBSD_PTHREAD_SETNAME_NP], [1],
1017 [Define to 1 if pthread_setname_np() is available and takes 3 parameters (like NetBSD).])
1018 ;;
8a8cd0ac
BP		 1019 esac
1020 fi])
5020f5f0
BP		 1021
1022dnl OVS_CHECK_LINUX_HOST.
1023dnl
1024dnl Checks whether we're building for a Linux host, based on the presence of
1025dnl the __linux__ preprocessor symbol, and sets up an Automake conditional
1026dnl LINUX based on the result.
1027AC_DEFUN([OVS_CHECK_LINUX_HOST],
1028 [AC_CACHE_CHECK(
1029 [whether __linux__ is defined],
1030 [ovs_cv_linux],
1031 [AC_COMPILE_IFELSE(
1032 [AC_LANG_PROGRAM([enum { LINUX = __linux__};], [])],
1033 [ovs_cv_linux=true],
1034 [ovs_cv_linux=false])])
1035 AM_CONDITIONAL([LINUX], [$ovs_cv_linux])])
openvswitch mirror